qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.sameteam = player is on same team as local client
   6 // self.fadedelay = time to wait before name tag starts fading in for enemies
   7 //
   8 const float SHOWNAMES_FADESPEED = 4;
   9 const float SHOWNAMES_FADEDELAY = 0.5;
  10 void Draw_ShowNames(entity ent)
  11 {
  12         if(!autocvar_hud_shownames)
  13                 return;
  14
  15         if((ent.sv_entnum == player_localentnum) && !(autocvar_hud_shownames_self && autocvar_chase_active))
  16                 return;
  17
  18         makevectors(view_angles);
  19
  20         if(ent.sameteam || (!ent.sameteam && autocvar_hud_shownames_enemies))
  21         {
  22                 ent.origin_z += autocvar_hud_shownames_offset;
  23
  24                 float hit;
  25                 if(ent.sameteam)
  26                 {
  27                         hit = 1;
  28                 }
  29                 else
  30                 {
  31                         traceline(view_origin, ent.origin, MOVE_NORMAL, ent);
  32                         if(trace_fraction < 1 && trace_networkentity != ent.sv_entnum)
  33                                 hit = 0;
  34                         else
  35                                 hit = 1;
  36                 }
  37
  38                 vector o, eo;
  39                 o = project_3d_to_2d(ent.origin);
  40                 float overlap, onscreen;
  41
  42                 if(autocvar_hud_shownames_antioverlap)
  43                 {
  44                         // fade tag out if another tag that is closer to you overlaps
  45                         entity e;
  46                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  47                         {
  48                                 if(e == ent)
  49                                         continue;
  50                                 eo = project_3d_to_2d(e.origin);
  51                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  52                                 {
  53                                         eo_z = 0;
  54                                         if(vlen((eX * o_x + eY * o_y) - eo) < autocvar_hud_shownames_antioverlap_distance && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  55                                         {
  56                                                 overlap = TRUE;
  57                                                 break;
  58                                         }
  59                                 }
  60                         }
  61                 }
  62
  63                 onscreen = (o_z >= 0 && o_x >= 0 && o_y >= 0 && o_x <= vid_conwidth && o_y <= vid_conheight);
  64
  65                 if(!ent.fadedelay)
  66                         ent.fadedelay = time + SHOWNAMES_FADEDELAY;
  67
  68                 if(!ent.sameteam && (!onscreen || !hit)) // out of view, fade out
  69                 {
  70                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  71                         ent.fadedelay = 0; // reset fade in delay, enemy has left the view
  72                 }
  73                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  74                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  75                 else if(overlap) // tag overlap detected, fade out
  76                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  77                 else if(ent.sameteam) // fade in for team mates
  78                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  79                 else if(time > ent.fadedelay) // fade in for enemies
  80                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  81
  82                 if(!ent.alpha)
  83                         return;
  84
  85                 float dist;
  86                 dist = vlen(ent.origin - view_origin);
  87
  88                 float a;
  89                 a = autocvar_hud_shownames_alpha;
  90                 a *= ent.alpha;
  91                 if(autocvar_hud_shownames_maxdistance)
  92                 {
  93                         if(dist >= autocvar_hud_shownames_maxdistance)
  94                                 return;
  95                         a *= ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
  96                 }
  97
  98                 if(!a)
  99                         return;
 100
 101                 float resize;
 102                 resize = 1;
 103                 if(autocvar_hud_shownames_resize) // limit resize so its never smaller than 0.5... gets unreadable
 104                         resize = 0.5 + 0.5 * ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
 105
 106                 // draw the sprite image
 107                 if(o_z >= 0)
 108                 {
 109                         o_z = 0;
 110
 111                         vector myPos, mySize;
 112                         mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
 113                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 114
 115                         // size scaling
 116                         mySize_x *= resize;
 117                         mySize_y *= resize;
 118
 119                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 120                         myPos_y += (mySize_y / resize - mySize_y);
 121
 122                         vector namepos; // this is where the origin of the string
 123                         float namewidth;
 124
 125                         namepos = myPos;
 126                         namewidth = mySize_x;
 127
 128                         if(autocvar_hud_shownames_status && teamplay)
 129                         {
 130                                 if(ent.sameteam)
 131                                 {
 132                                         if(ent.healthvalue > 0)
 133                                         {
 134                                                 HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.healthvalue/autocvar_hud_panel_healtharmor_maxhealth, 0, 1, '1 0 0', a, DRAWFLAG_NORMAL);
 135
 136                                                 if(ent.armorvalue > 0)
 137                                                         HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.armorvalue/autocvar_hud_panel_healtharmor_maxarmor, 0, 0, '0 1 0', a, DRAWFLAG_NORMAL);
 138                                         }
 139                                 }
 140                         }
 141
 142                         string s;
 143                         s = GetPlayerName(ent.sv_entnum-1);
 144                         if((autocvar_hud_shownames_decolorize == 1 && teamplay) || autocvar_hud_shownames_decolorize == 2)
 145                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 146
 147                         drawfontscale = '1 1 0' * resize;
 148                         s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 149
 150                         float width;
 151                         width = stringwidth(s, TRUE, '1 1 0' * autocvar_hud_shownames_fontsize);
 152
 153                         if (width != namewidth)
 154                                 namepos_x += (namewidth - width) / 2;
 155                         drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 156                         drawfontscale = '1 1 0';
 157                 }
 158         }
 159 }
 160
 161 entity shownames_ent[255];
 162 void Draw_ShowNames_All()
 163 {
 164         float i;
 165         for(i = 0; i < maxclients; ++i)
 166         {
 167                 float t;
 168                 t = GetPlayerColor(i);
 169                 if(t == COLOR_SPECTATOR)
 170                         continue;
 171
 172                 entity e;
 173                 e = shownames_ent[i];
 174                 if(!e)
 175                 {
 176                         e = spawn();
 177                         e.classname = "shownames_tag";
 178                         e.sv_entnum = i+1;
 179                         shownames_ent[i] = e;
 180                 }
 181
 182                 entity entcs;
 183                 entcs = entcs_receiver[i];
 184                 if(entcs)
 185                 {
 186                         e.healthvalue = entcs.healthvalue;
 187                         e.armorvalue = entcs.armorvalue;
 188                         e.sameteam = 1; /* (teamplay && (t == myteam)); */
 189                 }
 190                 else
 191                 {
 192                         e.healthvalue = 2342;
 193                         e.armorvalue = 0;
 194                         e.sameteam = 0;
 195                 }
 196
 197                 e.origin = getplayerorigin(i);
 198                 if(e.origin == GETPLAYERORIGIN_ERROR)
 199                         continue;
 200
 201                 Draw_ShowNames(e);
 202         }
 203 }