qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "casings.qh"
   4 #include "csqcmodel_hooks.qh"
   5 #include "damage.qh"
   6 #include "defs.qh"
   7 #include "effects.qh"
   8 #include "gibs.qh"
   9 #include "hud.qh"
  10 #include "hud_config.qh"
  11 #include "hook.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "scoreboard.qh"
  17 #include "shownames.qh"
  18 #include "sortlist.qh"
  19 #include "target_music.qh"
  20 #include "tturrets.qh"
  21 #include "tuba.qh"
  22 #include "wall.qh"
  23 #include "waypointsprites.qh"
  24 #include "miscfunctions.qh"
  25 #include "prandom.qh"
  26
  27 #include "vehicles/vehicles.qh"
  28
  29 #include "weapons/projectile.qh"
  30
  31 #include "../server/vehicles/bumblebee.qh"
  32 #include "../server/t_items.qh"
  33
  34 #include "../common/buffs.qh"
  35 #include "../common/deathtypes.qh"
  36 #include "../common/mapinfo.qh"
  37 #include "../common/notifications.qh"
  38 #include "../common/net_notice.qh"
  39 #include "../common/stats.qh"
  40 #include "../common/teams.qh"
  41
  42 #include "../common/weapons/weapons.qh"
  43 #include "../common/monsters/monsters.qh"
  44 #include "../common/nades.qh"
  45
  46 #include "../csqcmodellib/cl_model.qh"
  47 #include "../csqcmodellib/interpolate.qh"
  48
  49 #include "../warpzonelib/client.qh"
  50
  51 // --------------------------------------------------------------------------
  52 // BEGIN REQUIRED CSQC FUNCTIONS
  53 //include "main.qh"
  54
  55 entity clearentity_ent;
  56 void clearentity(entity e)
  57 {
  58         if (!clearentity_ent)
  59         {
  60                 clearentity_ent = spawn();
  61                 clearentity_ent.classname = "clearentity";
  62         }
  63         int n = e.entnum;
  64         copyentity(clearentity_ent, e);
  65         e.entnum = n;
  66 }
  67
  68 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  69 void menu_show_error()
  70 {
  71         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  72 }
  73
  74 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  75 // Useful for precaching things
  76
  77 void menu_sub_null()
  78 {
  79 }
  80
  81 string forcefog;
  82 void WaypointSprite_Load();
  83 void ConsoleCommand_macro_init();
  84 void CSQC_Init(void)
  85 {
  86         prvm_language = cvar_string("prvm_language");
  87
  88 #ifdef WATERMARK
  89         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  90 #endif
  91
  92         int i;
  93
  94         binddb = db_create();
  95         tempdb = db_create();
  96         ClientProgsDB = db_load("client.db");
  97         compressShortVector_init();
  98
  99         draw_endBoldFont();
 100         menu_visible = false;
 101         menu_show = menu_show_error;
 102         menu_action = func_null;
 103
 104         for(i = 0; i < 255; ++i)
 105                 if(getplayerkeyvalue(i, "viewentity") == "")
 106                         break;
 107         maxclients = i;
 108
 109         //registercommand("hud_configure");
 110         //registercommand("hud_save");
 111         //registercommand("menu_action");
 112
 113         ConsoleCommand_macro_init();
 114
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default");
 117
 118         registercvar("cl_nade_type", "3");
 119         registercvar("cl_pokenade_type", "zombie");
 120
 121         gametype = 0;
 122
 123         // hud_fields uses strunzone on the titles!
 124         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 125                 hud_title[i] = strzone("(null)");
 126
 127         Cmd_HUD_SetFields(0);
 128
 129         postinit = false;
 130
 131         calledhooks = 0;
 132
 133         teams = Sort_Spawn();
 134         players = Sort_Spawn();
 135
 136         GetTeam(NUM_SPECTATOR, true); // add specs first
 137
 138         // needs to be done so early because of the constants they create
 139         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 140         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 141         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 142         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 143         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 144         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 145         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 146
 147         WaypointSprite_Load();
 148
 149         // precaches
 150         precache_model("null");
 151         precache_sound("misc/hit.wav");
 152         precache_sound("misc/typehit.wav");
 153
 154         Projectile_Precache();
 155         Hook_Precache();
 156         GibSplash_Precache();
 157         Casings_Precache();
 158         Vehicles_Precache();
 159         turrets_precache();
 160         Tuba_Precache();
 161         CSQCPlayer_Precache();
 162
 163         if(autocvar_cl_reticle)
 164         {
 165                 precache_pic("gfx/reticle_normal");
 166                 // weapon reticles are precached in weapon files
 167         }
 168
 169         get_mi_min_max_texcoords(1); // try the CLEVER way first
 170         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 171         shortmapname = mi_shortname;
 172
 173         if(precache_pic(minimapname) == "")
 174         {
 175                 // but maybe we have a non-clever minimap
 176                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 177                 if(precache_pic(minimapname) == "")
 178                         minimapname = ""; // FAIL
 179                 else
 180                         get_mi_min_max_texcoords(0); // load new texcoords
 181         }
 182
 183         mi_center = (mi_min + mi_max) * 0.5;
 184         mi_scale = mi_max - mi_min;
 185         minimapname = strzone(minimapname);
 186
 187         WarpZone_Init();
 188
 189         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 190         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 191 }
 192
 193 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 194 void Shutdown(void)
 195 {
 196         WarpZone_Shutdown();
 197
 198         remove(teams);
 199         remove(players);
 200         db_close(binddb);
 201         db_close(tempdb);
 202         if(autocvar_cl_db_saveasdump)
 203                 db_dump(ClientProgsDB, "client.db");
 204         else
 205                 db_save(ClientProgsDB, "client.db");
 206         db_close(ClientProgsDB);
 207
 208         if(camera_active)
 209                 cvar_set("chase_active",ftos(chase_active_backup));
 210
 211         // unset the event chasecam's chase_active
 212         if(autocvar_chase_active < 0)
 213                 cvar_set("chase_active", "0");
 214
 215         if (!isdemo())
 216         {
 217                 if (!(calledhooks & HOOK_START))
 218                         localcmd("\n_cl_hook_gamestart nop\n");
 219                 if (!(calledhooks & HOOK_END))
 220                         localcmd("\ncl_hook_gameend\n");
 221         }
 222 }
 223
 224 .float has_team;
 225 float SetTeam(entity o, int Team)
 226 {
 227         entity tm;
 228         if(teamplay)
 229         {
 230                 switch(Team)
 231                 {
 232                         case -1:
 233                         case NUM_TEAM_1:
 234                         case NUM_TEAM_2:
 235                         case NUM_TEAM_3:
 236                         case NUM_TEAM_4:
 237                                 break;
 238                         default:
 239                                 if(GetTeam(Team, false) == world)
 240                                 {
 241                                         dprintf("trying to switch to unsupported team %d\n", Team);
 242                                         Team = NUM_SPECTATOR;
 243                                 }
 244                                 break;
 245                 }
 246         }
 247         else
 248         {
 249                 switch(Team)
 250                 {
 251                         case -1:
 252                         case 0:
 253                                 break;
 254                         default:
 255                                 if(GetTeam(Team, false) == world)
 256                                 {
 257                                         dprintf("trying to switch to unsupported team %d\n", Team);
 258                                         Team = NUM_SPECTATOR;
 259                                 }
 260                                 break;
 261                 }
 262         }
 263         if(Team == -1) // leave
 264         {
 265                 if(o.has_team)
 266                 {
 267                         tm = GetTeam(o.team, false);
 268                         tm.team_size -= 1;
 269                         o.has_team = 0;
 270                         return true;
 271                 }
 272         }
 273         else
 274         {
 275                 if (!o.has_team)
 276                 {
 277                         o.team = Team;
 278                         tm = GetTeam(Team, true);
 279                         tm.team_size += 1;
 280                         o.has_team = 1;
 281                         return true;
 282                 }
 283                 else if(Team != o.team)
 284                 {
 285                         tm = GetTeam(o.team, false);
 286                         tm.team_size -= 1;
 287                         o.team = Team;
 288                         tm = GetTeam(Team, true);
 289                         tm.team_size += 1;
 290                         return true;
 291                 }
 292         }
 293         return false;
 294 }
 295
 296 void Playerchecker_Think()
 297 {
 298     int i;
 299         entity e;
 300         for(i = 0; i < maxclients; ++i)
 301         {
 302                 e = playerslots[i];
 303                 if(GetPlayerName(i) == "")
 304                 {
 305                         if(e.sort_prev)
 306                         {
 307                                 // player disconnected
 308                                 SetTeam(e, -1);
 309                                 RemovePlayer(e);
 310                                 e.sort_prev = world;
 311                                 //e.gotscores = 0;
 312                         }
 313                 }
 314                 else
 315                 {
 316                         if (!e.sort_prev)
 317                         {
 318                                 // player connected
 319                                 if (!e)
 320                                         playerslots[i] = e = spawn();
 321                                 e.sv_entnum = i;
 322                                 e.ping = 0;
 323                                 e.ping_packetloss = 0;
 324                                 e.ping_movementloss = 0;
 325                                 //e.gotscores = 0; // we might already have the scores...
 326                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 HUD_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         self.nextthink = time + 0.2;
 333 }
 334
 335 void Porto_Init();
 336 void TrueAim_Init();
 337 void PostInit(void)
 338 {
 339         entity playerchecker;
 340         playerchecker = spawn();
 341         playerchecker.think = Playerchecker_Think;
 342         playerchecker.nextthink = time + 0.2;
 343
 344         Porto_Init();
 345         TrueAim_Init();
 346
 347         postinit = true;
 348 }
 349
 350 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 351 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 352 // All keys are in ascii.
 353 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 354 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 355 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 356 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 357 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 358 {
 359         float bSkipKey;
 360         bSkipKey = false;
 361
 362         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 363                 return true;
 364
 365         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 366                 return true;
 367
 368         if(menu_visible && menu_action)
 369                 if(menu_action(bInputType, nPrimary, nSecondary))
 370                         return true;
 371
 372         return bSkipKey;
 373 }
 374
 375 // END REQUIRED CSQC FUNCTIONS
 376 // --------------------------------------------------------------------------
 377
 378 // --------------------------------------------------------------------------
 379 // BEGIN OPTIONAL CSQC FUNCTIONS
 380 void Ent_RemoveEntCS()
 381 {
 382         entcs_receiver[self.sv_entnum] = world;
 383 }
 384 void Ent_ReadEntCS()
 385 {
 386     int sf;
 387         InterpolateOrigin_Undo();
 388
 389         self.classname = "entcs_receiver";
 390         sf = ReadByte();
 391
 392         if(sf & 1)
 393                 self.sv_entnum = ReadByte();
 394         if(sf & 2)
 395         {
 396                 self.origin_x = ReadShort();
 397                 self.origin_y = ReadShort();
 398                 self.origin_z = ReadShort();
 399                 setorigin(self, self.origin);
 400         }
 401         if(sf & 4)
 402         {
 403                 self.angles_y = ReadByte() * 360.0 / 256;
 404                 self.angles_x = self.angles_z = 0;
 405         }
 406         if(sf & 8)
 407                 self.healthvalue = ReadByte() * 10;
 408         if(sf & 16)
 409                 self.armorvalue = ReadByte() * 10;
 410
 411         entcs_receiver[self.sv_entnum] = self;
 412         self.entremove = Ent_RemoveEntCS;
 413         self.iflags |= IFLAG_ORIGIN;
 414
 415         InterpolateOrigin_Note();
 416 }
 417
 418 void Ent_Remove();
 419
 420 void Ent_RemovePlayerScore()
 421 {
 422         if(self.owner) {
 423                 SetTeam(self.owner, -1);
 424                 self.owner.gotscores = 0;
 425                 for(int i = 0; i < MAX_SCORE; ++i) {
 426                         self.owner.(scores[i]) = 0; // clear all scores
 427                 }
 428         }
 429 }
 430
 431 void Ent_ReadPlayerScore()
 432 {
 433         int i, n;
 434         bool isNew;
 435         entity o;
 436
 437         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 438         // (no I've never heard of M-x replace-string, sed, or anything like that)
 439         isNew = !self.owner; // workaround for DP bug
 440         n = ReadByte()-1;
 441
 442 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 443         if(!isNew && n != self.sv_entnum)
 444         {
 445                 //print("A CSQC entity changed its owner!\n");
 446                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 447                 isNew = true;
 448                 Ent_Remove();
 449                 self.enttype = ENT_CLIENT_SCORES;
 450         }
 451 #endif
 452
 453         self.sv_entnum = n;
 454
 455         if (!(playerslots[self.sv_entnum]))
 456                 playerslots[self.sv_entnum] = spawn();
 457         o = self.owner = playerslots[self.sv_entnum];
 458         o.sv_entnum = self.sv_entnum;
 459         o.gotscores = 1;
 460
 461         //if (!o.sort_prev)
 462         //      RegisterPlayer(o);
 463         //playerchecker will do this for us later, if it has not already done so
 464
 465     int sf, lf;
 466 #if MAX_SCORE <= 8
 467         sf = ReadByte();
 468         lf = ReadByte();
 469 #else
 470         sf = ReadShort();
 471         lf = ReadShort();
 472 #endif
 473     int p;
 474         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 475                 if(sf & p)
 476                 {
 477                         if(lf & p)
 478                                 o.(scores[i]) = ReadInt24_t();
 479                         else
 480                                 o.(scores[i]) = ReadChar();
 481                 }
 482
 483         if(o.sort_prev)
 484                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 485
 486         self.entremove = Ent_RemovePlayerScore;
 487 }
 488
 489 void Ent_ReadTeamScore()
 490 {
 491         int i;
 492         entity o;
 493
 494         self.team = ReadByte();
 495         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 496
 497     int sf, lf;
 498 #if MAX_TEAMSCORE <= 8
 499         sf = ReadByte();
 500         lf = ReadByte();
 501 #else
 502         sf = ReadShort();
 503         lf = ReadShort();
 504 #endif
 505         int p;
 506         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 507                 if(sf & p)
 508                 {
 509                         if(lf & p)
 510                                 o.(teamscores[i]) = ReadInt24_t();
 511                         else
 512                                 o.(teamscores[i]) = ReadChar();
 513                 }
 514
 515         HUD_UpdateTeamPos(o);
 516 }
 517
 518 void Ent_ClientData()
 519 {
 520         float newspectatee_status;
 521
 522     int f = ReadByte();
 523
 524         scoreboard_showscores_force = (f & 1);
 525
 526         if(f & 2)
 527         {
 528                 newspectatee_status = ReadByte();
 529                 if(newspectatee_status == player_localnum + 1)
 530                         newspectatee_status = -1; // observing
 531         }
 532         else
 533                 newspectatee_status = 0;
 534
 535         spectatorbutton_zoom = (f & 4);
 536
 537         if(f & 8)
 538         {
 539                 angles_held_status = 1;
 540                 angles_held.x = ReadAngle();
 541                 angles_held.y = ReadAngle();
 542                 angles_held.z = 0;
 543         }
 544         else
 545                 angles_held_status = 0;
 546
 547         if(newspectatee_status != spectatee_status)
 548         {
 549                 // clear race stuff
 550                 race_laptime = 0;
 551                 race_checkpointtime = 0;
 552         }
 553         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 554         {
 555                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 556                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 557                 )
 558                         prev_p_health = -1;
 559                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 560                         prev_health = -1;
 561         }
 562         spectatee_status = newspectatee_status;
 563
 564         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 565 }
 566
 567 void Ent_Nagger()
 568 {
 569     int i, j, b, f;
 570
 571     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 572
 573         if(!(nags & 4))
 574         {
 575                 if(vote_called_vote)
 576                         strunzone(vote_called_vote);
 577                 vote_called_vote = string_null;
 578                 vote_active = 0;
 579         }
 580         else
 581         {
 582                 vote_active = 1;
 583         }
 584
 585         if(nags & 64)
 586         {
 587                 vote_yescount = ReadByte();
 588                 vote_nocount = ReadByte();
 589                 vote_needed = ReadByte();
 590                 vote_highlighted = ReadChar();
 591         }
 592
 593         if(nags & 128)
 594         {
 595                 if(vote_called_vote)
 596                         strunzone(vote_called_vote);
 597                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 598         }
 599
 600         if(nags & 1)
 601         {
 602                 for(j = 0; j < maxclients; ++j)
 603                         if(playerslots[j])
 604                                 playerslots[j].ready = 1;
 605                 for(i = 1; i <= maxclients; i += 8)
 606                 {
 607                         f = ReadByte();
 608                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 609                                 if (!(f & b))
 610                                         if(playerslots[j])
 611                                                 playerslots[j].ready = 0;
 612                 }
 613         }
 614
 615         ready_waiting = (nags & 1);
 616         ready_waiting_for_me = (nags & 2);
 617         vote_waiting = (nags & 4);
 618         vote_waiting_for_me = (nags & 8);
 619         warmup_stage = (nags & 16);
 620 }
 621
 622 void Ent_EliminatedPlayers()
 623 {
 624     int i, j, b, f;
 625
 626     int sf = ReadByte();
 627         if(sf & 1)
 628         {
 629                 for(j = 0; j < maxclients; ++j)
 630                         if(playerslots[j])
 631                                 playerslots[j].eliminated = 1;
 632                 for(i = 1; i <= maxclients; i += 8)
 633                 {
 634                         f = ReadByte();
 635                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 636                                 if (!(f & b))
 637                                         if(playerslots[j])
 638                                                 playerslots[j].eliminated = 0;
 639                 }
 640         }
 641 }
 642
 643 void Ent_RandomSeed()
 644 {
 645         float s;
 646         prandom_debug();
 647         s = ReadShort();
 648         psrandom(s);
 649 }
 650
 651 void Ent_ReadAccuracy(void)
 652 {
 653     int f, w;
 654     int sf = ReadInt24_t();
 655         if(sf == 0)
 656         {
 657                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 658                         weapon_accuracy[w] = -1;
 659                 return;
 660         }
 661
 662         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 663         {
 664                 if(sf & f)
 665                 {
 666             int b = ReadByte();
 667                         if(b == 0)
 668                                 weapon_accuracy[w] = -1;
 669                         else if(b == 255)
 670                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 671                         else
 672                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 673                 }
 674                 if(f == 0x800000)
 675                         f = 1;
 676                 else
 677                         f *= 2;
 678         }
 679 }
 680
 681 void Spawn_Draw(void)
 682 {
 683         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 684 }
 685
 686 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 687 {
 688         float teamnum = (ReadByte() - 1);
 689         vector spn_origin;
 690         spn_origin.x = ReadShort();
 691         spn_origin.y = ReadShort();
 692         spn_origin.z = ReadShort();
 693
 694         if(is_new)
 695         {
 696                 self.origin = spn_origin;
 697                 setsize(self, PL_MIN, PL_MAX);
 698                 droptofloor();
 699
 700                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 701                 {
 702                         self.mdl = "models/spawnpoint.md3";
 703                         self.colormod = Team_ColorRGB(teamnum);
 704                         precache_model(self.mdl);
 705                         setmodel(self, self.mdl);
 706                         self.drawmask = MASK_NORMAL;
 707                         //self.movetype = MOVETYPE_NOCLIP;
 708                         //self.draw = Spawn_Draw;
 709                 }*/
 710                 if(autocvar_cl_spawn_point_particles)
 711                 {
 712                         if((serverflags & SERVERFLAG_TEAMPLAY))
 713                         {
 714                                 switch(teamnum)
 715                                 {
 716                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 717                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 718                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 719                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 720                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 721                                 }
 722                         }
 723                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 724
 725                         self.draw = Spawn_Draw;
 726                 }
 727         }
 728
 729         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 730 }
 731
 732 void Ent_ReadSpawnEvent(float is_new)
 733 {
 734         // If entnum is 0, ONLY do the local spawn actions
 735         // this way the server can disable the sending of
 736         // spawn origin or such to clients if wanted.
 737         float entnum = ReadByte();
 738
 739         if(entnum)
 740         {
 741                 self.origin_x = ReadShort();
 742                 self.origin_y = ReadShort();
 743                 self.origin_z = ReadShort();
 744
 745                 if(is_new)
 746                 {
 747                         float teamnum = GetPlayerColor(entnum - 1);
 748
 749                         if(autocvar_cl_spawn_event_particles)
 750                         {
 751                                 switch(teamnum)
 752                                 {
 753                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 754                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 755                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 756                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 757                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 758                                 }
 759                         }
 760                         if(autocvar_cl_spawn_event_sound)
 761                         {
 762                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 763                         }
 764                 }
 765         }
 766
 767         // local spawn actions
 768         if(is_new && (!entnum || (entnum == player_localentnum)))
 769         {
 770                 zoomin_effect = 1;
 771                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 772
 773                 if(autocvar_cl_unpress_zoom_on_spawn)
 774                 {
 775                         localcmd("-zoom\n");
 776                         button_zoom = false;
 777                 }
 778         }
 779
 780         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 781 }
 782
 783 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 784 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 785 void Ent_RadarLink();
 786 void Ent_Init();
 787 void Ent_ScoresInfo();
 788 void CSQC_Ent_Update(float bIsNewEntity)
 789 {
 790         float t;
 791         float savetime;
 792         t = ReadByte();
 793
 794         if(autocvar_developer_csqcentities)
 795                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 796
 797         // set up the "time" global for received entities to be correct for interpolation purposes
 798         savetime = time;
 799         if(servertime)
 800         {
 801                 time = servertime;
 802         }
 803         else
 804         {
 805                 serverprevtime = time;
 806                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 807                 time = serverprevtime + serverdeltatime;
 808         }
 809
 810 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 811         if(self.enttype)
 812         {
 813                 if(t != self.enttype || bIsNewEntity)
 814                 {
 815                         //print("A CSQC entity changed its type!\n");
 816                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 817                         Ent_Remove();
 818                         clearentity(self);
 819                         bIsNewEntity = 1;
 820                 }
 821         }
 822         else
 823         {
 824                 if(!bIsNewEntity)
 825                 {
 826                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 827                         bIsNewEntity = 1;
 828                 }
 829         }
 830 #endif
 831         self.enttype = t;
 832         switch(t)
 833         {
 834                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 835                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 836                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 837                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 838                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 839                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 840                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 841                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 842                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 843                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 844                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 845                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 846                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 847                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 848                 case ENT_CLIENT_INIT: Ent_Init(); break;
 849                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 850                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 851                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 852                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 853                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 854                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 855                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 856                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 857                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 858                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 859                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 860                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 861                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 862                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 863                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 864                 case ENT_CLIENT_TURRET: ent_turret(); break;
 865                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 866                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 867                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 868                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 869                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 870                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 871                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 872
 873                 default:
 874                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 875                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 876                         break;
 877         }
 878
 879         time = savetime;
 880 }
 881 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 882 // used when an entity changes its type. For an entity that someone interacts
 883 // with others, make sure it can no longer do so.
 884 void Ent_Remove()
 885 {
 886         if(self.entremove)
 887                 self.entremove();
 888
 889         if(self.skeletonindex)
 890         {
 891                 skel_delete(self.skeletonindex);
 892                 self.skeletonindex = 0;
 893         }
 894
 895         if(self.snd_looping > 0)
 896         {
 897                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 898                 self.snd_looping = 0;
 899         }
 900
 901         self.enttype = 0;
 902         self.classname = "";
 903         self.draw = menu_sub_null;
 904         self.entremove = menu_sub_null;
 905         // TODO possibly set more stuff to defaults
 906 }
 907 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 908 void CSQC_Ent_Remove()
 909 {
 910         if(autocvar_developer_csqcentities)
 911                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 912
 913         if(wasfreed(self))
 914         {
 915                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 916                 return;
 917         }
 918         if(self.enttype)
 919                 Ent_Remove();
 920         remove(self);
 921 }
 922
 923 void Gamemode_Init()
 924 {
 925         if (!isdemo())
 926         {
 927                 if(!(calledhooks & HOOK_START))
 928                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 929                 calledhooks |= HOOK_START;
 930         }
 931 }
 932 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 933 void CSQC_Parse_StuffCmd(string strMessage)
 934 {
 935         if(autocvar_developer_csqcentities)
 936                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 937
 938         localcmd(strMessage);
 939 }
 940 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 941 void CSQC_Parse_Print(string strMessage)
 942 {
 943         if(autocvar_developer_csqcentities)
 944                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 945
 946         print(ColorTranslateRGB(strMessage));
 947 }
 948
 949 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 950 void CSQC_Parse_CenterPrint(string strMessage)
 951 {
 952         if(autocvar_developer_csqcentities)
 953                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 954
 955         centerprint_hud(strMessage);
 956 }
 957
 958 string notranslate_fogcmd1 = "\nfog ";
 959 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 960 void Fog_Force()
 961 {
 962         // TODO somehow thwart prvm_globalset client ...
 963
 964         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 965                 { localcmd("\nr_drawfog 0\n"); }
 966         else if(forcefog != "")
 967                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 968 }
 969
 970 void Gamemode_Init();
 971 void Ent_ScoresInfo()
 972 {
 973     int i;
 974         self.classname = "ent_client_scores_info";
 975         gametype = ReadInt24_t();
 976         HUD_ModIcons_SetFunc();
 977         for(i = 0; i < MAX_SCORE; ++i)
 978         {
 979                 if(scores_label[i])
 980                         strunzone(scores_label[i]);
 981                 scores_label[i] = strzone(ReadString());
 982                 scores_flags[i] = ReadByte();
 983         }
 984         for(i = 0; i < MAX_TEAMSCORE; ++i)
 985         {
 986                 if(teamscores_label[i])
 987                         strunzone(teamscores_label[i]);
 988                 teamscores_label[i] = strzone(ReadString());
 989                 teamscores_flags[i] = ReadByte();
 990         }
 991         HUD_InitScores();
 992         Gamemode_Init();
 993 }
 994
 995 void Ent_Init()
 996 {
 997         self.classname = "ent_client_init";
 998
 999         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1000
1001         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1002         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1003         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1004         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1005         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1006         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1007         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1008         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1009
1010         if(forcefog)
1011                 strunzone(forcefog);
1012         forcefog = strzone(ReadString());
1013
1014         armorblockpercent = ReadByte() / 255.0;
1015
1016         g_balance_mortar_bouncefactor = ReadCoord();
1017         g_balance_mortar_bouncestop = ReadCoord();
1018         g_balance_electro_secondary_bouncefactor = ReadCoord();
1019         g_balance_electro_secondary_bouncestop = ReadCoord();
1020
1021         vortex_scope = !ReadByte();
1022         rifle_scope = !ReadByte();
1023
1024         serverflags = ReadByte();
1025
1026         minelayer_maxmines = ReadByte();
1027
1028         hagar_maxrockets = ReadByte();
1029
1030         g_trueaim_minrange = ReadCoord();
1031         g_balance_porto_secondary = ReadByte();
1032
1033         if(!postinit)
1034                 PostInit();
1035 }
1036
1037 void Net_ReadRace()
1038 {
1039         float b;
1040
1041         b = ReadByte();
1042
1043         switch(b)
1044         {
1045                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1046                         race_checkpoint = ReadByte();
1047                         race_time = ReadInt24_t();
1048                         race_previousbesttime = ReadInt24_t();
1049                         if(race_previousbestname)
1050                                 strunzone(race_previousbestname);
1051                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1052
1053                         race_checkpointtime = time;
1054
1055                         if(race_checkpoint == 0 || race_checkpoint == 254)
1056                         {
1057                                 race_penaltyaccumulator = 0;
1058                                 race_laptime = time; // valid
1059                         }
1060
1061                         break;
1062
1063                 case RACE_NET_CHECKPOINT_CLEAR:
1064                         race_laptime = 0;
1065                         race_checkpointtime = 0;
1066                         break;
1067
1068                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1069                         race_laptime = ReadCoord();
1070                         race_checkpointtime = -99999;
1071                         // fall through
1072                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1073                         race_nextcheckpoint = ReadByte();
1074
1075                         race_nextbesttime = ReadInt24_t();
1076                         if(race_nextbestname)
1077                                 strunzone(race_nextbestname);
1078                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1079                         break;
1080
1081                 case RACE_NET_CHECKPOINT_HIT_RACE:
1082                         race_mycheckpoint = ReadByte();
1083                         race_mycheckpointtime = time;
1084                         race_mycheckpointdelta = ReadInt24_t();
1085                         race_mycheckpointlapsdelta = ReadByte();
1086                         if(race_mycheckpointlapsdelta >= 128)
1087                                 race_mycheckpointlapsdelta -= 256;
1088                         if(race_mycheckpointenemy)
1089                                 strunzone(race_mycheckpointenemy);
1090                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1091                         break;
1092
1093                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1094                         race_othercheckpoint = ReadByte();
1095                         race_othercheckpointtime = time;
1096                         race_othercheckpointdelta = ReadInt24_t();
1097                         race_othercheckpointlapsdelta = ReadByte();
1098                         if(race_othercheckpointlapsdelta >= 128)
1099                                 race_othercheckpointlapsdelta -= 256;
1100                         if(race_othercheckpointenemy)
1101                                 strunzone(race_othercheckpointenemy);
1102                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1103                         break;
1104
1105                 case RACE_NET_PENALTY_RACE:
1106                         race_penaltyeventtime = time;
1107                         race_penaltytime = ReadShort();
1108                         //race_penaltyaccumulator += race_penaltytime;
1109                         if(race_penaltyreason)
1110                                 strunzone(race_penaltyreason);
1111                         race_penaltyreason = strzone(ReadString());
1112                         break;
1113
1114                 case RACE_NET_PENALTY_QUALIFYING:
1115                         race_penaltyeventtime = time;
1116                         race_penaltytime = ReadShort();
1117                         race_penaltyaccumulator += race_penaltytime;
1118                         if(race_penaltyreason)
1119                                 strunzone(race_penaltyreason);
1120                         race_penaltyreason = strzone(ReadString());
1121                         break;
1122
1123                 case RACE_NET_SERVER_RECORD:
1124                         race_server_record = ReadInt24_t();
1125                         break;
1126                 case RACE_NET_SPEED_AWARD:
1127                         race_speedaward = ReadInt24_t();
1128                         if(race_speedaward_holder)
1129                                 strunzone(race_speedaward_holder);
1130                         race_speedaward_holder = strzone(ReadString());
1131                         break;
1132                 case RACE_NET_SPEED_AWARD_BEST:
1133                         race_speedaward_alltimebest = ReadInt24_t();
1134                         if(race_speedaward_alltimebest_holder)
1135                                 strunzone(race_speedaward_alltimebest_holder);
1136                         race_speedaward_alltimebest_holder = strzone(ReadString());
1137                         break;
1138                 case RACE_NET_SERVER_RANKINGS:
1139                         float prevpos, del;
1140             int pos = ReadShort();
1141                         prevpos = ReadShort();
1142                         del = ReadShort();
1143
1144                         // move other rankings out of the way
1145             int i;
1146                         if (prevpos) {
1147                                 for (i=prevpos-1;i>pos-1;--i) {
1148                                         grecordtime[i] = grecordtime[i-1];
1149                                         if(grecordholder[i])
1150                                                 strunzone(grecordholder[i]);
1151                                         grecordholder[i] = strzone(grecordholder[i-1]);
1152                                 }
1153                         } else if (del) { // a record has been deleted by the admin
1154                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1155                                         if (i == RANKINGS_CNT-1) { // clear out last record
1156                                                 grecordtime[i] = 0;
1157                                                 if (grecordholder[i])
1158                                                         strunzone(grecordholder[i]);
1159                                                 grecordholder[i] = string_null;
1160                                         }
1161                                         else {
1162                                                 grecordtime[i] = grecordtime[i+1];
1163                                                 if (grecordholder[i])
1164                                                         strunzone(grecordholder[i]);
1165                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1166                                         }
1167                                 }
1168                         } else { // player has no ranked record yet
1169                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1170                                         grecordtime[i] = grecordtime[i-1];
1171                                         if(grecordholder[i])
1172                                                 strunzone(grecordholder[i]);
1173                                         grecordholder[i] = strzone(grecordholder[i-1]);
1174                                 }
1175                         }
1176
1177                         // store new ranking
1178                         if(grecordholder[pos-1] != "")
1179                                 strunzone(grecordholder[pos-1]);
1180                         grecordholder[pos-1] = strzone(ReadString());
1181                         grecordtime[pos-1] = ReadInt24_t();
1182                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1183                                 race_myrank = pos;
1184                         break;
1185                 case RACE_NET_SERVER_STATUS:
1186                         race_status = ReadShort();
1187                         if(race_status_name)
1188                                 strunzone(race_status_name);
1189                         race_status_name = strzone(ReadString());
1190         }
1191 }
1192
1193 void Net_TeamNagger()
1194 {
1195         teamnagger = 1;
1196 }
1197
1198 void Net_ReadPingPLReport()
1199 {
1200         int e, pi, pl, ml;
1201         e = ReadByte();
1202         pi = ReadShort();
1203         pl = ReadByte();
1204         ml = ReadByte();
1205         if (!(playerslots[e]))
1206                 return;
1207         playerslots[e].ping = pi;
1208         playerslots[e].ping_packetloss = pl / 255.0;
1209         playerslots[e].ping_movementloss = ml / 255.0;
1210 }
1211
1212 void Net_WeaponComplain()
1213 {
1214         complain_weapon = ReadByte();
1215
1216         if(complain_weapon_name)
1217                 strunzone(complain_weapon_name);
1218         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1219
1220         complain_weapon_type = ReadByte();
1221
1222         complain_weapon_time = time;
1223         weapontime = time; // ping the weapon panel
1224
1225         switch(complain_weapon_type)
1226         {
1227                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1228                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1229                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1230         }
1231 }
1232
1233 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1234 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1235 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1236 float CSQC_Parse_TempEntity()
1237 {
1238         float bHandled;
1239                 bHandled  = true;
1240         // Acquire TE ID
1241         float nTEID;
1242                 nTEID = ReadByte();
1243
1244         if(autocvar_developer_csqcentities)
1245                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1246
1247                 // NOTE: Could just do return instead of break...
1248         switch(nTEID)
1249         {
1250                 case TE_CSQC_TARGET_MUSIC:
1251                         Net_TargetMusic();
1252                         bHandled = true;
1253                         break;
1254                 case TE_CSQC_PICTURE:
1255                         Net_MapVote_Picture();
1256                         bHandled = true;
1257                         break;
1258                 case TE_CSQC_RACE:
1259                         Net_ReadRace();
1260                         bHandled = true;
1261                         break;
1262                 case TE_CSQC_VORTEXBEAMPARTICLE:
1263                         Net_ReadVortexBeamParticle();
1264                         bHandled = true;
1265                         break;
1266                 case TE_CSQC_TEAMNAGGER:
1267                         Net_TeamNagger();
1268                         bHandled = true;
1269                         break;
1270                 case TE_CSQC_ARC:
1271                         Net_ReadArc();
1272                         bHandled = true;
1273                         break;
1274                 case TE_CSQC_PINGPLREPORT:
1275                         Net_ReadPingPLReport();
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_WEAPONCOMPLAIN:
1279                         Net_WeaponComplain();
1280                         bHandled = true;
1281                         break;
1282                 case TE_CSQC_VEHICLESETUP:
1283                         Net_VehicleSetup();
1284                         bHandled = true;
1285                         break;
1286                 case TE_CSQC_SVNOTICE:
1287                         cl_notice_read();
1288                         bHandled = true;
1289                         break;
1290                 case TE_CSQC_SHOCKWAVEPARTICLE:
1291                         Net_ReadShockwaveParticle();
1292                         bHandled = true;
1293                         break;
1294                 default:
1295                         // No special logic for this temporary entity; return 0 so the engine can handle it
1296                         bHandled = false;
1297                         break;
1298         }
1299
1300         return bHandled;
1301 }
1302
1303 string getcommandkey(string text, string command)
1304 {
1305         string keys;
1306         float n, j, k, l = 0;
1307
1308         if (!autocvar_hud_showbinds)
1309                 return text;
1310
1311         keys = db_get(binddb, command);
1312         if (keys == "")
1313         {
1314                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1315                 for(j = 0; j < n; ++j)
1316                 {
1317                         k = stof(argv(j));
1318                         if(k != -1)
1319                         {
1320                                 if ("" == keys)
1321                                         keys = keynumtostring(k);
1322                                 else
1323                                         keys = strcat(keys, ", ", keynumtostring(k));
1324
1325                                 ++l;
1326                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1327                                         break;
1328                         }
1329
1330                 }
1331                 if (keys == "")
1332                         keys = "NO_KEY";
1333                 db_put(binddb, command, keys);
1334         }
1335
1336         if (keys == "NO_KEY") {
1337                 if (autocvar_hud_showbinds > 1)
1338                         return sprintf(_("%s (not bound)"), text);
1339                 else
1340                         return text;
1341         }
1342         else if (autocvar_hud_showbinds > 1)
1343                 return sprintf("%s (%s)", text, keys);
1344         else
1345                 return keys;
1346 }