qcsrc/client/player_skeleton.qc

   1 .float skeleton_info_modelindex;
   2 .float skeleton_info_skin;
   3 #define BONETYPE_LOWER 0
   4 #define BONETYPE_UPPER 1
   5 #define MAX_BONES 128
   6 .float skeleton_bonetype[MAX_BONES];
   7 .float skeleton_numbones;
   8
   9 void skeleton_loadinfo(entity e)
  10 {
  11         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  12                 return;
  13         e.bone_upperbody = 0;
  14         e.bone_weapon = gettagindex(e, "weapon");
  15         if(!e.bone_weapon)
  16                 e.bone_weapon = gettagindex(e, "tag_weapon");
  17         if(!e.bone_weapon)
  18                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  19         e.bone_aim = 0;
  20         e.fixbone = 0;
  21         if(get_model_parameters(e.model, e.skin))
  22         {
  23                 if(get_model_parameters_bone_upperbody)
  24                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  25                 if(get_model_parameters_bone_weapon)
  26                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  27                 if(get_model_parameters_bone_aim)
  28                         e.bone_aim = gettagindex(e, get_model_parameters_bone_aim);
  29                 if(e.bone_upperbody)
  30                         e.fixbone = get_model_parameters_fixbone;
  31         }
  32         else
  33                 dprint("No model parameters for ", e.model, "\n");
  34         dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  35         get_model_parameters(string_null, 0);
  36         e.skeleton_info_modelindex = e.modelindex;
  37         e.skeleton_info_skin = e.skin;
  38         if(e.skeletonindex)
  39         {
  40                 skel_delete(e.skeletonindex);
  41                 e.skeletonindex = 0;
  42         }
  43 }
  44
  45 void skeleton_markbones(entity e)
  46 {
  47         float s = e.skeletonindex;
  48         float n = (e.skeleton_numbones = skel_get_numbones(s));
  49         float i;
  50         for(i = 1; i <= n; ++i)
  51         {
  52                 float t = BONETYPE_LOWER;
  53                 float p = skel_get_boneparent(s, i);
  54                 if(p > 0)
  55                         t = e.(skeleton_bonetype[p-1]);
  56                 if(i == e.bone_upperbody)
  57                         t = BONETYPE_UPPER;
  58                 e.(skeleton_bonetype[i-1]) = t;
  59         }
  60 }
  61
  62 void skeleton_fixbone(entity e, vector ang)
  63 {
  64         if(!e.bone_upperbody)
  65                 return;
  66         float s = e.skeletonindex;
  67
  68         skel_get_boneabs(s, e.bone_upperbody);
  69         vector ang_cur = fixedvectoangles2(v_forward, v_up);
  70         vector fix = AnglesTransform_LeftDivide(ang_cur, ang);
  71         fixedmakevectors(fix);
  72         skel_mul_bone(s, e.bone_upperbody, '0 0 0');
  73 }
  74
  75 void free_skeleton_from_frames(entity e)
  76 {
  77         if(e.skeletonindex)
  78         {
  79                 skel_delete(e.skeletonindex);
  80                 e.skeletonindex = 0;
  81         }
  82 }
  83
  84 void skeleton_from_frames(entity e)
  85 {
  86         float m = e.modelindex;
  87         if(!e.skeletonindex)
  88         {
  89                 e.skeletonindex = skel_create(m);
  90                 skeleton_markbones(e);
  91         }
  92         float s = e.skeletonindex;
  93         if(!s)
  94                 return;
  95         float bone;
  96         float n = e.skeleton_numbones;
  97         float savelerpfrac = e.lerpfrac;
  98         float savelerpfrac3 = e.lerpfrac3;
  99         float savelerpfrac4 = e.lerpfrac4;
 100
 101         vector fixbone_oldangles = '0 0 0';
 102         if(e.fixbone)
 103         {
 104                 // make all bones BONETYPE_UPPER
 105                 e.lerpfrac = 0;
 106                 e.lerpfrac3 = savelerpfrac3 * 2;
 107                 e.lerpfrac4 = 0;
 108                 // build skeleton
 109                 skel_build(s, e, m, 0, 1, n);
 110                 // get hip bone
 111                 skel_get_boneabs(s, e.bone_upperbody);
 112                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 113         }
 114
 115         for(bone = 0; bone < n; )
 116         {
 117                 float firstbone = bone;
 118                 float bonetype = e.skeleton_bonetype[bone];
 119                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 120                         ;
 121                 if(bonetype == BONETYPE_UPPER)
 122                 {
 123                         // only show frames 1+3 (upper body)
 124                         e.lerpfrac = 0;
 125                         e.lerpfrac3 = savelerpfrac3 * 2;
 126                         e.lerpfrac4 = 0;
 127                 }
 128                 else
 129                 {
 130                         // only show frames 2+4 (lower body)
 131                         e.lerpfrac = savelerpfrac * 2;
 132                         e.lerpfrac3 = 0;
 133                         e.lerpfrac4 = savelerpfrac4 * 2;
 134                 }
 135                 //print(sprintf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype));
 136                 //print(sprintf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4));
 137                 skel_build(s, e, m, 0, firstbone + 1, bone);
 138         }
 139         e.lerpfrac = savelerpfrac;
 140         e.lerpfrac3 = savelerpfrac3;
 141         e.lerpfrac4 = savelerpfrac4;
 142
 143         if(e.fixbone)
 144         {
 145                 // FIX IT
 146                 skeleton_fixbone(e, fixbone_oldangles);
 147         }
 148
 149         if(e.bone_aim)
 150         {
 151                 vector aim = '-1 0 0' * self.v_angle_x;
 152
 153                 skel_get_boneabs(s, e.bone_aim);
 154                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 155                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 156                 vector fix = AnglesTransform_LeftDivide(ang_cur, ang);
 157                 fixedmakevectors(fix);
 158                 skel_mul_bone(s, e.bone_aim, '0 0 0');
 159
 160         }
 161 }