qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/checkextension.qh>
  17 #include <common/deathtypes/all.qh>
  18 #include <common/effects/all.inc>
  19 #include <common/effects/all.qh>
  20 #include <common/effects/effect.qh>
  21 #include <common/effects/qc/_mod.qh>
  22 #include <common/ent_cs.qh>
  23 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  24 #include <common/items/_mod.qh>
  25 #include <common/mapinfo.qh>
  26 #include <common/mapobjects/_mod.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/scores.qh>
  32 #include <common/vehicles/all.qh>
  33 #include <lib/csqcmodel/cl_model.qh>
  34 #include <lib/csqcmodel/interpolate.qh>
  35 #include <lib/warpzone/client.qh>
  36
  37 // --------------------------------------------------------------------------
  38 // BEGIN REQUIRED CSQC FUNCTIONS
  39 //include "main.qh"
  40
  41 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  42
  43 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  44 // Useful for precaching things
  45
  46 void CSQC_Init(float apilevel, string enginename, float engineversion)
  47 {
  48         prvm_language = strzone(cvar_string("prvm_language"));
  49
  50 #ifdef WATERMARK
  51         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  52 #endif
  53
  54         CheckEngineExtensions();
  55
  56         {
  57                 int i = 0;
  58                 for ( ; i < 255; ++i)
  59                         if (getplayerkeyvalue(i, "viewentity") == "")
  60                                 break;
  61                 maxclients = i;
  62         }
  63
  64         // needs to be done so early because of the constants they create
  65         static_init();
  66         static_init_late();
  67         static_init_precache();
  68
  69         binddb = db_create();
  70         tempdb = db_create();
  71         ClientProgsDB = db_load("client.db");
  72
  73         draw_endBoldFont();
  74
  75         //registercommand("hud_configure");
  76         //registercommand("hud_save");
  77         //registercommand("menu_action");
  78
  79         ConsoleCommand_macro_init();
  80
  81         registercvar("hud_usecsqc", "1");
  82         registercvar("scoreboard_columns", "default");
  83
  84         registercvar("cl_nade_type", "3");
  85         registercvar("cl_pokenade_type", "zombie");
  86
  87         registercvar("cl_jumpspeedcap_min", "");
  88         registercvar("cl_jumpspeedcap_max", "");
  89
  90         registercvar("cl_shootfromfixedorigin", "");
  91
  92         registercvar("cl_multijump", "-1");
  93
  94         registercvar("cl_dodging", "0");
  95
  96         registercvar("cl_spawn_near_teammate", "1");
  97
  98         registercvar("cl_weapon_switch_reload", "1");
  99         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 100
 101         registercvar("cl_allow_uidranking", "1");
 102
 103         if(autocvar_cl_lockview)
 104                 cvar_set("cl_lockview", "0");
 105
 106         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 107                 cvar_settemp("_scoreboard_team_selection_available", "1");
 108         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 109
 110         gametype = NULL;
 111
 112         postinit = false;
 113
 114         calledhooks = 0;
 115
 116         teams = Sort_Spawn();
 117         players = Sort_Spawn();
 118
 119         GetTeam(NUM_SPECTATOR, true); // add specs first
 120
 121         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 122                 weapon_accuracy[w] = -1;
 123
 124         // precaches
 125
 126         if(autocvar_cl_reticle)
 127         {
 128                 precache_pic("gfx/reticle_normal");
 129                 // weapon reticles are precached in weapon files
 130         }
 131
 132         {
 133                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 134                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 135
 136                 if (precache_pic(minimapname) == "")
 137                 {
 138                         // but maybe we have a non-clever minimap
 139                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 140                         if (precache_pic(minimapname) == "")
 141                                 minimapname = ""; // FAIL
 142                         else
 143                                 get_mi_min_max_texcoords(0); // load new texcoords
 144                 }
 145
 146                 mi_center = (mi_min + mi_max) * 0.5;
 147                 mi_scale = mi_max - mi_min;
 148                 minimapname = strzone(minimapname);
 149         }
 150
 151         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 152         LoadMenuSkinValues();
 153 }
 154
 155 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 156 void Shutdown()
 157 {
 158         WarpZone_Shutdown();
 159
 160         delete(teams);
 161         delete(players);
 162         db_close(binddb);
 163         db_close(tempdb);
 164         if(autocvar_cl_db_saveasdump)
 165                 db_dump(ClientProgsDB, "client.db");
 166         else
 167                 db_save(ClientProgsDB, "client.db");
 168         db_close(ClientProgsDB);
 169
 170         if(camera_active)
 171                 cvar_set("chase_active",ftos(chase_active_backup));
 172
 173         // unset the event chasecam's chase_active
 174         if(autocvar_chase_active < 0)
 175                 cvar_set("chase_active", "0");
 176
 177         if (autocvar_r_drawviewmodel < 0)
 178                 cvar_set("r_drawviewmodel", "0");
 179
 180         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 181
 182         if (!isdemo())
 183         {
 184                 if (!(calledhooks & HOOK_START))
 185                         localcmd("\n_cl_hook_gamestart nop\n");
 186                 if (!(calledhooks & HOOK_END))
 187                 {
 188                         int gamecount = cvar("cl_matchcount");
 189                         localcmd("\ncl_hook_gameend\n");
 190                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 191                         // earlier versions of the game abuse the hook to set this cvar
 192                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 193                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 194                 }
 195         }
 196
 197         localcmd("\ncl_hook_shutdown\n");
 198
 199         localcmd("\n-button12\n");
 200
 201         strfree(gametype_custom_name);
 202
 203         deactivate_minigame();
 204         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 205
 206         ReplicateVars(REPLICATEVARS_DESTROY);
 207 }
 208
 209 void AuditLists()
 210 {
 211         entity e;
 212         entity prev;
 213
 214         prev = players;
 215         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 216         {
 217                 if(prev != e.sort_prev)
 218                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 219         }
 220
 221         prev = teams;
 222         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 223         {
 224                 if(prev != e.sort_prev)
 225                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 226         }
 227 }
 228
 229 float RegisterPlayer(entity player)
 230 {
 231         entity pl;
 232         AuditLists();
 233         for(pl = players.sort_next; pl; pl = pl.sort_next)
 234                 if(pl == player)
 235                         error("Player already registered!");
 236         player.sort_next = players.sort_next;
 237         player.sort_prev = players;
 238         if(players.sort_next)
 239                 players.sort_next.sort_prev = player;
 240         players.sort_next = player;
 241         AuditLists();
 242         return true;
 243 }
 244
 245 void RemovePlayer(entity player)
 246 {
 247         entity pl, parent;
 248         AuditLists();
 249         parent = players;
 250         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 251                 parent = pl;
 252
 253         if(!pl)
 254         {
 255                 error("Trying to remove a player which is not in the playerlist!");
 256                 return;
 257         }
 258         parent.sort_next = player.sort_next;
 259         if(player.sort_next)
 260                 player.sort_next.sort_prev = parent;
 261         AuditLists();
 262 }
 263
 264 void MoveToLast(entity e)
 265 {
 266         AuditLists();
 267         entity ent = e.sort_next;
 268         while(ent)
 269         {
 270                 SORT_SWAP(ent, e);
 271                 ent = e.sort_next;
 272         }
 273         AuditLists();
 274 }
 275
 276 float RegisterTeam(entity Team)
 277 {
 278         assert_once(Team.team, eprint(Team));
 279         entity tm;
 280         AuditLists();
 281         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 282                 if(tm == Team)
 283                         error("Team already registered!");
 284         Team.sort_next = teams.sort_next;
 285         Team.sort_prev = teams;
 286         if(teams.sort_next)
 287                 teams.sort_next.sort_prev = Team;
 288         teams.sort_next = Team;
 289         if(Team.team && Team.team != NUM_SPECTATOR)
 290                 ++team_count;
 291         AuditLists();
 292         return true;
 293 }
 294
 295 void RemoveTeam(entity Team)
 296 {
 297         entity tm, parent;
 298         AuditLists();
 299         parent = teams;
 300         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 301                 parent = tm;
 302
 303         if(!tm)
 304         {
 305                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 306                 return;
 307         }
 308         parent.sort_next = Team.sort_next;
 309         if(Team.sort_next)
 310                 Team.sort_next.sort_prev = parent;
 311         if(Team.team && Team.team != NUM_SPECTATOR)
 312                 --team_count;
 313         AuditLists();
 314 }
 315
 316 entity GetTeam(int Team, bool add)
 317 {
 318         TC(int, Team); TC(bool, add);
 319         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 320         if(teamslots[num])
 321                 return teamslots[num];
 322         if (!add)
 323                 return NULL;
 324         entity tm = new_pure(team);
 325         tm.team = Team;
 326         teamslots[num] = tm;
 327         RegisterTeam(tm);
 328         return tm;
 329 }
 330
 331 .float has_team;
 332 bool SetTeam(entity o, int Team)
 333 {
 334         TC(int, Team);
 335         //devassert_once(Team);
 336         entity tm;
 337         if(teamplay)
 338         {
 339                 switch(Team)
 340                 {
 341                         case -1:
 342                         case NUM_TEAM_1:
 343                         case NUM_TEAM_2:
 344                         case NUM_TEAM_3:
 345                         case NUM_TEAM_4:
 346                                 break;
 347                         default:
 348                                 if(GetTeam(Team, false) == NULL)
 349                                 {
 350                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 351                                         Team = NUM_SPECTATOR;
 352                                 }
 353                                 break;
 354                 }
 355         }
 356         else
 357         {
 358                 switch(Team)
 359                 {
 360                         case -1:
 361                         case 0:
 362                                 break;
 363                         default:
 364                                 if(GetTeam(Team, false) == NULL)
 365                                 {
 366                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 367                                         Team = NUM_SPECTATOR;
 368                                 }
 369                                 break;
 370                 }
 371         }
 372         if(Team == -1) // leave
 373         {
 374                 if(o.has_team)
 375                 {
 376                         tm = GetTeam(o.team, false);
 377                         tm.team_size -= 1;
 378                         o.has_team = 0;
 379                         return true;
 380                 }
 381         }
 382         else
 383         {
 384                 if (!o.has_team)
 385                 {
 386                         o.team = Team;
 387                         tm = GetTeam(Team, true);
 388                         tm.team_size += 1;
 389                         o.has_team = 1;
 390                         return true;
 391                 }
 392                 else if(Team != o.team)
 393                 {
 394                         tm = GetTeam(o.team, false);
 395                         tm.team_size -= 1;
 396                         o.team = Team;
 397                         tm = GetTeam(Team, true);
 398                         tm.team_size += 1;
 399                         return true;
 400                 }
 401         }
 402         return false;
 403 }
 404
 405 void Playerchecker_Think(entity this)
 406 {
 407         int i;
 408         entity e;
 409         for(i = 0; i < maxclients; ++i)
 410         {
 411                 e = playerslots[i];
 412                 if(entcs_GetName(i) == "")
 413                 {
 414                         if(e.sort_prev)
 415                         {
 416                                 // player disconnected
 417                                 SetTeam(e, -1);
 418                                 RemovePlayer(e);
 419                                 e.sort_prev = NULL;
 420                                 //e.gotscores = 0;
 421                         }
 422                 }
 423                 else
 424                 {
 425                         if (!e.sort_prev)
 426                         {
 427                                 // player connected
 428                                 if (!e)
 429                                 {
 430                                         playerslots[i] = e = new_pure(playerslot);
 431                                 }
 432                                 e.sv_entnum = i;
 433                                 e.ping = 0;
 434                                 e.ping_packetloss = 0;
 435                                 e.ping_movementloss = 0;
 436                                 //e.gotscores = 0; // we might already have the scores...
 437                                 int t = entcs_GetScoreTeam(i);
 438                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 439                                 RegisterPlayer(e);
 440                                 Scoreboard_UpdatePlayerPos(e);
 441                         }
 442                 }
 443         }
 444         this.nextthink = time + 0.2;
 445 }
 446
 447 void PostInit()
 448 {
 449         entity playerchecker = new_pure(playerchecker);
 450         setthink(playerchecker, Playerchecker_Think);
 451         playerchecker.nextthink = time + 0.2;
 452
 453         TrueAim_Init();
 454
 455         // this can't be called in CSQC_Init as it'd send cvars too early
 456         ReplicateVars_Start();
 457
 458         postinit = true;
 459 }
 460
 461 void Release_Common_Keys()
 462 {
 463         localcmd("-fire\n");
 464         localcmd("-fire2\n");
 465         localcmd("-use\n");
 466         localcmd("-hook\n");
 467         localcmd("-jump\n");
 468         localcmd("-forward\n");
 469         localcmd("-back\n");
 470         localcmd("-moveleft\n");
 471         localcmd("-moveright\n");
 472 }
 473
 474 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 475 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 476 // All keys are in ascii.
 477 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 478 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 479 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 480 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 481 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 482 {
 483         TC(int, bInputType);
 484         bool override = false;
 485
 486         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 487         if (override)
 488                 return true;
 489
 490         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 491         if (override)
 492                 return true;
 493
 494         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 495
 496         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 497
 498         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 499
 500         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 501
 502         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 503
 504         if(override)
 505                 return true;
 506
 507         if(bInputType == 3 || bInputType == 2)
 508                 return false;
 509
 510         // at this point bInputType can only be 0 or 1 (key pressed or released)
 511         bool key_pressed = (bInputType == 0);
 512
 513         if(key_pressed) {
 514                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 515                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 516                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 517                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 518         }
 519         else {
 520                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 521                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 522                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 523                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 524         }
 525
 526         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 527         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 528         {
 529                 if (hudShiftState & S_TAB)
 530                 {
 531                         Scoreboard_UI_Enable(0);
 532                         return true;
 533                 }
 534                 if (autocvar_menu_gamemenu && !isdemo() && cvar("_menu_gamemenu_dialog_available"))
 535                 {
 536                         localcmd("\nmenu_showgamemenudialog\n");
 537                         return true;
 538                 }
 539         }
 540
 541         return false;
 542 }
 543
 544 // END REQUIRED CSQC FUNCTIONS
 545 // --------------------------------------------------------------------------
 546
 547 // --------------------------------------------------------------------------
 548 // BEGIN OPTIONAL CSQC FUNCTIONS
 549 .int survival_status;
 550 void Ent_RemovePlayerScore(entity this)
 551 {
 552         if(this.owner) {
 553                 SetTeam(this.owner, -1);
 554                 this.owner.gotscores = 0;
 555                 FOREACH(Scores, true, {
 556                         this.owner.(scores(it)) = 0; // clear all scores
 557                 });
 558                 this.owner.ready = 0;
 559                 this.owner.eliminated = 0;
 560                 this.owner.colormap = 0;
 561                 // TODO add a hook to reset this Survival field
 562                 this.owner.survival_status = 0;
 563         }
 564 }
 565
 566 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 567 {
 568         make_pure(this);
 569         entity o;
 570
 571         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 572         // (no I've never heard of M-x replace-string, sed, or anything like that)
 573         bool isNew = !this.owner; // workaround for DP bug
 574         int n = ReadByte()-1;
 575
 576 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 577         if(!isNew && n != this.sv_entnum)
 578         {
 579                 //print("A CSQC entity changed its owner!\n");
 580                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 581                 isNew = true;
 582                 Ent_Remove(this);
 583         }
 584 #endif
 585
 586         this.sv_entnum = n;
 587
 588         o = playerslots[this.sv_entnum];
 589         if (!o)
 590         {
 591                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 592         }
 593         this.owner = o;
 594         o.sv_entnum = this.sv_entnum;
 595         o.gotscores = 1;
 596
 597         //if (!o.sort_prev)
 598         //      RegisterPlayer(o);
 599         //playerchecker will do this for us later, if it has not already done so
 600
 601         int sf = ReadShort();
 602         int lf = ReadShort();
 603         FOREACH(Scores, true, {
 604                 int p = 1 << (i % 16);
 605                 if (sf & p)
 606                 {
 607                         if (lf & p)
 608                                 o.(scores(it)) = ReadInt24_t();
 609                         else
 610                                 o.(scores(it)) = ReadChar();
 611                 }
 612         });
 613
 614         return = true;
 615
 616         if(o.sort_prev)
 617                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 618
 619         this.entremove = Ent_RemovePlayerScore;
 620 }
 621
 622 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 623 {
 624         make_pure(this);
 625         int i;
 626
 627         this.team = ReadByte();
 628         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 629
 630 #if MAX_TEAMSCORE <= 8
 631         int sf = ReadByte();
 632         int lf = ReadByte();
 633 #else
 634         int sf = ReadShort();
 635         int lf = ReadShort();
 636 #endif
 637         for(i = 0; i < MAX_TEAMSCORE; ++i)
 638                 if(sf & BIT(i))
 639                 {
 640                         if(lf & BIT(i))
 641                                 o.(teamscores(i)) = ReadInt24_t();
 642                         else
 643                                 o.(teamscores(i)) = ReadChar();
 644                 }
 645
 646         return = true;
 647
 648         Scoreboard_UpdateTeamPos(o);
 649 }
 650
 651 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 652 {
 653         make_pure(this);
 654         float newspectatee_status;
 655
 656         int f = ReadByte();
 657
 658         scoreboard_showscores_force = (f & BIT(0));
 659
 660         if(f & BIT(1))
 661         {
 662                 newspectatee_status = ReadByte();
 663                 if(newspectatee_status == player_localnum + 1)
 664                         newspectatee_status = -1; // observing
 665         }
 666         else
 667                 newspectatee_status = 0;
 668
 669         spectatorbutton_zoom = (f & BIT(2));
 670         observe_blocked = (f & BIT(3));
 671
 672         if(f & BIT(4))
 673         {
 674                 num_spectators = ReadByte();
 675
 676                 float i, slot;
 677
 678                 for(i = 0; i < MAX_SPECTATORS; ++i)
 679                         spectatorlist[i] = 0; // reset list first
 680
 681                 int limit = min(num_spectators, MAX_SPECTATORS);
 682                 for(i = 0; i < limit; ++i)
 683                 {
 684                         slot = ReadByte();
 685                         spectatorlist[i] = slot - 1;
 686                 }
 687         }
 688         else
 689         {
 690                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 691                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 692                 num_spectators = 0;
 693         }
 694
 695         return = true;
 696
 697         if(newspectatee_status != spectatee_status)
 698         {
 699                 hud_dynamic_shake_factor = -1;
 700                 spectatee_status_changed_time = time;
 701         }
 702         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 703         {
 704                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 705                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 706                 )
 707                         prev_p_health = -1;
 708                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 709                         prev_health = -1;
 710         }
 711         spectatee_status = newspectatee_status;
 712
 713         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 714 }
 715
 716 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 717 {
 718         make_pure(this);
 719
 720         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 721
 722         if(!(nags & BIT(2)))
 723         {
 724                 strfree(vote_called_vote);
 725                 vote_active = 0;
 726         }
 727         else
 728         {
 729                 vote_active = 1;
 730         }
 731
 732         if(nags & BIT(6))
 733         {
 734                 vote_yescount = ReadByte();
 735                 vote_nocount = ReadByte();
 736                 vote_needed = ReadByte();
 737                 vote_highlighted = ReadChar();
 738         }
 739
 740         if(nags & BIT(7))
 741         {
 742                 strcpy(vote_called_vote, ReadString());
 743         }
 744
 745         if(nags & BIT(0))
 746                 for(int i = 0; i < maxclients;)
 747                         for(int f = ReadByte(), b = 0; b < 8 && i < maxclients; ++b, ++i)
 748                                 if(playerslots[i])
 749                                         playerslots[i].ready = f & BIT(b);
 750
 751         return = true;
 752
 753         ready_waiting = (nags & BIT(0));
 754         ready_waiting_for_me = (nags & BIT(1));
 755         vote_waiting = (nags & BIT(2));
 756         vote_waiting_for_me = (nags & BIT(3));
 757         warmup_stage = (nags & BIT(4));
 758 }
 759
 760 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 761 {
 762         make_pure(this);
 763         int sf = 0;
 764         serialize(byte, 0, sf);
 765         if (sf & 1) {
 766                 for (int j = 0; j < maxclients; ++j) {
 767                         if (playerslots[j]) {
 768                                 playerslots[j].eliminated = true;
 769                         }
 770                 }
 771                 for (int i = 1; i <= maxclients; i += 8) {
 772                         int f = 0;
 773                         serialize(byte, 0, f);
 774                         for (int b = 0; b < 8; ++b) {
 775                                 if (f & BIT(b)) continue;
 776                                 int j = i - 1 + b;
 777                                 if (playerslots[j]) {
 778                                         playerslots[j].eliminated = false;
 779                                 }
 780                         }
 781                 }
 782         }
 783         return true;
 784 }
 785
 786 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 787 {
 788         make_pure(this);
 789         prandom_debug();
 790         float s = ReadShort();
 791         psrandom(s);
 792         return true;
 793 }
 794
 795 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 796 {
 797         make_pure(this);
 798         int sf = ReadInt24_t();
 799         if (sf == 0) {
 800                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 801                         weapon_accuracy[w] = -1;
 802                 return true;
 803         }
 804
 805         int f = 1;
 806         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 807                 if (sf & f) {
 808                         int b = ReadByte();
 809                         if (b == 0)
 810                                 weapon_accuracy[w] = -1;
 811                         else if (b == 255)
 812                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 813                         else
 814                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 815                 }
 816                 f = (f == 0x800000) ? 1 : f * 2;
 817         }
 818         return true;
 819 }
 820
 821 void Spawn_Draw(entity this)
 822 {
 823         bool dodraw = autocvar_cl_spawn_point_particles;
 824         if(dodraw && autocvar_cl_spawn_point_dist_max)
 825         {
 826                 vector org = getpropertyvec(VF_ORIGIN);
 827                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 828         }
 829
 830         if(dodraw)
 831                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 832 }
 833
 834 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 835 {
 836         float teamnum = (ReadByte() - 1);
 837         vector spn_origin = ReadVector();
 838
 839         this.team = (teamnum + 1);
 840
 841         //if(is_new)
 842         //{
 843                 this.origin = spn_origin;
 844                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 845                 //droptofloor();
 846
 847                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 848                 {
 849                         this.mdl = "models/spawnpoint.md3";
 850                         this.colormod = Team_ColorRGB(teamnum);
 851                         precache_model(this.mdl);
 852                         setmodel(this, this.mdl);
 853                         this.drawmask = MASK_NORMAL;
 854                         //this.move_movetype = MOVETYPE_NOCLIP;
 855                         //this.draw = Spawn_Draw;
 856                         IL_PUSH(g_drawables, this);
 857                 }*/
 858                 this.draw = Spawn_Draw;
 859                 if (is_new) IL_PUSH(g_drawables, this);
 860         //}
 861
 862         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 863         return true;
 864 }
 865
 866 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 867 {
 868         // If entnum is 0, ONLY do the local spawn actions
 869         // this way the server can disable the sending of
 870         // spawn origin or such to clients if wanted.
 871         float entnum = ReadByte();
 872
 873         if(entnum)
 874         {
 875                 this.origin = ReadVector();
 876
 877                 int particlesAndOrSound = ReadByte();
 878
 879                 if(is_new)
 880                 {
 881                         float teamnum = entcs_GetTeam(entnum - 1);
 882
 883                         if(autocvar_cl_spawn_event_particles && (particlesAndOrSound & BIT(0)))
 884                         {
 885                                 switch(teamnum)
 886                                 {
 887                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 888                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 889                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 890                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 891                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 892                                 }
 893                         }
 894
 895                         if(autocvar_cl_spawn_event_sound && (particlesAndOrSound & BIT(1)))
 896                         {
 897                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 898                         }
 899                 }
 900         }
 901         return = true;
 902
 903         // local spawn actions
 904         if(is_new && (!entnum || (entnum == player_localentnum)))
 905         {
 906                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 907                 {
 908                         zoomin_effect = 1;
 909                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 910                 }
 911
 912                 if(autocvar_cl_unpress_zoom_on_spawn)
 913                 {
 914                         localcmd("-zoom\n");
 915                         button_zoom = false;
 916                 }
 917                 HUD_Radar_Hide_Maximized();
 918         }
 919         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 920 }
 921
 922 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 923 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 924 void CSQC_Ent_Update(entity this, bool isnew)
 925 {
 926         this.sourceLoc = __FILE__":"STR(__LINE__);
 927         int t = ReadByte();
 928
 929         // set up the "time" global for received entities to be correct for interpolation purposes
 930         float savetime = time;
 931         if(servertime)
 932         {
 933                 time = servertime;
 934         }
 935         else
 936         {
 937                 serverprevtime = time;
 938                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 939                 time = serverprevtime + serverdeltatime;
 940         }
 941
 942 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 943         if (this.enttype)
 944         {
 945                 if (t != this.enttype || isnew)
 946                 {
 947                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 948                         Ent_Remove(this);
 949                         ONREMOVE(this);
 950                         clearentity(this);
 951                         isnew = true;
 952                 }
 953         }
 954         else
 955         {
 956                 if (!isnew)
 957                 {
 958                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 959                         isnew = true;
 960                 }
 961         }
 962 #endif
 963         this.enttype = t;
 964         bool done = false;
 965         FOREACH(LinkedEntities, it.m_id == t, {
 966                 if (isnew) this.classname = it.netname;
 967                 if (autocvar_developer_csqcentities)
 968                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 969                 done = it.m_read(this, NULL, isnew);
 970                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 971                 break;
 972         });
 973         time = savetime;
 974         if (!done)
 975         {
 976                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 977         }
 978 }
 979
 980 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 981 // used when an entity changes its type. For an entity that someone interacts
 982 // with others, make sure it can no longer do so.
 983 void Ent_Remove(entity this)
 984 {
 985         if(this.entremove) this.entremove(this);
 986
 987         if(this.skeletonindex)
 988         {
 989                 skel_delete(this.skeletonindex);
 990                 this.skeletonindex = 0;
 991         }
 992
 993         if(this.snd_looping > 0)
 994         {
 995                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 996                 this.snd_looping = 0;
 997         }
 998
 999         this.enttype = 0;
1000         this.classname = "";
1001         this.draw = func_null;
1002         this.entremove = func_null;
1003         // TODO possibly set more stuff to defaults
1004 }
1005 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1006 void CSQC_Ent_Remove(entity this)
1007 {
1008         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1009         if (wasfreed(this))
1010         {
1011                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1012                 return;
1013         }
1014         if (this.enttype) Ent_Remove(this);
1015         delete(this);
1016 }
1017
1018 void Gamemode_Init()
1019 {
1020         if (!isdemo())
1021         {
1022                 if(!(calledhooks & HOOK_START))
1023                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1024                 calledhooks |= HOOK_START;
1025         }
1026 }
1027 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1028 void CSQC_Parse_StuffCmd(string strMessage)
1029 {
1030         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1031         localcmd(strMessage);
1032 }
1033 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1034 void CSQC_Parse_Print(string strMessage)
1035 {
1036         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1037         print(ColorTranslateRGB(strMessage));
1038 }
1039
1040 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1041 void CSQC_Parse_CenterPrint(string strMessage)
1042 {
1043         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1044         centerprint_AddStandard(strMessage);
1045 }
1046
1047 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1048 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1049 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1050 bool CSQC_Parse_TempEntity()
1051 {
1052         // Acquire TE ID
1053         int nTEID = ReadByte();
1054
1055         FOREACH(TempEntities, it.m_id == nTEID, {
1056                 if (autocvar_developer_csqcentities)
1057                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1058                 return it.m_read(NULL, NULL, true);
1059         });
1060
1061         if (autocvar_developer_csqcentities)
1062                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1063
1064         // No special logic for this temporary entity; return 0 so the engine can handle it
1065         return false;
1066 }
1067
1068 bool autocvar_r_drawfog;
1069 bool autocvar_r_fog_exp2;
1070 string forcefog;
1071 void Fog_Force()
1072 {
1073         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1074         {
1075                 if (autocvar_r_drawfog)
1076                         cvar_set("r_drawfog", "0");
1077         }
1078         else if (forcefog != "")
1079         {
1080                 // using cvar_set as it's faster and safer than a command
1081                 if (!autocvar_r_drawfog)
1082                         cvar_set("r_drawfog", "1");
1083                 if (autocvar_r_fog_exp2)
1084                         cvar_set("r_fog_exp2", "0");
1085                 localcmd(sprintf("\nfog %s\n", forcefog));
1086         }
1087 }
1088
1089 bool net_handle_ServerWelcome();
1090 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1091 {
1092         make_pure(this);
1093         gametype = ReadRegistered(Gametypes);
1094         strcpy(gametype_custom_name, ReadString());
1095         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1096         HUD_ModIcons_SetFunc();
1097         FOREACH(Scores, true, {
1098                 strcpy(scores_label(it), ReadString());
1099                 scores_flags(it) = ReadByte();
1100         });
1101         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1102         {
1103                 strcpy(teamscores_label(i), ReadString());
1104                 teamscores_flags(i) = ReadByte();
1105         }
1106         bool welcome_msg_too = ReadByte();
1107         if (welcome_msg_too)
1108                 net_handle_ServerWelcome();
1109         return = true;
1110         Scoreboard_InitScores();
1111         Gamemode_Init();
1112 }
1113
1114 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1115 {
1116         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1117
1118         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1119         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1120         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1121         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1122         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1123         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1124         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1125         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1126
1127         strcpy(forcefog, ReadString());
1128
1129         armorblockpercent = ReadByte() / 255.0;
1130         damagepush_speedfactor = ReadByte() / 255.0;
1131
1132         serverflags = ReadByte();
1133
1134         g_trueaim_minrange = ReadCoord();
1135
1136         return = true;
1137
1138         MUTATOR_CALLHOOK(Ent_Init);
1139
1140         if (!postinit) PostInit();
1141 }
1142
1143 float GetSpeedUnitFactor(int speed_unit)
1144 {
1145         switch(speed_unit)
1146         {
1147                 default:
1148                 case 1: return 1.0;
1149                 case 2: return 0.0254;
1150                 case 3: return 0.0254 * 3.6;
1151                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1152                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1153         }
1154 }
1155
1156 string GetSpeedUnit(int speed_unit)
1157 {
1158         switch(speed_unit)
1159         {
1160                 // translator-friendly strings without the initial space
1161                 default:
1162                 case 1: return strcat(" ", _("qu/s"));
1163                 case 2: return strcat(" ", _("m/s"));
1164                 case 3: return strcat(" ", _("km/h"));
1165                 case 4: return strcat(" ", _("mph"));
1166                 case 5: return strcat(" ", _("knots"));
1167         }
1168 }
1169
1170 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1171 {
1172         int b = ReadByte();
1173
1174         switch (b)
1175         {
1176                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1177                         race_checkpoint = ReadByte();
1178                         race_time = ReadInt24_t();
1179                         race_previousbesttime = ReadInt24_t();
1180                         race_mypreviousbesttime = ReadInt24_t();
1181                         string pbestname = ReadString();
1182                         if(autocvar_cl_race_cptimes_onlyself)
1183                         {
1184                                 race_previousbesttime = race_mypreviousbesttime;
1185                                 race_mypreviousbesttime = 0;
1186                                 strcpy(race_previousbestname, "");
1187                         }
1188                         else
1189                                 strcpy(race_previousbestname, pbestname);
1190
1191                         race_checkpointtime = time;
1192
1193                         if(race_checkpoint == 0 || race_checkpoint == 254)
1194                         {
1195                                 race_penaltyaccumulator = 0;
1196                                 race_laptime = time; // valid
1197                         }
1198
1199                         // show checkpoint splits after a run
1200                         // specs can switch players for confusing splits, deny service
1201                         // if hit 255 finish line or if finish line is 0 or if restarted
1202                         if (!entcs_IsSpectating(player_localnum)
1203                         && (race_checkpoint == 255
1204                         || race_checkpoint < race_checkpoint_splits_previous))
1205                         {
1206                                 LOG_HELP(_("Checkpoint times:"));
1207                                 for (int i = 0; i < 255; ++i)
1208                                 {
1209                                         // does this index have a split?
1210                                         if (race_checkpoint_splits[i])
1211                                         {
1212                                                 // print it and free it
1213                                                 LOG_HELP(race_checkpoint_splits[i]);
1214                                                 strfree(race_checkpoint_splits[i]);
1215                                         }
1216                                 }
1217
1218                                 // allow registering 0th cp in case we start at 254 start line
1219                                 race_checkpoint_splits_previous = 0;
1220                         }
1221                         break;
1222
1223                 case RACE_NET_CHECKPOINT_CLEAR:
1224                         race_laptime = 0;
1225                         race_checkpointtime = 0;
1226                         break;
1227
1228                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1229                         race_laptime = ReadCoord();
1230                         race_checkpointtime = -99999;
1231                         // fall through
1232                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1233                         race_nextcheckpoint = ReadByte();
1234
1235                         race_nextbesttime = ReadInt24_t();
1236                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1237                                 race_mybesttime = ReadInt24_t();
1238                         string newname = ReadString();
1239                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1240                         {
1241                                 race_nextbesttime = race_mybesttime;
1242                                 race_mybesttime = 0;
1243                                 strcpy(race_nextbestname, "");
1244                         }
1245                         else
1246                                 strcpy(race_nextbestname, newname);
1247                         break;
1248
1249                 case RACE_NET_CHECKPOINT_HIT_RACE:
1250                         race_mycheckpoint = ReadByte();
1251                         race_mycheckpointtime = time;
1252                         race_mycheckpointdelta = ReadInt24_t();
1253                         race_mycheckpointlapsdelta = ReadByte();
1254                         if(race_mycheckpointlapsdelta >= 128)
1255                                 race_mycheckpointlapsdelta -= 256;
1256                         int who = ReadByte();
1257                         if(who)
1258                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1259                         else
1260                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1261                         break;
1262
1263                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1264                         race_othercheckpoint = ReadByte();
1265                         race_othercheckpointtime = time;
1266                         race_othercheckpointdelta = ReadInt24_t();
1267                         race_othercheckpointlapsdelta = ReadByte();
1268                         if(race_othercheckpointlapsdelta >= 128)
1269                                 race_othercheckpointlapsdelta -= 256;
1270                         int what = ReadByte();
1271                         if(what)
1272                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1273                         else
1274                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1275                         break;
1276
1277                 case RACE_NET_PENALTY_RACE:
1278                 case RACE_NET_PENALTY_QUALIFYING:
1279                         race_penaltyeventtime = time;
1280                         race_penaltytime = ReadShort();
1281                         string reason = ReadString();
1282                         if (reason == "missing a checkpoint")
1283                                 reason = _("missing a checkpoint");
1284                         strcpy(race_penaltyreason, reason);
1285                         if (b == RACE_NET_PENALTY_QUALIFYING)
1286                                 race_penaltyaccumulator += race_penaltytime;
1287                         break;
1288
1289                 case RACE_NET_SERVER_RECORD:
1290                         race_server_record = ReadInt24_t();
1291                         break;
1292                 case RACE_NET_SPEED_AWARD:
1293                         race_speedaward = ReadInt24_t();
1294                         strcpy(race_speedaward_holder, ReadString());
1295                         break;
1296                 case RACE_NET_SPEED_AWARD_BEST:
1297                         race_speedaward_alltimebest = ReadInt24_t();
1298                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1299                         break;
1300                 case RACE_NET_RANKINGS_CNT:
1301                         RANKINGS_DISPLAY_CNT = ReadByte();
1302                         break;
1303                 case RACE_NET_SERVER_RANKINGS:
1304                         float prevpos, del;
1305                         int pos = ReadShort();
1306                         prevpos = ReadShort();
1307                         del = ReadShort();
1308
1309                         // move other rankings out of the way
1310                         int i;
1311                         if (prevpos) {
1312                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1313                                 for (i=m-1; i>pos-1; --i) {
1314                                         grecordtime[i] = grecordtime[i-1];
1315                                         strcpy(grecordholder[i], grecordholder[i-1]);
1316                                 }
1317                         } else if (del) { // a record has been deleted by the admin
1318                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1319                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1320                                                 grecordtime[i] = 0;
1321                                                 strfree(grecordholder[i]);
1322                                         }
1323                                         else {
1324                                                 grecordtime[i] = grecordtime[i+1];
1325                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1326                                         }
1327                                 }
1328                         } else { // player has no ranked record yet
1329                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1330                                         grecordtime[i] = grecordtime[i-1];
1331                                         strcpy(grecordholder[i], grecordholder[i-1]);
1332                                 }
1333                         }
1334
1335                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1336                                 // kick off the player who fell from the last displayed position
1337                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1338                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1339                         }
1340
1341                         // store new ranking
1342                         strcpy(grecordholder[pos-1], ReadString());
1343                         grecordtime[pos-1] = ReadInt24_t();
1344                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1345                                 race_myrank = pos;
1346                         break;
1347                 case RACE_NET_SERVER_STATUS:
1348                         race_status = ReadShort();
1349                         strcpy(race_status_name, ReadString());
1350         }
1351         return true;
1352 }
1353
1354 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1355 {
1356         teamnagger = 1;
1357         return true;
1358 }
1359
1360 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1361 {
1362         int i = ReadByte();
1363         int pi = ReadShort();
1364         int pl = ReadByte();
1365         int ml = ReadByte();
1366         return = true;
1367         entity e = playerslots[i];
1368         if (!e) return;
1369         e.ping = pi;
1370         e.ping_packetloss = pl / 255.0;
1371         e.ping_movementloss = ml / 255.0;
1372 }
1373
1374 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1375 {
1376         int weapon_id = ReadByte();
1377         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1378         complain_weapon_type = ReadByte();
1379         return = true;
1380
1381         complain_weapon_time = time;
1382         weapontime = time; // ping the weapon panel
1383
1384         switch(complain_weapon_type)
1385         {
1386                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1387                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1388                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1389         }
1390 }
1391
1392 string translate_modifications(string s)
1393 {
1394         return build_mutator_list(s);
1395 }
1396
1397 string translate_weaponarena(string s)
1398 {
1399         if (s == "") return s;
1400         if (s == "All Weapons Arena") return _("All Weapons Arena");
1401         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1402         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1403         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1404         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1405         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1406         if (s == "No Weapons Arena") return _("No Weapons Arena");
1407
1408         int n = tokenizebyseparator(s, " & ");
1409         string wpn_list = "";
1410         for (int i = 0; i < n; ++i)
1411         {
1412                 Weapon wep = Weapon_from_name(argv(i));
1413                 if (wep == WEP_Null)
1414                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1415                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1416         }
1417         if (wpn_list != "")
1418                 return sprintf(_("%s Arena"), wpn_list);
1419         else
1420                 return _("No Weapons Arena");
1421 }
1422
1423 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1424 {
1425         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1426         if (version_mismatch)
1427         {
1428                 if(!version_check)
1429                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1430                                 _("Your client version is outdated."), "\n\n\n",
1431                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1432                                 _("Please update!"));
1433                 else
1434                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1435                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1436                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1437         }
1438         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1439 }
1440
1441 bool net_handle_ServerWelcome()
1442 {
1443         int flags = ReadByte();
1444
1445         campaign = flags & 1;
1446         if (campaign)
1447         {
1448                 int campaign_level = ReadByte();
1449                 // Menu can't build the whole campaign message because it lacks getcommandkey and CCR
1450                 // so we build part of the message here and let the menu insert the level description
1451                 // (that client doesn't know) by replacing the keyword _LEVEL_DESC
1452                 string key = getcommandkey(_("jump"), "+jump");
1453                 string msg = strcat(
1454                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1455                         sprintf(CCR(" ^BG%s\n\n"), "_LEVEL_DESC"),
1456                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1457                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1458                 string welcomedialog_args = strcat("CAMPAIGN ", itos(campaign_level), " \"", msg, "\"");
1459
1460                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1461                 return true;
1462         }
1463
1464         strcpy(hostname, ReadString());
1465         string hostversion = ReadString();
1466         bool version_mismatch = flags & 2;
1467         bool version_check = flags & 4;
1468         MapInfo_Map_titlestring = ReadString();
1469         MapInfo_Map_author = flags & 8 ? ReadString() : "";
1470         srv_minplayers = ReadByte();
1471         srv_maxplayers = ReadByte();
1472         string modifications = translate_modifications(ReadString());
1473         string weaponarena_list = translate_weaponarena(ReadString());
1474         string cache_mutatormsg = ReadString();
1475         string motd = ReadString();
1476
1477         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1478
1479         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1480
1481         msg = strcat(msg, "\n", _("Map:"), " ", MapInfo_Map_titlestring, "\n");
1482         if (flags & 8)
1483                 msg = strcat(msg, "^9", _("by:"), " ", MapInfo_Map_author, "\n");
1484
1485         if (srv_minplayers || srv_maxplayers)
1486         {
1487                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1488                 if (srv_minplayers == srv_maxplayers)
1489                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1490                 else if (srv_minplayers && srv_maxplayers)
1491                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1492                 else if (srv_maxplayers)
1493                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1494                 else
1495                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1496         }
1497
1498         modifications = cons_mid(modifications, ", ", weaponarena_list);
1499         if(modifications != "")
1500                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1501
1502         if (cache_mutatormsg != "")
1503                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1504         string mutator_msg = "";
1505         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1506         mutator_msg = M_ARGV(0, string);
1507         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1508
1509         if (motd != "")
1510                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1511
1512         strcpy(welcome_msg, msg);
1513         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1514         return true;
1515 }
1516
1517 void Welcome_Message_Show_Try()
1518 {
1519         if (!welcome_msg_menu_check_maxtime)
1520                 return;
1521
1522         // if want dialog check if menu is initialized but for a short time
1523         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1524         {
1525                 if (cvar("_menu_welcome_dialog_available"))
1526                 {
1527                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1528                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1529                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1530
1531                         if (intermission || isdemo() || !autocvar_cl_welcome)
1532                         {
1533                                 if (cvar("_menu_cmd_closemenu_available"))
1534                                 {
1535                                         // initialize the dialog without opening it
1536                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1537                                 }
1538                                 else
1539                                 {
1540                                         // legacy code for clients with old menus
1541                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1542                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1543                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1544                                         // close it after it's been initialized so it can still be opened manually
1545                                         localcmd("\ntogglemenu 0\n");
1546                                 }
1547                         }
1548                         else
1549                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1550                 }
1551
1552                 strfree(welcome_msg);
1553                 welcome_msg_menu_check_maxtime = 0;
1554         }
1555 }
1556
1557 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1558 {
1559         return net_handle_ServerWelcome();
1560 }
1561
1562 string _getcommandkey(string cmd_name, string command, bool forcename)
1563 {
1564         string keys;
1565         float n, j, k, l = 0;
1566
1567         if (!autocvar_hud_showbinds)
1568                 return cmd_name;
1569
1570         keys = db_get(binddb, command);
1571         if (keys == "")
1572         {
1573                 bool joy_active = cvar("joy_active");
1574                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1575                 for(j = 0; j < n; ++j)
1576                 {
1577                         k = stof(argv(j));
1578                         if(k != -1)
1579                         {
1580                                 string key = keynumtostring(k);
1581                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1582                                         continue;
1583
1584                                 key = translate_key(key);
1585
1586                                 if (keys == "")
1587                                         keys = key;
1588                                 else
1589                                         keys = strcat(keys, ", ", key);
1590
1591                                 ++l;
1592                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1593                                         break;
1594                         }
1595
1596                 }
1597                 if (keys == "")
1598                         keys = "NO_KEY";
1599                 db_put(binddb, command, keys);
1600         }
1601
1602         if (keys == "NO_KEY") {
1603                 if (autocvar_hud_showbinds > 1)
1604                         return sprintf(_("%s (not bound)"), cmd_name);
1605                 else
1606                         return cmd_name;
1607         }
1608         else if (autocvar_hud_showbinds > 1 || forcename)
1609                 return sprintf("%s (%s)", cmd_name, keys);
1610         else
1611                 return keys;
1612 }
1613
1614 /** engine callback */
1615 void URI_Get_Callback(int id, int status, string data)
1616 {
1617         TC(int, id); TC(int, status);
1618         if(url_URI_Get_Callback(id, status, data))
1619         {
1620                 // handled
1621         }
1622         else if (id == URI_GET_DISCARD)
1623         {
1624                 // discard
1625         }
1626         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1627         {
1628                 // sv_cmd curl
1629                 Curl_URI_Get_Callback(id, status, data);
1630         }
1631         else
1632         {
1633                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1634         }
1635 }