qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "hud/all.qh"
   4 #include "scoreboard.qh"
   5
   6 #include <common/mapinfo.qh>
   7
   8
   9 int mv_num_maps;
  10
  11 string mv_maps[MAPVOTE_COUNT];
  12 string mv_pics[MAPVOTE_COUNT];
  13 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  14 string mv_desc[MAPVOTE_COUNT];
  15 float mv_preview[MAPVOTE_COUNT];
  16 float mv_votes[MAPVOTE_COUNT];
  17 float mv_flags[MAPVOTE_COUNT];
  18 float mv_flags_start[MAPVOTE_COUNT];
  19 entity mv_pk3list;
  20 float mv_abstain;
  21 float mv_ownvote;
  22 float mv_detail;
  23 float mv_timeout;
  24 float mv_top2_time;
  25 float mv_top2_alpha;
  26
  27 vector mv_mousepos;
  28 int mv_selection;
  29 int mv_columns;
  30 int mv_mouse_selection;
  31 int mv_selection_keyboard;
  32
  33 float gametypevote;
  34 string mapvote_chosenmap;
  35 vector gtv_text_size;
  36 vector gtv_text_size_small;
  37
  38 const int NUM_SSDIRS = 4;
  39 string ssdirs[NUM_SSDIRS];
  40 int n_ssdirs;
  41
  42 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  43 {
  44     TC(int, id);
  45         string pre, post;
  46         pre = sprintf("%d. ", id+1);
  47         if(mv_detail)
  48         {
  49                 if(_count == 1)
  50                         post = _(" (1 vote)");
  51                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  52                         post = sprintf(_(" (%d votes)"), _count);
  53                 else
  54                         post = "";
  55         }
  56         else
  57                 post = "";
  58         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  59         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  60         return strcat(pre, map, post);
  61 }
  62
  63 vector MapVote_RGB(int id)
  64 {
  65     TC(int, id);
  66         if(!(mv_flags[id] & GTV_AVAILABLE))
  67                 return '1 1 1';
  68         if(id == mv_ownvote)
  69                 return '0 1 0';
  70         else if (id == mv_selection)
  71                 return '1 1 0';
  72         else
  73                 return '1 1 1';
  74 }
  75
  76 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  77 {
  78     TC(int, id);
  79         // Find the correct alpha
  80         float alpha;
  81         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  82                 alpha = 0.2; // The gametype isn't supported by the map
  83         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  84                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  85         else
  86                 alpha = 1; // Normal, full alpha
  87
  88         // Bounding box details
  89         float rect_margin = hud_fontsize.y / 2;
  90
  91         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
  92         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
  93         maxh -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  94         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  95
  96         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  97         vector rect_size = '1 1 0';
  98         rect_size.x = tsize + rect_margin;
  99         rect_size.y = maxh + rect_margin;
 100
 101         // Highlight selected item
 102         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 103         {
 104                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 105         }
 106
 107         // Highlight current vote
 108         vector rgb = MapVote_RGB(id);
 109         if(id == mv_ownvote)
 110         {
 111                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 112                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 113         }
 114
 115         vector offset = pos;
 116
 117         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 118         pos.y += title_gap;
 119         maxh -= title_gap;
 120
 121         // Evaluate the image size
 122         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 123         if ( maxh < image_size.y )
 124                 image_size = '1 1 0' * maxh;
 125         image_size *= 0.8;
 126         float desc_padding = gtv_text_size.x * 0.6;
 127         pos.x += image_size.x + desc_padding;
 128         tsize -= image_size.x + desc_padding;
 129
 130         // Split the description into lines
 131         entity title;
 132         title = spawn();
 133         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 134
 135         string thelabel = mv_desc[id], ts;
 136         entity last = title;
 137         entity next = world;
 138         float nlines = 0;
 139         if( thelabel != "")
 140         {
 141                 float i,n = tokenizebyseparator(thelabel, "\n");
 142                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 143                 {
 144                         getWrappedLine_remaining = argv(i);
 145                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 146                         {
 147                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 148                                 if (ts != "")
 149                                 {
 150                                         next = spawn();
 151                                         next.message = ts;
 152                                         next.origin = pos-offset;
 153                                         last.chain = next;
 154                                         last = next;
 155                                         pos.y += gtv_text_size_small.y;
 156                                         nlines++;
 157                                 }
 158                         }
 159                 }
 160         }
 161
 162         // Center the contents in the bounding box
 163         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 164         if ( maxh > 0 )
 165                 offset.y += maxh/2;
 166
 167         // Draw the title
 168         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 169
 170         // Draw the icon
 171         if(pic != "")
 172                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 173
 174         // Draw the description
 175         for ( last = title.chain; last ; )
 176         {
 177                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 178                 next = last;
 179                 last = last.chain;
 180                 remove(next);
 181         }
 182
 183         // Cleanup
 184         remove(title);
 185 }
 186
 187 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 188 {
 189     TC(int, id);
 190         vector img_size = '0 0 0';
 191         string label;
 192         float text_size;
 193
 194         float rect_margin = hud_fontsize.y / 2;
 195
 196         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
 197         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
 198         isize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
 199         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
 200
 201         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 202         vector rect_size = '1 1 0';
 203         rect_size.x = tsize + rect_margin;
 204         rect_size.y = isize + rect_margin;
 205
 206         float img_ar = 4/3;
 207         img_size.x = min(tsize, isize * img_ar);
 208         img_size.y = img_size.x / img_ar;
 209         img_size.y -= hud_fontsize.y;
 210         img_size.x = img_size.y * img_ar;
 211
 212         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 213
 214         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 215
 216         text_size = stringwidth(label, false, hud_fontsize);
 217
 218         float save_rect_sizex = rect_size.x;
 219         rect_size.x = max(img_size.x, text_size) + rect_margin;
 220         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 221
 222         vector text_pos = '0 0 0';
 223         text_pos.x = pos.x + (tsize - text_size) / 2;
 224         text_pos.y = pos.y + img_size.y;
 225
 226         pos.x += (tsize - img_size.x) / 2;
 227
 228         float theAlpha;
 229         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 230                 theAlpha = mv_top2_alpha;
 231         else
 232                 theAlpha = 1;
 233
 234         // Highlight selected item
 235         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 236                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 237
 238         // Highlight current vote
 239         vector rgb = MapVote_RGB(id);
 240         if(id == mv_ownvote)
 241         {
 242                 drawfill(rect_pos, rect_size, rgb, 0.1*theAlpha, DRAWFLAG_NORMAL);
 243                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 244         }
 245
 246         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 247
 248         if(pic == "")
 249         {
 250                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 251         }
 252         else
 253         {
 254                 if(drawgetimagesize(pic) == '0 0 0')
 255                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 256                 else
 257                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 258         }
 259 }
 260
 261 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 262 {
 263     TC(int, id);
 264         vector rgb;
 265         float text_size;
 266         string label;
 267
 268         rgb = MapVote_RGB(id);
 269
 270         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 271
 272         text_size = stringwidth(label, false, hud_fontsize);
 273
 274         pos.x -= text_size*0.5;
 275         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 276 }
 277
 278 vector MapVote_GridVec(vector gridspec, int i, int m)
 279 {
 280     TC(int, i); TC(int, m);
 281         int r = i % m;
 282         return
 283                 '1 0 0' * (gridspec.x * r)
 284                 +
 285                 '0 1 0' * (gridspec.y * (i - r) / m);
 286 }
 287
 288 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 289 {
 290
 291         float c, r;
 292
 293         mv_mouse_selection = -1;
 294
 295         for (r = 0; r < rows; ++r)
 296                 for (c = 0; c < columns; ++c)
 297                 {
 298                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 299                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 300                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 301                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 302                         {
 303                                 mv_mouse_selection = r * columns + c;
 304                                 break;
 305                         }
 306                 }
 307
 308         if (mv_mouse_selection >= mv_num_maps)
 309                 mv_mouse_selection = -1;
 310
 311         if (mv_abstain && mv_mouse_selection < 0)
 312                 mv_mouse_selection = mv_num_maps;
 313
 314         if ( mv_selection_keyboard )
 315                 return mv_selection;
 316
 317         return mv_mouse_selection;
 318 }
 319
 320 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 321 void MapVote_Draw()
 322 {
 323         string map;
 324         int i;
 325         float tmp;
 326         vector pos;
 327         float center;
 328         float rows;
 329         vector dist = '0 0 0';
 330
 331         //if(intermission != 2) return;
 332         if(!mv_active)
 333                 return;
 334
 335         if (!autocvar_hud_cursormode)
 336         {
 337                 vector mpos = mv_mousepos + getmousepos();
 338                 mpos.x = bound(0, mpos.x, vid_conwidth);
 339                 mpos.y = bound(0, mpos.y, vid_conheight);
 340
 341                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 342                         mv_selection_keyboard = 0;
 343                 mv_mousepos = mpos;
 344
 345         }
 346
 347         center = (vid_conwidth - 1)/2;
 348         xmin = vid_conwidth * 0.08;
 349         xmax = vid_conwidth - xmin;
 350         ymin = 20;
 351         ymax = vid_conheight - ymin;
 352
 353         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 354                 ymin += chat_sizey;
 355         else
 356                 ymax -= chat_sizey;
 357
 358         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 359
 360         pos.y = ymin;
 361         pos.z = 0;
 362
 363         draw_beginBoldFont();
 364
 365         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 366         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 367         drawstring(pos, map, hud_fontsize * 2, '1 1 1', 1, DRAWFLAG_NORMAL);
 368         pos.y += hud_fontsize.y * 2;
 369
 370         if( mapvote_chosenmap != "" )
 371         {
 372                 pos.y += hud_fontsize.y * 0.25;
 373                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 374                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 375                 pos.y += hud_fontsize.y * 1.5;
 376                 pos.y += hud_fontsize.y * 0.5;
 377         }
 378         else
 379                 pos.y += hud_fontsize.y * 0.5;
 380
 381         draw_endBoldFont();
 382
 383         i = ceil(max(0, mv_timeout - time));
 384         map = sprintf(_("%d seconds left"), i);
 385         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 386         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', 1, DRAWFLAG_NORMAL);
 387         pos.y += hud_fontsize.y * 1.5;
 388         pos.y += hud_fontsize.y * 0.5;
 389
 390         HUD_Panel_UpdateCvars();
 391
 392         // base for multi-column stuff...
 393         pos.y += hud_fontsize.y;
 394         pos.x = xmin;
 395         ymin = pos.y;
 396         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 397         if(mv_abstain)
 398         {
 399                 mv_num_maps -= 1;
 400                 ymax -= abstain_spacing;
 401         }
 402
 403         // higher than the image itself ratio for mapvote items to reserve space for long map names
 404         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 405         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 406         mv_columns = table_size.x;
 407         rows = table_size.y;
 408
 409         dist.x = (xmax - xmin) / mv_columns;
 410         dist.y = (ymax - pos.y) / rows;
 411
 412         // reduce size of too wide items
 413         tmp = vid_conwidth / 3; // max width
 414         if(dist.x > tmp)
 415         {
 416                 dist.x = tmp;
 417                 dist.y = min(dist.y, dist.x / item_aspect);
 418         }
 419         tmp = vid_conheight / 3; // max height
 420         if(dist.y > tmp)
 421         {
 422                 dist.y = tmp;
 423                 dist.x = min(dist.x, dist.y * item_aspect);
 424         }
 425
 426         // reduce size to fix aspect ratio
 427         if(dist.x / dist.y > item_aspect)
 428                 dist.x = dist.y * item_aspect;
 429         else
 430                 dist.y = dist.x / item_aspect;
 431
 432         // adjust table pos and size according to the new size
 433         float offset;
 434         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 435         xmin = pos.x += offset;
 436         xmax -= offset;
 437         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 438         ymax -= 2 * offset;
 439
 440         // override panel_pos and panel_size
 441         panel_pos.x = pos.x;
 442         panel_pos.y = pos.y;
 443         panel_size.x = xmax - xmin;
 444         panel_size.y = ymax - ymin;
 445         HUD_Scale_Disable();
 446         HUD_Panel_DrawBg(1);
 447
 448         if(panel_bg_padding)
 449         {
 450                 // FIXME item AR gets slightly changed here...
 451                 // it's rather hard to avoid it at this point
 452                 dist.x -= 2 * panel_bg_padding / mv_columns;
 453                 dist.y -= 2 * panel_bg_padding / rows;
 454                 xmin = pos.x += panel_bg_padding;
 455                 ymin = pos.y += panel_bg_padding;
 456                 xmax -= 2 * panel_bg_padding;
 457                 ymax -= 2 * panel_bg_padding;
 458         }
 459
 460         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 461
 462         if (mv_top2_time)
 463                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 464
 465         void (vector, float, float, string, string, float, float) DrawItem;
 466
 467         if(gametypevote)
 468                 DrawItem = GameTypeVote_DrawGameTypeItem;
 469         else
 470                 DrawItem = MapVote_DrawMapItem;
 471
 472         for(i = 0; i < mv_num_maps; ++i)
 473         {
 474                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 475                 map = mv_maps[i];
 476                 if(mv_preview[i])
 477                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 478                 else
 479                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 480         }
 481
 482         if(mv_abstain)
 483                 ++mv_num_maps;
 484
 485         if(mv_abstain && i < mv_num_maps) {
 486                 tmp = mv_votes[i];
 487                 pos.y = ymax + abstain_spacing;
 488                 pos.x = (xmax+xmin)*0.5;
 489                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 490         }
 491
 492         draw_cursor_normal(mv_mousepos, '1 1 1', 1 - autocvar__menu_alpha);
 493 }
 494
 495 void Cmd_MapVote_MapDownload(int argc)
 496 {
 497     TC(int, argc);
 498         entity pak;
 499
 500         if(argc != 2 || !mv_pk3list)
 501         {
 502                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 503                 return;
 504         }
 505
 506         int id = stof(argv(1));
 507         for(pak = mv_pk3list; pak; pak = pak.chain)
 508                 if(pak.sv_entnum == id)
 509                         break;
 510
 511         if(!pak || pak.sv_entnum != id) {
 512                 LOG_INFO(_("^1Error:^7 Couldn't find pak index.\n"));
 513                 return;
 514         }
 515
 516         if(PreviewExists(pak.message))
 517         {
 518                 mv_preview[id] = true;
 519                 return;
 520         } else {
 521                 LOG_INFO(_("Requesting preview...\n"));
 522                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 523         }
 524 }
 525
 526 void MapVote_CheckPK3(string pic, string pk3, int id)
 527 {
 528     TC(int, id);
 529         entity pak;
 530         pak = spawn();
 531         pak.netname = pk3;
 532         pak.message = pic;
 533         pak.sv_entnum = id;
 534
 535         pak.chain = mv_pk3list;
 536         mv_pk3list = pak;
 537
 538         if(pk3 != "")
 539         {
 540                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 541         }
 542         else
 543         {
 544                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 545         }
 546 }
 547
 548 void MapVote_CheckPic(string pic, string pk3, int id)
 549 {
 550     TC(int, id);
 551         // never try to retrieve a pic for the "don't care" 'map'
 552         if(mv_abstain && id == mv_num_maps - 1)
 553                 return;
 554
 555         if(PreviewExists(pic))
 556         {
 557                 mv_preview[id] = true;
 558                 return;
 559         }
 560         MapVote_CheckPK3(pic, pk3, id);
 561 }
 562
 563 void MapVote_ReadMask()
 564 {
 565         int i;
 566         if ( mv_num_maps < 24 )
 567         {
 568                 int mask, power;
 569                 if(mv_num_maps < 8)
 570                         mask = ReadByte();
 571                 else if(mv_num_maps < 16)
 572                         mask = ReadShort();
 573                 else
 574                         mask = ReadLong();
 575
 576                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 577                 {
 578                         if ( mask & power )
 579                                 mv_flags[i] |= GTV_AVAILABLE;
 580                         else
 581                                 mv_flags[i] &= ~GTV_AVAILABLE;
 582                 }
 583         }
 584         else
 585         {
 586                 for(i = 0; i < mv_num_maps; ++i )
 587                         mv_flags[i] = ReadByte();
 588         }
 589 }
 590
 591 void MapVote_ReadOption(int i)
 592 {
 593     TC(int, i);
 594         string map = strzone(ReadString());
 595         string pk3 = strzone(ReadString());
 596         int j = bound(0, ReadByte(), n_ssdirs - 1);
 597
 598         mv_maps[i] = map;
 599         mv_pk3[i] = pk3;
 600         mv_flags[i] = GTV_AVAILABLE;
 601
 602         string pic = strzone(strcat(ssdirs[j], "/", map));
 603         mv_pics[i] = pic;
 604         mv_preview[i] = false;
 605         MapVote_CheckPic(pic, pk3, i);
 606 }
 607
 608 void GameTypeVote_ReadOption(int i)
 609 {
 610     TC(int, i);
 611         string gt = strzone(ReadString());
 612
 613         mv_maps[i] = gt;
 614         mv_flags[i] = ReadByte();
 615
 616         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 617         if(precache_pic(mv_picpath) == "")
 618                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 619         string pic = strzone(mv_picpath);
 620         mv_pics[i] = pic;
 621         mv_preview[i] = PreviewExists(pic);
 622
 623         if ( mv_flags[i] & GTV_CUSTOM )
 624         {
 625                 string name = ReadString();
 626                 if ( strlen(name) < 1 )
 627                         name = gt;
 628                 mv_pk3[i] = strzone(name);
 629                 mv_desc[i] = strzone(ReadString());
 630         }
 631         else
 632         {
 633                 int type = MapInfo_Type_FromString(gt);
 634                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 635                 mv_desc[i] = MapInfo_Type_Description(type);
 636         }
 637 }
 638
 639 void MapVote_Init()
 640 {
 641         mv_active = 1;
 642         if(autocvar_hud_cursormode) { setcursormode(1); }
 643         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 644         mv_selection = -1;
 645         mv_selection_keyboard = 0;
 646
 647         string s;
 648         for(n_ssdirs = 0; ; ++n_ssdirs)
 649         {
 650                 s = ReadString();
 651                 if(s == "")
 652                         break;
 653                 if(n_ssdirs < NUM_SSDIRS)
 654                         ssdirs[n_ssdirs] = s;
 655         }
 656         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 657
 658         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 659         mv_abstain = ReadByte();
 660         if(mv_abstain)
 661                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 662         mv_detail = ReadByte();
 663
 664         mv_ownvote = -1;
 665         mv_timeout = ReadCoord();
 666
 667         gametypevote = ReadByte();
 668
 669         if(gametypevote)
 670         {
 671                 mapvote_chosenmap = strzone(ReadString());
 672                 if ( gametypevote == 2 )
 673                         gametypevote = 0;
 674
 675                 gtv_text_size = hud_fontsize*1.4;
 676                 gtv_text_size_small = hud_fontsize*1.1;
 677         }
 678
 679         MapVote_ReadMask();
 680         int i;
 681         for(i = 0; i < mv_num_maps; ++i )
 682                 mv_flags_start[i] = mv_flags[i];
 683
 684         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 685         mv_pk3list = world; // I'm still paranoid!
 686
 687         for(i = 0; i < mv_num_maps; ++i)
 688         {
 689                 mv_votes[i] = 0;
 690
 691                 if ( gametypevote )
 692                         GameTypeVote_ReadOption(i);
 693                 else
 694                         MapVote_ReadOption(i);
 695         }
 696
 697         for(i = 0; i < n_ssdirs; ++i)
 698                 ssdirs[n_ssdirs] = string_null;
 699         n_ssdirs = 0;
 700 }
 701
 702 void MapVote_SendChoice(int index)
 703 {
 704     TC(int, index);
 705         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 706 }
 707
 708 int MapVote_MoveLeft(int pos)
 709 {
 710     TC(int, pos);
 711         int imp;
 712         if ( pos < 0 )
 713                 imp = mv_num_maps - 1;
 714         else
 715                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 716         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 717                 imp = MapVote_MoveLeft(imp);
 718         return imp;
 719 }
 720 int MapVote_MoveRight(int pos)
 721 {
 722     TC(int, pos);
 723         int imp;
 724         if ( pos < 0 )
 725                 imp = 0;
 726         else
 727                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 728         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 729                 imp = MapVote_MoveRight(imp);
 730         return imp;
 731 }
 732 int MapVote_MoveUp(int pos)
 733 {
 734     TC(int, pos);
 735         int imp;
 736         if ( pos < 0 )
 737                 imp = mv_num_maps - 1;
 738         else
 739         {
 740                 imp = pos - mv_columns;
 741                 if ( imp < 0 )
 742                 {
 743                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 744                         if ( imp >= mv_num_maps )
 745                                 imp -= mv_columns;
 746                 }
 747         }
 748         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 749                 imp = MapVote_MoveUp(imp);
 750         return imp;
 751 }
 752 int MapVote_MoveDown(int pos)
 753 {
 754     TC(int, pos);
 755         int imp;
 756         if ( pos < 0 )
 757                 imp = 0;
 758         else
 759         {
 760                 imp = pos + mv_columns;
 761                 if ( imp >= mv_num_maps )
 762                         imp = imp % mv_columns;
 763         }
 764         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 765                 imp = MapVote_MoveDown(imp);
 766         return imp;
 767 }
 768
 769 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 770 {
 771     TC(int, bInputType);
 772         float imp;
 773
 774         if (!mv_active)
 775                 return false;
 776
 777         if(bInputType == 3)
 778         {
 779                 mv_mousepos.x = nPrimary;
 780                 mv_mousepos.y = nSecondary;
 781                 mv_selection_keyboard = 0;
 782                 return true;
 783         }
 784
 785         if (bInputType != 0)
 786                 return false;
 787
 788         if ('0' <= nPrimary && nPrimary <= '9')
 789         {
 790                 imp = nPrimary - '0';
 791                 if (imp == 0) imp = 10;
 792                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 793                 return true;
 794         }
 795         switch(nPrimary)
 796         {
 797                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 798                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 799                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 800                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 801                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 802                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 803                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 804                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 805                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 806                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 807
 808                 case K_RIGHTARROW:
 809                         mv_selection_keyboard = 1;
 810                         mv_selection = MapVote_MoveRight(mv_selection);
 811                         return true;
 812                 case K_LEFTARROW:
 813                         mv_selection_keyboard = 1;
 814                         mv_selection = MapVote_MoveLeft(mv_selection);
 815                         return true;
 816                 case K_DOWNARROW:
 817                         mv_selection_keyboard = 1;
 818                         mv_selection = MapVote_MoveDown(mv_selection);
 819                         return true;
 820                 case K_UPARROW:
 821                         mv_selection_keyboard = 1;
 822                         mv_selection = MapVote_MoveUp(mv_selection);
 823                         return true;
 824                 case K_KP_ENTER:
 825                 case K_ENTER:
 826                 case K_SPACE:
 827                         if ( mv_selection_keyboard )
 828                                 MapVote_SendChoice(mv_selection);
 829                         return true;
 830         }
 831
 832         if (nPrimary == K_MOUSE1)
 833         {
 834                 mv_selection_keyboard = 0;
 835                 mv_selection = mv_mouse_selection;
 836                 if (mv_selection >= 0)
 837                 {
 838                         imp = min(mv_selection + 1, mv_num_maps);
 839                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 840                         return true;
 841                 }
 842         }
 843
 844         return false;
 845 }
 846
 847 void MapVote_UpdateMask()
 848 {
 849         MapVote_ReadMask();
 850         mv_top2_time = time;
 851 }
 852
 853 void MapVote_UpdateVotes()
 854 {
 855         int i;
 856         for(i = 0; i < mv_num_maps; ++i)
 857         {
 858                 if(mv_flags[i] & GTV_AVAILABLE)
 859                 {
 860                         if(mv_detail)
 861                                 mv_votes[i] = ReadByte();
 862                         else
 863                                 mv_votes[i] = 0;
 864                 }
 865                 else
 866                         mv_votes[i] = -1;
 867         }
 868
 869         mv_ownvote = ReadByte()-1;
 870 }
 871
 872 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 873 {
 874         make_pure(this);
 875         int sf = ReadByte();
 876         return = true;
 877
 878         if(sf & 1)
 879                 MapVote_Init();
 880
 881         if(sf & 2)
 882                 MapVote_UpdateMask();
 883
 884         if(sf & 4)
 885                 MapVote_UpdateVotes();
 886 }
 887
 888 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 889 {
 890         Net_MapVote_Picture();
 891         return true;
 892 }
 893
 894 void Net_MapVote_Picture()
 895 {
 896         int type = ReadByte();
 897         mv_preview[type] = true;
 898         mv_pics[type] = strzone(ReadPicture());
 899 }