qcsrc/client/quickmenu.qc

   1 // QUICKMENU_MAXLINES must be <= 10
   2 const int QUICKMENU_MAXLINES = 10;
   3 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
   4 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
   5 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
   6 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
   7 int QuickMenu_Page_Entries;
   8 int QuickMenu_Page;
   9 int QuickMenu_Page_ActivatedEntry = -1;
  10 bool QuickMenu_Page_ActivatedEntry_Close;
  11 float QuickMenu_Page_ActivatedEntry_Time;
  12 bool QuickMenu_IsLastPage;
  13 // all the entries are loaded into QuickMenu_Buffer
  14 // each entry (submenu or command) is composed of 2 entries
  15 const int QUICKMENU_MAXENTRIES = 256;
  16 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  17 int QuickMenu_Buffer = -1;
  18 int QuickMenu_Buffer_Size;
  19 int QuickMenu_Buffer_Index;
  20 string QuickMenu_CurrentSubMenu;
  21 float QuickMenu_TimeOut;
  22 // if s1 is not empty s will be displayed as command otherwise as submenu
  23 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  24 {
  25         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  26         if (QuickMenu_Page_Description[i])
  27                 strunzone(QuickMenu_Page_Description[i]);
  28         QuickMenu_Page_Description[i] = strzone(s);
  29         if (QuickMenu_Page_Command[i])
  30                 strunzone(QuickMenu_Page_Command[i]);
  31         QuickMenu_Page_Command[i] = strzone(s1);
  32 }
  33
  34 void QuickMenu_Page_ClearEntry(int i)
  35 {
  36         if (QuickMenu_Page_Description[i])
  37                 strunzone(QuickMenu_Page_Description[i]);
  38         QuickMenu_Page_Description[i] = string_null;
  39         if (QuickMenu_Page_Command[i])
  40                 strunzone(QuickMenu_Page_Command[i]);
  41         QuickMenu_Page_Command[i] = string_null;
  42 }
  43
  44 float QuickMenu_Page_Load(string target_submenu, float new_page);
  45 void QuickMenu_Default(string submenu);
  46 bool QuickMenu_Open(string mode, string submenu)
  47 {
  48         int fh = -1;
  49         string s;
  50
  51         if(mode == "")
  52         {
  53                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  54                         mode = "default";
  55                 else
  56                         mode = "file";
  57         }
  58
  59         if(mode == "default")
  60         {
  61                 QuickMenu_Buffer = buf_create();
  62                 if(QuickMenu_Buffer < 0)
  63                         return false;
  64
  65                 QuickMenu_Default(submenu);
  66         }
  67         else if(mode == "file")
  68         {
  69                 if(autocvar_hud_panel_quickmenu_file != "")
  70                 if(autocvar_hud_panel_quickmenu_file != "0")
  71                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  72                 if(fh < 0)
  73                 {
  74                         printf("Couldn't open file \"%s\"\n", autocvar_hud_panel_quickmenu_file);
  75                         return false;
  76                 }
  77
  78                 QuickMenu_Buffer = buf_create();
  79                 if(QuickMenu_Buffer < 0)
  80                 {
  81                         fclose(fh);
  82                         return false;
  83                 }
  84
  85                 QuickMenu_Buffer_Size = 0;
  86                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
  87                 {
  88                         // first skip invalid entries, so we don't check them anymore
  89                         float argc;
  90                         argc = tokenize_console(s);
  91                         if(argc == 0 || argv(0) == "" || substring(argv(0), 0, 2) == "////")
  92                                 continue;
  93                         if(argc == 1)
  94                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
  95                         else if(argc == 2)
  96                         {
  97                                 if(argv(1) == "")
  98                                         continue;
  99                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", argv(0))); // command Title
 100                                 ++QuickMenu_Buffer_Size;
 101                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", argv(1))); // command
 102                         }
 103                         else if(argc == 3)
 104                         {
 105                                 // check for special keywords
 106                                 float teamplayers = 0, without_me = 0;
 107                                 switch(argv(2))
 108                                 {
 109                                         case "ALLPLAYERS_BUT_ME":               without_me = 1;
 110                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 111                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1;
 112                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 113                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 114                                         default: continue;
 115                                 }
 116
 117                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 118                                 {
 119                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 120                                         ++QuickMenu_Buffer_Size;
 121                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); // command arguments
 122                                         ++QuickMenu_Buffer_Size;
 123                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", argv(1))); // command for each player
 124                                         ++QuickMenu_Buffer_Size;
 125                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 126                                 }
 127                         }
 128                         ++QuickMenu_Buffer_Size;
 129                 }
 130                 fclose(fh);
 131         }
 132         else
 133         {
 134                 printf("Unrecognized mode %s\n", mode);
 135                 return false;
 136         }
 137
 138         if (QuickMenu_Buffer_Size <= 0)
 139         {
 140                 buf_del(QuickMenu_Buffer);
 141                 QuickMenu_Buffer = -1;
 142                 return false;
 143         }
 144
 145         if(mode == "file")
 146                 QuickMenu_Page_Load(submenu, 0);
 147         else
 148                 QuickMenu_Page_Load("", 0);
 149
 150         hud_panel_quickmenu = 1;
 151         if(autocvar_hud_cursormode)
 152                 setcursormode(1);
 153         hudShiftState = 0;
 154
 155         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 156         return true;
 157 }
 158
 159 void QuickMenu_Buffer_Close()
 160 {
 161         if (QuickMenu_Buffer >= 0)
 162         {
 163                 buf_del(QuickMenu_Buffer);
 164                 QuickMenu_Buffer = -1;
 165                 QuickMenu_Buffer_Size = 0;
 166         }
 167 }
 168
 169 void QuickMenu_Close()
 170 {
 171         if (QuickMenu_CurrentSubMenu)
 172                 strunzone(QuickMenu_CurrentSubMenu);
 173         QuickMenu_CurrentSubMenu = string_null;
 174         int i;
 175         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 176                 QuickMenu_Page_ClearEntry(i);
 177         QuickMenu_Page_Entries = 0;
 178         hud_panel_quickmenu = 0;
 179         mouseClicked = 0;
 180         prevMouseClicked = 0;
 181         QuickMenu_Buffer_Close();
 182
 183         if(autocvar_hud_cursormode)
 184         if(!mv_active)
 185                 setcursormode(0);
 186 }
 187
 188 // It assumes submenu open tag is already detected
 189 void QuickMenu_skip_submenu(string submenu)
 190 {
 191         string s, z_submenu;
 192         z_submenu = strzone(submenu);
 193         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 194         {
 195                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 196                 if(substring(s, 0, 1) != "S")
 197                         continue;
 198                 if(substring(s, 1, -1) == z_submenu) // submenu end
 199                         break;
 200                 QuickMenu_skip_submenu(substring(s, 1, -1));
 201         }
 202         strunzone(z_submenu);
 203 }
 204
 205 bool QuickMenu_IsOpened()
 206 {
 207         return (QuickMenu_Page_Entries > 0);
 208 }
 209
 210 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, float without_me);
 211 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, float without_me)
 212 {
 213         int i;
 214         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 215                 QuickMenu_Page_ClearEntry(i);
 216         QuickMenu_Buffer_Close();
 217
 218         QuickMenu_Buffer = buf_create();
 219         if(QuickMenu_Buffer < 0)
 220                 return false;
 221
 222         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 223
 224         if(QuickMenu_Buffer_Size <= 0)
 225         {
 226                 buf_del(QuickMenu_Buffer);
 227                 QuickMenu_Buffer = -1;
 228                 return false;
 229         }
 230         return true;
 231 }
 232
 233 // new_page 0 means page 0, new_page != 0 means next page
 234 int QuickMenu_Buffer_Index_Prev;
 235 bool QuickMenu_Page_Load(string target_submenu, int new_page)
 236 {
 237         string s = string_null, cmd = string_null, z_submenu;
 238
 239         if (new_page == 0)
 240                 QuickMenu_Page = 0;
 241         else
 242                 ++QuickMenu_Page;
 243
 244         z_submenu = strzone(target_submenu);
 245         if (QuickMenu_CurrentSubMenu)
 246                 strunzone(QuickMenu_CurrentSubMenu);
 247         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 248
 249         QuickMenu_IsLastPage = true;
 250         QuickMenu_Page_Entries = 0;
 251
 252         QuickMenu_Buffer_Index = 0;
 253         if (z_submenu != "")
 254         {
 255                 // skip everything until the submenu open tag is found
 256                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 257                 {
 258                         s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 259                         if(substring(s, 0, 1) == "S" && substring(s, 1, -1) == z_submenu)
 260                         {
 261                                 // printf("^3 beginning of %s\n", z_submenu);
 262                                 ++QuickMenu_Buffer_Index;
 263                                 break; // target_submenu found!
 264                         }
 265                         // printf("^1 skipping %s\n", s);
 266                 }
 267                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 268                         printf("Couldn't find submenu \"%s\"\n", z_submenu);
 269         }
 270
 271         // only the last page can contain up to QUICKMENU_MAXLINES entries
 272         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 273         // so that the panel can show an empty row and "Continue..."
 274         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 275         int entry_num = 0; // counts entries in target_submenu
 276         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 277         {
 278                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 279
 280                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 281                 {
 282                         // printf("^3 end of %s\n", z_submenu);
 283                         break;
 284                 }
 285
 286                 if(entry_num >= first_entry)
 287                 {
 288                         ++QuickMenu_Page_Entries;
 289                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 290                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 291                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 292                         {
 293                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 294                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 295                                 QuickMenu_IsLastPage = false;
 296                                 break;
 297                         }
 298                 }
 299
 300                 // NOTE: entries are loaded starting from 1, not from 0
 301                 if(substring(s, 0, 1) == "S") // submenu
 302                 {
 303                         if(entry_num >= first_entry)
 304                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 305                         QuickMenu_skip_submenu(substring(s, 1, -1));
 306                 }
 307                 else if(entry_num >= first_entry && substring(s, 0, 1) == "T")
 308                 {
 309                         ++QuickMenu_Buffer_Index;
 310                         cmd = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 311                         string command_code = substring(cmd, 0, 1);
 312                         if(command_code == "C")
 313                                 cmd = substring(cmd, 1, -1);
 314                         else if(command_code == "P")
 315                         {
 316                                 // throw away the current quickmenu buffer and load a new one
 317                                 cmd = substring(cmd, 1, -1);
 318                                 strunzone(z_submenu);
 319                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 320                                         return QuickMenu_Page_Load("", 0);
 321                                 QuickMenu_Close();
 322                                 return false;
 323                         }
 324
 325                         tokenize_console(cmd);
 326                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 327
 328                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 329                 }
 330
 331                 ++entry_num;
 332         }
 333         strunzone(z_submenu);
 334         if (QuickMenu_Page_Entries == 0)
 335         {
 336                 QuickMenu_Close();
 337                 return false;
 338         }
 339         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 340         return true;
 341 }
 342
 343 bool QuickMenu_ActionForNumber(int num)
 344 {
 345         if (!QuickMenu_IsLastPage)
 346         {
 347                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 348                         return false;
 349                 if (num == QUICKMENU_MAXLINES - 1)
 350                         return false;
 351                 if (num == 0)
 352                 {
 353                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 354                         return false;
 355                 }
 356         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 357                 return false;
 358
 359         if (QuickMenu_Page_Command[num] != "")
 360         {
 361                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 362                 QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 363                 return true;
 364         }
 365         if (QuickMenu_Page_Description[num] != "")
 366                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 367         return false;
 368 }
 369
 370 void QuickMenu_Page_ActiveEntry(float entry_num)
 371 {
 372         QuickMenu_Page_ActivatedEntry = entry_num;
 373         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 374         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 375         {
 376                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 377                 // toggle commands don't close the quickmenu
 378                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 379                         QuickMenu_Page_ActivatedEntry_Close = false;
 380                 else
 381                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 382         }
 383         else
 384                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 385 }
 386
 387 bool QuickMenu_InputEvent(float bInputType, float nPrimary, float nSecondary)
 388 {
 389         // we only care for keyboard events
 390         if(bInputType == 2)
 391                 return false;
 392
 393         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 394                 return false;
 395
 396         if(bInputType == 3)
 397         {
 398                 mousepos_x = nPrimary;
 399                 mousepos_y = nSecondary;
 400                 return true;
 401         }
 402
 403         // allow console bind to work
 404         string con_keys;
 405         float keys;
 406         con_keys = findkeysforcommand("toggleconsole", 0);
 407         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 408
 409         bool hit_con_bind = false;
 410         int i;
 411         for (i = 0; i < keys; ++i)
 412         {
 413                 if(nPrimary == stof(argv(i)))
 414                         hit_con_bind = true;
 415         }
 416
 417         if(bInputType == 0) {
 418                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 419                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 420                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 421         }
 422         else if(bInputType == 1) {
 423                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 424                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 425                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 426         }
 427
 428         if(nPrimary == K_ESCAPE)
 429         {
 430                 if (bInputType == 1)
 431                         return true;
 432                 QuickMenu_Close();
 433         }
 434         else if(nPrimary >= '0' && nPrimary <= '9')
 435         {
 436                 if (bInputType == 1)
 437                         return true;
 438                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 439         }
 440         if(nPrimary == K_MOUSE1)
 441         {
 442                 if(bInputType == 0) // key pressed
 443                         mouseClicked |= S_MOUSE1;
 444                 else if(bInputType == 1) // key released
 445                         mouseClicked -= (mouseClicked & S_MOUSE1);
 446         }
 447         else if(nPrimary == K_MOUSE2)
 448         {
 449                 if(bInputType == 0) // key pressed
 450                         mouseClicked |= S_MOUSE2;
 451                 else if(bInputType == 1) // key released
 452                         mouseClicked -= (mouseClicked & S_MOUSE2);
 453         }
 454         else if(hit_con_bind)
 455                 return false;
 456
 457         return true;
 458 }
 459
 460 void QuickMenu_Mouse()
 461 {
 462         if(mv_active) return;
 463
 464         if(!mouseClicked)
 465         if(prevMouseClicked & S_MOUSE2)
 466         {
 467                 QuickMenu_Close();
 468                 return;
 469         }
 470
 471         if(!autocvar_hud_cursormode)
 472         {
 473                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 474
 475                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
 476                 mousepos_y = bound(0, mousepos_y, vid_conheight);
 477         }
 478
 479         HUD_Panel_UpdateCvars();
 480
 481         if(panel_bg_padding)
 482         {
 483                 panel_pos += '1 1 0' * panel_bg_padding;
 484                 panel_size -= '2 2 0' * panel_bg_padding;
 485         }
 486
 487         float first_entry_pos, entries_height;
 488         vector fontsize;
 489         fontsize = '1 1 0' * (panel_size_y / QUICKMENU_MAXLINES);
 490         first_entry_pos = panel_pos_y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y) / 2;
 491         entries_height = panel_size_y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y);
 492
 493         if (mousepos_x >= panel_pos_x && mousepos_y >= first_entry_pos && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= first_entry_pos + entries_height)
 494         {
 495                 float entry_num;
 496                 entry_num = floor((mousepos_y - first_entry_pos) / fontsize_y);
 497                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 498                 {
 499                         panel_pos_y = first_entry_pos + entry_num * fontsize_y;
 500                         vector color;
 501                         if(mouseClicked & S_MOUSE1)
 502                                 color = '0.5 1 0.5';
 503                         else if(hudShiftState & S_CTRL)
 504                                 color = '1 1 0.3';
 505                         else
 506                                 color = '1 1 1';
 507                         drawfill(panel_pos, eX * panel_size_x + eY * fontsize_y, color, .2, DRAWFLAG_NORMAL);
 508
 509                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 510                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 511                 }
 512         }
 513
 514         vector cursorsize = '32 32 0';
 515         drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', 0.8, DRAWFLAG_NORMAL);
 516
 517         prevMouseClicked = mouseClicked;
 518 }
 519
 520 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 521 {
 522         string entry;
 523         float offset;
 524         float desc_size = panel_size_x;
 525         if(option)
 526         {
 527                 float option_size = stringwidth_nocolors(option, fontsize);
 528                 desc_size -= option_size;
 529                 drawstring(pos + eX * desc_size, option, fontsize, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 530         }
 531         entry = textShortenToWidth(desc, desc_size, fontsize, stringwidth_colors);
 532         if (autocvar_hud_panel_quickmenu_align > 0)
 533         {
 534                 offset = (desc_size - stringwidth_colors(entry, fontsize)) * min(autocvar_hud_panel_quickmenu_align, 1);
 535                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 536         }
 537         else
 538                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 539 }
 540
 541 void HUD_QuickMenu(void)
 542 {
 543         if(!autocvar__hud_configure)
 544         {
 545                 if (hud_configure_prev && hud_configure_prev != -1)
 546                         QuickMenu_Close();
 547
 548                 if(!hud_draw_maximized) return;
 549                 if(mv_active) return;
 550                 //if(!autocvar_hud_panel_quickmenu) return;
 551                 if(!hud_panel_quickmenu) return;
 552
 553                 if(time > QuickMenu_TimeOut)
 554                 {
 555                         QuickMenu_Close();
 556                         return;
 557                 }
 558         }
 559         else
 560         {
 561                 if(!QuickMenu_IsOpened())
 562                 {
 563                         QuickMenu_Page_Entries = 1;
 564                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 565                         ++QuickMenu_Page_Entries;
 566                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 567                         ++QuickMenu_Page_Entries;
 568                         // although real command doesn't matter here, it must not be empty
 569                         // otherwise the entry is displayed like a submenu
 570                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 571                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 572                         ++QuickMenu_Page_Entries;
 573                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 574                         QuickMenu_IsLastPage = false;
 575                 }
 576         }
 577
 578         HUD_Panel_UpdateCvars();
 579
 580         HUD_Panel_DrawBg(1);
 581
 582         if(panel_bg_padding)
 583         {
 584                 panel_pos += '1 1 0' * panel_bg_padding;
 585                 panel_size -= '2 2 0' * panel_bg_padding;
 586         }
 587
 588         int i;
 589         vector fontsize;
 590         string color;
 591         fontsize = '1 1 0' * (panel_size_y / QUICKMENU_MAXLINES);
 592
 593         if (!QuickMenu_IsLastPage)
 594         {
 595                 color = "^5";
 596                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size_y - fontsize_y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 597         }
 598         else
 599                 panel_pos_y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y) / 2;
 600
 601         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 602                 if (QuickMenu_Page_Description[i] == "")
 603                         break;
 604                 string option = string_null;
 605                 if (QuickMenu_Page_Command[i] == "")
 606                         color = "^4";
 607                 else
 608                 {
 609                         color = "^3";
 610                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 611                         {
 612                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 613                                 if(end < 0)
 614                                         tokenize_console(QuickMenu_Page_Command[i]);
 615                                 else
 616                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 617
 618                                 //if(argv(1) && argv(0) == "toggle") // already checked
 619                                 {
 620                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 621                                         // "disable feature xxx" "toggle xxx 0 1"
 622                                         float ON_value = 1, OFF_value = 0;
 623                                         if(argv(2))
 624                                                 ON_value = stof(argv(2));
 625
 626                                         if(argv(3))
 627                                                 OFF_value = stof(argv(3));
 628                                         else
 629                                                 OFF_value = !ON_value;
 630
 631                                         float value = cvar(argv(1));
 632                                         if(value == ON_value)
 633                                                 option = "[X]";
 634                                         else if(value == OFF_value)
 635                                                 option = "[_]";
 636                                         else
 637                                                 option = "[?]";
 638                                 }
 639                         }
 640                 }
 641                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 642
 643                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 644                         && QuickMenu_Page_ActivatedEntry == i)
 645                         drawfill(panel_pos, eX * panel_size_x + eY * fontsize_y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 646
 647                 panel_pos_y += fontsize_y;
 648         }
 649
 650         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 651         {
 652                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 653                 {
 654                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 655                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 656                                 QuickMenu_Close();
 657                 }
 658                 else if(QuickMenu_Page_ActivatedEntry_Close)
 659                         QuickMenu_Close();
 660                 QuickMenu_Page_ActivatedEntry = -1;
 661                 QuickMenu_Page_ActivatedEntry_Time = 0;
 662         }
 663 }
 664
 665
 666 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 667         if(target_submenu == eng_submenu && target_submenu_found) \
 668                 return; /* target_submenu entries are now loaded, exit */ \
 669         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 670                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", submenu)); \
 671         ++QuickMenu_Buffer_Size; \
 672         if(target_submenu == eng_submenu && !target_submenu_found) { \
 673                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 674                 target_submenu_found = true; \
 675         } \
 676 }
 677
 678 #define QUICKMENU_ENTRY(title,command) { \
 679         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 680         { \
 681                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", title)); \
 682                 ++QuickMenu_Buffer_Size; \
 683                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", command)); \
 684         } \
 685         ++QuickMenu_Buffer_Size; \
 686 }
 687
 688 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 689         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 690                 QUICKMENU_SMENU(submenu,eng_submenu) \
 691                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); \
 692                 ++QuickMenu_Buffer_Size; \
 693                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", command)); \
 694                 ++QuickMenu_Buffer_Size; \
 695                 QUICKMENU_SMENU(submenu,eng_submenu) \
 696         } \
 697 }
 698
 699
 700
 701 // useful to Translate a string inside the Command
 702 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 703         if(prvm_language == "en") \
 704                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 705         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 706                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 707         else \
 708                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 709 }
 710
 711 void HUD_Quickmenu_PlayerListEntries(string cmd, float teamplayers, float without_me)
 712 {
 713         entity pl;
 714         if(teamplayers && !team_count)
 715                 return;
 716
 717         for(pl = players.sort_next; pl; pl = pl.sort_next)
 718         {
 719                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 720                         continue;
 721                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 722                         continue;
 723                 if(without_me && pl.sv_entnum == player_localnum)
 724                         continue;
 725                 QUICKMENU_ENTRY(GetPlayerName(pl.sv_entnum), sprintf(cmd, GetPlayerName(pl.sv_entnum)))
 726         }
 727
 728         return;
 729 }
 730
 731
 732 // Specifying target_submenu, this function only loads entries inside target_submenu
 733 // NOTE: alternatively we could have loaded the whole default quickmenu and
 734 // then called QuickMenu_Page_Load(target_submenu, 0);
 735 // but this sytem is more reliable since we can always refer to target_submenu
 736 // with the English title even if a translation is active
 737 void QuickMenu_Default(string target_submenu)
 738 {
 739         bool target_submenu_found = false;
 740         if(target_submenu != "")
 741                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 742
 743         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 744                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 745                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 746                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 747         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 748
 749         if(teamplay)
 750         {
 751         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 752                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 753                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 754                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 755                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 756                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 757                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 758                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 759                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 760                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 761                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 762                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 763                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 764                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 765                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 766                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; +use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 767         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 768         }
 769
 770         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s\" ^7", 0, 1)
 771
 772         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 773                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 774                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 775                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 776                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 777                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 778                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 779                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 780                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 781
 782                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 783                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 784                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle cl_chatsound")
 785                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 786
 787                 if(spectatee_status > 0)
 788                 {
 789                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 790                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 791                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 792                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 793                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 794                 }
 795
 796                 if(spectatee_status == -1)
 797                 {
 798                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 799                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 800                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 801                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 802                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 803                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 804                 }
 805
 806                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 807                 if(prvm_language != "en")
 808                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 809         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 810
 811         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 812                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 813                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 814                 if(getstatf(STAT_TIMELIMIT) > 0)
 815                 {
 816                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 817                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 818                 }
 819                 if(teamplay)
 820                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 821         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 822
 823         if(target_submenu != "" && !target_submenu_found)
 824         {
 825                 printf("Couldn't find submenu \"%s\"\n", target_submenu);
 826                 if(prvm_language != "en")
 827                         printf("^3Warning: submenu must be in English\n", target_submenu);
 828                 QuickMenu_Buffer_Size = 0;
 829         }
 830 }
 831 #undef QUICKMENU_SMENU
 832 #undef QUICKMENU_ENTRY
 833 #undef QUICKMENU_ENTRY_TC