qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         ReplicateVars(REPLICATEVARS_SEND_ALL);
  62
  63         // needs to be done so early because of the constants they create
  64         static_init();
  65         static_init_late();
  66         static_init_precache();
  67
  68         binddb = db_create();
  69         tempdb = db_create();
  70         ClientProgsDB = db_load("client.db");
  71
  72         draw_endBoldFont();
  73
  74         //registercommand("hud_configure");
  75         //registercommand("hud_save");
  76         //registercommand("menu_action");
  77
  78         ConsoleCommand_macro_init();
  79
  80         registercvar("hud_usecsqc", "1");
  81         registercvar("scoreboard_columns", "default");
  82
  83         registercvar("cl_nade_type", "3");
  84         registercvar("cl_pokenade_type", "zombie");
  85
  86         registercvar("cl_jumpspeedcap_min", "");
  87         registercvar("cl_jumpspeedcap_max", "");
  88
  89         registercvar("cl_shootfromfixedorigin", "");
  90
  91         registercvar("cl_multijump", "-1");
  92
  93         registercvar("cl_dodging", "0");
  94
  95         registercvar("cl_spawn_near_teammate", "1");
  96
  97         registercvar("cl_weapon_switch_reload", "1");
  98         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  99
 100         registercvar("cl_allow_uidranking", "1");
 101
 102         if(autocvar_cl_lockview)
 103                 cvar_set("cl_lockview", "0");
 104
 105         gametype = NULL;
 106
 107         postinit = false;
 108
 109         calledhooks = 0;
 110
 111         teams = Sort_Spawn();
 112         players = Sort_Spawn();
 113
 114         GetTeam(NUM_SPECTATOR, true); // add specs first
 115
 116         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 117                 weapon_accuracy[w] = -1;
 118
 119         // precaches
 120
 121         if(autocvar_cl_reticle)
 122         {
 123                 precache_pic("gfx/reticle_normal");
 124                 // weapon reticles are precached in weapon files
 125         }
 126
 127         {
 128                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 129                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 130                 shortmapname = mi_shortname;
 131
 132                 if (precache_pic(minimapname) == "")
 133                 {
 134                         // but maybe we have a non-clever minimap
 135                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 136                         if (precache_pic(minimapname) == "")
 137                                 minimapname = ""; // FAIL
 138                         else
 139                                 get_mi_min_max_texcoords(0); // load new texcoords
 140                 }
 141
 142                 mi_center = (mi_min + mi_max) * 0.5;
 143                 mi_scale = mi_max - mi_min;
 144                 minimapname = strzone(minimapname);
 145         }
 146
 147         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 148         LoadMenuSkinValues();
 149 }
 150
 151 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 152 void Shutdown()
 153 {
 154         WarpZone_Shutdown();
 155
 156         delete(teams);
 157         delete(players);
 158         db_close(binddb);
 159         db_close(tempdb);
 160         if(autocvar_cl_db_saveasdump)
 161                 db_dump(ClientProgsDB, "client.db");
 162         else
 163                 db_save(ClientProgsDB, "client.db");
 164         db_close(ClientProgsDB);
 165
 166         if(camera_active)
 167                 cvar_set("chase_active",ftos(chase_active_backup));
 168
 169         // unset the event chasecam's chase_active
 170         if(autocvar_chase_active < 0)
 171                 cvar_set("chase_active", "0");
 172
 173         if (autocvar_r_drawviewmodel < 0)
 174                 cvar_set("r_drawviewmodel", "0");
 175
 176         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 177
 178         if (!isdemo())
 179         {
 180                 if (!(calledhooks & HOOK_START))
 181                         localcmd("\n_cl_hook_gamestart nop\n");
 182                 if (!(calledhooks & HOOK_END))
 183                 {
 184                         int gamecount = cvar("cl_matchcount");
 185                         localcmd("\ncl_hook_gameend\n");
 186                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 187                         // earlier versions of the game abuse the hook to set this cvar
 188                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 189                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 190                 }
 191         }
 192
 193         localcmd("\ncl_hook_shutdown\n");
 194
 195         localcmd("\n-button12\n");
 196
 197         deactivate_minigame();
 198         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 199
 200         ReplicateVars(REPLICATEVARS_DESTROY);
 201 }
 202
 203 void AuditLists()
 204 {
 205         entity e;
 206         entity prev;
 207
 208         prev = players;
 209         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 210         {
 211                 if(prev != e.sort_prev)
 212                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 213         }
 214
 215         prev = teams;
 216         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 217         {
 218                 if(prev != e.sort_prev)
 219                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 220         }
 221 }
 222
 223 float RegisterPlayer(entity player)
 224 {
 225         entity pl;
 226         AuditLists();
 227         for(pl = players.sort_next; pl; pl = pl.sort_next)
 228                 if(pl == player)
 229                         error("Player already registered!");
 230         player.sort_next = players.sort_next;
 231         player.sort_prev = players;
 232         if(players.sort_next)
 233                 players.sort_next.sort_prev = player;
 234         players.sort_next = player;
 235         AuditLists();
 236         return true;
 237 }
 238
 239 void RemovePlayer(entity player)
 240 {
 241         entity pl, parent;
 242         AuditLists();
 243         parent = players;
 244         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 245                 parent = pl;
 246
 247         if(!pl)
 248         {
 249                 error("Trying to remove a player which is not in the playerlist!");
 250                 return;
 251         }
 252         parent.sort_next = player.sort_next;
 253         if(player.sort_next)
 254                 player.sort_next.sort_prev = parent;
 255         AuditLists();
 256 }
 257
 258 void MoveToLast(entity e)
 259 {
 260         AuditLists();
 261         entity ent = e.sort_next;
 262         while(ent)
 263         {
 264                 SORT_SWAP(ent, e);
 265                 ent = e.sort_next;
 266         }
 267         AuditLists();
 268 }
 269
 270 float RegisterTeam(entity Team)
 271 {
 272         assert_once(Team.team, eprint(Team));
 273         entity tm;
 274         AuditLists();
 275         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 276                 if(tm == Team)
 277                         error("Team already registered!");
 278         Team.sort_next = teams.sort_next;
 279         Team.sort_prev = teams;
 280         if(teams.sort_next)
 281                 teams.sort_next.sort_prev = Team;
 282         teams.sort_next = Team;
 283         if(Team.team && Team.team != NUM_SPECTATOR)
 284                 ++team_count;
 285         AuditLists();
 286         return true;
 287 }
 288
 289 void RemoveTeam(entity Team)
 290 {
 291         entity tm, parent;
 292         AuditLists();
 293         parent = teams;
 294         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 295                 parent = tm;
 296
 297         if(!tm)
 298         {
 299                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 300                 return;
 301         }
 302         parent.sort_next = Team.sort_next;
 303         if(Team.sort_next)
 304                 Team.sort_next.sort_prev = parent;
 305         if(Team.team && Team.team != NUM_SPECTATOR)
 306                 --team_count;
 307         AuditLists();
 308 }
 309
 310 entity GetTeam(int Team, bool add)
 311 {
 312         TC(int, Team); TC(bool, add);
 313         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 314         if(teamslots[num])
 315                 return teamslots[num];
 316         if (!add)
 317                 return NULL;
 318         entity tm = new_pure(team);
 319         tm.team = Team;
 320         teamslots[num] = tm;
 321         RegisterTeam(tm);
 322         return tm;
 323 }
 324
 325 .float has_team;
 326 bool SetTeam(entity o, int Team)
 327 {
 328         TC(int, Team);
 329         //devassert_once(Team);
 330         entity tm;
 331         if(teamplay)
 332         {
 333                 switch(Team)
 334                 {
 335                         case -1:
 336                         case NUM_TEAM_1:
 337                         case NUM_TEAM_2:
 338                         case NUM_TEAM_3:
 339                         case NUM_TEAM_4:
 340                                 break;
 341                         default:
 342                                 if(GetTeam(Team, false) == NULL)
 343                                 {
 344                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 345                                         Team = NUM_SPECTATOR;
 346                                 }
 347                                 break;
 348                 }
 349         }
 350         else
 351         {
 352                 switch(Team)
 353                 {
 354                         case -1:
 355                         case 0:
 356                                 break;
 357                         default:
 358                                 if(GetTeam(Team, false) == NULL)
 359                                 {
 360                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 361                                         Team = NUM_SPECTATOR;
 362                                 }
 363                                 break;
 364                 }
 365         }
 366         if(Team == -1) // leave
 367         {
 368                 if(o.has_team)
 369                 {
 370                         tm = GetTeam(o.team, false);
 371                         tm.team_size -= 1;
 372                         o.has_team = 0;
 373                         return true;
 374                 }
 375         }
 376         else
 377         {
 378                 if (!o.has_team)
 379                 {
 380                         o.team = Team;
 381                         tm = GetTeam(Team, true);
 382                         tm.team_size += 1;
 383                         o.has_team = 1;
 384                         return true;
 385                 }
 386                 else if(Team != o.team)
 387                 {
 388                         tm = GetTeam(o.team, false);
 389                         tm.team_size -= 1;
 390                         o.team = Team;
 391                         tm = GetTeam(Team, true);
 392                         tm.team_size += 1;
 393                         return true;
 394                 }
 395         }
 396         return false;
 397 }
 398
 399 void Playerchecker_Think(entity this)
 400 {
 401         int i;
 402         entity e;
 403         for(i = 0; i < maxclients; ++i)
 404         {
 405                 e = playerslots[i];
 406                 if(entcs_GetName(i) == "")
 407                 {
 408                         if(e.sort_prev)
 409                         {
 410                                 // player disconnected
 411                                 SetTeam(e, -1);
 412                                 RemovePlayer(e);
 413                                 e.sort_prev = NULL;
 414                                 //e.gotscores = 0;
 415                         }
 416                 }
 417                 else
 418                 {
 419                         if (!e.sort_prev)
 420                         {
 421                                 // player connected
 422                                 if (!e)
 423                                 {
 424                                         playerslots[i] = e = new_pure(playerslot);
 425                                 }
 426                                 e.sv_entnum = i;
 427                                 e.ping = 0;
 428                                 e.ping_packetloss = 0;
 429                                 e.ping_movementloss = 0;
 430                                 //e.gotscores = 0; // we might already have the scores...
 431                                 int t = entcs_GetScoreTeam(i);
 432                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 433                                 RegisterPlayer(e);
 434                                 Scoreboard_UpdatePlayerPos(e);
 435                         }
 436                 }
 437         }
 438         this.nextthink = time + 0.2;
 439 }
 440
 441 void PostInit()
 442 {
 443         entity playerchecker = new_pure(playerchecker);
 444         setthink(playerchecker, Playerchecker_Think);
 445         playerchecker.nextthink = time + 0.2;
 446
 447         TrueAim_Init();
 448
 449         postinit = true;
 450 }
 451
 452 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 453 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 454 // All keys are in ascii.
 455 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 456 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 457 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 458 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 459 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 460 {
 461         TC(int, bInputType);
 462         bool override = false;
 463
 464         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 465         if (override)
 466                 return true;
 467
 468         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 469
 470         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 471
 472         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 473
 474         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 475
 476         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 477
 478         if(override)
 479                 return true;
 480
 481         if(bInputType == 3 || bInputType == 2)
 482                 return false;
 483
 484         // at this point bInputType can only be 0 or 1 (key pressed or released)
 485         bool key_pressed = (bInputType == 0);
 486
 487         if(key_pressed) {
 488                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 489                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 490                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 491         }
 492         else {
 493                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 494                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 495                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 496         }
 497
 498         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 499         {
 500                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 501                 {
 502                         localcmd("\nmenu_showgamemenudialog\n");
 503                         return true;
 504                 }
 505         }
 506
 507         return false;
 508 }
 509
 510 // END REQUIRED CSQC FUNCTIONS
 511 // --------------------------------------------------------------------------
 512
 513 // --------------------------------------------------------------------------
 514 // BEGIN OPTIONAL CSQC FUNCTIONS
 515
 516 void Ent_RemovePlayerScore(entity this)
 517 {
 518         if(this.owner) {
 519                 SetTeam(this.owner, -1);
 520                 this.owner.gotscores = 0;
 521                 FOREACH(Scores, true, {
 522                         this.owner.(scores(it)) = 0; // clear all scores
 523                 });
 524         }
 525 }
 526
 527 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 528 {
 529         make_pure(this);
 530         entity o;
 531
 532         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 533         // (no I've never heard of M-x replace-string, sed, or anything like that)
 534         bool isNew = !this.owner; // workaround for DP bug
 535         int n = ReadByte()-1;
 536
 537 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 538         if(!isNew && n != this.sv_entnum)
 539         {
 540                 //print("A CSQC entity changed its owner!\n");
 541                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 542                 isNew = true;
 543                 Ent_Remove(this);
 544         }
 545 #endif
 546
 547         this.sv_entnum = n;
 548
 549         o = playerslots[this.sv_entnum];
 550         if (!o)
 551         {
 552                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 553         }
 554         this.owner = o;
 555         o.sv_entnum = this.sv_entnum;
 556         o.gotscores = 1;
 557
 558         //if (!o.sort_prev)
 559         //      RegisterPlayer(o);
 560         //playerchecker will do this for us later, if it has not already done so
 561
 562         int sf = ReadShort();
 563         int lf = ReadShort();
 564         FOREACH(Scores, true, {
 565                 int p = 1 << (i % 16);
 566                 if (sf & p)
 567                 {
 568                         if (lf & p)
 569                                 o.(scores(it)) = ReadInt24_t();
 570                         else
 571                                 o.(scores(it)) = ReadChar();
 572                 }
 573         });
 574
 575         return = true;
 576
 577         if(o.sort_prev)
 578                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 579
 580         this.entremove = Ent_RemovePlayerScore;
 581 }
 582
 583 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 584 {
 585         make_pure(this);
 586         int i;
 587
 588         this.team = ReadByte();
 589         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 590
 591 #if MAX_TEAMSCORE <= 8
 592         int sf = ReadByte();
 593         int lf = ReadByte();
 594 #else
 595         int sf = ReadShort();
 596         int lf = ReadShort();
 597 #endif
 598         for(i = 0; i < MAX_TEAMSCORE; ++i)
 599                 if(sf & BIT(i))
 600                 {
 601                         if(lf & BIT(i))
 602                                 o.(teamscores(i)) = ReadInt24_t();
 603                         else
 604                                 o.(teamscores(i)) = ReadChar();
 605                 }
 606
 607         return = true;
 608
 609         Scoreboard_UpdateTeamPos(o);
 610 }
 611
 612 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 613 {
 614         make_pure(this);
 615         float newspectatee_status;
 616
 617         int f = ReadByte();
 618
 619         scoreboard_showscores_force = (f & BIT(0));
 620
 621         if(f & BIT(1))
 622         {
 623                 newspectatee_status = ReadByte();
 624                 if(newspectatee_status == player_localnum + 1)
 625                         newspectatee_status = -1; // observing
 626         }
 627         else
 628                 newspectatee_status = 0;
 629
 630         spectatorbutton_zoom = (f & BIT(2));
 631
 632         if(f & BIT(4))
 633         {
 634                 num_spectators = ReadByte();
 635
 636                 float i, slot;
 637
 638                 for(i = 0; i < MAX_SPECTATORS; ++i)
 639                         spectatorlist[i] = 0; // reset list first
 640
 641                 int limit = min(num_spectators, MAX_SPECTATORS);
 642                 for(i = 0; i < limit; ++i)
 643                 {
 644                         slot = ReadByte();
 645                         spectatorlist[i] = slot - 1;
 646                 }
 647         }
 648         else
 649         {
 650                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 651                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 652                 num_spectators = 0;
 653         }
 654
 655         return = true;
 656
 657         if(newspectatee_status != spectatee_status)
 658         {
 659                 // clear race stuff
 660                 race_laptime = 0;
 661                 race_checkpointtime = 0;
 662                 hud_dynamic_shake_factor = -1;
 663                 spectatee_status_changed_time = time;
 664         }
 665         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 666         {
 667                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 668                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 669                 )
 670                         prev_p_health = -1;
 671                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 672                         prev_health = -1;
 673         }
 674         spectatee_status = newspectatee_status;
 675
 676         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 677 }
 678
 679 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 680 {
 681         make_pure(this);
 682         int i, j, b, f;
 683
 684         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 685
 686         if(!(nags & BIT(2)))
 687         {
 688                 strfree(vote_called_vote);
 689                 vote_active = 0;
 690         }
 691         else
 692         {
 693                 vote_active = 1;
 694         }
 695
 696         if(nags & BIT(6))
 697         {
 698                 vote_yescount = ReadByte();
 699                 vote_nocount = ReadByte();
 700                 vote_needed = ReadByte();
 701                 vote_highlighted = ReadChar();
 702         }
 703
 704         if(nags & BIT(7))
 705         {
 706                 strcpy(vote_called_vote, ReadString());
 707         }
 708
 709         if(nags & 1)
 710         {
 711                 for(j = 0; j < maxclients; ++j)
 712                         if(playerslots[j])
 713                                 playerslots[j].ready = true;
 714                 for(i = 1; i <= maxclients; i += 8)
 715                 {
 716                         f = ReadByte();
 717                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 718                                 if (!(f & b))
 719                                         if(playerslots[j])
 720                                                 playerslots[j].ready = false;
 721                 }
 722         }
 723
 724         return = true;
 725
 726         ready_waiting = (nags & BIT(0));
 727         ready_waiting_for_me = (nags & BIT(1));
 728         vote_waiting = (nags & BIT(2));
 729         vote_waiting_for_me = (nags & BIT(3));
 730         warmup_stage = (nags & BIT(4));
 731 }
 732
 733 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 734 {
 735         make_pure(this);
 736         int sf = 0;
 737         serialize(byte, 0, sf);
 738         if (sf & 1) {
 739                 for (int j = 0; j < maxclients; ++j) {
 740                         if (playerslots[j]) {
 741                                 playerslots[j].eliminated = true;
 742                         }
 743                 }
 744                 for (int i = 1; i <= maxclients; i += 8) {
 745                         int f = 0;
 746                         serialize(byte, 0, f);
 747                         for (int b = 0; b < 8; ++b) {
 748                                 if (f & BIT(b)) continue;
 749                                 int j = i - 1 + b;
 750                                 if (playerslots[j]) {
 751                                         playerslots[j].eliminated = false;
 752                                 }
 753                         }
 754                 }
 755         }
 756         return true;
 757 }
 758
 759 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 760 {
 761         make_pure(this);
 762         prandom_debug();
 763         float s = ReadShort();
 764         psrandom(s);
 765         return true;
 766 }
 767
 768 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 769 {
 770         make_pure(this);
 771         int sf = ReadInt24_t();
 772         if (sf == 0) {
 773                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 774                         weapon_accuracy[w] = -1;
 775                 return true;
 776         }
 777
 778         int f = 1;
 779         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 780                 if (sf & f) {
 781                         int b = ReadByte();
 782                         if (b == 0)
 783                                 weapon_accuracy[w] = -1;
 784                         else if (b == 255)
 785                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 786                         else
 787                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 788                 }
 789                 f = (f == 0x800000) ? 1 : f * 2;
 790         }
 791         return true;
 792 }
 793
 794 void Spawn_Draw(entity this)
 795 {
 796         bool dodraw = autocvar_cl_spawn_point_particles;
 797         if(dodraw && autocvar_cl_spawn_point_dist_max)
 798         {
 799                 vector org = getpropertyvec(VF_ORIGIN);
 800                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 801         }
 802
 803         if(dodraw)
 804                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 805 }
 806
 807 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 808 {
 809         float teamnum = (ReadByte() - 1);
 810         vector spn_origin = ReadVector();
 811
 812         this.team = (teamnum + 1);
 813
 814         //if(is_new)
 815         //{
 816                 this.origin = spn_origin;
 817                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 818                 //droptofloor();
 819
 820                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 821                 {
 822                         this.mdl = "models/spawnpoint.md3";
 823                         this.colormod = Team_ColorRGB(teamnum);
 824                         precache_model(this.mdl);
 825                         setmodel(this, this.mdl);
 826                         this.drawmask = MASK_NORMAL;
 827                         //this.move_movetype = MOVETYPE_NOCLIP;
 828                         //this.draw = Spawn_Draw;
 829                         IL_PUSH(g_drawables, this);
 830                 }*/
 831                 this.draw = Spawn_Draw;
 832                 if (is_new) IL_PUSH(g_drawables, this);
 833         //}
 834
 835         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 836         return true;
 837 }
 838
 839 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 840 {
 841         // If entnum is 0, ONLY do the local spawn actions
 842         // this way the server can disable the sending of
 843         // spawn origin or such to clients if wanted.
 844         float entnum = ReadByte();
 845
 846         if(entnum)
 847         {
 848                 this.origin = ReadVector();
 849
 850                 if(is_new)
 851                 {
 852                         float teamnum = entcs_GetTeam(entnum - 1);
 853
 854                         if(autocvar_cl_spawn_event_particles)
 855                         {
 856                                 switch(teamnum)
 857                                 {
 858                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 859                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 860                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 861                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 862                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 863                                 }
 864                         }
 865                         if(autocvar_cl_spawn_event_sound)
 866                         {
 867                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 868                         }
 869                 }
 870         }
 871         return = true;
 872
 873         // local spawn actions
 874         if(is_new && (!entnum || (entnum == player_localentnum)))
 875         {
 876                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 877                 {
 878                         zoomin_effect = 1;
 879                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 880                 }
 881
 882                 if(autocvar_cl_unpress_zoom_on_spawn)
 883                 {
 884                         localcmd("-zoom\n");
 885                         button_zoom = false;
 886                 }
 887                 HUD_Radar_Hide_Maximized();
 888         }
 889         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 890 }
 891
 892 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 893 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 894 void CSQC_Ent_Update(entity this, bool isnew)
 895 {
 896         this.sourceLoc = __FILE__":"STR(__LINE__);
 897         int t = ReadByte();
 898
 899         // set up the "time" global for received entities to be correct for interpolation purposes
 900         float savetime = time;
 901         if(servertime)
 902         {
 903                 time = servertime;
 904         }
 905         else
 906         {
 907                 serverprevtime = time;
 908                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 909                 time = serverprevtime + serverdeltatime;
 910         }
 911
 912 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 913         if (this.enttype)
 914         {
 915                 if (t != this.enttype || isnew)
 916                 {
 917                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 918                         Ent_Remove(this);
 919                         ONREMOVE(this);
 920                         clearentity(this);
 921                         isnew = true;
 922                 }
 923         }
 924         else
 925         {
 926                 if (!isnew)
 927                 {
 928                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 929                         isnew = true;
 930                 }
 931         }
 932 #endif
 933         this.enttype = t;
 934         bool done = false;
 935         FOREACH(LinkedEntities, it.m_id == t, {
 936                 if (isnew) this.classname = it.netname;
 937                 if (autocvar_developer_csqcentities)
 938                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 939                 done = it.m_read(this, NULL, isnew);
 940                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 941                 break;
 942         });
 943         time = savetime;
 944         if (!done)
 945         {
 946                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 947         }
 948 }
 949
 950 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 951 // used when an entity changes its type. For an entity that someone interacts
 952 // with others, make sure it can no longer do so.
 953 void Ent_Remove(entity this)
 954 {
 955         if(this.entremove) this.entremove(this);
 956
 957         if(this.skeletonindex)
 958         {
 959                 skel_delete(this.skeletonindex);
 960                 this.skeletonindex = 0;
 961         }
 962
 963         if(this.snd_looping > 0)
 964         {
 965                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 966                 this.snd_looping = 0;
 967         }
 968
 969         this.enttype = 0;
 970         this.classname = "";
 971         this.draw = func_null;
 972         this.entremove = func_null;
 973         // TODO possibly set more stuff to defaults
 974 }
 975 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 976 void CSQC_Ent_Remove(entity this)
 977 {
 978         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 979         if (wasfreed(this))
 980         {
 981                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 982                 return;
 983         }
 984         if (this.enttype) Ent_Remove(this);
 985         delete(this);
 986 }
 987
 988 void Gamemode_Init()
 989 {
 990         if (!isdemo())
 991         {
 992                 if(!(calledhooks & HOOK_START))
 993                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 994                 calledhooks |= HOOK_START;
 995         }
 996 }
 997 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 998 void CSQC_Parse_StuffCmd(string strMessage)
 999 {
1000         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1001         localcmd(strMessage);
1002 }
1003 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1004 void CSQC_Parse_Print(string strMessage)
1005 {
1006         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1007         print(ColorTranslateRGB(strMessage));
1008 }
1009
1010 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1011 void CSQC_Parse_CenterPrint(string strMessage)
1012 {
1013         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1014         centerprint_AddStandard(strMessage);
1015 }
1016
1017 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1018 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1019 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1020 bool CSQC_Parse_TempEntity()
1021 {
1022         // Acquire TE ID
1023         int nTEID = ReadByte();
1024
1025         FOREACH(TempEntities, it.m_id == nTEID, {
1026                 if (autocvar_developer_csqcentities)
1027                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1028                 return it.m_read(NULL, NULL, true);
1029         });
1030
1031         if (autocvar_developer_csqcentities)
1032                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1033
1034         // No special logic for this temporary entity; return 0 so the engine can handle it
1035         return false;
1036 }
1037
1038 string forcefog;
1039 void Fog_Force()
1040 {
1041         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1042                 localcmd("\nr_drawfog 0\n");
1043         else if (forcefog != "")
1044                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1045 }
1046
1047 bool net_handle_ServerWelcome();
1048 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1049 {
1050         make_pure(this);
1051         gametype = ReadRegistered(Gametypes);
1052         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1053         HUD_ModIcons_SetFunc();
1054         FOREACH(Scores, true, {
1055                 strcpy(scores_label(it), ReadString());
1056                 scores_flags(it) = ReadByte();
1057         });
1058         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1059         {
1060                 strcpy(teamscores_label(i), ReadString());
1061                 teamscores_flags(i) = ReadByte();
1062         }
1063         bool welcome_msg_too = ReadByte();
1064         if (welcome_msg_too)
1065                 net_handle_ServerWelcome();
1066         return = true;
1067         Scoreboard_InitScores();
1068         Gamemode_Init();
1069 }
1070
1071 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1072 {
1073         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1074
1075         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1076         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1077         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1078         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1079         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1080         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1081         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1082         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1083
1084         strcpy(forcefog, ReadString());
1085
1086         armorblockpercent = ReadByte() / 255.0;
1087         damagepush_speedfactor = ReadByte() / 255.0;
1088
1089         serverflags = ReadByte();
1090
1091         g_trueaim_minrange = ReadCoord();
1092
1093         return = true;
1094
1095         MUTATOR_CALLHOOK(Ent_Init);
1096
1097         if (!postinit) PostInit();
1098 }
1099
1100 float GetSpeedUnitFactor(int speed_unit)
1101 {
1102         switch(speed_unit)
1103         {
1104                 default:
1105                 case 1: return 1.0;
1106                 case 2: return 0.0254;
1107                 case 3: return 0.0254 * 3.6;
1108                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1109                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1110         }
1111 }
1112
1113 string GetSpeedUnit(int speed_unit)
1114 {
1115         switch(speed_unit)
1116         {
1117                 // translator-friendly strings without the initial space
1118                 default:
1119                 case 1: return strcat(" ", _("qu/s"));
1120                 case 2: return strcat(" ", _("m/s"));
1121                 case 3: return strcat(" ", _("km/h"));
1122                 case 4: return strcat(" ", _("mph"));
1123                 case 5: return strcat(" ", _("knots"));
1124         }
1125 }
1126
1127 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1128 {
1129         int b = ReadByte();
1130
1131         switch (b)
1132         {
1133                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1134                         race_checkpoint = ReadByte();
1135                         race_time = ReadInt24_t();
1136                         race_previousbesttime = ReadInt24_t();
1137                         race_mypreviousbesttime = ReadInt24_t();
1138                         string pbestname = ReadString();
1139                         if(autocvar_cl_race_cptimes_onlyself)
1140                         {
1141                                 race_previousbesttime = race_mypreviousbesttime;
1142                                 race_mypreviousbesttime = 0;
1143                                 strcpy(race_previousbestname, "");
1144                         }
1145                         else
1146                                 strcpy(race_previousbestname, pbestname);
1147
1148                         race_checkpointtime = time;
1149
1150                         if(race_checkpoint == 0 || race_checkpoint == 254)
1151                         {
1152                                 race_penaltyaccumulator = 0;
1153                                 race_laptime = time; // valid
1154                         }
1155                         break;
1156
1157                 case RACE_NET_CHECKPOINT_CLEAR:
1158                         race_laptime = 0;
1159                         race_checkpointtime = 0;
1160                         break;
1161
1162                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1163                         race_laptime = ReadCoord();
1164                         race_checkpointtime = -99999;
1165                         // fall through
1166                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1167                         race_nextcheckpoint = ReadByte();
1168
1169                         race_nextbesttime = ReadInt24_t();
1170                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1171                                 race_mybesttime = ReadInt24_t();
1172                         string newname = ReadString();
1173                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1174                         {
1175                                 race_nextbesttime = race_mybesttime;
1176                                 race_mybesttime = 0;
1177                                 strcpy(race_nextbestname, "");
1178                         }
1179                         else
1180                                 strcpy(race_nextbestname, newname);
1181                         break;
1182
1183                 case RACE_NET_CHECKPOINT_HIT_RACE:
1184                         race_mycheckpoint = ReadByte();
1185                         race_mycheckpointtime = time;
1186                         race_mycheckpointdelta = ReadInt24_t();
1187                         race_mycheckpointlapsdelta = ReadByte();
1188                         if(race_mycheckpointlapsdelta >= 128)
1189                                 race_mycheckpointlapsdelta -= 256;
1190                         int who = ReadByte();
1191                         if(who)
1192                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1193                         else
1194                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1195                         break;
1196
1197                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1198                         race_othercheckpoint = ReadByte();
1199                         race_othercheckpointtime = time;
1200                         race_othercheckpointdelta = ReadInt24_t();
1201                         race_othercheckpointlapsdelta = ReadByte();
1202                         if(race_othercheckpointlapsdelta >= 128)
1203                                 race_othercheckpointlapsdelta -= 256;
1204                         int what = ReadByte();
1205                         if(what)
1206                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1207                         else
1208                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1209                         break;
1210
1211                 case RACE_NET_PENALTY_RACE:
1212                 case RACE_NET_PENALTY_QUALIFYING:
1213                         race_penaltyeventtime = time;
1214                         race_penaltytime = ReadShort();
1215                         string reason = ReadString();
1216                         if (reason == "missing a checkpoint")
1217                                 reason = _("missing a checkpoint");
1218                         strcpy(race_penaltyreason, reason);
1219                         if (b == RACE_NET_PENALTY_QUALIFYING)
1220                                 race_penaltyaccumulator += race_penaltytime;
1221                         break;
1222
1223                 case RACE_NET_SERVER_RECORD:
1224                         race_server_record = ReadInt24_t();
1225                         break;
1226                 case RACE_NET_SPEED_AWARD:
1227                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1228                         strcpy(race_speedaward_holder, ReadString());
1229                         break;
1230                 case RACE_NET_SPEED_AWARD_BEST:
1231                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1232                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1233                         break;
1234                 case RACE_NET_RANKINGS_CNT:
1235                         RANKINGS_DISPLAY_CNT = ReadByte();
1236                         break;
1237                 case RACE_NET_SERVER_RANKINGS:
1238                         float prevpos, del;
1239                         int pos = ReadShort();
1240                         prevpos = ReadShort();
1241                         del = ReadShort();
1242
1243                         // move other rankings out of the way
1244                         int i;
1245                         if (prevpos) {
1246                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1247                                 for (i=m-1; i>pos-1; --i) {
1248                                         grecordtime[i] = grecordtime[i-1];
1249                                         strcpy(grecordholder[i], grecordholder[i-1]);
1250                                 }
1251                         } else if (del) { // a record has been deleted by the admin
1252                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1253                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1254                                                 grecordtime[i] = 0;
1255                                                 strfree(grecordholder[i]);
1256                                         }
1257                                         else {
1258                                                 grecordtime[i] = grecordtime[i+1];
1259                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1260                                         }
1261                                 }
1262                         } else { // player has no ranked record yet
1263                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1264                                         grecordtime[i] = grecordtime[i-1];
1265                                         strcpy(grecordholder[i], grecordholder[i-1]);
1266                                 }
1267                         }
1268
1269                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1270                                 // kick off the player who fell from the last displayed position
1271                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1272                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1273                         }
1274
1275                         // store new ranking
1276                         strcpy(grecordholder[pos-1], ReadString());
1277                         grecordtime[pos-1] = ReadInt24_t();
1278                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1279                                 race_myrank = pos;
1280                         break;
1281                 case RACE_NET_SERVER_STATUS:
1282                         race_status = ReadShort();
1283                         strcpy(race_status_name, ReadString());
1284         }
1285         return true;
1286 }
1287
1288 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1289 {
1290         teamnagger = 1;
1291         return true;
1292 }
1293
1294 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1295 {
1296         int i = ReadByte();
1297         int pi = ReadShort();
1298         int pl = ReadByte();
1299         int ml = ReadByte();
1300         return = true;
1301         entity e = playerslots[i];
1302         if (!e) return;
1303         e.ping = pi;
1304         e.ping_packetloss = pl / 255.0;
1305         e.ping_movementloss = ml / 255.0;
1306 }
1307
1308 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1309 {
1310         int weapon_id = ReadByte();
1311         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1312         complain_weapon_type = ReadByte();
1313         return = true;
1314
1315         complain_weapon_time = time;
1316         weapontime = time; // ping the weapon panel
1317
1318         switch(complain_weapon_type)
1319         {
1320                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1321                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1322                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1323         }
1324 }
1325
1326 bool net_handle_ServerWelcome()
1327 {
1328         bool campaign = ReadByte();
1329         if (campaign)
1330         {
1331                 string campaign_title = ReadString();
1332                 int campaign_level = ReadByte();
1333                 string campaign_msg = ReadString();
1334                 string welcomedialog_args;
1335                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1336                 string key = getcommandkey(_("jump"), "+jump");
1337                 string msg = strcat(
1338                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1339                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1340                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1341                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1342                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1343                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1344                 return true;
1345         }
1346
1347         welcome_msg_force_centerprint = ReadByte();
1348         strcpy(hostname, ReadString());
1349         string ver = ReadString();
1350         string modifications = ReadString();
1351         string cache_mutatormsg = ReadString();
1352         string mutator_msg = ReadString();
1353         string motd = ReadString();
1354
1355         string msg = "";
1356         msg = strcat(msg, ver);
1357         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1358         if(modifications != "")
1359                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1360         if (cache_mutatormsg != "")
1361                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1362         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1363         if (motd != "")
1364                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1365
1366         strcpy(welcome_msg, msg);
1367         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1368         return true;
1369 }
1370
1371 void Welcome_Message_Show_Try()
1372 {
1373         if (!welcome_msg_menu_check_maxtime)
1374                 return;
1375
1376         bool want_dialog = (!welcome_msg_force_centerprint && !isdemo() && autocvar_cl_welcome_in_menu_dialog);
1377         // if want dialog check if menu is initialized but for a short time
1378         if (!want_dialog || cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1379         {
1380                 if (want_dialog && cvar("_menu_welcome_dialog_available"))
1381                 {
1382                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1383                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1384                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1385                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1386                 }
1387                 else
1388                         centerprint_Add(ORDINAL(CPID_MOTD), strcat(hostname, "\n\n\n", welcome_msg), -1, 0);
1389
1390                 strfree(welcome_msg);
1391                 welcome_msg_menu_check_maxtime = 0;
1392         }
1393 }
1394
1395 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1396 {
1397         return net_handle_ServerWelcome();
1398 }
1399
1400 string _getcommandkey(string cmd_name, string command, bool forcename)
1401 {
1402         string keys;
1403         float n, j, k, l = 0;
1404
1405         if (!autocvar_hud_showbinds)
1406                 return cmd_name;
1407
1408         keys = db_get(binddb, command);
1409         if (keys == "")
1410         {
1411                 bool joy_active = cvar("joy_active");
1412                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1413                 for(j = 0; j < n; ++j)
1414                 {
1415                         k = stof(argv(j));
1416                         if(k != -1)
1417                         {
1418                                 string key = keynumtostring(k);
1419                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1420                                         continue;
1421
1422                                 key = translate_key(key);
1423
1424                                 if (keys == "")
1425                                         keys = key;
1426                                 else
1427                                         keys = strcat(keys, ", ", key);
1428
1429                                 ++l;
1430                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1431                                         break;
1432                         }
1433
1434                 }
1435                 if (keys == "")
1436                         keys = "NO_KEY";
1437                 db_put(binddb, command, keys);
1438         }
1439
1440         if (keys == "NO_KEY") {
1441                 if (autocvar_hud_showbinds > 1)
1442                         return sprintf(_("%s (not bound)"), cmd_name);
1443                 else
1444                         return cmd_name;
1445         }
1446         else if (autocvar_hud_showbinds > 1 || forcename)
1447                 return sprintf("%s (%s)", cmd_name, keys);
1448         else
1449                 return keys;
1450 }
1451
1452 /** engine callback */
1453 void URI_Get_Callback(int id, int status, string data)
1454 {
1455         TC(int, id); TC(int, status);
1456         if(url_URI_Get_Callback(id, status, data))
1457         {
1458                 // handled
1459         }
1460         else if (id == URI_GET_DISCARD)
1461         {
1462                 // discard
1463         }
1464         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1465         {
1466                 // sv_cmd curl
1467                 Curl_URI_Get_Callback(id, status, data);
1468         }
1469         else
1470         {
1471                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1472         }
1473 }