qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89
  90         // Bounding box details
  91         float rect_margin = hud_fontsize.y / 2;
  92
  93         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
  94         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
  95         maxh -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  96         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  97
  98         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  99         vector rect_size = '1 1 0';
 100         rect_size.x = tsize + rect_margin;
 101         rect_size.y = maxh + rect_margin;
 102
 103         // Highlight selected item
 104         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 105         {
 106                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 107         }
 108
 109         // Highlight current vote
 110         vector rgb = MapVote_RGB(id);
 111         if(id == mv_ownvote)
 112         {
 113                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 114                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 115         }
 116
 117         vector offset = pos;
 118
 119         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 120         pos.y += title_gap;
 121         maxh -= title_gap;
 122
 123         // Evaluate the image size
 124         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 125         if ( maxh < image_size.y )
 126                 image_size = '1 1 0' * maxh;
 127         image_size *= 0.8;
 128         float desc_padding = gtv_text_size.x * 0.6;
 129         pos.x += image_size.x + desc_padding;
 130         tsize -= image_size.x + desc_padding;
 131
 132         // Split the description into lines
 133         entity title;
 134         title = spawn();
 135         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 136
 137         string thelabel = mv_desc[id], ts;
 138         entity last = title;
 139         entity next = world;
 140         float nlines = 0;
 141         if( thelabel != "")
 142         {
 143                 float i,n = tokenizebyseparator(thelabel, "\n");
 144                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 145                 {
 146                         getWrappedLine_remaining = argv(i);
 147                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 148                         {
 149                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 150                                 if (ts != "")
 151                                 {
 152                                         next = spawn();
 153                                         next.message = ts;
 154                                         next.origin = pos-offset;
 155                                         last.chain = next;
 156                                         last = next;
 157                                         pos.y += gtv_text_size_small.y;
 158                                         nlines++;
 159                                 }
 160                         }
 161                 }
 162         }
 163
 164         // Center the contents in the bounding box
 165         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 166         if ( maxh > 0 )
 167                 offset.y += maxh/2;
 168
 169         // Draw the title
 170         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 171
 172         // Draw the icon
 173         if(pic != "")
 174                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 175
 176         // Draw the description
 177         for ( last = title.chain; last ; )
 178         {
 179                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 180                 next = last;
 181                 last = last.chain;
 182                 remove(next);
 183         }
 184
 185         // Cleanup
 186         remove(title);
 187 }
 188
 189 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 190 {
 191         vector img_size = '0 0 0';
 192         vector rgb;
 193         string label;
 194         float text_size;
 195
 196         rgb = MapVote_RGB(id);
 197
 198         float padding = hud_fontsize.y / 2;
 199
 200         pos.x += padding;
 201         pos.y += padding;
 202         isize -= 2 * padding;
 203         tsize -= 2 * padding;
 204
 205         float img_ar = 4/3;
 206         img_size.x = min(tsize, isize * img_ar);
 207         img_size.y = img_size.x / img_ar;
 208         img_size.y -= hud_fontsize.y - autocvar_scoreboard_border_thickness * 2;
 209         img_size.x = img_size.y * img_ar;
 210
 211         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 212
 213         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 214
 215         text_size = stringwidth(label, false, hud_fontsize);
 216
 217         vector text_pos = '0 0 0';
 218         text_pos.x = pos.x + (tsize - text_size) / 2;
 219         text_pos.y = pos.y + img_size.y + autocvar_scoreboard_border_thickness;
 220
 221         pos.x += (tsize - img_size.x) / 2;
 222
 223         float theAlpha;
 224         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 225                 theAlpha = mv_top2_alpha;
 226         else
 227                 theAlpha = 1;
 228         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 229
 230         if(pic == "")
 231         {
 232                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 233         }
 234         else
 235         {
 236                 if(drawgetimagesize(pic) == '0 0 0')
 237                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 238                 else
 239                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 240         }
 241
 242         if(id == mv_ownvote)
 243                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 244         else
 245                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 246
 247         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 248                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 249 }
 250
 251 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 252 {
 253         vector rgb;
 254         float text_size;
 255         string label;
 256
 257         rgb = MapVote_RGB(id);
 258
 259         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 260
 261         text_size = stringwidth(label, false, hud_fontsize);
 262
 263         pos.x -= text_size*0.5;
 264         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 265 }
 266
 267 vector MapVote_GridVec(vector gridspec, int i, int m)
 268 {
 269         int r = i % m;
 270         return
 271                 '1 0 0' * (gridspec.x * r)
 272                 +
 273                 '0 1 0' * (gridspec.y * (i - r) / m);
 274 }
 275
 276 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 277 {
 278
 279         float c, r;
 280
 281         mv_mouse_selection = -1;
 282
 283         for (r = 0; r < rows; ++r)
 284                 for (c = 0; c < columns; ++c)
 285                 {
 286                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 287                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 288                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 289                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 290                         {
 291                                 mv_mouse_selection = r * columns + c;
 292                                 break;
 293                         }
 294                 }
 295
 296         if (mv_mouse_selection >= mv_num_maps)
 297                 mv_mouse_selection = -1;
 298
 299         if (mv_abstain && mv_mouse_selection < 0)
 300                 mv_mouse_selection = mv_num_maps;
 301
 302         if ( mv_selection_keyboard )
 303                 return mv_selection;
 304
 305         return mv_mouse_selection;
 306 }
 307
 308 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 309 void MapVote_Draw()
 310 {
 311         string map;
 312         int i;
 313         float tmp;
 314         vector pos;
 315         float center;
 316         float rows;
 317         vector dist = '0 0 0';
 318
 319         //if(intermission != 2) return;
 320         if(!mv_active)
 321                 return;
 322
 323         if (!autocvar_hud_cursormode)
 324         {
 325                 vector mpos = mv_mousepos + getmousepos();
 326                 mpos.x = bound(0, mpos.x, vid_conwidth);
 327                 mpos.y = bound(0, mpos.y, vid_conheight);
 328
 329                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 330                         mv_selection_keyboard = 0;
 331                 mv_mousepos = mpos;
 332
 333         }
 334
 335         center = (vid_conwidth - 1)/2;
 336         xmin = vid_conwidth * 0.08;
 337         xmax = vid_conwidth - xmin;
 338         ymin = 20;
 339         ymax = vid_conheight - ymin;
 340
 341         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 342                 ymin += chat_sizey;
 343         else
 344                 ymax -= chat_sizey;
 345
 346         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 347
 348         pos.y = ymin;
 349         pos.z = 0;
 350
 351         draw_beginBoldFont();
 352
 353         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 354         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 355         drawstring(pos, map, hud_fontsize * 2, '1 1 1', 1, DRAWFLAG_NORMAL);
 356         pos.y += hud_fontsize.y * 2;
 357
 358         if( mapvote_chosenmap != "" )
 359         {
 360                 pos.y += hud_fontsize.y * 0.25;
 361                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 362                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 363                 pos.y += hud_fontsize.y * 1.5;
 364                 pos.y += hud_fontsize.y * 0.5;
 365         }
 366         else
 367                 pos.y += hud_fontsize.y * 0.5;
 368
 369         draw_endBoldFont();
 370
 371         i = ceil(max(0, mv_timeout - time));
 372         map = sprintf(_("%d seconds left"), i);
 373         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 374         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', 1, DRAWFLAG_NORMAL);
 375         pos.y += hud_fontsize.y * 1.5;
 376         pos.y += hud_fontsize.y * 0.5;
 377
 378         HUD_Panel_UpdateCvars();
 379
 380         // base for multi-column stuff...
 381         pos.y += hud_fontsize.y;
 382         pos.x = xmin;
 383         ymin = pos.y;
 384         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 385         if(mv_abstain)
 386         {
 387                 mv_num_maps -= 1;
 388                 ymax -= abstain_spacing;
 389         }
 390
 391         // higher than the image itself ratio for mapvote items to reserve space for long map names
 392         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 393         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 394         mv_columns = table_size.x;
 395         rows = table_size.y;
 396
 397         dist.x = (xmax - xmin) / mv_columns;
 398         dist.y = (ymax - pos.y) / rows;
 399
 400         // reduce size of too wide items
 401         tmp = vid_conwidth / 3; // max width
 402         if(dist.x > tmp)
 403         {
 404                 dist.x = tmp;
 405                 dist.y = min(dist.y, dist.x / item_aspect);
 406         }
 407         tmp = vid_conheight / 3; // max height
 408         if(dist.y > tmp)
 409         {
 410                 dist.y = tmp;
 411                 dist.x = min(dist.x, dist.y * item_aspect);
 412         }
 413
 414         // reduce size to fix aspect ratio
 415         if(dist.x / dist.y > item_aspect)
 416                 dist.x = dist.y * item_aspect;
 417         else
 418                 dist.y = dist.x / item_aspect;
 419
 420         // adjust table pos and size according to the new size
 421         float offset;
 422         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 423         xmin = pos.x += offset;
 424         xmax -= offset;
 425         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 426         ymax -= 2 * offset;
 427
 428         // override panel_pos and panel_size
 429         panel_pos.x = pos.x;
 430         panel_pos.y = pos.y;
 431         panel_size.x = xmax - xmin;
 432         panel_size.y = ymax - ymin;
 433         HUD_Panel_DrawBg(1);
 434
 435         if(panel_bg_padding)
 436         {
 437                 // FIXME item AR gets slightly changed here...
 438                 // it's rather hard to avoid it at this point
 439                 dist.x -= 2 * panel_bg_padding / mv_columns;
 440                 dist.y -= 2 * panel_bg_padding / rows;
 441                 xmin = pos.x += panel_bg_padding;
 442                 ymin = pos.y += panel_bg_padding;
 443                 xmax -= 2 * panel_bg_padding;
 444                 ymax -= 2 * panel_bg_padding;
 445         }
 446
 447         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 448
 449         if (mv_top2_time)
 450                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 451
 452         void (vector, float, float, string, string, float, float) DrawItem;
 453
 454         if(gametypevote)
 455                 DrawItem = GameTypeVote_DrawGameTypeItem;
 456         else
 457                 DrawItem = MapVote_DrawMapItem;
 458
 459         for(i = 0; i < mv_num_maps; ++i)
 460         {
 461                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 462                 map = mv_maps[i];
 463                 if(mv_preview[i])
 464                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 465                 else
 466                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 467         }
 468
 469         if(mv_abstain)
 470                 ++mv_num_maps;
 471
 472         if(mv_abstain && i < mv_num_maps) {
 473                 tmp = mv_votes[i];
 474                 pos.y = ymax + abstain_spacing;
 475                 pos.x = (xmax+xmin)*0.5;
 476                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 477         }
 478
 479         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 480 }
 481
 482 void Cmd_MapVote_MapDownload(float argc)
 483 {
 484         entity pak;
 485
 486         if(argc != 2 || !mv_pk3list)
 487         {
 488                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 489                 return;
 490         }
 491
 492         int id = stof(argv(1));
 493         for(pak = mv_pk3list; pak; pak = pak.chain)
 494                 if(pak.sv_entnum == id)
 495                         break;
 496
 497         if(!pak || pak.sv_entnum != id) {
 498                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 499                 return;
 500         }
 501
 502         if(PreviewExists(pak.message))
 503         {
 504                 mv_preview[id] = true;
 505                 return;
 506         } else {
 507                 print(_("Requesting preview...\n"));
 508                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 509         }
 510 }
 511
 512 void MapVote_CheckPK3(string pic, string pk3, int id)
 513 {
 514         entity pak;
 515         pak = spawn();
 516         pak.netname = pk3;
 517         pak.message = pic;
 518         pak.sv_entnum = id;
 519
 520         pak.chain = mv_pk3list;
 521         mv_pk3list = pak;
 522
 523         if(pk3 != "")
 524         {
 525                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 526         }
 527         else
 528         {
 529                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 530         }
 531 }
 532
 533 void MapVote_CheckPic(string pic, string pk3, int id)
 534 {
 535         // never try to retrieve a pic for the "don't care" 'map'
 536         if(mv_abstain && id == mv_num_maps - 1)
 537                 return;
 538
 539         if(PreviewExists(pic))
 540         {
 541                 mv_preview[id] = true;
 542                 return;
 543         }
 544         MapVote_CheckPK3(pic, pk3, id);
 545 }
 546
 547 void MapVote_ReadMask()
 548 {
 549         int i;
 550         if ( mv_num_maps < 24 )
 551         {
 552                 int mask, power;
 553                 if(mv_num_maps < 8)
 554                         mask = ReadByte();
 555                 else if(mv_num_maps < 16)
 556                         mask = ReadShort();
 557                 else
 558                         mask = ReadLong();
 559
 560                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 561                 {
 562                         if ( mask & power )
 563                                 mv_flags[i] |= GTV_AVAILABLE;
 564                         else
 565                                 mv_flags[i] &= ~GTV_AVAILABLE;
 566                 }
 567         }
 568         else
 569         {
 570                 for(i = 0; i < mv_num_maps; ++i )
 571                         mv_flags[i] = ReadByte();
 572         }
 573 }
 574
 575 void MapVote_ReadOption(int i)
 576 {
 577         string map = strzone(ReadString());
 578         string pk3 = strzone(ReadString());
 579         int j = bound(0, ReadByte(), n_ssdirs - 1);
 580
 581         mv_maps[i] = map;
 582         mv_pk3[i] = pk3;
 583         mv_flags[i] = GTV_AVAILABLE;
 584
 585         string pic = strzone(strcat(ssdirs[j], "/", map));
 586         mv_pics[i] = pic;
 587         mv_preview[i] = false;
 588         MapVote_CheckPic(pic, pk3, i);
 589 }
 590
 591 void GameTypeVote_ReadOption(int i)
 592 {
 593         string gt = strzone(ReadString());
 594
 595         mv_maps[i] = gt;
 596         mv_flags[i] = ReadByte();
 597
 598         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 599         if(precache_pic(mv_picpath) == "")
 600                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 601         string pic = strzone(mv_picpath);
 602         mv_pics[i] = pic;
 603         mv_preview[i] = PreviewExists(pic);
 604
 605         if ( mv_flags[i] & GTV_CUSTOM )
 606         {
 607                 string name = ReadString();
 608                 if ( strlen(name) < 1 )
 609                         name = gt;
 610                 mv_pk3[i] = strzone(name);
 611                 mv_desc[i] = strzone(ReadString());
 612         }
 613         else
 614         {
 615                 int type = MapInfo_Type_FromString(gt);
 616                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 617                 mv_desc[i] = MapInfo_Type_Description(type);
 618         }
 619 }
 620
 621 void MapVote_Init()
 622 {
 623         precache_sound ("misc/invshot.wav");
 624
 625         mv_active = 1;
 626         if(autocvar_hud_cursormode) { setcursormode(1); }
 627         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 628         mv_selection = -1;
 629         mv_selection_keyboard = 0;
 630
 631         string s;
 632         for(n_ssdirs = 0; ; ++n_ssdirs)
 633         {
 634                 s = ReadString();
 635                 if(s == "")
 636                         break;
 637                 if(n_ssdirs < NUM_SSDIRS)
 638                         ssdirs[n_ssdirs] = s;
 639         }
 640         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 641
 642         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 643         mv_abstain = ReadByte();
 644         if(mv_abstain)
 645                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 646         mv_detail = ReadByte();
 647
 648         mv_ownvote = -1;
 649         mv_timeout = ReadCoord();
 650
 651         gametypevote = ReadByte();
 652
 653         if(gametypevote)
 654         {
 655                 mapvote_chosenmap = strzone(ReadString());
 656                 if ( gametypevote == 2 )
 657                         gametypevote = 0;
 658
 659                 gtv_text_size = hud_fontsize*1.4;
 660                 gtv_text_size_small = hud_fontsize*1.1;
 661         }
 662
 663         MapVote_ReadMask();
 664         int i;
 665         for(i = 0; i < mv_num_maps; ++i )
 666                 mv_flags_start[i] = mv_flags[i];
 667
 668         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 669         mv_pk3list = world; // I'm still paranoid!
 670
 671         for(i = 0; i < mv_num_maps; ++i)
 672         {
 673                 mv_votes[i] = 0;
 674
 675                 if ( gametypevote )
 676                         GameTypeVote_ReadOption(i);
 677                 else
 678                         MapVote_ReadOption(i);
 679         }
 680
 681         for(i = 0; i < n_ssdirs; ++i)
 682                 ssdirs[n_ssdirs] = string_null;
 683         n_ssdirs = 0;
 684 }
 685
 686 void MapVote_SendChoice(float index)
 687 {
 688         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 689 }
 690
 691 int MapVote_MoveLeft(int pos)
 692 {
 693         int imp;
 694         if ( pos < 0 )
 695                 imp = mv_num_maps - 1;
 696         else
 697                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 698         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 699                 imp = MapVote_MoveLeft(imp);
 700         return imp;
 701 }
 702 int MapVote_MoveRight(int pos)
 703 {
 704         int imp;
 705         if ( pos < 0 )
 706                 imp = 0;
 707         else
 708                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 709         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 710                 imp = MapVote_MoveRight(imp);
 711         return imp;
 712 }
 713 int MapVote_MoveUp(int pos)
 714 {
 715         int imp;
 716         if ( pos < 0 )
 717                 imp = mv_num_maps - 1;
 718         else
 719         {
 720                 imp = pos - mv_columns;
 721                 if ( imp < 0 )
 722                 {
 723                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 724                         if ( imp >= mv_num_maps )
 725                                 imp -= mv_columns;
 726                 }
 727         }
 728         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 729                 imp = MapVote_MoveUp(imp);
 730         return imp;
 731 }
 732 int MapVote_MoveDown(int pos)
 733 {
 734         int imp;
 735         if ( pos < 0 )
 736                 imp = 0;
 737         else
 738         {
 739                 imp = pos + mv_columns;
 740                 if ( imp >= mv_num_maps )
 741                         imp = imp % mv_columns;
 742         }
 743         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 744                 imp = MapVote_MoveDown(imp);
 745         return imp;
 746 }
 747
 748 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 749 {
 750         float imp;
 751
 752         if (!mv_active)
 753                 return false;
 754
 755         if(bInputType == 3)
 756         {
 757                 mv_mousepos.x = nPrimary;
 758                 mv_mousepos.y = nSecondary;
 759                 mv_selection_keyboard = 0;
 760                 return true;
 761         }
 762
 763         if (bInputType != 0)
 764                 return false;
 765
 766         if ('0' <= nPrimary && nPrimary <= '9')
 767         {
 768                 imp = nPrimary - '0';
 769                 if (imp == 0) imp = 10;
 770                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 771                 return true;
 772         }
 773         switch(nPrimary)
 774         {
 775                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 776                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 777                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 778                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 779                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 780                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 781                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 782                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 783                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 784                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 785
 786                 case K_RIGHTARROW:
 787                         mv_selection_keyboard = 1;
 788                         mv_selection = MapVote_MoveRight(mv_selection);
 789                         return true;
 790                 case K_LEFTARROW:
 791                         mv_selection_keyboard = 1;
 792                         mv_selection = MapVote_MoveLeft(mv_selection);
 793                         return true;
 794                 case K_DOWNARROW:
 795                         mv_selection_keyboard = 1;
 796                         mv_selection = MapVote_MoveDown(mv_selection);
 797                         return true;
 798                 case K_UPARROW:
 799                         mv_selection_keyboard = 1;
 800                         mv_selection = MapVote_MoveUp(mv_selection);
 801                         return true;
 802                 case K_KP_ENTER:
 803                 case K_ENTER:
 804                 case K_SPACE:
 805                         if ( mv_selection_keyboard )
 806                                 MapVote_SendChoice(mv_selection);
 807                         return true;
 808         }
 809
 810         if (nPrimary == K_MOUSE1)
 811         {
 812                 mv_selection_keyboard = 0;
 813                 mv_selection = mv_mouse_selection;
 814                 if (mv_selection >= 0)
 815                 {
 816                         imp = min(mv_selection + 1, mv_num_maps);
 817                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 818                         return true;
 819                 }
 820         }
 821
 822         return false;
 823 }
 824
 825 void MapVote_UpdateMask()
 826 {
 827         MapVote_ReadMask();
 828         mv_top2_time = time;
 829 }
 830
 831 void MapVote_UpdateVotes()
 832 {
 833         int i;
 834         for(i = 0; i < mv_num_maps; ++i)
 835         {
 836                 if(mv_flags[i] & GTV_AVAILABLE)
 837                 {
 838                         if(mv_detail)
 839                                 mv_votes[i] = ReadByte();
 840                         else
 841                                 mv_votes[i] = 0;
 842                 }
 843                 else
 844                         mv_votes[i] = -1;
 845         }
 846
 847         mv_ownvote = ReadByte()-1;
 848 }
 849
 850 void Ent_MapVote()
 851 {
 852         int sf = ReadByte();
 853
 854         if(sf & 1)
 855                 MapVote_Init();
 856
 857         if(sf & 2)
 858                 MapVote_UpdateMask();
 859
 860         if(sf & 4)
 861                 MapVote_UpdateVotes();
 862 }
 863
 864 void Net_MapVote_Picture()
 865 {
 866         int type = ReadByte();
 867         mv_preview[type] = true;
 868         mv_pics[type] = strzone(ReadPicture());
 869 }