qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/items/items.qh>
  10 #include <client/mapvoting.qh>
  11 #include <client/mutators/_mod.qh>
  12 #include <client/shownames.qh>
  13 #include <client/view.qh>
  14 #include <client/weapons/projectile.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/effects/all.inc>
  17 #include <common/effects/all.qh>
  18 #include <common/effects/effect.qh>
  19 #include <common/effects/qc/_mod.qh>
  20 #include <common/ent_cs.qh>
  21 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/mapobjects/_mod.qh>
  25 #include <common/minigames/cl_minigames.qh>
  26 #include <common/minigames/cl_minigames_hud.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/scores.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  42 // Useful for precaching things
  43
  44 void CSQC_Init()
  45 {
  46         prvm_language = strzone(cvar_string("prvm_language"));
  47
  48 #ifdef WATERMARK
  49         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  50 #endif
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         // needs to be done so early because of the constants they create
  61         static_init();
  62         static_init_late();
  63         static_init_precache();
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68
  69         draw_endBoldFont();
  70
  71         //registercommand("hud_configure");
  72         //registercommand("hud_save");
  73         //registercommand("menu_action");
  74
  75         ConsoleCommand_macro_init();
  76
  77         registercvar("hud_usecsqc", "1");
  78         registercvar("scoreboard_columns", "default");
  79
  80         registercvar("cl_nade_type", "3");
  81         registercvar("cl_pokenade_type", "zombie");
  82
  83         registercvar("cl_jumpspeedcap_min", "");
  84         registercvar("cl_jumpspeedcap_max", "");
  85
  86         registercvar("cl_shootfromfixedorigin", "");
  87
  88         registercvar("cl_multijump", "-1");
  89
  90         registercvar("cl_dodging", "0");
  91
  92         registercvar("cl_spawn_near_teammate", "1");
  93
  94         registercvar("cl_weapon_switch_reload", "1");
  95         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  96
  97         registercvar("cl_allow_uidranking", "1");
  98
  99         if(autocvar_cl_lockview)
 100                 cvar_set("cl_lockview", "0");
 101
 102         gametype = NULL;
 103
 104         postinit = false;
 105
 106         calledhooks = 0;
 107
 108         teams = Sort_Spawn();
 109         players = Sort_Spawn();
 110
 111         GetTeam(NUM_SPECTATOR, true); // add specs first
 112
 113         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 114                 weapon_accuracy[w] = -1;
 115
 116         // precaches
 117
 118         if(autocvar_cl_reticle)
 119         {
 120                 precache_pic("gfx/reticle_normal");
 121                 // weapon reticles are precached in weapon files
 122         }
 123
 124         {
 125                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 126                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 127                 shortmapname = mi_shortname;
 128
 129                 if (precache_pic(minimapname) == "")
 130                 {
 131                         // but maybe we have a non-clever minimap
 132                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 133                         if (precache_pic(minimapname) == "")
 134                                 minimapname = ""; // FAIL
 135                         else
 136                                 get_mi_min_max_texcoords(0); // load new texcoords
 137                 }
 138
 139                 mi_center = (mi_min + mi_max) * 0.5;
 140                 mi_scale = mi_max - mi_min;
 141                 minimapname = strzone(minimapname);
 142         }
 143
 144         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 145         LoadMenuSkinValues();
 146 }
 147
 148 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 149 void Shutdown()
 150 {
 151         WarpZone_Shutdown();
 152
 153         delete(teams);
 154         delete(players);
 155         db_close(binddb);
 156         db_close(tempdb);
 157         if(autocvar_cl_db_saveasdump)
 158                 db_dump(ClientProgsDB, "client.db");
 159         else
 160                 db_save(ClientProgsDB, "client.db");
 161         db_close(ClientProgsDB);
 162
 163         if(camera_active)
 164                 cvar_set("chase_active",ftos(chase_active_backup));
 165
 166         // unset the event chasecam's chase_active
 167         if(autocvar_chase_active < 0)
 168                 cvar_set("chase_active", "0");
 169
 170         if (autocvar_r_drawviewmodel < 0)
 171                 cvar_set("r_drawviewmodel", "0");
 172
 173         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 174
 175         if (!isdemo())
 176         {
 177                 if (!(calledhooks & HOOK_START))
 178                         localcmd("\n_cl_hook_gamestart nop\n");
 179                 if (!(calledhooks & HOOK_END))
 180                         localcmd("\ncl_hook_gameend\n");
 181         }
 182
 183         localcmd("\ncl_hook_shutdown\n");
 184
 185         localcmd("\n-button12\n");
 186
 187         deactivate_minigame();
 188         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 189
 190         ReplicateVars(true); // destroy
 191 }
 192
 193 void AuditLists()
 194 {
 195         entity e;
 196         entity prev;
 197
 198         prev = players;
 199         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 200         {
 201                 if(prev != e.sort_prev)
 202                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 203         }
 204
 205         prev = teams;
 206         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 207         {
 208                 if(prev != e.sort_prev)
 209                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 210         }
 211 }
 212
 213 float RegisterPlayer(entity player)
 214 {
 215         entity pl;
 216         AuditLists();
 217         for(pl = players.sort_next; pl; pl = pl.sort_next)
 218                 if(pl == player)
 219                         error("Player already registered!");
 220         player.sort_next = players.sort_next;
 221         player.sort_prev = players;
 222         if(players.sort_next)
 223                 players.sort_next.sort_prev = player;
 224         players.sort_next = player;
 225         AuditLists();
 226         return true;
 227 }
 228
 229 void RemovePlayer(entity player)
 230 {
 231         entity pl, parent;
 232         AuditLists();
 233         parent = players;
 234         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 235                 parent = pl;
 236
 237         if(!pl)
 238         {
 239                 error("Trying to remove a player which is not in the playerlist!");
 240                 return;
 241         }
 242         parent.sort_next = player.sort_next;
 243         if(player.sort_next)
 244                 player.sort_next.sort_prev = parent;
 245         AuditLists();
 246 }
 247
 248 void MoveToLast(entity e)
 249 {
 250         AuditLists();
 251         entity ent = e.sort_next;
 252         while(ent)
 253         {
 254                 SORT_SWAP(ent, e);
 255                 ent = e.sort_next;
 256         }
 257         AuditLists();
 258 }
 259
 260 float RegisterTeam(entity Team)
 261 {
 262         assert_once(Team.team, eprint(Team));
 263         entity tm;
 264         AuditLists();
 265         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 266                 if(tm == Team)
 267                         error("Team already registered!");
 268         Team.sort_next = teams.sort_next;
 269         Team.sort_prev = teams;
 270         if(teams.sort_next)
 271                 teams.sort_next.sort_prev = Team;
 272         teams.sort_next = Team;
 273         if(Team.team && Team.team != NUM_SPECTATOR)
 274                 ++team_count;
 275         AuditLists();
 276         return true;
 277 }
 278
 279 void RemoveTeam(entity Team)
 280 {
 281         entity tm, parent;
 282         AuditLists();
 283         parent = teams;
 284         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 285                 parent = tm;
 286
 287         if(!tm)
 288         {
 289                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 290                 return;
 291         }
 292         parent.sort_next = Team.sort_next;
 293         if(Team.sort_next)
 294                 Team.sort_next.sort_prev = parent;
 295         if(Team.team && Team.team != NUM_SPECTATOR)
 296                 --team_count;
 297         AuditLists();
 298 }
 299
 300 entity GetTeam(int Team, bool add)
 301 {
 302         TC(int, Team); TC(bool, add);
 303         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 304         if(teamslots[num])
 305                 return teamslots[num];
 306         if (!add)
 307                 return NULL;
 308         entity tm = new_pure(team);
 309         tm.team = Team;
 310         teamslots[num] = tm;
 311         RegisterTeam(tm);
 312         return tm;
 313 }
 314
 315 .float has_team;
 316 bool SetTeam(entity o, int Team)
 317 {
 318         TC(int, Team);
 319         //devassert_once(Team);
 320         entity tm;
 321         if(teamplay)
 322         {
 323                 switch(Team)
 324                 {
 325                         case -1:
 326                         case NUM_TEAM_1:
 327                         case NUM_TEAM_2:
 328                         case NUM_TEAM_3:
 329                         case NUM_TEAM_4:
 330                                 break;
 331                         default:
 332                                 if(GetTeam(Team, false) == NULL)
 333                                 {
 334                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 335                                         Team = NUM_SPECTATOR;
 336                                 }
 337                                 break;
 338                 }
 339         }
 340         else
 341         {
 342                 switch(Team)
 343                 {
 344                         case -1:
 345                         case 0:
 346                                 break;
 347                         default:
 348                                 if(GetTeam(Team, false) == NULL)
 349                                 {
 350                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 351                                         Team = NUM_SPECTATOR;
 352                                 }
 353                                 break;
 354                 }
 355         }
 356         if(Team == -1) // leave
 357         {
 358                 if(o.has_team)
 359                 {
 360                         tm = GetTeam(o.team, false);
 361                         tm.team_size -= 1;
 362                         o.has_team = 0;
 363                         return true;
 364                 }
 365         }
 366         else
 367         {
 368                 if (!o.has_team)
 369                 {
 370                         o.team = Team;
 371                         tm = GetTeam(Team, true);
 372                         tm.team_size += 1;
 373                         o.has_team = 1;
 374                         return true;
 375                 }
 376                 else if(Team != o.team)
 377                 {
 378                         tm = GetTeam(o.team, false);
 379                         tm.team_size -= 1;
 380                         o.team = Team;
 381                         tm = GetTeam(Team, true);
 382                         tm.team_size += 1;
 383                         return true;
 384                 }
 385         }
 386         return false;
 387 }
 388
 389 void Playerchecker_Think(entity this)
 390 {
 391         int i;
 392         entity e;
 393         for(i = 0; i < maxclients; ++i)
 394         {
 395                 e = playerslots[i];
 396                 if(entcs_GetName(i) == "")
 397                 {
 398                         if(e.sort_prev)
 399                         {
 400                                 // player disconnected
 401                                 SetTeam(e, -1);
 402                                 RemovePlayer(e);
 403                                 e.sort_prev = NULL;
 404                                 //e.gotscores = 0;
 405                         }
 406                 }
 407                 else
 408                 {
 409                         if (!e.sort_prev)
 410                         {
 411                                 // player connected
 412                                 if (!e)
 413                                 {
 414                                         playerslots[i] = e = new_pure(playerslot);
 415                                 }
 416                                 e.sv_entnum = i;
 417                                 e.ping = 0;
 418                                 e.ping_packetloss = 0;
 419                                 e.ping_movementloss = 0;
 420                                 //e.gotscores = 0; // we might already have the scores...
 421                                 int t = entcs_GetScoreTeam(i);
 422                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 423                                 RegisterPlayer(e);
 424                                 Scoreboard_UpdatePlayerPos(e);
 425                         }
 426                 }
 427         }
 428         this.nextthink = time + 0.2;
 429 }
 430
 431 void PostInit()
 432 {
 433         entity playerchecker = new_pure(playerchecker);
 434         setthink(playerchecker, Playerchecker_Think);
 435         playerchecker.nextthink = time + 0.2;
 436
 437         TrueAim_Init();
 438
 439         postinit = true;
 440 }
 441
 442 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 443 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 444 // All keys are in ascii.
 445 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 446 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 447 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 448 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 449 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 450 {
 451         TC(int, bInputType);
 452         bool override = false;
 453         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 454         if (override)
 455                 return true;
 456
 457         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 458
 459         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 460
 461         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 462
 463         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 464
 465         if(override)
 466                 return true;
 467
 468         return false;
 469 }
 470
 471 // END REQUIRED CSQC FUNCTIONS
 472 // --------------------------------------------------------------------------
 473
 474 // --------------------------------------------------------------------------
 475 // BEGIN OPTIONAL CSQC FUNCTIONS
 476
 477 void Ent_RemovePlayerScore(entity this)
 478 {
 479         if(this.owner) {
 480                 SetTeam(this.owner, -1);
 481                 this.owner.gotscores = 0;
 482                 FOREACH(Scores, true, {
 483                         this.owner.(scores(it)) = 0; // clear all scores
 484                 });
 485         }
 486 }
 487
 488 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 489 {
 490         make_pure(this);
 491         entity o;
 492
 493         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 494         // (no I've never heard of M-x replace-string, sed, or anything like that)
 495         bool isNew = !this.owner; // workaround for DP bug
 496         int n = ReadByte()-1;
 497
 498 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 499         if(!isNew && n != this.sv_entnum)
 500         {
 501                 //print("A CSQC entity changed its owner!\n");
 502                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 503                 isNew = true;
 504                 Ent_Remove(this);
 505         }
 506 #endif
 507
 508         this.sv_entnum = n;
 509
 510         o = playerslots[this.sv_entnum];
 511         if (!o)
 512         {
 513                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 514         }
 515         this.owner = o;
 516         o.sv_entnum = this.sv_entnum;
 517         o.gotscores = 1;
 518
 519         //if (!o.sort_prev)
 520         //      RegisterPlayer(o);
 521         //playerchecker will do this for us later, if it has not already done so
 522
 523         int sf = ReadShort();
 524         int lf = ReadShort();
 525         FOREACH(Scores, true, {
 526                 int p = 1 << (i % 16);
 527                 if (sf & p)
 528                 {
 529                         if (lf & p)
 530                                 o.(scores(it)) = ReadInt24_t();
 531                         else
 532                                 o.(scores(it)) = ReadChar();
 533                 }
 534         });
 535
 536         return = true;
 537
 538         if(o.sort_prev)
 539                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 540
 541         this.entremove = Ent_RemovePlayerScore;
 542 }
 543
 544 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 545 {
 546         make_pure(this);
 547         int i;
 548
 549         this.team = ReadByte();
 550         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 551
 552 #if MAX_TEAMSCORE <= 8
 553         int sf = ReadByte();
 554         int lf = ReadByte();
 555 #else
 556         int sf = ReadShort();
 557         int lf = ReadShort();
 558 #endif
 559         for(i = 0; i < MAX_TEAMSCORE; ++i)
 560                 if(sf & BIT(i))
 561                 {
 562                         if(lf & BIT(i))
 563                                 o.(teamscores(i)) = ReadInt24_t();
 564                         else
 565                                 o.(teamscores(i)) = ReadChar();
 566                 }
 567
 568         return = true;
 569
 570         Scoreboard_UpdateTeamPos(o);
 571 }
 572
 573 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 574 {
 575         make_pure(this);
 576         float newspectatee_status;
 577
 578         int f = ReadByte();
 579
 580         scoreboard_showscores_force = (f & BIT(0));
 581
 582         if(f & BIT(1))
 583         {
 584                 newspectatee_status = ReadByte();
 585                 if(newspectatee_status == player_localnum + 1)
 586                         newspectatee_status = -1; // observing
 587         }
 588         else
 589                 newspectatee_status = 0;
 590
 591         spectatorbutton_zoom = (f & BIT(2));
 592
 593         if(f & BIT(4))
 594         {
 595                 num_spectators = ReadByte();
 596
 597                 float i, slot;
 598
 599                 for(i = 0; i < MAX_SPECTATORS; ++i)
 600                         spectatorlist[i] = 0; // reset list first
 601
 602                 int limit = min(num_spectators, MAX_SPECTATORS);
 603                 for(i = 0; i < limit; ++i)
 604                 {
 605                         slot = ReadByte();
 606                         spectatorlist[i] = slot - 1;
 607                 }
 608         }
 609         else
 610         {
 611                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 612                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 613                 num_spectators = 0;
 614         }
 615
 616         return = true;
 617
 618         if(newspectatee_status != spectatee_status)
 619         {
 620                 // clear race stuff
 621                 race_laptime = 0;
 622                 race_checkpointtime = 0;
 623                 hud_dynamic_shake_factor = -1;
 624                 spectatee_status_changed_time = time;
 625         }
 626         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 627         {
 628                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 629                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 630                 )
 631                         prev_p_health = -1;
 632                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 633                         prev_health = -1;
 634         }
 635         spectatee_status = newspectatee_status;
 636
 637         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 641 {
 642         make_pure(this);
 643         int i, j, b, f;
 644
 645         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 646
 647         if(!(nags & BIT(2)))
 648         {
 649                 strfree(vote_called_vote);
 650                 vote_active = 0;
 651         }
 652         else
 653         {
 654                 vote_active = 1;
 655         }
 656
 657         if(nags & BIT(6))
 658         {
 659                 vote_yescount = ReadByte();
 660                 vote_nocount = ReadByte();
 661                 vote_needed = ReadByte();
 662                 vote_highlighted = ReadChar();
 663         }
 664
 665         if(nags & BIT(7))
 666         {
 667                 strcpy(vote_called_vote, ReadString());
 668         }
 669
 670         if(nags & 1)
 671         {
 672                 for(j = 0; j < maxclients; ++j)
 673                         if(playerslots[j])
 674                                 playerslots[j].ready = true;
 675                 for(i = 1; i <= maxclients; i += 8)
 676                 {
 677                         f = ReadByte();
 678                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 679                                 if (!(f & b))
 680                                         if(playerslots[j])
 681                                                 playerslots[j].ready = false;
 682                 }
 683         }
 684
 685         return = true;
 686
 687         ready_waiting = (nags & BIT(0));
 688         ready_waiting_for_me = (nags & BIT(1));
 689         vote_waiting = (nags & BIT(2));
 690         vote_waiting_for_me = (nags & BIT(3));
 691         warmup_stage = (nags & BIT(4));
 692 }
 693
 694 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 695 {
 696         make_pure(this);
 697         int sf = 0;
 698         serialize(byte, 0, sf);
 699         if (sf & 1) {
 700                 for (int j = 0; j < maxclients; ++j) {
 701                         if (playerslots[j]) {
 702                                 playerslots[j].eliminated = true;
 703                         }
 704                 }
 705                 for (int i = 1; i <= maxclients; i += 8) {
 706                         int f = 0;
 707                         serialize(byte, 0, f);
 708                         for (int b = 0; b < 8; ++b) {
 709                                 if (f & BIT(b)) continue;
 710                                 int j = i - 1 + b;
 711                                 if (playerslots[j]) {
 712                                         playerslots[j].eliminated = false;
 713                                 }
 714                         }
 715                 }
 716         }
 717         return true;
 718 }
 719
 720 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 721 {
 722         make_pure(this);
 723         prandom_debug();
 724         float s = ReadShort();
 725         psrandom(s);
 726         return true;
 727 }
 728
 729 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 730 {
 731         make_pure(this);
 732         int sf = ReadInt24_t();
 733         if (sf == 0) {
 734                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 735                         weapon_accuracy[w] = -1;
 736                 return true;
 737         }
 738
 739         int f = 1;
 740         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 741                 if (sf & f) {
 742                         int b = ReadByte();
 743                         if (b == 0)
 744                                 weapon_accuracy[w] = -1;
 745                         else if (b == 255)
 746                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 747                         else
 748                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 749                 }
 750                 f = (f == 0x800000) ? 1 : f * 2;
 751         }
 752         return true;
 753 }
 754
 755 void Spawn_Draw(entity this)
 756 {
 757         bool dodraw = autocvar_cl_spawn_point_particles;
 758         if(dodraw && autocvar_cl_spawn_point_dist_max)
 759         {
 760                 vector org = getpropertyvec(VF_ORIGIN);
 761                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 762         }
 763
 764         if(dodraw)
 765                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 766 }
 767
 768 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 769 {
 770         float teamnum = (ReadByte() - 1);
 771         vector spn_origin = ReadVector();
 772
 773         this.team = (teamnum + 1);
 774
 775         //if(is_new)
 776         //{
 777                 this.origin = spn_origin;
 778                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 779                 //droptofloor();
 780
 781                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 782                 {
 783                         this.mdl = "models/spawnpoint.md3";
 784                         this.colormod = Team_ColorRGB(teamnum);
 785                         precache_model(this.mdl);
 786                         setmodel(this, this.mdl);
 787                         this.drawmask = MASK_NORMAL;
 788                         //this.move_movetype = MOVETYPE_NOCLIP;
 789                         //this.draw = Spawn_Draw;
 790                         IL_PUSH(g_drawables, this);
 791                 }*/
 792                 this.draw = Spawn_Draw;
 793                 if (is_new) IL_PUSH(g_drawables, this);
 794         //}
 795
 796         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 797         return true;
 798 }
 799
 800 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 801 {
 802         // If entnum is 0, ONLY do the local spawn actions
 803         // this way the server can disable the sending of
 804         // spawn origin or such to clients if wanted.
 805         float entnum = ReadByte();
 806
 807         if(entnum)
 808         {
 809                 this.origin = ReadVector();
 810
 811                 if(is_new)
 812                 {
 813                         float teamnum = entcs_GetTeam(entnum - 1);
 814
 815                         if(autocvar_cl_spawn_event_particles)
 816                         {
 817                                 switch(teamnum)
 818                                 {
 819                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 820                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 821                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 822                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 823                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 824                                 }
 825                         }
 826                         if(autocvar_cl_spawn_event_sound)
 827                         {
 828                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 829                         }
 830                 }
 831         }
 832         return = true;
 833
 834         // local spawn actions
 835         if(is_new && (!entnum || (entnum == player_localentnum)))
 836         {
 837                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 838                 {
 839                         zoomin_effect = 1;
 840                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 841                 }
 842
 843                 if(autocvar_cl_unpress_zoom_on_spawn)
 844                 {
 845                         localcmd("-zoom\n");
 846                         button_zoom = false;
 847                 }
 848                 HUD_Radar_Hide_Maximized();
 849         }
 850         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 851 }
 852
 853 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 854 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 855 void CSQC_Ent_Update(entity this, bool isnew)
 856 {
 857         this.sourceLoc = __FILE__":"STR(__LINE__);
 858         int t = ReadByte();
 859
 860         // set up the "time" global for received entities to be correct for interpolation purposes
 861         float savetime = time;
 862         if(servertime)
 863         {
 864                 time = servertime;
 865         }
 866         else
 867         {
 868                 serverprevtime = time;
 869                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 870                 time = serverprevtime + serverdeltatime;
 871         }
 872
 873 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 874         if (this.enttype)
 875         {
 876                 if (t != this.enttype || isnew)
 877                 {
 878                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 879                         Ent_Remove(this);
 880                         clearentity(this);
 881                         isnew = true;
 882                 }
 883         }
 884         else
 885         {
 886                 if (!isnew)
 887                 {
 888                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 889                         isnew = true;
 890                 }
 891         }
 892 #endif
 893         this.enttype = t;
 894         bool done = false;
 895         FOREACH(LinkedEntities, it.m_id == t, {
 896                 if (isnew) this.classname = it.netname;
 897                 if (autocvar_developer_csqcentities)
 898                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 899                 done = it.m_read(this, NULL, isnew);
 900                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 901                 break;
 902         });
 903         time = savetime;
 904         if (!done)
 905         {
 906                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 907         }
 908 }
 909
 910 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 911 // used when an entity changes its type. For an entity that someone interacts
 912 // with others, make sure it can no longer do so.
 913 void Ent_Remove(entity this)
 914 {
 915         if(this.entremove) this.entremove(this);
 916
 917         if(this.skeletonindex)
 918         {
 919                 skel_delete(this.skeletonindex);
 920                 this.skeletonindex = 0;
 921         }
 922
 923         if(this.snd_looping > 0)
 924         {
 925                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 926                 this.snd_looping = 0;
 927         }
 928
 929         this.enttype = 0;
 930         this.classname = "";
 931         this.draw = func_null;
 932         this.entremove = func_null;
 933         // TODO possibly set more stuff to defaults
 934 }
 935 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 936 void CSQC_Ent_Remove(entity this)
 937 {
 938         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 939         if (wasfreed(this))
 940         {
 941                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 942                 return;
 943         }
 944         if (this.enttype) Ent_Remove(this);
 945         delete(this);
 946 }
 947
 948 void Gamemode_Init()
 949 {
 950         if (!isdemo())
 951         {
 952                 if(!(calledhooks & HOOK_START))
 953                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 954                 calledhooks |= HOOK_START;
 955         }
 956 }
 957 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 958 void CSQC_Parse_StuffCmd(string strMessage)
 959 {
 960         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 961         localcmd(strMessage);
 962 }
 963 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 964 void CSQC_Parse_Print(string strMessage)
 965 {
 966         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 967         print(ColorTranslateRGB(strMessage));
 968 }
 969
 970 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 971 void CSQC_Parse_CenterPrint(string strMessage)
 972 {
 973         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 974         centerprint_AddStandard(strMessage);
 975 }
 976
 977 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 978 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 979 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 980 bool CSQC_Parse_TempEntity()
 981 {
 982         // Acquire TE ID
 983         int nTEID = ReadByte();
 984
 985         FOREACH(TempEntities, it.m_id == nTEID, {
 986                 if (autocvar_developer_csqcentities)
 987                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 988                 return it.m_read(NULL, NULL, true);
 989         });
 990
 991         if (autocvar_developer_csqcentities)
 992                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 993
 994         // No special logic for this temporary entity; return 0 so the engine can handle it
 995         return false;
 996 }
 997
 998 string forcefog;
 999 void Fog_Force()
1000 {
1001         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1002                 localcmd("\nr_drawfog 0\n");
1003         else if (forcefog != "")
1004                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1005 }
1006
1007 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1008 {
1009         make_pure(this);
1010         gametype = ReadRegistered(Gametypes);
1011         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1012         HUD_ModIcons_SetFunc();
1013         FOREACH(Scores, true, {
1014                 strcpy(scores_label(it), ReadString());
1015                 scores_flags(it) = ReadByte();
1016         });
1017         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1018         {
1019                 strcpy(teamscores_label(i), ReadString());
1020                 teamscores_flags(i) = ReadByte();
1021         }
1022         return = true;
1023         Scoreboard_InitScores();
1024         Gamemode_Init();
1025 }
1026
1027 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1028 {
1029         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1030
1031         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1032         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1033         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1034         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1035         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1036         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1037         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1039
1040         strcpy(forcefog, ReadString());
1041
1042         armorblockpercent = ReadByte() / 255.0;
1043         damagepush_speedfactor = ReadByte() / 255.0;
1044
1045         serverflags = ReadByte();
1046
1047         g_trueaim_minrange = ReadCoord();
1048
1049         return = true;
1050
1051         MUTATOR_CALLHOOK(Ent_Init);
1052
1053         if (!postinit) PostInit();
1054 }
1055
1056 float GetSpeedUnitFactor(int speed_unit)
1057 {
1058         switch(speed_unit)
1059         {
1060                 default:
1061                 case 1: return 1.0;
1062                 case 2: return 0.0254;
1063                 case 3: return 0.0254 * 3.6;
1064                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1065                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1066         }
1067 }
1068
1069 string GetSpeedUnit(int speed_unit)
1070 {
1071         switch(speed_unit)
1072         {
1073                 // translator-friendly strings without the initial space
1074                 default:
1075                 case 1: return strcat(" ", _("qu/s"));
1076                 case 2: return strcat(" ", _("m/s"));
1077                 case 3: return strcat(" ", _("km/h"));
1078                 case 4: return strcat(" ", _("mph"));
1079                 case 5: return strcat(" ", _("knots"));
1080         }
1081 }
1082
1083 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1084 {
1085         int b = ReadByte();
1086
1087         switch (b)
1088         {
1089                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1090                         race_checkpoint = ReadByte();
1091                         race_time = ReadInt24_t();
1092                         race_previousbesttime = ReadInt24_t();
1093                         race_mypreviousbesttime = ReadInt24_t();
1094                         string pbestname = ReadString();
1095                         if(autocvar_cl_race_cptimes_onlyself)
1096                         {
1097                                 race_previousbesttime = race_mypreviousbesttime;
1098                                 race_mypreviousbesttime = 0;
1099                                 strcpy(race_previousbestname, "");
1100                         }
1101                         else
1102                                 strcpy(race_previousbestname, pbestname);
1103
1104                         race_checkpointtime = time;
1105
1106                         if(race_checkpoint == 0 || race_checkpoint == 254)
1107                         {
1108                                 race_penaltyaccumulator = 0;
1109                                 race_laptime = time; // valid
1110                         }
1111                         break;
1112
1113                 case RACE_NET_CHECKPOINT_CLEAR:
1114                         race_laptime = 0;
1115                         race_checkpointtime = 0;
1116                         break;
1117
1118                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1119                         race_laptime = ReadCoord();
1120                         race_checkpointtime = -99999;
1121                         // fall through
1122                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1123                         race_nextcheckpoint = ReadByte();
1124
1125                         race_nextbesttime = ReadInt24_t();
1126                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1127                                 race_mybesttime = ReadInt24_t();
1128                         string newname = ReadString();
1129                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1130                         {
1131                                 race_nextbesttime = race_mybesttime;
1132                                 race_mybesttime = 0;
1133                                 strcpy(race_nextbestname, "");
1134                         }
1135                         else
1136                                 strcpy(race_nextbestname, newname);
1137                         break;
1138
1139                 case RACE_NET_CHECKPOINT_HIT_RACE:
1140                         race_mycheckpoint = ReadByte();
1141                         race_mycheckpointtime = time;
1142                         race_mycheckpointdelta = ReadInt24_t();
1143                         race_mycheckpointlapsdelta = ReadByte();
1144                         if(race_mycheckpointlapsdelta >= 128)
1145                                 race_mycheckpointlapsdelta -= 256;
1146                         int who = ReadByte();
1147                         if(who)
1148                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1149                         else
1150                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1151                         break;
1152
1153                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1154                         race_othercheckpoint = ReadByte();
1155                         race_othercheckpointtime = time;
1156                         race_othercheckpointdelta = ReadInt24_t();
1157                         race_othercheckpointlapsdelta = ReadByte();
1158                         if(race_othercheckpointlapsdelta >= 128)
1159                                 race_othercheckpointlapsdelta -= 256;
1160                         int what = ReadByte();
1161                         if(what)
1162                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1163                         else
1164                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1165                         break;
1166
1167                 case RACE_NET_PENALTY_RACE:
1168                 case RACE_NET_PENALTY_QUALIFYING:
1169                         race_penaltyeventtime = time;
1170                         race_penaltytime = ReadShort();
1171                         string reason = ReadString();
1172                         if (reason == "missing a checkpoint")
1173                                 reason = _("missing a checkpoint");
1174                         strcpy(race_penaltyreason, reason);
1175                         if (b == RACE_NET_PENALTY_QUALIFYING)
1176                                 race_penaltyaccumulator += race_penaltytime;
1177                         break;
1178
1179                 case RACE_NET_SERVER_RECORD:
1180                         race_server_record = ReadInt24_t();
1181                         break;
1182                 case RACE_NET_SPEED_AWARD:
1183                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1184                         strcpy(race_speedaward_holder, ReadString());
1185                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1186                         break;
1187                 case RACE_NET_SPEED_AWARD_BEST:
1188                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1189                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1190                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1191                         break;
1192                 case RACE_NET_RANKINGS_CNT:
1193                         RANKINGS_DISPLAY_CNT = ReadByte();
1194                         break;
1195                 case RACE_NET_SERVER_RANKINGS:
1196                         float prevpos, del;
1197                         int pos = ReadShort();
1198                         prevpos = ReadShort();
1199                         del = ReadShort();
1200
1201                         // move other rankings out of the way
1202                         int i;
1203                         if (prevpos) {
1204                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1205                                 for (i=m-1; i>pos-1; --i) {
1206                                         grecordtime[i] = grecordtime[i-1];
1207                                         strcpy(grecordholder[i], grecordholder[i-1]);
1208                                 }
1209                         } else if (del) { // a record has been deleted by the admin
1210                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1211                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1212                                                 grecordtime[i] = 0;
1213                                                 strfree(grecordholder[i]);
1214                                         }
1215                                         else {
1216                                                 grecordtime[i] = grecordtime[i+1];
1217                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1218                                         }
1219                                 }
1220                         } else { // player has no ranked record yet
1221                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1222                                         grecordtime[i] = grecordtime[i-1];
1223                                         strcpy(grecordholder[i], grecordholder[i-1]);
1224                                 }
1225                         }
1226
1227                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1228                                 // kick off the player who fell from the last displayed position
1229                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1230                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1231                         }
1232
1233                         // store new ranking
1234                         strcpy(grecordholder[pos-1], ReadString());
1235                         grecordtime[pos-1] = ReadInt24_t();
1236                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1237                                 race_myrank = pos;
1238                         break;
1239                 case RACE_NET_SERVER_STATUS:
1240                         race_status = ReadShort();
1241                         strcpy(race_status_name, ReadString());
1242         }
1243         return true;
1244 }
1245
1246 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1247 {
1248         teamnagger = 1;
1249         return true;
1250 }
1251
1252 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1253 {
1254         int i = ReadByte();
1255         int pi = ReadShort();
1256         int pl = ReadByte();
1257         int ml = ReadByte();
1258         return = true;
1259         entity e = playerslots[i];
1260         if (!e) return;
1261         e.ping = pi;
1262         e.ping_packetloss = pl / 255.0;
1263         e.ping_movementloss = ml / 255.0;
1264 }
1265
1266 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1267 {
1268         int weapon_id = ReadByte();
1269         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1270         complain_weapon_type = ReadByte();
1271         return = true;
1272
1273         complain_weapon_time = time;
1274         weapontime = time; // ping the weapon panel
1275
1276         switch(complain_weapon_type)
1277         {
1278                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1279                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1280                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1281         }
1282 }
1283
1284 string _getcommandkey(string cmd_name, string command, bool forcename)
1285 {
1286         string keys;
1287         float n, j, k, l = 0;
1288
1289         if (!autocvar_hud_showbinds)
1290                 return cmd_name;
1291
1292         keys = db_get(binddb, command);
1293         if (keys == "")
1294         {
1295                 bool joy_active = cvar("joy_active");
1296                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1297                 for(j = 0; j < n; ++j)
1298                 {
1299                         k = stof(argv(j));
1300                         if(k != -1)
1301                         {
1302                                 string key = keynumtostring(k);
1303                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1304                                         continue;
1305
1306                                 key = translate_key(key);
1307
1308                                 if (keys == "")
1309                                         keys = key;
1310                                 else
1311                                         keys = strcat(keys, ", ", key);
1312
1313                                 ++l;
1314                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1315                                         break;
1316                         }
1317
1318                 }
1319                 if (keys == "")
1320                         keys = "NO_KEY";
1321                 db_put(binddb, command, keys);
1322         }
1323
1324         if (keys == "NO_KEY") {
1325                 if (autocvar_hud_showbinds > 1)
1326                         return sprintf(_("%s (not bound)"), cmd_name);
1327                 else
1328                         return cmd_name;
1329         }
1330         else if (autocvar_hud_showbinds > 1 || forcename)
1331                 return sprintf("%s (%s)", cmd_name, keys);
1332         else
1333                 return keys;
1334 }
1335
1336 /** engine callback */
1337 void URI_Get_Callback(int id, int status, string data)
1338 {
1339         TC(int, id); TC(int, status);
1340         if(url_URI_Get_Callback(id, status, data))
1341         {
1342                 // handled
1343         }
1344         else if (id == URI_GET_DISCARD)
1345         {
1346                 // discard
1347         }
1348         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1349         {
1350                 // sv_cmd curl
1351                 Curl_URI_Get_Callback(id, status, data);
1352         }
1353         else
1354         {
1355                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1356         }
1357 }