qcsrc/client/particles.qc

   1 .float dphitcontentsmask;
   2
   3 .float cnt; // effect number
   4 .vector velocity; // particle velocity
   5 .float waterlevel; // direction jitter
   6 .float count; // count multiplier
   7 .float impulse; // density
   8 .string noise; // sound
   9 .float atten;
  10 .float volume;
  11 .float absolute; // 1 = count per second is absolute, 2 = only spawn at toggle
  12 .vector movedir; // trace direction
  13
  14 void Draw_PointParticles()
  15 {
  16         float n, i, fail;
  17         vector p;
  18         vector sz;
  19         vector o;
  20         o = self.origin;
  21         sz = self.maxs - self.mins;
  22         n = BGMScript(self);
  23         if(self.absolute == 2)
  24         {
  25                 if(n >= 0)
  26                         n = self.just_toggled ? self.impulse : 0;
  27                 else
  28                         n = self.impulse * drawframetime;
  29         }
  30         else
  31         {
  32                 n *= self.impulse * drawframetime;
  33                 if(self.just_toggled)
  34                         if(n < 1)
  35                                 n = 1;
  36         }
  37         if(n == 0)
  38                 return;
  39         fail = 0;
  40         for(i = random(); i <= n && fail <= 64*n; ++i)
  41         {
  42                 p = o + self.mins;
  43                 p_x += random() * sz_x;
  44                 p_y += random() * sz_y;
  45                 p_z += random() * sz_z;
  46                 if(WarpZoneLib_BoxTouchesBrush(p, p, self, world))
  47                 {
  48                         if(self.movedir != '0 0 0')
  49                         {
  50                                 traceline(p, p + normalize(self.movedir) * 4096, 0, world);
  51                                 p = trace_endpos;
  52                                 pointparticles(self.cnt, p, trace_plane_normal * vlen(self.movedir) + self.velocity + randomvec() * self.waterlevel, self.count);
  53                         }
  54                         else
  55                         {
  56                                 pointparticles(self.cnt, p, self.velocity + randomvec() * self.waterlevel, self.count);
  57                         }
  58                         if(self.noise != "")
  59                         {
  60                                 setorigin(self, p);
  61                                 sound(self, CH_AMBIENT, self.noise, VOL_BASE * self.volume, self.atten);
  62                         }
  63                         self.just_toggled = 0;
  64                 }
  65                 else if(self.absolute)
  66                 {
  67                         ++fail;
  68                         --i;
  69                 }
  70         }
  71         setorigin(self, o);
  72 }
  73
  74 void Ent_PointParticles_Remove()
  75 {
  76         if(self.noise)
  77                 strunzone(self.noise);
  78         self.noise = string_null;
  79         if(self.bgmscript)
  80                 strunzone(self.bgmscript);
  81         self.bgmscript = string_null;
  82 }
  83
  84 void Ent_PointParticles()
  85 {
  86         float f, i;
  87         vector v;
  88         f = ReadByte();
  89         if(f & 2)
  90         {
  91                 i = ReadCoord(); // density (<0: point, >0: volume)
  92                 if(i && !self.impulse && self.cnt) // self.cnt check is so it only happens if the ent already existed
  93                         self.just_toggled = 1;
  94                 self.impulse = i;
  95         }
  96         if(f & 4)
  97         {
  98                 self.origin_x = ReadCoord();
  99                 self.origin_y = ReadCoord();
 100                 self.origin_z = ReadCoord();
 101         }
 102         if(f & 1)
 103         {
 104                 self.modelindex = ReadShort();
 105                 if(f & 0x80)
 106                 {
 107                         if(self.modelindex)
 108                         {
 109                                 self.mins_x = ReadCoord();
 110                                 self.mins_y = ReadCoord();
 111                                 self.mins_z = ReadCoord();
 112                                 self.maxs_x = ReadCoord();
 113                                 self.maxs_y = ReadCoord();
 114                                 self.maxs_z = ReadCoord();
 115                         }
 116                         else
 117                         {
 118                                 self.mins    = '0 0 0';
 119                                 self.maxs_x = ReadCoord();
 120                                 self.maxs_y = ReadCoord();
 121                                 self.maxs_z = ReadCoord();
 122                         }
 123                 }
 124                 else
 125                 {
 126                         self.mins = self.maxs = '0 0 0';
 127                 }
 128
 129                 self.cnt = ReadShort(); // effect number
 130
 131                 if(f & 0x20)
 132                 {
 133                         self.velocity = decompressShortVector(ReadShort());
 134                         self.movedir = decompressShortVector(ReadShort());
 135                 }
 136                 else
 137                 {
 138                         self.velocity = self.movedir = '0 0 0';
 139                 }
 140                 if(f & 0x40)
 141                 {
 142                         self.waterlevel = ReadShort() / 16.0;
 143                         self.count = ReadByte() / 16.0;
 144                 }
 145                 else
 146                 {
 147                         self.waterlevel = 0;
 148                         self.count = 1;
 149                 }
 150                 if(self.noise)
 151                         strunzone(self.noise);
 152                 if(self.bgmscript)
 153                         strunzone(self.bgmscript);
 154                 self.noise = strzone(ReadString());
 155                 if(self.noise != "")
 156                 {
 157                         self.atten = ReadByte() / 64.0;
 158                         self.volume = ReadByte() / 255.0;
 159                 }
 160                 self.bgmscript = strzone(ReadString());
 161                 if(self.bgmscript != "")
 162                 {
 163                         self.bgmscriptattack = ReadByte() / 64.0;
 164                         self.bgmscriptdecay = ReadByte() / 64.0;
 165                         self.bgmscriptsustain = ReadByte() / 255.0;
 166                         self.bgmscriptrelease = ReadByte() / 64.0;
 167                 }
 168                 BGMScript_InitEntity(self);
 169         }
 170
 171         if(f & 2)
 172         {
 173                 self.absolute = (self.impulse >= 0);
 174                 if(!self.absolute)
 175                 {
 176                         v = self.maxs - self.mins;
 177                         self.impulse *= -v_x * v_y * v_z / 262144; // relative: particles per 64^3 cube
 178                 }
 179         }
 180
 181         if(f & 0x10)
 182                 self.absolute = 2;
 183
 184         setorigin(self, self.origin);
 185         setsize(self, self.mins, self.maxs);
 186         self.solid = SOLID_NOT;
 187         self.draw = Draw_PointParticles;
 188         self.entremove = Ent_PointParticles_Remove;
 189 }
 190
 191 .float glow_color; // palette index
 192 void Draw_Rain()
 193 {
 194     te_particlerain(self.origin + self.mins, self.origin + self.maxs, self.velocity, floor(self.count * drawframetime + random()), self.glow_color);
 195 }
 196
 197 void Draw_Snow()
 198 {
 199     te_particlesnow(self.origin + self.mins, self.origin + self.maxs, self.velocity, floor(self.count * drawframetime + random()), self.glow_color);
 200 }
 201
 202 void Ent_RainOrSnow()
 203 {
 204         self.impulse = ReadByte(); // Rain, Snow, or Whatever
 205         self.origin_x = ReadCoord();
 206         self.origin_y = ReadCoord();
 207         self.origin_z = ReadCoord();
 208         self.maxs_x = ReadCoord();
 209         self.maxs_y = ReadCoord();
 210         self.maxs_z = ReadCoord();
 211         self.velocity = decompressShortVector(ReadShort());
 212         self.count = ReadShort() * 10;
 213         self.glow_color = ReadByte(); // color
 214
 215         self.mins    = -0.5 * self.maxs;
 216         self.maxs    =  0.5 * self.maxs;
 217         self.origin  = self.origin - self.mins;
 218
 219         setorigin(self, self.origin);
 220         setsize(self, self.mins, self.maxs);
 221         self.solid = SOLID_NOT;
 222         if(self.impulse)
 223                 self.draw = Draw_Rain;
 224         else
 225                 self.draw = Draw_Snow;
 226 }
 227
 228 void Net_ReadVortexBeamParticle()
 229 {
 230         vector shotorg, endpos;
 231         float charge;
 232         shotorg_x = ReadCoord(); shotorg_y = ReadCoord(); shotorg_z = ReadCoord();
 233         endpos_x = ReadCoord(); endpos_y = ReadCoord(); endpos_z = ReadCoord();
 234         charge = ReadByte() / 255.0;
 235
 236         pointparticles(particleeffectnum("nex_muzzleflash"), shotorg, normalize(endpos - shotorg) * 1000, 1);
 237
 238         //draw either the old v2.3 beam or the new beam
 239         charge = sqrt(charge); // divide evenly among trail spacing and alpha
 240         particles_alphamin = particles_alphamax = particles_fade = charge;
 241
 242         if (autocvar_cl_particles_oldnexbeam && (getstati(STAT_ALLOW_OLDNEXBEAM) || isdemo()))
 243                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum("TE_TEI_G3"), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 244         else
 245                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum("nex_beam"), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 246 }
 247
 248 .vector sw_shotorg;
 249 .vector sw_endpos;
 250 .float sw_spread_max;
 251 .float sw_spread_min;
 252 .float sw_time;
 253
 254 void Draw_Shockwave()
 255 {
 256         float a = bound(0, (0.5 - ((time - self.sw_time) / 0.4)), 0.5);
 257
 258         if(!a) { remove(self); }
 259
 260         vector deviation, angle;
 261
 262         vector sw_color = getcsqcplayercolor(self.sv_entnum); // GetTeamRGB(GetPlayerColor(self.sv_entnum));
 263
 264         vector first_min_end = '0 0 0', prev_min_end = '0 0 0', new_min_end = '0 0 0';
 265         vector first_max_end = '0 0 0', prev_max_end = '0 0 0', new_max_end = '0 0 0';
 266
 267         float new_max_dist, new_min_dist;
 268
 269         vector shotdir = normalize(self.sw_endpos - self.sw_shotorg);
 270         vectorvectors(shotdir);
 271         vector right = v_right;
 272         vector up = v_up;
 273
 274         float counter, dist_before_normal = 200, shots = 20;
 275
 276         vector min_end = ((self.sw_shotorg + (shotdir * dist_before_normal)) + (up * self.sw_spread_min));
 277         vector max_end = (self.sw_endpos + (up * self.sw_spread_max));
 278
 279         float spread_to_min = vlen(normalize(min_end - self.sw_shotorg) - shotdir);
 280         float spread_to_max = vlen(normalize(max_end - min_end) - shotdir);
 281
 282         for(counter = 0; counter < shots; ++counter)
 283         {
 284                 // perfect circle effect lines
 285                 angle = '0 0 0';
 286                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / shots));
 287                 angle_y = v_forward_x;
 288                 angle_z = v_forward_y;
 289
 290                 // first do the spread_to_min effect
 291                 deviation = angle * spread_to_min;
 292                 deviation = ((shotdir + (right * deviation_y) + (up * deviation_z)));
 293                 new_min_dist = dist_before_normal;
 294                 new_min_end = (self.sw_shotorg + (deviation * new_min_dist));
 295                 //te_lightning2(world, new_min_end, self.sw_shotorg);
 296
 297                 // then calculate spread_to_max effect
 298                 deviation = angle * spread_to_max;
 299                 deviation = ((shotdir + (right * deviation_y) + (up * deviation_z)));
 300                 new_max_dist = vlen(new_min_end - self.sw_endpos);
 301                 new_max_end = (new_min_end + (deviation * new_max_dist));
 302                 //te_lightning2(world, new_end, prev_min_end);
 303
 304
 305                 if(counter == 0)
 306                 {
 307                         first_min_end = new_min_end;
 308                         first_max_end = new_max_end;
 309                 }
 310
 311                 if(counter >= 1)
 312                 {
 313                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 314                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 315                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
 316                         R_PolygonVertex(self.sw_shotorg, '0 0 0', sw_color, a);
 317                         R_EndPolygon();
 318
 319                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 320                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
 321                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 322                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
 323                         R_PolygonVertex(new_max_end, '0 0 0', sw_color, a);
 324                         R_EndPolygon();
 325                 }
 326
 327                 prev_min_end = new_min_end;
 328                 prev_max_end = new_max_end;
 329
 330                 if((counter + 1) == shots)
 331                 {
 332                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 333                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 334                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
 335                         R_PolygonVertex(self.sw_shotorg, '0 0 0', sw_color, a);
 336                         R_EndPolygon();
 337
 338                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 339                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
 340                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 341                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
 342                         R_PolygonVertex(first_max_end, '0 0 0', sw_color, a);
 343                         R_EndPolygon();
 344                 }
 345         }
 346 }
 347
 348 void Net_ReadShockwaveParticle()
 349 {
 350         entity shockwave;
 351         shockwave = spawn();
 352         shockwave.draw = Draw_Shockwave;
 353
 354         shockwave.sw_shotorg_x = ReadCoord(); shockwave.sw_shotorg_y = ReadCoord(); shockwave.sw_shotorg_z = ReadCoord();
 355         shockwave.sw_endpos_x  = ReadCoord(); shockwave.sw_endpos_y  = ReadCoord(); shockwave.sw_endpos_z  = ReadCoord();
 356
 357         shockwave.sw_spread_max = ReadByte();
 358         shockwave.sw_spread_min = ReadByte();
 359
 360         shockwave.sv_entnum = ReadByte();
 361
 362         shockwave.sw_time = time;
 363 }
 364
 365 .vector beam_color;
 366 .float beam_alpha;
 367 .float beam_thickness;
 368 .float beam_traileffect;
 369 .float beam_hiteffect;
 370 .float beam_muzzleflash;
 371 .string beam_image;
 372
 373 // WEAPONTODO: Add beam_hitlight and beam_muzzlelight which uses direct real time light control
 374
 375 .entity beam_muzzleentity;
 376
 377 .float beam_usevieworigin;
 378 .float beam_initialized;
 379 .float beam_maxangle;
 380 .float beam_range;
 381 .float beam_returnspeed;
 382 .float beam_tightness;
 383 .vector beam_shotorigin;
 384 .vector beam_dir;
 385 void Draw_ArcBeam()
 386 {
 387         InterpolateOrigin_Do();
 388
 389         // origin = beam starting origin
 390         // v_angle = wanted/aim direction
 391         // angles = current direction of beam
 392
 393         vector start_pos;
 394         vector wantdir; //= view_forward;
 395         vector beamdir; //= self.beam_dir;
 396
 397         float segments;
 398         if(self.beam_usevieworigin)
 399         {
 400                 // WEAPONTODO:
 401                 // Currently we have to replicate nearly the same method of figuring
 402                 // out the shotdir that the server does... Ideally in the future we
 403                 // should be able to acquire this from a generalized function built
 404                 // into a weapon system for client code.
 405
 406                 // find where we are aiming
 407                 makevectors(view_angles);
 408
 409                 // decide upon start position
 410                 if(self.beam_usevieworigin == 2)
 411                         { start_pos = view_origin; }
 412                 else
 413                         { start_pos = self.origin; }
 414
 415                 // trace forward with an estimation
 416                 WarpZone_TraceLine(start_pos, start_pos + view_forward * self.beam_range, MOVE_NOMONSTERS, self);
 417
 418                 // untransform in case our trace went through a warpzone
 419                 vector vf, vr, vu;
 420                 vf = view_forward;
 421                 vr = view_right;
 422                 vu = view_up;
 423                 vector shothitpos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 424                 view_forward = vf;
 425                 view_right = vr;
 426                 view_up = vu;
 427
 428                 // un-adjust trueaim if shotend is too close
 429                 if(vlen(shothitpos - view_origin) < g_trueaim_minrange)
 430                         shothitpos = view_origin + (view_forward * g_trueaim_minrange);
 431
 432                 // move shot origin to the actual gun muzzle origin
 433                 vector origin_offset = view_forward * self.beam_shotorigin_x + view_right * -self.beam_shotorigin_y + view_up * self.beam_shotorigin_z;
 434                 start_pos = start_pos + origin_offset;
 435
 436                 // calculate the aim direction now
 437                 wantdir = normalize(shothitpos - start_pos);
 438
 439                 if(!self.beam_initialized)
 440                 {
 441                         self.beam_dir = wantdir;
 442                         self.beam_initialized = TRUE;
 443                 }
 444
 445                 // WEAPONTODO: Calculate segments dyanmically similarly to the server code
 446                 segments = 20;
 447                 if(self.beam_dir != wantdir)
 448                 {
 449                         float angle = ceil(vlen(wantdir - self.beam_dir) * RAD2DEG);
 450                         float anglelimit;
 451                         if(angle && (angle > self.beam_maxangle))
 452                         {
 453                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 454                                 anglelimit = min(self.beam_maxangle / angle, 1);
 455                         }
 456                         else
 457                         {
 458                                 // the radius is not too far yet, no worries :D
 459                                 anglelimit = 1;
 460                         }
 461
 462                         // calculate how much we're going to move the end of the beam to the want position
 463                         float blendfactor = bound(0, anglelimit * (1 - (self.beam_returnspeed * frametime)), 1);
 464                         self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 465
 466                         // WEAPONTODO (server and client):
 467                         // blendfactor never actually becomes 0 in this situation, which is a problem
 468                         // regarding precision... this means that self.beam_dir and w_shotdir approach
 469                         // eachother, however they never actually become the same value with this method.
 470
 471                         // Perhaps we should do some form of rounding/snapping?
 472
 473                         // printf("blendfactor = %f\n", blendfactor);
 474
 475                         #if 0
 476                         // calculate how many segments are needed
 477                         float max_allowed_segments;
 478
 479                         if(WEP_CVAR(arc, beam_distancepersegment))
 480                                 max_allowed_segments = min(ARC_MAX_SEGMENTS, 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment))));
 481                         else
 482                                 max_allowed_segments = ARC_MAX_SEGMENTS;
 483
 484                         if(WEP_CVAR(arc, beam_degreespersegment))
 485                         {
 486                                 segments = min( max(1, ( min(angle, WEP_CVAR(arc, beam_maxangle)) / WEP_CVAR(arc, beam_degreespersegment) ) ), max_allowed_segments );
 487                         }
 488                         else
 489                         {
 490                                 segments = 1;
 491                         }
 492                         #endif
 493                 }
 494                 #if 0
 495                 else
 496                 {
 497                         segments = 1;
 498                 }
 499                 #endif
 500
 501                 // set the beam direction which the rest of the code will refer to
 502                 beamdir = self.beam_dir;
 503
 504                 // finally, set self.angles to the proper direction so that muzzle attachment points in proper direction
 505                 self.angles = fixedvectoangles2(view_forward, view_up);
 506         }
 507         else
 508         {
 509                 // set the values from the provided info from the networked entity
 510                 start_pos = self.origin;
 511                 wantdir = self.v_angle;
 512                 beamdir = self.angles;
 513
 514                 // WEAPONTODO: Calculate segments dyanmically similarly to the server code
 515                 segments = 20;
 516                 #if 0
 517                 if(beamdir != wantdir)
 518                 {
 519                         // calculate how many segments are needed
 520                         float max_allowed_segments;
 521
 522                         if(WEP_CVAR(arc, beam_distancepersegment))
 523                                 max_allowed_segments = min(ARC_MAX_SEGMENTS, 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment))));
 524                         else
 525                                 max_allowed_segments = ARC_MAX_SEGMENTS;
 526
 527                         if(WEP_CVAR(arc, beam_degreespersegment))
 528                         {
 529                                 segments = min( max(1, ( min(angle, WEP_CVAR(arc, beam_maxangle)) / WEP_CVAR(arc, beam_degreespersegment) ) ), max_allowed_segments );
 530                         }
 531                         else
 532                         {
 533                                 segments = 1;
 534                         }
 535                 }
 536                 else
 537                 {
 538                         segments = 1;
 539                 }
 540                 #endif
 541         }
 542
 543         setorigin(self, start_pos);
 544         self.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
 545
 546         vector beam_endpos_estimate = (start_pos + (beamdir * self.beam_range));
 547
 548         float maxthickness = self.beam_thickness;
 549
 550         vector thickdir = normalize(cross(beamdir, view_origin - start_pos));
 551
 552         vector last_origin = start_pos;
 553
 554         float lastthickness = 0;
 555
 556         vector last_top = start_pos + (thickdir * lastthickness);
 557         vector last_bottom = start_pos - (thickdir * lastthickness);
 558
 559         vector hitorigin = start_pos;
 560
 561         float i;
 562         for(i = 1; i <= segments; ++i)
 563         {
 564                 // WEAPONTODO (server and client):
 565                 // Segment blend and distance should probably really be calculated in a better way,
 566                 // however I am not sure how to do it properly. There are a few things I have tried,
 567                 // but most of them do not work properly due to my lack of understanding regarding
 568                 // the mathematics behind them.
 569
 570                 // Ideally, we should calculate the positions along a perfect curve
 571                 // between wantdir and self.beam_dir with an option for depth of arc
 572
 573                 // Another issue is that (on the client code) we must separate the
 574                 // curve into multiple rendered curves when handling warpzones.
 575
 576                 // I can handle this by detecting it for each segment, however that
 577                 // is a fairly inefficient method in comparison to having a curved line
 578                 // drawing function similar to Draw_CylindricLine that accepts
 579                 // top and bottom origins as input, this way there would be no
 580                 // overlapping edges when connecting the curved pieces.
 581
 582                 // WEAPONTODO (client):
 583                 // In order to do nice fading and pointing on the starting segment, we must always
 584                 // have that drawn as a separate triangle... However, that is difficult to do when
 585                 // keeping in mind the above problems and also optimizing the amount of segments
 586                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 587
 588                 // calculate this on every segment to ensure that we always reach the full length of the attack
 589                 float segmentblend = bound(0, (i/segments) + self.beam_tightness, 1);
 590                 float segmentdist = vlen(beam_endpos_estimate - last_origin) * (i/segments);
 591
 592                 vector new_dir = normalize( (wantdir * (1 - segmentblend)) + (normalize(beam_endpos_estimate - last_origin) * segmentblend) );
 593                 vector new_origin = last_origin + (new_dir * segmentdist);
 594
 595                 WarpZone_TraceLine(
 596                         last_origin,
 597                         new_origin,
 598                         MOVE_NORMAL,
 599                         self
 600                 );
 601
 602                 // draw segment
 603                 if(trace_fraction != 1)
 604                 {
 605                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 606                         hitorigin = last_origin + (new_dir * segmentdist * trace_fraction);
 607                 }
 608                 else
 609                 {
 610                         hitorigin = new_origin;
 611                 }
 612
 613                 #if 0
 614                 float falloff = ExponentialFalloff(
 615                         WEP_CVAR(arc, beam_falloff_mindist),
 616                         WEP_CVAR(arc, beam_falloff_maxdist),
 617                         WEP_CVAR(arc, beam_falloff_halflifedist),
 618                         vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - start_pos)
 619                 );
 620                 #else
 621                 //float falloff = 1;
 622                 #endif
 623
 624                 // draw primary beam render
 625                 vector top    = hitorigin + (thickdir * self.beam_thickness);
 626                 vector bottom = hitorigin - (thickdir * self.beam_thickness);
 627
 628                 R_BeginPolygon(self.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 629                 R_PolygonVertex(top,          '0 0.5 0' + ('0 0.5 0' * (self.beam_thickness / maxthickness)),  self.beam_color,  self.beam_alpha);
 630                 R_PolygonVertex(last_top,     '0 0.5 0' + ('0 0.5 0' * (lastthickness / maxthickness)),        self.beam_color,  self.beam_alpha);
 631                 R_PolygonVertex(last_bottom,  '0 0.5 0' * (1 - (lastthickness / maxthickness)),                self.beam_color,  self.beam_alpha);
 632                 R_PolygonVertex(bottom,       '0 0.5 0' * (1 - (self.beam_thickness / maxthickness)),          self.beam_color,  self.beam_alpha);
 633                 R_EndPolygon();
 634
 635                 // draw trailing particles
 636                 // NOTES:
 637                 //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 638                 //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 639                 if(self.beam_traileffect)
 640                 {
 641                         trailparticles(self, self.beam_traileffect, last_origin, hitorigin);
 642                 }
 643
 644                 // check if we're going to proceed with drawing
 645                 if(trace_fraction != 1)
 646                 {
 647                         // we're done with drawing this frame
 648                         break;
 649                 }
 650                 else
 651                 {
 652                         // continue onto the next segment
 653                         last_origin = new_origin;
 654                         last_top = top;
 655                         last_bottom = bottom;
 656                         lastthickness = self.beam_thickness;
 657                 }
 658         }
 659
 660         if(self.beam_hiteffect)
 661         {
 662                 pointparticles(self.beam_hiteffect, hitorigin, beamdir * -1, frametime * 2);
 663         }
 664         if(self.beam_muzzleflash)
 665         {
 666                 pointparticles(self.beam_muzzleflash, start_pos + wantdir * 20, wantdir * 1000, frametime * 0.1);
 667         }
 668 }
 669
 670 void Remove_ArcBeam(void)
 671 {
 672         remove(self.beam_muzzleentity);
 673         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 674 }
 675
 676 void Ent_ReadArcBeam(float isnew)
 677 {
 678         float sf = ReadByte();
 679         entity flash;
 680
 681         // self.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
 682         self.iflags = IFLAG_ORIGIN;
 683
 684         InterpolateOrigin_Undo();
 685
 686         if(isnew)
 687         {
 688                 // calculate shot origin offset from gun alignment
 689                 float gunalign = autocvar_cl_gunalign;
 690                 if(gunalign != 1 && gunalign != 2 && gunalign != 4)
 691                         gunalign = 3; // default value
 692                 --gunalign;
 693
 694                 self.beam_shotorigin = arc_shotorigin[gunalign];
 695
 696                 // set other main attributes of the beam
 697                 self.draw = Draw_ArcBeam;
 698                 self.entremove = Remove_ArcBeam;
 699                 sound(self, CH_SHOTS_SINGLE, "weapons/lgbeam_fly.wav", VOL_BASE, ATTEN_NORM);
 700
 701                 flash = spawn();
 702                 flash.owner = self;
 703                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 704                 flash.drawmask = MASK_NORMAL;
 705                 flash.solid = SOLID_NOT;
 706                 setattachment(flash, self, "");
 707                 setorigin(flash, '0 0 0');
 708
 709                 self.beam_muzzleentity = flash;
 710         }
 711         else
 712         {
 713                 flash = self.beam_muzzleentity;
 714         }
 715
 716         if(sf & 1) // settings information
 717         {
 718                 self.beam_maxangle = ReadShort();
 719                 self.beam_range = ReadCoord();
 720                 self.beam_returnspeed = ReadShort();
 721                 self.beam_tightness = (ReadByte() / 10);
 722
 723                 if(ReadByte())
 724                 {
 725                         if(autocvar_chase_active)
 726                                 { self.beam_usevieworigin = 1; }
 727                         else // use view origin
 728                                 { self.beam_usevieworigin = 2; }
 729                 }
 730                 else
 731                 {
 732                         self.beam_usevieworigin = 0;
 733                 }
 734         }
 735
 736         if(sf & 2) // starting location
 737         {
 738                 self.origin_x = ReadCoord();
 739                 self.origin_y = ReadCoord();
 740                 self.origin_z = ReadCoord();
 741         }
 742         else if(self.beam_usevieworigin) // infer the location from player location
 743         {
 744                 if(self.beam_usevieworigin == 2)
 745                 {
 746                         // use view origin
 747                         self.origin = view_origin;
 748                 }
 749                 else
 750                 {
 751                         // use player origin so that third person display still works
 752                         self.origin = getplayerorigin(player_localnum) + ('0 0 1' * getstati(STAT_VIEWHEIGHT));
 753                 }
 754         }
 755
 756         setorigin(self, self.origin);
 757
 758         if(sf & 4) // want/aim direction
 759         {
 760                 self.v_angle_x = ReadCoord();
 761                 self.v_angle_y = ReadCoord();
 762                 self.v_angle_z = ReadCoord();
 763         }
 764
 765         if(sf & 8) // beam direction
 766         {
 767                 self.angles_x = ReadCoord();
 768                 self.angles_y = ReadCoord();
 769                 self.angles_z = ReadCoord();
 770         }
 771
 772         if(sf & 16) // beam type
 773         {
 774                 self.beam_type = ReadByte();
 775                 switch(self.beam_type)
 776                 {
 777                         case ARC_BT_MISS:
 778                         {
 779                                 self.beam_color = '-1 -1 1';
 780                                 self.beam_alpha = 0.5;
 781                                 self.beam_thickness = 8;
 782                                 self.beam_traileffect = FALSE;
 783                                 self.beam_hiteffect = particleeffectnum("electro_lightning");
 784                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 785                                 self.beam_image = "particles/lgbeam";
 786                                 setmodel(flash, "models/flash.md3");
 787                                 flash.alpha = self.beam_alpha;
 788                                 flash.colormod = self.beam_color;
 789                                 flash.scale = 0.5;
 790                                 break;
 791                         }
 792                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
 793                         {
 794                                 self.beam_color = '0.5 0.5 1';
 795                                 self.beam_alpha = 0.5;
 796                                 self.beam_thickness = 8;
 797                                 self.beam_traileffect = FALSE;
 798                                 self.beam_hiteffect = particleeffectnum("electro_lightning");
 799                                 self.beam_muzzleflash = FALSE; // particleeffectnum("grenadelauncher_muzzleflash");
 800                                 self.beam_image = "particles/lgbeam";
 801                                 setmodel(flash, "models/flash.md3");
 802                                 flash.alpha = self.beam_alpha;
 803                                 flash.colormod = self.beam_color;
 804                                 flash.scale = 0.5;
 805                                 break;
 806                         }
 807                         case ARC_BT_HEAL:
 808                         {
 809                                 self.beam_color = '0 1 0';
 810                                 self.beam_alpha = 0.5;
 811                                 self.beam_thickness = 8;
 812                                 self.beam_traileffect = FALSE;
 813                                 self.beam_hiteffect = particleeffectnum("healray_impact");
 814                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 815                                 self.beam_image = "particles/lgbeam";
 816                                 setmodel(flash, "models/flash.md3");
 817                                 flash.alpha = self.beam_alpha;
 818                                 flash.colormod = self.beam_color;
 819                                 flash.scale = 0.5;
 820                                 break;
 821                         }
 822                         case ARC_BT_HIT:
 823                         {
 824                                 self.beam_color = '1 0 1';
 825                                 self.beam_alpha = 0.5;
 826                                 self.beam_thickness = 8;
 827                                 self.beam_traileffect = particleeffectnum("nex_beam");
 828                                 self.beam_hiteffect = particleeffectnum("electro_lightning");
 829                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 830                                 self.beam_image = "particles/lgbeam";
 831                                 setmodel(flash, "models/flash.md3");
 832                                 flash.alpha = self.beam_alpha;
 833                                 flash.colormod = self.beam_color;
 834                                 flash.scale = 0.5;
 835                                 break;
 836                         }
 837                         case ARC_BT_BURST_MISS:
 838                         {
 839                                 self.beam_color = '-1 -1 1';
 840                                 self.beam_alpha = 0.5;
 841                                 self.beam_thickness = 14;
 842                                 self.beam_traileffect = FALSE;
 843                                 self.beam_hiteffect = particleeffectnum("electro_lightning");
 844                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 845                                 self.beam_image = "particles/lgbeam";
 846                                 setmodel(flash, "models/flash.md3");
 847                                 flash.alpha = self.beam_alpha;
 848                                 flash.colormod = self.beam_color;
 849                                 flash.scale = 0.5;
 850                                 break;
 851                         }
 852                         case ARC_BT_BURST_WALL:
 853                         {
 854                                 self.beam_color = '0.5 0.5 1';
 855                                 self.beam_alpha = 0.5;
 856                                 self.beam_thickness = 14;
 857                                 self.beam_traileffect = FALSE;
 858                                 self.beam_hiteffect = particleeffectnum("electro_lightning");
 859                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 860                                 self.beam_image = "particles/lgbeam";
 861                                 setmodel(flash, "models/flash.md3");
 862                                 flash.alpha = self.beam_alpha;
 863                                 flash.colormod = self.beam_color;
 864                                 flash.scale = 0.5;
 865                                 break;
 866                         }
 867                         case ARC_BT_BURST_HEAL:
 868                         {
 869                                 self.beam_color = '0 1 0';
 870                                 self.beam_alpha = 0.5;
 871                                 self.beam_thickness = 14;
 872                                 self.beam_traileffect = FALSE;
 873                                 self.beam_hiteffect = particleeffectnum("electro_lightning");
 874                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 875                                 self.beam_image = "particles/lgbeam";
 876                                 setmodel(flash, "models/flash.md3");
 877                                 flash.alpha = self.beam_alpha;
 878                                 flash.colormod = self.beam_color;
 879                                 flash.scale = 0.5;
 880                                 break;
 881                         }
 882                         case ARC_BT_BURST_HIT:
 883                         {
 884                                 self.beam_color = '1 0 1';
 885                                 self.beam_alpha = 0.5;
 886                                 self.beam_thickness = 14;
 887                                 self.beam_traileffect = FALSE;
 888                                 self.beam_hiteffect = particleeffectnum("electro_lightning");
 889                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 890                                 self.beam_image = "particles/lgbeam";
 891                                 setmodel(flash, "models/flash.md3");
 892                                 flash.alpha = self.beam_alpha;
 893                                 flash.colormod = self.beam_color;
 894                                 flash.scale = 0.5;
 895                                 break;
 896                         }
 897
 898                         // shouldn't be possible, but lets make it colorful if it does :D
 899                         default:
 900                         {
 901                                 self.beam_color = randomvec();
 902                                 self.beam_alpha = 1;
 903                                 self.beam_thickness = 8;
 904                                 self.beam_traileffect = FALSE;
 905                                 self.beam_hiteffect = FALSE;
 906                                 self.beam_muzzleflash = FALSE; //particleeffectnum("nex_muzzleflash");
 907                                 self.beam_image = "particles/lgbeam";
 908                                 setmodel(flash, "models/flash.md3");
 909                                 flash.alpha = self.beam_alpha;
 910                                 flash.colormod = self.beam_color;
 911                                 flash.scale = 0.5;
 912                                 break;
 913                         }
 914                 }
 915         }
 916
 917         InterpolateOrigin_Note();
 918
 919         #if 0
 920         printf(
 921                 "Ent_ReadArcBeam(%d): sf = %d, start = %s, want = %s, dir = %s, type = %d\n",
 922                 isnew,
 923                 sf,
 924                 vtos(self.beam_start),
 925                 vtos(self.v_angle),
 926                 vtos(self.angles),
 927                 self.beam_type
 928         );
 929         #endif
 930 }
 931