qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include <client/draw.qh>
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "main.qh"
   8 #include "mapvoting.qh"
   9 #include "shownames.qh"
  10 #include "hud/panel/scoreboard.qh"
  11 #include "hud/panel/quickmenu.qh"
  12
  13 #include <client/mutators/_mod.qh>
  14
  15 #include <common/animdecide.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/ent_cs.qh>
  18 #include <common/anim.qh>
  19 #include <common/constants.qh>
  20 #include <common/net_linked.qh>
  21 #include <common/net_notice.qh>
  22 #include <common/debug.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/gamemodes/_mod.qh>
  25 #include <common/physics/player.qh>
  26 #include <common/stats.qh>
  27 #include <common/mapobjects/target/music.qh>
  28 #include <common/teams.qh>
  29 #include <common/wepent.qh>
  30
  31 #include <common/weapons/weapon/tuba.qh>
  32
  33 #include <common/vehicles/all.qh>
  34 #include <common/weapons/_all.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 float autocvar_cl_viewmodel_scale;
  49 float autocvar_cl_viewmodel_alpha = 1;
  50
  51 bool autocvar_cl_bobmodel;
  52 float autocvar_cl_bobmodel_speed;
  53 float autocvar_cl_bobmodel_side;
  54 float autocvar_cl_bobmodel_up;
  55
  56 float autocvar_cl_followmodel;
  57 float autocvar_cl_followmodel_speed = 0.3;
  58 float autocvar_cl_followmodel_limit = 135;
  59 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  60 float autocvar_cl_followmodel_highpass = 0.05;
  61 float autocvar_cl_followmodel_lowpass = 0.03;
  62 bool autocvar_cl_followmodel_velocity_absolute;
  63
  64 float autocvar_cl_leanmodel;
  65 float autocvar_cl_leanmodel_speed = 0.3;
  66 float autocvar_cl_leanmodel_limit = 30;
  67 float autocvar_cl_leanmodel_highpass1 = 0.2;
  68 float autocvar_cl_leanmodel_highpass = 0.2;
  69 float autocvar_cl_leanmodel_lowpass = 0.05;
  70
  71 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  72
  73 #define lowpass(value, frac, ref_store, ret) \
  74         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  75
  76 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  77         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  78         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  79 MACRO_END
  80
  81 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  82         float __f = 0; lowpass(value, frac, ref_store, __f); \
  83         ret = (value) - __f; \
  84 MACRO_END
  85
  86 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  87         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  88         ret = (value) - __f; \
  89 MACRO_END
  90
  91 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  93         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  94 MACRO_END
  95
  96 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  97         highpass(value.x, frac, ref_store.x, ref_out.x); \
  98         highpass(value.y, frac, ref_store.y, ref_out.y); \
  99 MACRO_END
 100
 101 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 108         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 109         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 110 MACRO_END
 111
 112 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 113         highpass(value.x, frac, ref_store.x, ref_out.x); \
 114         highpass(value.y, frac, ref_store.y, ref_out.y); \
 115         highpass(value.z, frac, ref_store.z, ref_out.z); \
 116 MACRO_END
 117
 118 void calc_followmodel_ofs(entity view)
 119 {
 120         if(cl_followmodel_time == time)
 121                 return; // cl_followmodel_ofs already calculated for this frame
 122
 123         float frac;
 124         vector gunorg = '0 0 0';
 125         static vector vel_average;
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward, right, up;
 135                 MAKE_VECTORS(view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward, right, up;
 161                 MAKE_VECTORS(view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 292         int wepskin = this.m_skin;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         Weapon wep = this.activeweapon;
 296         int c = entcs_GetClientColors(current_player);
 297         vector g = weaponentity_glowmod(wep, NULL, c, this);
 298         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 299         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 300                 | EF_NODEPTHTEST)
 301                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 302         for (entity e = this; e; e = e.weaponchild)
 303         {
 304                 e.drawmask = mask;
 305                 e.alpha = a;
 306                 e.skin = wepskin;
 307                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 308                 e.glowmod = g;
 309                 e.csqcmodel_effects = fx;
 310                 CSQCModel_Effects_Apply(e);
 311         }
 312         if(a >= 0)
 313         {
 314                 string name = wep.mdl;
 315                 string newname = wep.wr_viewmodel(wep, this);
 316                 if(newname)
 317                         name = newname;
 318                 bool swap = name != this.name_last;
 319                 // if (swap)
 320                 {
 321                         this.name_last = name;
 322                         CL_WeaponEntity_SetModel(this, name, swap);
 323                         this.viewmodel_origin = this.origin;
 324                         this.viewmodel_angles = this.angles;
 325                 }
 326                 anim_update(this);
 327                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 328                         anim_set(this, this.anim_idle, true, false, false);
 329         }
 330         float f = 0; // 0..1; 0: fully active
 331         float rate = STAT(WEAPONRATEFACTOR);
 332         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 333         if (eta <= 0) f = this.weapon_eta_last;
 334         else switch (this.state)
 335         {
 336                 case WS_RAISE:
 337                 {
 338                         f = eta / max(eta, this.weapon_switchdelay);
 339                         break;
 340                 }
 341                 case WS_DROP:
 342                 {
 343                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 344                         break;
 345                 }
 346                 case WS_CLEAR:
 347                 {
 348                         f = 1;
 349                         break;
 350                 }
 351         }
 352         this.weapon_eta_last = f;
 353         this.origin = this.viewmodel_origin;
 354         this.angles = this.viewmodel_angles;
 355         this.angles_x = (-90 * f * f);
 356         viewmodel_animate(this);
 357         MUTATOR_CALLHOOK(DrawViewModel, this);
 358         setorigin(this, this.origin);
 359 }
 360
 361 STATIC_INIT(viewmodel) {
 362     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 363         viewmodels[slot] = new(viewmodel);
 364 }
 365
 366 vector project_3d_to_2d(vector vec)
 367 {
 368         vec = cs_project(vec);
 369         if(cs_project_is_b0rked > 0)
 370         {
 371                 vec.x *= vid_conwidth / vid_width;
 372                 vec.y *= vid_conheight / vid_height;
 373         }
 374         return vec;
 375 }
 376
 377 bool projected_on_screen(vector screen_pos)
 378 {
 379         return screen_pos.z >= 0
 380                 && screen_pos.x >= 0
 381                 && screen_pos.y >= 0
 382                 && screen_pos.x < vid_conwidth
 383                 && screen_pos.y < vid_conheight;
 384 }
 385
 386 void update_mousepos()
 387 {
 388         mousepos += getmousepos() * autocvar_menu_mouse_speed;
 389         mousepos.x = bound(0, mousepos.x, vid_conwidth);
 390         mousepos.y = bound(0, mousepos.y, vid_conheight);
 391 }
 392
 393 float showfps_prevfps;
 394 float showfps_prevfps_time;
 395 int showfps_framecounter;
 396
 397 void fpscounter_update()
 398 {
 399         if(!STAT(SHOWFPS))
 400                 return;
 401
 402         float currentTime = gettime(GETTIME_FRAMESTART);
 403
 404         showfps_framecounter += 1;
 405         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 406         {
 407                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 408                 showfps_framecounter = 0;
 409                 showfps_prevfps_time = currentTime;
 410
 411                 int channel = MSG_C2S;
 412                 WriteHeader(channel, fpsreport);
 413                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 414         }
 415 }
 416
 417 STATIC_INIT(fpscounter_init)
 418 {
 419         float currentTime = gettime(GETTIME_FRAMESTART);
 420         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 421 }
 422
 423 float avgspeed;
 424 vector GetCurrentFov(float fov)
 425 {
 426         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 427         float velocityzoom, curspeed;
 428         vector v;
 429
 430         zoomsensitivity = autocvar_cl_zoomsensitivity;
 431         zoomfactor = autocvar_cl_zoomfactor;
 432         if(zoomfactor < 1 || zoomfactor > 30)
 433                 zoomfactor = 2.5;
 434         zoomspeed = autocvar_cl_zoomspeed;
 435         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 436                 zoomspeed = 3.5;
 437
 438         zoomdir = button_zoom;
 439
 440         if(hud == HUD_NORMAL && !spectatee_status)
 441         {
 442                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 443                 {
 444                         entity wepent = viewmodels[slot];
 445                         if(wepent.switchweapon != wepent.activeweapon)
 446                                 continue;
 447                         Weapon wep = wepent.activeweapon;
 448                         if(wep != WEP_Null && wep.wr_zoomdir)
 449                         {
 450                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 451                                 zoomdir += do_zoom;
 452                         }
 453                 }
 454         }
 455         if(spectatee_status > 0 || isdemo())
 456         {
 457                 if(spectatorbutton_zoom)
 458                 {
 459                         if(zoomdir)
 460                                 zoomdir = 0;
 461                         else
 462                                 zoomdir = 1;
 463                 }
 464                 // fteqcc failed twice here already, don't optimize this
 465         }
 466
 467         if(zoomdir) { zoomin_effect = 0; }
 468
 469         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 470         {
 471                 current_viewzoom = 1;
 472         }
 473         else if (camera_active)
 474         {
 475                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 476         }
 477         else if(autocvar_cl_spawnzoom && zoomin_effect)
 478         {
 479                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 480
 481                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 482                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 483                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 484         }
 485         else
 486         {
 487                 if(zoomspeed < 0) // instant zoom
 488                 {
 489                         if(zoomdir)
 490                                 current_viewzoom = 1 / zoomfactor;
 491                         else
 492                                 current_viewzoom = 1;
 493                 }
 494                 else
 495                 {
 496                         if(zoomdir)
 497                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 498                         else
 499                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 500                 }
 501         }
 502
 503         if(almost_equals(current_viewzoom, 1))
 504                 current_zoomfraction = 0;
 505         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 506                 current_zoomfraction = 1;
 507         else
 508                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 509
 510         if(zoomsensitivity < 1)
 511                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 512         else
 513                 setsensitivityscale(1);
 514
 515         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && !autocvar_cl_lockview) // _type = 0 disables velocity zoom too
 516         {
 517                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 518                         curspeed = 0;
 519                 else
 520                 {
 521                         vector forward, right, up;
 522                         MAKE_VECTORS(view_angles, forward, right, up);
 523                         v = pmove_vel;
 524                         if(csqcplayer)
 525                                 v = csqcplayer.velocity;
 526
 527                         switch(autocvar_cl_velocityzoom_type)
 528                         {
 529                                 case 3: curspeed = max(0, forward * v); break;
 530                                 case 2: curspeed = (forward * v); break;
 531                                 case 1: default: curspeed = vlen(v); break;
 532                         }
 533                 }
 534
 535                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 536                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 537                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 538
 539                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 540         }
 541         else
 542                 velocityzoom = 1;
 543
 544         float frustumx, frustumy, fovx, fovy;
 545         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 546         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 547         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 548         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 549
 550         return '1 0 0' * fovx + '0 1 0' * fovy;
 551 }
 552
 553 vector GetViewLocationFOV(float fov)
 554 {
 555         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 556         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 557         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 558         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 559         return '1 0 0' * fovx + '0 1 0' * fovy;
 560 }
 561
 562 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 563 {
 564         float fovx, fovy;
 565         float width = (ov_worldmax.x - ov_worldmin.x);
 566         float height = (ov_worldmax.y - ov_worldmin.y);
 567         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 568         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 569         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 570         return '1 0 0' * fovx + '0 1 0' * fovy;
 571 }
 572
 573 // this function must match W_SetupShot!
 574
 575 bool minigame_wasactive;
 576
 577 float camera_mode;
 578 const float CAMERA_FREE = 1;
 579 const float CAMERA_CHASE = 2;
 580 string NextFrameCommand;
 581
 582 vector freeze_org, freeze_ang;
 583 entity nightvision_noise, nightvision_noise2;
 584
 585 float myhealth, myhealth_prev;
 586 float myhealth_flash;
 587
 588 float old_blurradius, old_bluralpha;
 589 float old_sharpen_intensity;
 590
 591 vector myhealth_gentlergb;
 592
 593 float contentavgalpha, liquidalpha_prev;
 594 vector liquidcolor_prev;
 595
 596 float eventchase_current_distance;
 597 float eventchase_running;
 598 int WantEventchase(entity this, bool want_vehiclechase)
 599 {
 600         if(autocvar_cl_orthoview)
 601                 return 0;
 602         if(STAT(GAME_STOPPED) || intermission)
 603                 return 1;
 604         if(this.viewloc)
 605                 return 1;
 606         if(spectatee_status >= 0)
 607         {
 608                 if(want_vehiclechase)
 609                         return 1;
 610                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 611                         return 1;
 612                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 613                         return 1;
 614                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 615                 {
 616                         if(autocvar_cl_eventchase_death == 2)
 617                         {
 618                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 619                                 if(this.velocity == '0 0 0' || eventchase_running)
 620                                         return 1;
 621                         }
 622                         else return 1;
 623                 }
 624                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 625                 {
 626                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 627                                 return 1;
 628                         else if (eventchase_running)
 629                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 630                 }
 631         }
 632         return 0;
 633 }
 634
 635 void View_EventChase(entity this)
 636 {
 637         // event chase camera
 638         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 639         {
 640                 if(STAT(CAMERA_SPECTATOR))
 641                 {
 642                         if(spectatee_status > 0)
 643                         {
 644                                 if(!autocvar_chase_active)
 645                                 {
 646                                         cvar_set("chase_active", "-2");
 647                                         return;
 648                                 }
 649                         }
 650                         else if(autocvar_chase_active == -2)
 651                                 cvar_set("chase_active", "0");
 652
 653                         if(autocvar_chase_active == -2)
 654                                 return;
 655                 }
 656                 else if(autocvar_chase_active == -2)
 657                         cvar_set("chase_active", "0");
 658
 659                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 660
 661                 float vehicle_viewdist = 0;
 662                 vector vehicle_viewofs = '0 0 0';
 663
 664                 if(vehicle_chase)
 665                 {
 666                         if(hud != HUD_BUMBLEBEE_GUN)
 667                         {
 668                                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 669                                 vehicle_viewdist = info.height;
 670                                 vehicle_viewofs = info.view_ofs;
 671                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 672                                         vehicle_chase = false;
 673                         }
 674                         else
 675                                 vehicle_chase = false;
 676                 }
 677
 678                 int eventchase = WantEventchase(this, vehicle_chase);
 679                 if (eventchase)
 680                 {
 681                         vector current_view_origin_override = '0 0 0';
 682                         vector view_offset_override = '0 0 0';
 683                         float chase_distance_override = 0;
 684                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 685                         if(custom_eventchase)
 686                         {
 687                                 current_view_origin_override = M_ARGV(0, vector);
 688                                 view_offset_override = M_ARGV(1, vector);
 689                                 chase_distance_override = M_ARGV(0, float);
 690                         }
 691                         eventchase_running = true;
 692
 693                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 694                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 695                         if (custom_eventchase)
 696                                 current_view_origin = current_view_origin_override;
 697
 698                         // detect maximum viewoffset and use it
 699                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 700                         if(vehicle_chase)
 701                         {
 702                                 if(vehicle_viewofs)
 703                                         view_offset = vehicle_viewofs;
 704                                 else
 705                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 706                         }
 707                         if (custom_eventchase)
 708                                 view_offset = view_offset_override;
 709
 710                         if(view_offset)
 711                         {
 712                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 713                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 714                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 715                         }
 716
 717                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 718                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 719                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 720                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 721
 722                         // make the camera smooth back
 723                         float chase_distance = autocvar_cl_eventchase_distance;
 724                         if(vehicle_chase)
 725                         {
 726                                 if(vehicle_viewofs)
 727                                         chase_distance = vehicle_viewdist;
 728                                 else
 729                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 730                         }
 731                         if (custom_eventchase)
 732                                 chase_distance = chase_distance_override;
 733
 734                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 735                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 736                         else if(eventchase_current_distance != chase_distance)
 737                                 eventchase_current_distance = chase_distance;
 738
 739                         vector forward, right, up;
 740                         MAKE_VECTORS(view_angles, forward, right, up);
 741
 742                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 743                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 744
 745                         // If the boxtrace fails, revert back to line tracing.
 746                         if(!this.viewloc)
 747                         if(trace_startsolid)
 748                         {
 749                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 750                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 751                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 752                         }
 753                         else { setproperty(VF_ORIGIN, trace_endpos); }
 754
 755                         if(!this.viewloc)
 756                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 757                 }
 758
 759                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 760                 {
 761                         eventchase_running = false;
 762                         cvar_set("chase_active", "0");
 763                         eventchase_current_distance = 0; // start from 0 next time
 764                 }
 765         }
 766         // workaround for camera stuck between player's legs when using chase_active 1
 767         // because the engine stops updating the chase_active camera when the game ends
 768         else if(intermission)
 769         {
 770                 cvar_settemp("chase_active", "-1");
 771                 eventchase_current_distance = 0;
 772         }
 773 }
 774
 775 vector damage_blurpostprocess, content_blurpostprocess;
 776
 777 void UpdateDamage()
 778 {
 779         // accumulate damage with each stat update
 780         static float damage_total_prev = 0;
 781         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 782         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 783         damage_total_prev = damage_total;
 784
 785         static float damage_dealt_time_prev = 0;
 786         float damage_dealt_time = STAT(HIT_TIME);
 787         if (damage_dealt_time != damage_dealt_time_prev)
 788         {
 789                 unaccounted_damage += unaccounted_damage_new;
 790                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 791         }
 792         damage_dealt_time_prev = damage_dealt_time;
 793
 794         // prevent hitsound when switching spectatee
 795         static float spectatee_status_prev = 0;
 796         if (spectatee_status != spectatee_status_prev)
 797                 unaccounted_damage = 0;
 798         spectatee_status_prev = spectatee_status;
 799 }
 800
 801 void HitSound()
 802 {
 803         // varying sound pitch
 804
 805         bool have_arc = false;
 806         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 807         {
 808                 entity wepent = viewmodels[slot];
 809
 810                 if(wepent.activeweapon == WEP_ARC)
 811                         have_arc = true;
 812         }
 813
 814         static float hitsound_time_prev = 0;
 815         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 816         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 817         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 818         {
 819                 if (autocvar_cl_hitsound && unaccounted_damage)
 820                 {
 821                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 822                         float a = autocvar_cl_hitsound_max_pitch;
 823                         float b = autocvar_cl_hitsound_min_pitch;
 824                         float c = autocvar_cl_hitsound_nom_damage;
 825                         float d = unaccounted_damage;
 826                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 827
 828                         // if sound variation is disabled, set pitch_shift to 1
 829                         if (autocvar_cl_hitsound == 1)
 830                                 pitch_shift = 1;
 831
 832                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 833                         if (autocvar_cl_hitsound == 3)
 834                         {
 835                                 float mirror_value = (a-b)/2 + b;
 836                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 837                         }
 838
 839                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 840
 841                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 842                         // todo: normalize sound pressure levels? seems unnecessary
 843
 844                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 845                 }
 846                 unaccounted_damage = 0;
 847                 hitsound_time_prev = time;
 848         }
 849
 850         static float typehit_time_prev = 0;
 851         float typehit_time = STAT(TYPEHIT_TIME);
 852         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 853         {
 854                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 855                 typehit_time_prev = typehit_time;
 856         }
 857
 858         static float kill_time_prev = 0;
 859         float kill_time = STAT(KILL_TIME);
 860         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 861         {
 862                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 863                 kill_time_prev = kill_time;
 864         }
 865 }
 866
 867 const int MAX_SPECIALCOMMAND = 15;
 868 vector specialcommand_slots[MAX_SPECIALCOMMAND];
 869 vector specialcommand_colors[MAX_SPECIALCOMMAND];
 870 const float SPECIALCOMMAND_SPEED = 150;
 871 const float SPECIALCOMMAND_TURNSPEED = 2;
 872 const float SPECIALCOMMAND_SIZE = 0.025;
 873 const float SPECIALCOMMAND_CHANCE = 0.35;
 874 float sc_spawntime, sc_changetime;
 875 vector sc_color = '1 1 1';
 876 void SpecialCommand()
 877 {
 878         if(!STAT(MOVEVARS_SPECIALCOMMAND))
 879                 return;
 880
 881         if(time >= sc_changetime)
 882         {
 883                 sc_changetime = time + 1;
 884                 sc_color = randomvec() * 1.5;
 885                 sc_color.x = bound(0.2, sc_color.x, 0.75);
 886                 sc_color.y = bound(0.2, sc_color.y, 0.75);
 887                 sc_color.z = bound(0.2, sc_color.z, 0.75);
 888         }
 889         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
 890
 891         if(!precache_pic("gfx/smile"))
 892                 return; // damn party poopers
 893
 894         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
 895         {
 896                 vector slot = specialcommand_slots[j];
 897                 if(slot.y)
 898                         slot.y += SPECIALCOMMAND_SPEED * frametime;
 899                 //if(slot.z)
 900                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
 901                 if(slot.y >= vid_conheight)
 902                         slot = '0 0 0';
 903
 904                 if(slot == '0 0 0')
 905                 {
 906                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
 907                         {
 908                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
 909                                 slot.y = 1; // start it off 0 so we can use it
 910                                 slot.z = floor(random() * REGISTRY_MAX(Weapons));
 911                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
 912                                 vector newcolor = randomvec() * 2;
 913                                 newcolor.x = bound(0.4, newcolor.x, 1);
 914                                 newcolor.y = bound(0.4, newcolor.y, 1);
 915                                 newcolor.z = bound(0.4, newcolor.z, 1);
 916                                 specialcommand_colors[j] = newcolor;
 917                         }
 918                 }
 919                 else
 920                 {
 921                         vector splash_size = '0 0 0';
 922                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 923                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 924                         entity wep = REGISTRY_GET(Weapons, slot.z);
 925                         if(wep == WEP_Null)
 926                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 927                         else
 928                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 929                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 930                 }
 931
 932                 specialcommand_slots[j] = slot;
 933         }
 934 }
 935
 936 void HUD_Draw(entity this)
 937 {
 938         // if we don't know gametype and scores yet avoid drawing the scoreboard
 939         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
 940         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
 941         // cl_deathscoreboard would show the scoreboard and so on
 942         if(!gametype)
 943                 return;
 944
 945         Hud_Dynamic_Frame();
 946
 947         if(!intermission)
 948         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
 949         {
 950                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
 951         }
 952         else if(STAT(FROZEN))
 953         {
 954                 vector col = '0.25 0.90 1';
 955                 if(STAT(REVIVE_PROGRESS))
 956                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
 957                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 958         }
 959
 960         HUD_Scale_Enable();
 961         if(!intermission)
 962         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 963         {
 964                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
 965                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 966                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 967         }
 968         else if(STAT(CAPTURE_PROGRESS))
 969         {
 970                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 971                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 972         }
 973         else if(STAT(REVIVE_PROGRESS))
 974         {
 975                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 976                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 977         }
 978         HUD_Scale_Disable();
 979
 980         if(autocvar_r_letterbox == 0)
 981                 if(autocvar_viewsize < 120)
 982                 {
 983                         if(!MUTATOR_CALLHOOK(DrawScoreboardAccuracy))
 984                                 Accuracy_LoadLevels();
 985
 986                         HUD_Main();
 987                         HUD_Scale_Disable();
 988                 }
 989
 990         // crosshair goes VERY LAST
 991         SpecialCommand();
 992         UpdateDamage();
 993         HUD_Crosshair(this);
 994         HitSound();
 995 }
 996
 997 void ViewLocation_Mouse()
 998 {
 999         if(spectatee_status)
1000                 return; // don't draw it as spectator!
1001
1002         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1003         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1004         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1005
1006         //float cursor_alpha = 1 - autocvar__menu_alpha;
1007         //cursor_type = CURSOR_NORMAL;
1008         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1009 }
1010
1011 void HUD_Cursor_Show()
1012 {
1013         float cursor_alpha = 1 - autocvar__menu_alpha;
1014         if(cursor_type == CURSOR_NORMAL)
1015                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1016         else if(cursor_type == CURSOR_MOVE)
1017                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1018         else if(cursor_type == CURSOR_RESIZE)
1019                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1020         else if(cursor_type == CURSOR_RESIZE2)
1021                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1022 }
1023
1024 void HUD_Mouse(entity player)
1025 {
1026         if(autocvar__menu_alpha == 1)
1027                 return;
1028
1029         if(!cursor_active)
1030         {
1031                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1032                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1033                 return;
1034         }
1035
1036         if (cursor_active == -1) // starting to display the cursor
1037         {
1038                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1039                 // in the first frame mousepos is the mouse position of the last time
1040                 // the cursor was displayed, thus we ignore it to avoid a glictch
1041                 cursor_active = 1;
1042                 return;
1043         }
1044
1045         if(!autocvar_hud_cursormode)
1046                 update_mousepos();
1047
1048         cursor_type = CURSOR_NORMAL;
1049         if(autocvar__hud_configure)
1050                 HUD_Panel_Mouse();
1051         else
1052         {
1053                 if (HUD_MinigameMenu_IsOpened())
1054                         HUD_Minigame_Mouse();
1055                 if (QuickMenu_IsOpened())
1056                         QuickMenu_Mouse();
1057                 if (HUD_Radar_Clickable())
1058                         HUD_Radar_Mouse();
1059         }
1060
1061         prevMouseClicked = mouseClicked;
1062
1063         HUD_Cursor_Show();
1064 }
1065
1066 void View_NightVision()
1067 {
1068         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1069                 return;
1070
1071         // apply night vision effect
1072         vector tc_00, tc_01, tc_10, tc_11;
1073         vector rgb = '0 0 0';
1074         float a;
1075
1076         if(!nightvision_noise)
1077         {
1078                 nightvision_noise = new(nightvision_noise);
1079         }
1080         if(!nightvision_noise2)
1081         {
1082                 nightvision_noise2 = new(nightvision_noise2);
1083         }
1084
1085         // color tint in yellow
1086         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1087
1088         // draw BG
1089         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1090         rgb = '1 1 1';
1091         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1092         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1093         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1094         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1095         tc_11 = tc_01 + tc_10 - tc_00;
1096         R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE, true);
1097         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1098         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1099         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1100         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1101         R_EndPolygon();
1102
1103         // draw FG
1104         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1105         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1106         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1107         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1108         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1109         tc_11 = tc_01 + tc_10 - tc_00;
1110         R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE, true);
1111         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1112         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1113         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1114         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1115         R_EndPolygon();
1116 }
1117
1118 // visual overlay while in liquids
1119 // provides some effects to the postprocessing function
1120 void HUD_Contents()
1121 {
1122         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1123                 return;
1124
1125         // improved polyblend
1126         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1127         vector liquidcolor;
1128
1129         switch(pointcontents(view_origin))
1130         {
1131                 case CONTENT_WATER:
1132                         liquidalpha = autocvar_hud_contents_water_alpha;
1133                         liquidcolor = stov(autocvar_hud_contents_water_color);
1134                         incontent = 1;
1135                         break;
1136
1137                 case CONTENT_LAVA:
1138                         liquidalpha = autocvar_hud_contents_lava_alpha;
1139                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1140                         incontent = 1;
1141                         break;
1142
1143                 case CONTENT_SLIME:
1144                         liquidalpha = autocvar_hud_contents_slime_alpha;
1145                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1146                         incontent = 1;
1147                         break;
1148
1149                 default:
1150                         liquidalpha = 0;
1151                         liquidcolor = '0 0 0';
1152                         incontent = 0;
1153                         break;
1154         }
1155
1156         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1157         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1158                 contentfadetime = autocvar_hud_contents_fadeintime;
1159                 liquidalpha_prev = liquidalpha;
1160                 liquidcolor_prev = liquidcolor;
1161         }
1162         else
1163                 contentfadetime = autocvar_hud_contents_fadeouttime;
1164
1165         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1166         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1167
1168         if(contentavgalpha)
1169                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1170
1171         if(autocvar_hud_postprocessing)
1172         {
1173                 if(autocvar_hud_contents_blur && contentavgalpha)
1174                 {
1175                         content_blurpostprocess.x = 1;
1176                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1177                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1178                 }
1179                 else
1180                 {
1181                         content_blurpostprocess.x = 0;
1182                         content_blurpostprocess.y = 0;
1183                         content_blurpostprocess.z = 0;
1184                 }
1185         }
1186 }
1187
1188 // visual pain effects on the screen
1189 // provides some effects to the postprocessing function
1190 void HUD_Damage()
1191 {
1192         if(!autocvar_hud_damage || STAT(FROZEN))
1193                 return;
1194
1195         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1196         splash_size.x = max(vid_conwidth, vid_conheight);
1197         splash_size.y = max(vid_conwidth, vid_conheight);
1198         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1199         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1200
1201         float myhealth_flash_temp;
1202         myhealth = STAT(HEALTH);
1203
1204         // fade out
1205         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1206         // add new damage
1207         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1208
1209         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1210         pain_threshold = autocvar_hud_damage_pain_threshold;
1211         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1212         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1213
1214         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1215         {
1216                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1217         }
1218
1219         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1220
1221         if(myhealth_prev < 1)
1222         {
1223                 if(myhealth >= 1)
1224                 {
1225                         myhealth_flash = 0; // just spawned, clear the flash immediately
1226                         myhealth_flash_temp = 0;
1227                 }
1228                 else
1229                 {
1230                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1231                 }
1232         }
1233
1234         if(spectatee_status == -1 || intermission)
1235         {
1236                 myhealth_flash = 0; // observing, or match ended
1237                 myhealth_flash_temp = 0;
1238         }
1239
1240         myhealth_prev = myhealth;
1241
1242         // IDEA: change damage color/picture based on player model for robot/alien species?
1243         // pro: matches model better
1244         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1245         // maybe different reddish pics?
1246         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1247         {
1248                 if(autocvar_cl_gentle_damage == 2)
1249                 {
1250                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1251                                 myhealth_gentlergb = randomvec();
1252                 }
1253                 else
1254                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1255
1256                 if(myhealth_flash_temp > 0)
1257                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1258         }
1259         else if(myhealth_flash_temp > 0)
1260                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1261
1262         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1263         {
1264                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1265                 {
1266                         damage_blurpostprocess.x = 1;
1267                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1268                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1269                 }
1270                 else
1271                 {
1272                         damage_blurpostprocess.x = 0;
1273                         damage_blurpostprocess.y = 0;
1274                         damage_blurpostprocess.z = 0;
1275                 }
1276         }
1277 }
1278
1279 void View_PostProcessing()
1280 {
1281         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1282         float e2 = (autocvar_hud_powerup != 0);
1283         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1284         {
1285                 // enable or disable rendering types if they are used or not
1286                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1287                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1288
1289                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1290                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1291                 {
1292                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1293                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1294                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1295                         {
1296                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1297                                 old_blurradius = blurradius;
1298                                 old_bluralpha = bluralpha;
1299                         }
1300                 }
1301                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1302                 {
1303                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1304                         old_blurradius = 0;
1305                         old_bluralpha = 0;
1306                 }
1307
1308                 // edge detection postprocess handling done second (used by hud_powerup)
1309                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
1310                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1311                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1312
1313                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1314
1315                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1316                 {
1317                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1318                         {
1319                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1320                                 old_sharpen_intensity = sharpen_intensity;
1321                         }
1322                 }
1323                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1324                 {
1325                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1326                         old_sharpen_intensity = 0;
1327                 }
1328
1329                 if(cvar("r_glsl_postprocess") == 0)
1330                         cvar_set("r_glsl_postprocess", "2");
1331         }
1332         else if(cvar("r_glsl_postprocess") == 2)
1333                 cvar_set("r_glsl_postprocess", "0");
1334 }
1335
1336 void View_Lock()
1337 {
1338         int lock_type = autocvar_cl_lockview;
1339
1340         if (!autocvar_hud_cursormode
1341                 && ((autocvar__hud_configure && spectatee_status <= 0)
1342                         || intermission > 1
1343                         || HUD_Radar_Clickable()
1344                         || HUD_MinigameMenu_IsOpened()
1345                         || QuickMenu_IsOpened()
1346                 )
1347         )
1348                 lock_type = 1;
1349
1350         // lock_type 1: lock origin and angles
1351         // lock_type 2: lock only origin
1352         if(lock_type >= 1)
1353                 setproperty(VF_ORIGIN, freeze_org);
1354         else
1355                 freeze_org = getpropertyvec(VF_ORIGIN);
1356         if(lock_type == 1)
1357                 setproperty(VF_ANGLES, freeze_ang);
1358         else
1359                 freeze_ang = getpropertyvec(VF_ANGLES);
1360 }
1361
1362 void View_DemoCamera()
1363 {
1364         if(camera_active) // Camera for demo playback
1365         {
1366                 if(autocvar_camera_enable)
1367                         CSQC_Demo_Camera();
1368                 else
1369                 {
1370                         cvar_set("chase_active", ftos(chase_active_backup));
1371                         cvar_set("cl_demo_mousegrab", "0");
1372                         camera_active = false;
1373                 }
1374         }
1375         else
1376         {
1377 #ifdef CAMERATEST
1378                 if(autocvar_camera_enable)
1379 #else
1380                 if(autocvar_camera_enable && isdemo())
1381 #endif
1382                 {
1383                         // Enable required Darkplaces cvars
1384                         chase_active_backup = autocvar_chase_active;
1385                         cvar_set("chase_active", "2");
1386                         cvar_set("cl_demo_mousegrab", "1");
1387                         camera_active = true;
1388                         camera_mode = false;
1389                 }
1390         }
1391 }
1392
1393 #ifdef BLURTEST
1394 void View_BlurTest()
1395 {
1396         if(time > blurtest_time0 && time < blurtest_time1)
1397         {
1398                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1399                 float r = t * blurtest_radius;
1400                 float f = 1 / (t ** blurtest_power) - 1;
1401
1402                 cvar_set("r_glsl_postprocess", "1");
1403                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1404         }
1405         else
1406         {
1407                 cvar_set("r_glsl_postprocess", "0");
1408                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1409         }
1410 }
1411 #endif
1412
1413 void View_CheckButtonStatus()
1414 {
1415         float is_dead = (STAT(HEALTH) <= 0);
1416
1417         // FIXME do we need this hack?
1418         if(isdemo())
1419         {
1420                 // in demos, input_buttons do not work
1421                 button_zoom = (autocvar__togglezoom == "-");
1422         }
1423         else if(button_zoom
1424                 && autocvar_cl_unpress_zoom_on_death
1425                 && (spectatee_status >= 0)
1426                 && (is_dead || intermission))
1427         {
1428                 // no zoom while dead or in intermission please
1429                 localcmd("-zoom\n");
1430                 button_zoom = false;
1431         }
1432
1433         if(autocvar_fov <= 59.5)
1434         {
1435                 if(!zoomscript_caught)
1436                 {
1437                         localcmd("+button9\n");
1438                         zoomscript_caught = 1;
1439                 }
1440         }
1441         else
1442         {
1443                 if(zoomscript_caught)
1444                 {
1445                         localcmd("-button9\n");
1446                         zoomscript_caught = 0;
1447                 }
1448         }
1449
1450         if(active_minigame && HUD_MinigameMenu_IsOpened())
1451         {
1452                 if(!minigame_wasactive)
1453                 {
1454                         localcmd("+button12\n");
1455                         minigame_wasactive = true;
1456                 }
1457         }
1458         else if(minigame_wasactive)
1459         {
1460                 localcmd("-button12\n");
1461                 minigame_wasactive = false;
1462         }
1463
1464         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1465         {
1466                 entity wepent = viewmodels[slot];
1467
1468                 if(wepent.last_switchweapon != wepent.switchweapon)
1469                 {
1470                         weapontime = time;
1471                         wepent.last_switchweapon = wepent.switchweapon;
1472                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1473                         {
1474                                 localcmd("-zoom\n");
1475                                 button_zoom = false;
1476                         }
1477                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1478                         {
1479                                 localcmd("-fire\n");
1480                                 localcmd("-fire2\n");
1481                                 button_attack2 = false;
1482                         }
1483                 }
1484                 if(wepent.last_activeweapon != wepent.activeweapon)
1485                 {
1486                         wepent.last_activeweapon = wepent.activeweapon;
1487
1488                         entity e = wepent.activeweapon;
1489                         if(e.netname != "")
1490                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1491                         else if(slot == 0)
1492                                 localcmd("\ncl_hook_activeweapon none\n");
1493                 }
1494         }
1495 }
1496
1497 bool ov_enabled;
1498 float oldr_nearclip;
1499 float oldr_farclip_base;
1500 float oldr_farclip_world;
1501 float oldr_novis;
1502 float oldr_useportalculling;
1503 float oldr_useinfinitefarclip;
1504 vector ov_org = '0 0 0';
1505 vector ov_mid = '0 0 0';
1506 vector ov_worldmin = '0 0 0';
1507 vector ov_worldmax = '0 0 0';
1508
1509 void View_Ortho()
1510 {
1511         ov_org = '0 0 0';
1512         ov_mid = '0 0 0';
1513         ov_worldmin = '0 0 0';
1514         ov_worldmax = '0 0 0';
1515         if(autocvar_cl_orthoview)
1516         {
1517                 ov_worldmin = mi_picmin;
1518                 ov_worldmax = mi_picmax;
1519
1520                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1521                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1522                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1523
1524                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1525                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1526
1527                 float ov_nearest = vlen(ov_org - vec3(
1528                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1529                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1530                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1531                 ));
1532
1533                 float ov_furthest = 0;
1534                 float dist = 0;
1535
1536                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1537                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1538                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1539                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1540                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1541                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1542                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1543                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1544
1545                 if(!ov_enabled)
1546                 {
1547                         oldr_nearclip = cvar("r_nearclip");
1548                         oldr_farclip_base = cvar("r_farclip_base");
1549                         oldr_farclip_world = cvar("r_farclip_world");
1550                         oldr_novis = cvar("r_novis");
1551                         oldr_useportalculling = cvar("r_useportalculling");
1552                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1553                 }
1554
1555                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1556                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1557                 cvar_settemp("r_farclip_world", "0");
1558                 cvar_settemp("r_novis", "1");
1559                 cvar_settemp("r_useportalculling", "0");
1560                 cvar_settemp("r_useinfinitefarclip", "0");
1561
1562                 setproperty(VF_ORIGIN, ov_org);
1563                 setproperty(VF_ANGLES, '90 0 0');
1564
1565                 ov_enabled = true;
1566
1567                 #if 0
1568                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1569                         vtos(ov_org),
1570                         vtos(getpropertyvec(VF_ANGLES)),
1571                         ov_distance,
1572                         ov_nearest,
1573                         ov_furthest);
1574                 #endif
1575         }
1576         else
1577         {
1578                 if(ov_enabled)
1579                 {
1580                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1581                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1582                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1583                         cvar_set("r_novis", ftos(oldr_novis));
1584                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1585                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1586                 }
1587                 ov_enabled = false;
1588         }
1589 }
1590
1591 void View_UpdateFov()
1592 {
1593         vector fov;
1594         if(autocvar_cl_orthoview)
1595                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
1596         else if(csqcplayer.viewloc)
1597                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
1598         else
1599                 fov = GetCurrentFov(autocvar_fov);
1600
1601         setproperty(VF_FOV, fov);
1602 }
1603
1604 void CSQC_UpdateView(entity this, float w, float h)
1605 {
1606         TC(int, w); TC(int, h);
1607
1608         execute_next_frame();
1609
1610         ++framecount;
1611
1612         stats_get();
1613         hud = STAT(HUD);
1614
1615         ReplicateVars(false);
1616         if (ReplicateVars_NOT_SENDING())
1617                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1618
1619         HUD_Scale_Disable();
1620
1621         if(autocvar__hud_showbinds_reload) // menu can set this one
1622         {
1623                 db_close(binddb);
1624                 binddb = db_create();
1625                 cvar_set("_hud_showbinds_reload", "0");
1626         }
1627
1628         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1629                 view_quality = getproperty(VF_MINFPS_QUALITY);
1630         else
1631                 view_quality = 1;
1632
1633         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1634         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1635
1636         vector vf_size = getpropertyvec(VF_SIZE);
1637         vector vf_min = getpropertyvec(VF_MIN);
1638         vid_width = vf_size.x;
1639         vid_height = vf_size.y;
1640
1641         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1642
1643         WaypointSprite_Load();
1644
1645         CSQCPlayer_SetCamera();
1646
1647         if(player_localentnum <= maxclients) // is it a client?
1648                 current_player = player_localentnum - 1;
1649         else // then player_localentnum is the vehicle I'm driving
1650                 current_player = player_localnum;
1651         myteam = entcs_GetTeam(current_player);
1652
1653         // abused multiple places below
1654         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1655         if(!local_player)
1656                 local_player = this; // fall back!
1657
1658         View_EventChase(local_player);
1659
1660         // do lockview after event chase camera so that it still applies whenever necessary.
1661         View_Lock();
1662
1663         WarpZone_FixView();
1664         //WarpZone_FixPMove();
1665
1666         View_Ortho();
1667
1668         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1669         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1670         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1671                 viewmodel_draw(viewmodels[slot]);
1672
1673         // Render the Scene
1674         view_origin = getpropertyvec(VF_ORIGIN);
1675         view_angles = getpropertyvec(VF_ANGLES);
1676         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1677
1678 #ifdef BLURTEST
1679         View_BlurTest();
1680 #endif
1681
1682         TargetMusic_Advance();
1683         Fog_Force();
1684         fpscounter_update();
1685
1686         if(drawtime == 0)
1687                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1688         else
1689                 drawframetime = bound(0.000001, time - drawtime, 1);
1690         drawtime = time;
1691
1692         // watch for gametype changes here...
1693         // in ParseStuffCMD the cmd isn't executed yet :/
1694         // might even be better to add the gametype to TE_CSQC_INIT...?
1695         if(!postinit)
1696                 PostInit();
1697
1698         if(intermission && !intermission_time)
1699                 intermission_time = time;
1700
1701         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1702         {
1703                 if(calledhooks & HOOK_START)
1704                 {
1705                         localcmd("\ncl_hook_gameend\n");
1706                         calledhooks |= HOOK_END;
1707                 }
1708         }
1709
1710         Announcer();
1711
1712         View_CheckButtonStatus();
1713
1714         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1715
1716         // ALWAYS Clear Current Scene First
1717         clearscene();
1718
1719         setproperty(VF_ORIGIN, view_origin);
1720         setproperty(VF_ANGLES, view_angles);
1721
1722         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1723         setproperty(VF_SIZE, vf_size);
1724         setproperty(VF_MIN, vf_min);
1725
1726         // Assign Standard Viewflags
1727         // Draw the World (and sky)
1728         setproperty(VF_DRAWWORLD, 1);
1729
1730         // Set the console size vars
1731         vid_conwidth = autocvar_vid_conwidth;
1732         vid_conheight = autocvar_vid_conheight;
1733         vid_pixelheight = autocvar_vid_pixelheight;
1734
1735         View_UpdateFov();
1736
1737         View_DemoCamera();
1738
1739         // Draw the Crosshair
1740         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1741
1742         // Draw the Engine Status Bar (the default Quake HUD)
1743         setproperty(VF_DRAWENGINESBAR, 0);
1744
1745         // Update the mouse position
1746         /*
1747            mousepos_x = vid_conwidth;
1748            mousepos_y = vid_conheight;
1749            mousepos = mousepos*0.5 + getmousepos();
1750          */
1751
1752         IL_EACH(g_drawables, it.draw, it.draw(it));
1753
1754         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
1755         renderscene();
1756
1757         // Now the the scene has been rendered, begin with the 2D drawing functions
1758
1759         View_NightVision();
1760         DrawReticle(local_player);
1761         HUD_Contents();
1762         HUD_Damage();
1763         View_PostProcessing();
1764
1765         // draw 2D entities
1766         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
1767         Draw_ShowNames_All();
1768 #if ENABLE_DEBUGDRAW
1769         Debug_Draw();
1770 #endif
1771
1772         scoreboard_active = Scoreboard_WouldDraw();
1773
1774         HUD_Draw(this); // this parameter for deep vehicle function
1775
1776         if(NextFrameCommand)
1777         {
1778                 localcmd("\n", NextFrameCommand, "\n");
1779                 NextFrameCommand = string_null;
1780         }
1781
1782         // we must do this check AFTER a frame was rendered, or it won't work
1783         if(cs_project_is_b0rked == 0)
1784         {
1785                 string w0, h0;
1786                 w0 = ftos(autocvar_vid_conwidth);
1787                 h0 = ftos(autocvar_vid_conheight);
1788                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1789                 //setproperty(VF_FOV, '90 90 0');
1790                 setproperty(VF_ORIGIN, '0 0 0');
1791                 setproperty(VF_ANGLES, '0 0 0');
1792                 setproperty(VF_PERSPECTIVE, 1);
1793                 vector forward, right, up;
1794                 MAKE_VECTORS('0 0 0', forward, right, up);
1795                 vector v1, v2;
1796                 cvar_set("vid_conwidth", "800");
1797                 cvar_set("vid_conheight", "600");
1798                 v1 = cs_project(forward);
1799                 cvar_set("vid_conwidth", "640");
1800                 cvar_set("vid_conheight", "480");
1801                 v2 = cs_project(forward);
1802                 if(v1 == v2)
1803                         cs_project_is_b0rked = 1;
1804                 else
1805                         cs_project_is_b0rked = -1;
1806                 cvar_set("vid_conwidth", w0);
1807                 cvar_set("vid_conheight", h0);
1808         }
1809
1810         HUD_Mouse(local_player);
1811
1812         cl_notice_run();
1813         unpause_update();
1814         Net_Flush();
1815
1816         // let's reset the view back to normal for the end
1817         setproperty(VF_MIN, '0 0 0');
1818         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1819
1820         IL_ENDFRAME();
1821 }
1822
1823
1824 // following vectors must be global to allow seamless switching between camera modes
1825 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1826 void CSQC_Demo_Camera()
1827 {
1828         float speed, attenuation, dimensions;
1829         vector tmp, delta;
1830
1831         if( autocvar_camera_reset || !camera_mode )
1832         {
1833                 camera_offset = '0 0 0';
1834                 current_angles = '0 0 0';
1835                 camera_direction = '0 0 0';
1836                 camera_offset.z += 30;
1837                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1838                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1839                 current_origin = view_origin;
1840                 current_camera_offset  = camera_offset;
1841                 cvar_set("camera_reset", "0");
1842                 camera_mode = CAMERA_CHASE;
1843         }
1844
1845         // Camera angles
1846         if( camera_roll )
1847                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1848
1849         if(autocvar_camera_look_player)
1850         {
1851                 vector dir;
1852                 float n;
1853
1854                 dir = normalize(view_origin - current_position);
1855                 n = mouse_angles.z;
1856                 mouse_angles = vectoangles(dir);
1857                 mouse_angles.x = mouse_angles.x * -1;
1858                 mouse_angles.z = n;
1859         }
1860         else
1861         {
1862                 tmp = getmousepos() * 0.1;
1863                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
1864                 {
1865                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1866                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1867                 }
1868         }
1869
1870         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1871         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1872         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1873         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1874
1875         // Fix difference when angles don't have the same sign
1876         delta = '0 0 0';
1877         if(mouse_angles.y < -60 && current_angles.y > 60)
1878                 delta = '0 360 0';
1879         if(mouse_angles.y > 60 && current_angles.y < -60)
1880                 delta = '0 -360 0';
1881
1882         if(autocvar_camera_look_player)
1883                 attenuation = autocvar_camera_look_attenuation;
1884         else
1885                 attenuation = autocvar_camera_speed_attenuation;
1886
1887         attenuation = 1 / max(1, attenuation);
1888         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1889
1890         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1891         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1892         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1893         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1894
1895         // Camera position
1896         tmp = '0 0 0';
1897         dimensions = 0;
1898
1899         if( camera_direction.x )
1900         {
1901                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1902                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1903                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1904                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1905                 ++dimensions;
1906         }
1907
1908         if( camera_direction.y )
1909         {
1910                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1911                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1912                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1913                 ++dimensions;
1914         }
1915
1916         if( camera_direction.z )
1917         {
1918                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1919                 ++dimensions;
1920         }
1921
1922         if(autocvar_camera_free)
1923                 speed = autocvar_camera_speed_free;
1924         else
1925                 speed = autocvar_camera_speed_chase;
1926
1927         if(dimensions)
1928         {
1929                 speed = speed * sqrt(1 / dimensions);
1930                 camera_offset += tmp * speed;
1931         }
1932
1933         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1934
1935         // Camera modes
1936         if( autocvar_camera_free )
1937         {
1938                 if ( camera_mode == CAMERA_CHASE )
1939                 {
1940                         current_camera_offset = current_origin + current_camera_offset;
1941                         camera_offset = current_origin + camera_offset;
1942                 }
1943
1944                 camera_mode = CAMERA_FREE;
1945                 current_position = current_camera_offset;
1946         }
1947         else
1948         {
1949                 if ( camera_mode == CAMERA_FREE )
1950                 {
1951                         current_origin = view_origin;
1952                         camera_offset = camera_offset - current_origin;
1953                         current_camera_offset = current_camera_offset - current_origin;
1954                 }
1955
1956                 camera_mode = CAMERA_CHASE;
1957
1958                 if(autocvar_camera_chase_smoothly)
1959                         current_origin += (view_origin - current_origin) * attenuation;
1960                 else
1961                         current_origin = view_origin;
1962
1963                 current_position = current_origin + current_camera_offset;
1964         }
1965
1966         setproperty(VF_ANGLES, current_angles);
1967         setproperty(VF_ORIGIN, current_position);
1968 }