qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward, right, up;
 137                 MAKE_VECTORS(view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward, right, up;
 163                 MAKE_VECTORS(view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         bool invehicle = player_localentnum > maxclients;
 295         if (invehicle) a = -1;
 296         Weapon wep = this.activeweapon;
 297         int c = entcs_GetClientColors(current_player);
 298         vector g = weaponentity_glowmod(wep, NULL, c, this);
 299         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 300         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 301                 | EF_NODEPTHTEST)
 302                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 303         for (entity e = this; e; e = e.weaponchild)
 304         {
 305                 e.drawmask = mask;
 306                 e.alpha = a;
 307                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 308                 e.glowmod = g;
 309                 e.csqcmodel_effects = fx;
 310                 CSQCModel_Effects_Apply(e);
 311         }
 312         if(a >= 0)
 313         {
 314                 string name = wep.mdl;
 315                 string newname = wep.wr_viewmodel(wep, this);
 316                 if(newname)
 317                         name = newname;
 318                 bool swap = name != this.name_last;
 319                 // if (swap)
 320                 {
 321                         this.name_last = name;
 322                         CL_WeaponEntity_SetModel(this, name, swap);
 323                         this.viewmodel_origin = this.origin;
 324                         this.viewmodel_angles = this.angles;
 325                 }
 326                 anim_update(this);
 327                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 328                         anim_set(this, this.anim_idle, true, false, false);
 329         }
 330         float f = 0; // 0..1; 0: fully active
 331         float rate = STAT(WEAPONRATEFACTOR);
 332         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 333         if (eta <= 0) f = this.weapon_eta_last;
 334         else switch (this.state)
 335         {
 336                 case WS_RAISE:
 337                 {
 338                         f = eta / max(eta, this.weapon_switchdelay);
 339                         break;
 340                 }
 341                 case WS_DROP:
 342                 {
 343                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 344                         break;
 345                 }
 346                 case WS_CLEAR:
 347                 {
 348                         f = 1;
 349                         break;
 350                 }
 351         }
 352         this.weapon_eta_last = f;
 353         this.origin = this.viewmodel_origin;
 354         this.angles = this.viewmodel_angles;
 355         this.angles_x = (-90 * f * f);
 356         viewmodel_animate(this);
 357         MUTATOR_CALLHOOK(DrawViewModel, this);
 358         setorigin(this, this.origin);
 359 }
 360
 361 STATIC_INIT(viewmodel) {
 362     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 363         viewmodels[slot] = new(viewmodel);
 364 }
 365
 366 float showfps_prevfps;
 367 float showfps_prevfps_time;
 368 int showfps_framecounter;
 369
 370 void fpscounter_update()
 371 {
 372         if(!STAT(SHOWFPS))
 373                 return;
 374
 375         float currentTime = gettime(GETTIME_REALTIME);
 376         showfps_framecounter += 1;
 377         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 378         {
 379                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 380                 showfps_framecounter = 0;
 381                 showfps_prevfps_time = currentTime;
 382
 383                 int channel = MSG_C2S;
 384                 WriteHeader(channel, fpsreport);
 385                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 386         }
 387 }
 388
 389 STATIC_INIT(fpscounter_init)
 390 {
 391         float currentTime = gettime(GETTIME_REALTIME);
 392         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 393 }
 394
 395 STATIC_INIT(Porto)
 396 {
 397         entity e = new_pure(porto);
 398         e.draw = Porto_Draw;
 399         IL_PUSH(g_drawables, e);
 400         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 401 }
 402
 403 const int polyline_length = 16;
 404 .vector polyline[polyline_length];
 405 void Porto_Draw(entity this)
 406 {
 407         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 408         {
 409                 entity wepent = viewmodels[slot];
 410
 411                 if (wepent.activeweapon != WEP_PORTO) continue;
 412                 if (spectatee_status) continue;
 413                 if (WEP_CVAR(porto, secondary)) continue;
 414                 if (intermission == 1) continue;
 415                 if (intermission == 2) continue;
 416                 if (STAT(HEALTH) <= 0) continue;
 417
 418                 vector pos = view_origin;
 419                 vector dir = view_forward;
 420                 vector forward, right, up;
 421                 MAKE_VECTORS(autocvar_chase_active ? warpzone_save_view_angles : view_angles, forward, right, up);
 422                 pos += right * -wepent.movedir.y
 423                         +  up * wepent.movedir.z;
 424
 425                 if (wepent.angles_held_status)
 426                 {
 427                         MAKE_VECTORS(wepent.angles_held, forward, right, up);
 428                         dir = forward;
 429                 }
 430
 431                 wepent.polyline[0] = pos;
 432
 433                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 434                 int n = 1 + 2;  // 2 lines == 3 points
 435                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 436                 {
 437                         traceline(pos, pos + 65536 * dir, true, this);
 438                         dir = reflect(dir, trace_plane_normal);
 439                         pos = trace_endpos;
 440                         wepent.polyline[++idx] = pos;
 441                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 442                         {
 443                                 n += 1;
 444                                 continue;
 445                         }
 446                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 447                         {
 448                                 n = max(2, idx);
 449                                 break;
 450                         }
 451                         // check size
 452                         {
 453                                 vector ang = vectoangles2(trace_plane_normal, dir);
 454                                 ang.x = -ang.x;
 455                                 MAKE_VECTORS(ang, forward, right, up);
 456                                 if (!CheckWireframeBox(this, pos - 48 * right - 48 * up + 16 * forward, 96 * right, 96 * up, 96 * forward))
 457                                 {
 458                                         n = max(2, idx);
 459                                         break;
 460                                 }
 461                         }
 462                         portal_number += 1;
 463                         if (portal_number >= portal_max) break;
 464                         if (portal_number == 1) portal1_idx = idx;
 465                 }
 466                 for (int idx = 0; idx < n - 1; ++idx)
 467                 {
 468                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 469                         if (idx == 0) p -= view_up * 16;  // line from player
 470                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 471                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 472                 }
 473         }
 474 }
 475
 476 float drawtime;
 477 float avgspeed;
 478 vector GetCurrentFov(float fov)
 479 {
 480         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 481         float velocityzoom, curspeed;
 482         vector v;
 483
 484         zoomsensitivity = autocvar_cl_zoomsensitivity;
 485         zoomfactor = autocvar_cl_zoomfactor;
 486         if(zoomfactor < 1 || zoomfactor > 30)
 487                 zoomfactor = 2.5;
 488         zoomspeed = autocvar_cl_zoomspeed;
 489         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 490                 zoomspeed = 3.5;
 491
 492         zoomdir = button_zoom;
 493
 494         if(hud == HUD_NORMAL && !spectatee_status)
 495         {
 496                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 497                 {
 498                         entity wepent = viewmodels[slot];
 499                         if(wepent.switchweapon != wepent.activeweapon)
 500                                 continue;
 501                         Weapon wep = wepent.activeweapon;
 502                         if(wep != WEP_Null && wep.wr_zoomdir)
 503                         {
 504                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 505                                 zoomdir += do_zoom;
 506                         }
 507                 }
 508         }
 509         if(spectatee_status > 0 || isdemo())
 510         {
 511                 if(spectatorbutton_zoom)
 512                 {
 513                         if(zoomdir)
 514                                 zoomdir = 0;
 515                         else
 516                                 zoomdir = 1;
 517                 }
 518                 // fteqcc failed twice here already, don't optimize this
 519         }
 520
 521         if(zoomdir) { zoomin_effect = 0; }
 522
 523         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 524         {
 525                 current_viewzoom = 1;
 526         }
 527         else if (camera_active)
 528         {
 529                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 530         }
 531         else if(autocvar_cl_spawnzoom && zoomin_effect)
 532         {
 533                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 534
 535                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 536                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 537                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 538         }
 539         else
 540         {
 541                 if(zoomspeed < 0) // instant zoom
 542                 {
 543                         if(zoomdir)
 544                                 current_viewzoom = 1 / zoomfactor;
 545                         else
 546                                 current_viewzoom = 1;
 547                 }
 548                 else
 549                 {
 550                         if(zoomdir)
 551                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 552                         else
 553                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 554                 }
 555         }
 556
 557         if(almost_equals(current_viewzoom, 1))
 558                 current_zoomfraction = 0;
 559         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 560                 current_zoomfraction = 1;
 561         else
 562                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 563
 564         if(zoomsensitivity < 1)
 565                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 566         else
 567                 setsensitivityscale(1);
 568
 569         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 570         {
 571                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 572                         curspeed = 0;
 573                 else
 574                 {
 575                         vector forward, right, up;
 576                         MAKE_VECTORS(view_angles, forward, right, up);
 577                         v = pmove_vel;
 578                         if(csqcplayer)
 579                                 v = csqcplayer.velocity;
 580
 581                         switch(autocvar_cl_velocityzoom_type)
 582                         {
 583                                 case 3: curspeed = max(0, forward * v); break;
 584                                 case 2: curspeed = (forward * v); break;
 585                                 case 1: default: curspeed = vlen(v); break;
 586                         }
 587                 }
 588
 589                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 590                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 591                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 592
 593                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 594         }
 595         else
 596                 velocityzoom = 1;
 597
 598         float frustumx, frustumy, fovx, fovy;
 599         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 600         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 601         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 602         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 603
 604         return '1 0 0' * fovx + '0 1 0' * fovy;
 605 }
 606
 607 vector GetViewLocationFOV(float fov)
 608 {
 609         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 610         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 611         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 612         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 613         return '1 0 0' * fovx + '0 1 0' * fovy;
 614 }
 615
 616 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 617 {
 618         float fovx, fovy;
 619         float width = (ov_worldmax.x - ov_worldmin.x);
 620         float height = (ov_worldmax.y - ov_worldmin.y);
 621         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 622         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 623         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 624         return '1 0 0' * fovx + '0 1 0' * fovy;
 625 }
 626
 627 // this function must match W_SetupShot!
 628 float zoomscript_caught;
 629
 630 bool minigame_wasactive;
 631
 632 vector wcross_origin;
 633 float wcross_scale_prev, wcross_alpha_prev;
 634 vector wcross_color_prev;
 635 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 636 vector wcross_color_goal_prev;
 637 float wcross_changedonetime;
 638
 639 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 640 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 641 float wcross_name_changestarttime, wcross_name_changedonetime;
 642 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 643
 644 float wcross_ring_prev;
 645
 646 entity trueaim;
 647 entity trueaim_rifle;
 648
 649 const float SHOTTYPE_HITTEAM = 1;
 650 const float SHOTTYPE_HITOBSTRUCTION = 2;
 651 const float SHOTTYPE_HITWORLD = 3;
 652 const float SHOTTYPE_HITENEMY = 4;
 653
 654 void TrueAim_Init()
 655 {
 656         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 657         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 658 }
 659
 660 float EnemyHitCheck()
 661 {
 662         float t, n;
 663         wcross_origin = project_3d_to_2d(trace_endpos);
 664         wcross_origin.z = 0;
 665         if(trace_ent)
 666                 n = trace_ent.entnum;
 667         else
 668                 n = trace_networkentity;
 669         if(n < 1)
 670                 return SHOTTYPE_HITWORLD;
 671         if(n > maxclients)
 672                 return SHOTTYPE_HITWORLD;
 673         t = entcs_GetTeam(n - 1);
 674         if(teamplay)
 675                 if(t == myteam)
 676                         return SHOTTYPE_HITTEAM;
 677         if(t == NUM_SPECTATOR)
 678                 return SHOTTYPE_HITWORLD;
 679         return SHOTTYPE_HITENEMY;
 680 }
 681
 682 float TrueAimCheck(entity wepent)
 683 {
 684         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 685         vector vecs, trueaimpoint, w_shotorg;
 686         vector mi, ma, dv;
 687         float shottype;
 688         entity ta;
 689         float mv;
 690
 691         mi = ma = '0 0 0';
 692         ta = trueaim;
 693         mv = MOVE_NOMONSTERS;
 694
 695         switch(wepent.activeweapon) // WEAPONTODO
 696         {
 697                 case WEP_TUBA: // no aim
 698                 case WEP_PORTO: // shoots from eye
 699                 case WEP_NEXBALL: // shoots from eye
 700                 case WEP_HOOK: // no trueaim
 701                 case WEP_MORTAR: // toss curve
 702                         return SHOTTYPE_HITWORLD;
 703                 case WEP_VORTEX:
 704                 case WEP_OVERKILL_NEX:
 705                 case WEP_VAPORIZER:
 706                         mv = MOVE_NORMAL;
 707                         break;
 708                 case WEP_RIFLE:
 709                         ta = trueaim_rifle;
 710                         mv = MOVE_NORMAL;
 711                         if(zoomscript_caught)
 712                         {
 713                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 714                                 return EnemyHitCheck();
 715                         }
 716                         break;
 717                 case WEP_DEVASTATOR: // projectile has a size!
 718                         mi = '-3 -3 -3';
 719                         ma = '3 3 3';
 720                         break;
 721                 case WEP_FIREBALL: // projectile has a size!
 722                         mi = '-16 -16 -16';
 723                         ma = '16 16 16';
 724                         break;
 725                 case WEP_SEEKER: // projectile has a size!
 726                         mi = '-2 -2 -2';
 727                         ma = '2 2 2';
 728                         break;
 729                 case WEP_ELECTRO: // projectile has a size!
 730                         mi = '0 0 -3';
 731                         ma = '0 0 -3';
 732                         break;
 733         }
 734
 735         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 736
 737         vecs = decompressShotOrigin(STAT(SHOTORG));
 738
 739         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 740         trueaimpoint = trace_endpos;
 741
 742         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 743                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 744
 745         if(vecs.x > 0)
 746                 vecs.y = -vecs.y;
 747         else
 748                 vecs = '0 0 0';
 749
 750         dv = view_right * vecs.y + view_up * vecs.z;
 751         w_shotorg = traceorigin + dv;
 752
 753         // now move the vecs forward as much as requested if possible
 754         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 755         w_shotorg = trace_endpos - view_forward * nudge;
 756
 757         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 758         shottype = EnemyHitCheck();
 759         if(shottype != SHOTTYPE_HITWORLD)
 760                 return shottype;
 761
 762 #if 0
 763         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 764         // or rather, I know why, but see no fix
 765         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 766                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 767                 return SHOTTYPE_HITOBSTRUCTION;
 768 #endif
 769
 770         return SHOTTYPE_HITWORLD;
 771 }
 772
 773 float camera_mode;
 774 const float CAMERA_FREE = 1;
 775 const float CAMERA_CHASE = 2;
 776 float reticle_type;
 777 string NextFrameCommand;
 778
 779 vector freeze_org, freeze_ang;
 780 entity nightvision_noise, nightvision_noise2;
 781
 782 const float MAX_TIME_DIFF = 5;
 783 float pickup_crosshair_time, pickup_crosshair_size;
 784 float hitindication_crosshair_size;
 785 float use_vortex_chargepool;
 786
 787 float myhealth, myhealth_prev;
 788 float myhealth_flash;
 789
 790 float old_blurradius, old_bluralpha;
 791 float old_sharpen_intensity;
 792
 793 vector myhealth_gentlergb;
 794
 795 float contentavgalpha, liquidalpha_prev;
 796 vector liquidcolor_prev;
 797
 798 float eventchase_current_distance;
 799 float eventchase_running;
 800 int WantEventchase(entity this)
 801 {
 802         if(autocvar_cl_orthoview)
 803                 return 0;
 804         if(STAT(GAME_STOPPED) || intermission)
 805                 return 1;
 806         if(this.viewloc)
 807                 return 1;
 808         if(spectatee_status >= 0)
 809         {
 810                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 811                         return 1;
 812                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 813                         return 1;
 814                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 815                         return 1;
 816                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 817                 {
 818                         if(autocvar_cl_eventchase_death == 2)
 819                         {
 820                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 821                                 if(this.velocity == '0 0 0' || eventchase_running)
 822                                         return 1;
 823                         }
 824                         else return 1;
 825                 }
 826                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 827                 {
 828                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 829                                 return 1;
 830                         else if (eventchase_running)
 831                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 832                 }
 833         }
 834         return 0;
 835 }
 836
 837 void HUD_Crosshair_Vehicle(entity this)
 838 {
 839         if(hud != HUD_BUMBLEBEE_GUN)
 840         {
 841                 Vehicle info = Vehicles_from(hud);
 842                 info.vr_crosshair(info, this);
 843         }
 844 }
 845
 846 vector damage_blurpostprocess, content_blurpostprocess;
 847
 848 float unaccounted_damage = 0;
 849 void UpdateDamage()
 850 {
 851         // accumulate damage with each stat update
 852         static float damage_total_prev = 0;
 853         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 854         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 855         damage_total_prev = damage_total;
 856
 857         static float damage_dealt_time_prev = 0;
 858         float damage_dealt_time = STAT(HIT_TIME);
 859         if (damage_dealt_time != damage_dealt_time_prev)
 860         {
 861                 unaccounted_damage += unaccounted_damage_new;
 862                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 863         }
 864         damage_dealt_time_prev = damage_dealt_time;
 865
 866         // prevent hitsound when switching spectatee
 867         static float spectatee_status_prev = 0;
 868         if (spectatee_status != spectatee_status_prev)
 869                 unaccounted_damage = 0;
 870         spectatee_status_prev = spectatee_status;
 871 }
 872
 873 void HitSound()
 874 {
 875         // varying sound pitch
 876
 877         bool have_arc = false;
 878         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 879         {
 880                 entity wepent = viewmodels[slot];
 881
 882                 if(wepent.activeweapon == WEP_ARC)
 883                         have_arc = true;
 884         }
 885
 886         static float hitsound_time_prev = 0;
 887         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 888         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 889         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 890         {
 891                 if (autocvar_cl_hitsound && unaccounted_damage)
 892                 {
 893                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 894                         float a = autocvar_cl_hitsound_max_pitch;
 895                         float b = autocvar_cl_hitsound_min_pitch;
 896                         float c = autocvar_cl_hitsound_nom_damage;
 897                         float d = unaccounted_damage;
 898                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 899
 900                         // if sound variation is disabled, set pitch_shift to 1
 901                         if (autocvar_cl_hitsound == 1)
 902                                 pitch_shift = 1;
 903
 904                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 905                         if (autocvar_cl_hitsound == 3)
 906                         {
 907                                 float mirror_value = (a-b)/2 + b;
 908                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 909                         }
 910
 911                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 912
 913                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 914                         // todo: normalize sound pressure levels? seems unnecessary
 915
 916                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 917                 }
 918                 unaccounted_damage = 0;
 919                 hitsound_time_prev = time;
 920         }
 921
 922         static float typehit_time_prev = 0;
 923         float typehit_time = STAT(TYPEHIT_TIME);
 924         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 925         {
 926                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 927                 typehit_time_prev = typehit_time;
 928         }
 929
 930         static float kill_time_prev = 0;
 931         float kill_time = STAT(KILL_TIME);
 932         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 933         {
 934                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 935                 kill_time_prev = kill_time;
 936         }
 937 }
 938
 939 vector crosshair_getcolor(entity this, float health_stat)
 940 {
 941         static float rainbow_last_flicker;
 942         static vector rainbow_prev_color;
 943         vector wcross_color = '0 0 0';
 944         switch(autocvar_crosshair_color_special)
 945         {
 946                 case 1: // crosshair_color_per_weapon
 947                 {
 948                         if(this != WEP_Null && hud == HUD_NORMAL)
 949                         {
 950                                 wcross_color = this.wpcolor;
 951                                 break;
 952                         }
 953                         else { goto normalcolor; }
 954                 }
 955
 956                 case 2: // crosshair_color_by_health
 957                 {
 958                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 959                         float hp = floor(v.x + 1);
 960
 961                         //x = red
 962                         //y = green
 963                         //z = blue
 964
 965                         wcross_color.z = 0;
 966
 967                         if(hp > 200)
 968                         {
 969                                 wcross_color.x = 0;
 970                                 wcross_color.y = 1;
 971                         }
 972                         else if(hp > 150)
 973                         {
 974                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 975                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 976                         }
 977                         else if(hp > 100)
 978                         {
 979                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 980                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 981                                 wcross_color.z = 1 - (hp-100)*0.02;
 982                         }
 983                         else if(hp > 50)
 984                         {
 985                                 wcross_color.x = 1;
 986                                 wcross_color.y = 1;
 987                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 988                         }
 989                         else if(hp > 20)
 990                         {
 991                                 wcross_color.x = 1;
 992                                 wcross_color.y = (hp-20)*90/27/100;
 993                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 994                         }
 995                         else
 996                         {
 997                                 wcross_color.x = 1;
 998                                 wcross_color.y = 0;
 999                         }
1000                         break;
1001                 }
1002
1003                 case 3: // crosshair_color_rainbow
1004                 {
1005                         if(time >= rainbow_last_flicker)
1006                         {
1007                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1008                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1009                         }
1010                         wcross_color = rainbow_prev_color;
1011                         break;
1012                 }
1013 LABEL(normalcolor)
1014                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1015         }
1016
1017         return wcross_color;
1018 }
1019
1020 void HUD_Crosshair(entity this)
1021 {
1022         float f, i, j;
1023         vector v;
1024         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1025                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1026                 !HUD_MinigameMenu_IsOpened() )
1027         {
1028                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1029                         return;
1030
1031                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1032                         return;
1033
1034                 if (hud != HUD_NORMAL)
1035                 {
1036                         HUD_Crosshair_Vehicle(this);
1037                         return;
1038                 }
1039
1040                 string wcross_style;
1041                 float wcross_alpha, wcross_resolution;
1042                 wcross_style = autocvar_crosshair;
1043                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1044                         wcross_style = autocvar_crosshair_2d;
1045                 if (wcross_style == "0")
1046                         return;
1047                 wcross_resolution = autocvar_crosshair_size;
1048                 if (wcross_resolution == 0)
1049                         return;
1050                 wcross_alpha = autocvar_crosshair_alpha;
1051                 if (wcross_alpha == 0)
1052                         return;
1053
1054                 // TrueAim check
1055                 float shottype;
1056
1057                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1058                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1059                         wcross_origin = viewloc_mousepos;
1060                 else
1061                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1062                 wcross_origin.z = 0;
1063                 if(autocvar_crosshair_hittest)
1064                 {
1065                         vector wcross_oldorigin;
1066                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1067                         wcross_oldorigin = wcross_origin;
1068                         shottype = TrueAimCheck(thiswep);
1069                         if(shottype == SHOTTYPE_HITWORLD)
1070                         {
1071                                 v = wcross_origin - wcross_oldorigin;
1072                                 v.x /= vid_conwidth;
1073                                 v.y /= vid_conheight;
1074                                 if(vdist(v, >, 0.01))
1075                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1076                         }
1077                         if(!autocvar_crosshair_hittest_showimpact)
1078                                 wcross_origin = wcross_oldorigin;
1079                 }
1080                 else
1081                         shottype = SHOTTYPE_HITWORLD;
1082
1083                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1084                 string wcross_name = "";
1085                 float wcross_scale, wcross_blur;
1086
1087         entity e = WEP_Null;
1088                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1089                 {
1090                         entity wepent = viewmodels[0]; // TODO: unhardcode
1091                         e = wepent.switchingweapon;
1092                         if(e)
1093                         {
1094                                 if(autocvar_crosshair_per_weapon)
1095                                 {
1096                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1097                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1098                                         //if (wcross_resolution == 0)
1099                                                 //return;
1100
1101                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1102                                         wcross_resolution *= e.w_crosshair_size;
1103                                         wcross_name = e.w_crosshair;
1104                                 }
1105                         }
1106                 }
1107
1108                 if(wcross_name == "")
1109                         wcross_name = strcat("gfx/crosshair", wcross_style);
1110
1111                 // MAIN CROSSHAIR COLOR DECISION
1112                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1113
1114                 if(autocvar_crosshair_effect_scalefade)
1115                 {
1116                         wcross_scale = wcross_resolution;
1117                         wcross_resolution = 1;
1118                 }
1119                 else
1120                 {
1121                         wcross_scale = 1;
1122                 }
1123
1124                 if(autocvar_crosshair_pickup)
1125                 {
1126                         float stat_pickup_time = STAT(LAST_PICKUP);
1127
1128                         if(pickup_crosshair_time < stat_pickup_time)
1129                         {
1130                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1131                                         pickup_crosshair_size = 1;
1132
1133                                 pickup_crosshair_time = stat_pickup_time;
1134                         }
1135
1136                         if(pickup_crosshair_size > 0)
1137                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1138                         else
1139                                 pickup_crosshair_size = 0;
1140
1141                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1142                 }
1143
1144                 // todo: make crosshair hit indication dependent on damage dealt
1145                 if(autocvar_crosshair_hitindication)
1146                 {
1147                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1148
1149                         if(unaccounted_damage)
1150                         {
1151                                 hitindication_crosshair_size = 1;
1152                         }
1153
1154                         if(hitindication_crosshair_size > 0)
1155                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1156                         else
1157                                 hitindication_crosshair_size = 0;
1158
1159                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1160                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1161                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1162                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1163                 }
1164
1165                 if(shottype == SHOTTYPE_HITENEMY)
1166                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1167                 if(shottype == SHOTTYPE_HITTEAM)
1168                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1169
1170                 f = fabs(autocvar_crosshair_effect_time);
1171                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1172                 {
1173                         wcross_changedonetime = time + f;
1174                 }
1175                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1176                 {
1177                         wcross_name_changestarttime = time;
1178                         wcross_name_changedonetime = time + f;
1179                         if(wcross_name_goal_prev_prev)
1180                                 strunzone(wcross_name_goal_prev_prev);
1181                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1182                         wcross_name_goal_prev = strzone(wcross_name);
1183                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1184                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1185                         wcross_resolution_goal_prev = wcross_resolution;
1186                 }
1187
1188                 wcross_scale_goal_prev = wcross_scale;
1189                 wcross_alpha_goal_prev = wcross_alpha;
1190                 wcross_color_goal_prev = wcross_color;
1191
1192                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1193                 {
1194                         wcross_blur = 1;
1195                         wcross_alpha *= 0.75;
1196                 }
1197                 else
1198                         wcross_blur = 0;
1199                 // *_prev is at time-frametime
1200                 // * is at wcross_changedonetime+f
1201                 // what do we have at time?
1202                 if(time < wcross_changedonetime)
1203                 {
1204                         f = frametime / (wcross_changedonetime - time + frametime);
1205                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1206                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1207                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1208                 }
1209
1210                 wcross_scale_prev = wcross_scale;
1211                 wcross_alpha_prev = wcross_alpha;
1212                 wcross_color_prev = wcross_color;
1213
1214                 MUTATOR_CALLHOOK(UpdateCrosshair);
1215
1216                 wcross_scale *= 1 - autocvar__menu_alpha;
1217                 wcross_alpha *= 1 - autocvar__menu_alpha;
1218                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1219
1220                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1221                 {
1222                         // crosshair rings for weapon stats
1223                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1224                         {
1225                                 // declarations and stats
1226                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1227                                 string ring_image = string_null, ring_inner_image = string_null;
1228                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1229
1230                                 ring_scale = autocvar_crosshair_ring_size;
1231
1232                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1233
1234                                 int weapon_clipload = wepent.clip_load;
1235                                 int weapon_clipsize = wepent.clip_size;
1236
1237                                 float arc_heat = wepent.arc_heat_percent;
1238                                 float vcharge = wepent.vortex_charge;
1239                                 float vchargepool = wepent.vortex_chargepool_ammo;
1240                                 float oknex_charge_ = wepent.oknex_charge;
1241                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1242
1243                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1244                                         vortex_charge_movingavg = vcharge;
1245
1246                                 // handle the values
1247                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1248                                 {
1249                                         if (vchargepool || use_vortex_chargepool) {
1250                                                 use_vortex_chargepool = 1;
1251                                                 ring_inner_value = vchargepool;
1252                                         } else {
1253                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1254                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1255                                         }
1256
1257                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1258                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1259                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1260
1261                                         // draw the outer ring to show the current charge of the weapon
1262                                         ring_value = vcharge;
1263                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1264                                         ring_rgb = wcross_color;
1265                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1266                                 }
1267                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1268                                 {
1269                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1270                                                 use_vortex_chargepool = 1;
1271                                                 ring_inner_value = oknex_chargepool_;
1272                                         } else {
1273                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1274                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1275                                         }
1276
1277                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1278                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1279                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1280
1281                                         // draw the outer ring to show the current charge of the weapon
1282                                         ring_value = oknex_charge_;
1283                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1284                                         ring_rgb = wcross_color;
1285                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1286                                 }
1287                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1288                                 {
1289                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1290                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1291                                         ring_rgb = wcross_color;
1292                                         ring_image = "gfx/crosshair_ring.tga";
1293                                 }
1294                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1295                                 {
1296                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1297                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1298                                         ring_rgb = wcross_color;
1299                                         ring_image = "gfx/crosshair_ring.tga";
1300                                 }
1301                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1302                                 {
1303                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1304                                         ring_scale = autocvar_crosshair_ring_reload_size;
1305                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1306                                         ring_rgb = wcross_color;
1307
1308                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1309                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1310                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1311                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1312                                         else
1313                                                 ring_image = "gfx/crosshair_ring.tga";
1314                                 }
1315                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1316                                 {
1317                                         ring_value = arc_heat;
1318                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1319                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1320                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1321                                         ring_image = "gfx/crosshair_ring.tga";
1322                                 }
1323
1324                                 // if in weapon switch animation, fade ring out/in
1325                                 if(autocvar_crosshair_effect_time > 0)
1326                                 {
1327                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1328                                         if (f >= 1)
1329                                         {
1330                                                 wcross_ring_prev = ((ring_image) ? true : false);
1331                                         }
1332
1333                                         if(wcross_ring_prev)
1334                                         {
1335                                                 if(f < 1)
1336                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1337                                         }
1338                                         else
1339                                         {
1340                                                 if(f < 1)
1341                                                         ring_alpha *= bound(0, f, 1);
1342                                         }
1343                                 }
1344
1345                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1346                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1347
1348                                 if (ring_value)
1349                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1350                         }
1351
1352 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1353                         MACRO_BEGIN \
1354                                 vector scaled_sz = sz * wcross_size; \
1355                                 if(wcross_blur > 0) \
1356                                 { \
1357                                         for(i = -2; i <= 2; ++i) \
1358                                         for(j = -2; j <= 2; ++j) \
1359                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1360                                 } \
1361                                 else \
1362                                 { \
1363                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1364                                 } \
1365                         MACRO_END
1366
1367 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1368                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1369
1370 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1371                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1372
1373                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1374                         {
1375                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1376                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1377                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1378                                 f = 1 - f;
1379                         }
1380                         else
1381                         {
1382                                 f = 1;
1383                         }
1384                         wcross_name_alpha_goal_prev = f;
1385
1386                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1387                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1388
1389                         if(autocvar_crosshair_dot)
1390                         {
1391                                 vector wcross_color_old;
1392                                 wcross_color_old = wcross_color;
1393
1394                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1395                                         wcross_color = stov(autocvar_crosshair_dot_color);
1396
1397                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1398                                 // FIXME why don't we use wcross_alpha here?
1399                                 wcross_color = wcross_color_old;
1400                         }
1401                 }
1402         }
1403         else
1404         {
1405                 wcross_scale_prev = 0;
1406                 wcross_alpha_prev = 0;
1407                 wcross_scale_goal_prev = 0;
1408                 wcross_alpha_goal_prev = 0;
1409                 wcross_changedonetime = 0;
1410                 strfree(wcross_name_goal_prev);
1411                 strfree(wcross_name_goal_prev_prev);
1412                 wcross_name_changestarttime = 0;
1413                 wcross_name_changedonetime = 0;
1414                 wcross_name_alpha_goal_prev = 0;
1415                 wcross_name_alpha_goal_prev_prev = 0;
1416                 wcross_resolution_goal_prev = 0;
1417                 wcross_resolution_goal_prev_prev = 0;
1418         }
1419 }
1420
1421 const int MAX_SPECIALCOMMAND = 15;
1422 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1423 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1424 const float SPECIALCOMMAND_SPEED = 150;
1425 const float SPECIALCOMMAND_TURNSPEED = 2;
1426 const float SPECIALCOMMAND_SIZE = 0.025;
1427 const float SPECIALCOMMAND_CHANCE = 0.35;
1428 float sc_spawntime, sc_changetime;
1429 vector sc_color = '1 1 1';
1430 void SpecialCommand()
1431 {
1432         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1433                 return;
1434
1435         if(time >= sc_changetime)
1436         {
1437                 sc_changetime = time + 1;
1438                 sc_color = randomvec() * 1.5;
1439                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1440                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1441                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1442         }
1443         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1444
1445         if(!precache_pic("gfx/smile"))
1446                 return; // damn party poopers
1447
1448         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1449         {
1450                 vector slot = specialcommand_slots[j];
1451                 if(slot.y)
1452                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1453                 //if(slot.z)
1454                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1455                 if(slot.y >= vid_conheight)
1456                         slot = '0 0 0';
1457
1458                 if(slot == '0 0 0')
1459                 {
1460                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1461                         {
1462                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1463                                 slot.y = 1; // start it off 0 so we can use it
1464                                 slot.z = floor(random() * Weapons_MAX);
1465                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1466                                 vector newcolor = randomvec() * 2;
1467                                 newcolor.x = bound(0.4, newcolor.x, 1);
1468                                 newcolor.y = bound(0.4, newcolor.y, 1);
1469                                 newcolor.z = bound(0.4, newcolor.z, 1);
1470                                 specialcommand_colors[j] = newcolor;
1471                         }
1472                 }
1473                 else
1474                 {
1475                         vector splash_size = '0 0 0';
1476                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1477                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1478                         entity wep = Weapons_from(slot.z);
1479                         if(wep == WEP_Null)
1480                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1481                         else
1482                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1483                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1484                 }
1485
1486                 specialcommand_slots[j] = slot;
1487         }
1488 }
1489
1490 void HUD_Draw(entity this)
1491 {
1492         // if we don't know gametype and scores yet avoid drawing the scoreboard
1493         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1494         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1495         // cl_deathscoreboard would show the scoreboard and so on
1496         if(!gametype)
1497                 return;
1498
1499         Hud_Dynamic_Frame();
1500
1501         if(!intermission)
1502         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1503         {
1504                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1505         }
1506         else if(STAT(FROZEN))
1507         {
1508                 vector col = '0.25 0.90 1';
1509                 if(STAT(REVIVE_PROGRESS))
1510                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1511                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1512         }
1513
1514         HUD_Scale_Enable();
1515         if(!intermission)
1516         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1517         {
1518                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1519                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1520                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1521         }
1522         else if(STAT(CAPTURE_PROGRESS))
1523         {
1524                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1525                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1526         }
1527         else if(STAT(REVIVE_PROGRESS))
1528         {
1529                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1530                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1531         }
1532         HUD_Scale_Disable();
1533
1534         if(autocvar_r_letterbox == 0)
1535                 if(autocvar_viewsize < 120)
1536                 {
1537                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1538                                 Accuracy_LoadLevels();
1539
1540                         HUD_Main();
1541                         HUD_Scale_Disable();
1542                 }
1543
1544         // crosshair goes VERY LAST
1545         SpecialCommand();
1546         UpdateDamage();
1547         HUD_Crosshair(this);
1548         HitSound();
1549 }
1550
1551 void ViewLocation_Mouse()
1552 {
1553         if(spectatee_status)
1554                 return; // don't draw it as spectator!
1555
1556         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1557         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1558         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1559
1560         //float cursor_alpha = 1 - autocvar__menu_alpha;
1561         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1562 }
1563
1564 void HUD_Cursor_Show()
1565 {
1566         float cursor_alpha = 1 - autocvar__menu_alpha;
1567         if(cursor_type == CURSOR_NORMAL)
1568                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1569         else if(cursor_type == CURSOR_MOVE)
1570                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1571         else if(cursor_type == CURSOR_RESIZE)
1572                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1573         else if(cursor_type == CURSOR_RESIZE2)
1574                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1575 }
1576
1577 void HUD_Mouse(entity player)
1578 {
1579         if(autocvar__menu_alpha == 1)
1580                 return;
1581
1582         if(!cursor_active)
1583         {
1584                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1585                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1586                 return;
1587         }
1588
1589         if (cursor_active == -1) // starting to display the cursor
1590         {
1591                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1592                 // in the first frame mousepos is the mouse position of the last time
1593                 // the cursor was displayed, thus we ignore it to avoid a glictch
1594                 cursor_active = 1;
1595                 return;
1596         }
1597
1598         if(!autocvar_hud_cursormode)
1599                 update_mousepos();
1600
1601         if(autocvar__hud_configure)
1602                 HUD_Panel_Mouse();
1603         else
1604         {
1605                 if (HUD_MinigameMenu_IsOpened())
1606                         HUD_Minigame_Mouse();
1607                 if (QuickMenu_IsOpened())
1608                         QuickMenu_Mouse();
1609                 if (HUD_Radar_Clickable())
1610                         HUD_Radar_Mouse();
1611         }
1612
1613         prevMouseClicked = mouseClicked;
1614
1615         HUD_Cursor_Show();
1616 }
1617
1618 bool ov_enabled;
1619 float oldr_nearclip;
1620 float oldr_farclip_base;
1621 float oldr_farclip_world;
1622 float oldr_novis;
1623 float oldr_useportalculling;
1624 float oldr_useinfinitefarclip;
1625
1626 float prev_myteam;
1627 int lasthud;
1628 float vh_notice_time;
1629 void CSQC_UpdateView(entity this, float w, float h)
1630 {
1631         TC(int, w); TC(int, h);
1632         entity e;
1633         float fov;
1634         float f;
1635         vector vf_size, vf_min;
1636         float a;
1637
1638         execute_next_frame();
1639
1640         ++framecount;
1641
1642         stats_get();
1643         hud = STAT(HUD);
1644
1645         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1646                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1647
1648         lasthud = hud;
1649
1650         HUD_Scale_Disable();
1651
1652         if(autocvar__hud_showbinds_reload) // menu can set this one
1653         {
1654                 db_close(binddb);
1655                 binddb = db_create();
1656                 cvar_set("_hud_showbinds_reload", "0");
1657         }
1658
1659         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1660                 view_quality = getproperty(VF_MINFPS_QUALITY);
1661         else
1662                 view_quality = 1;
1663
1664         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1665         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1666
1667         vf_size = getpropertyvec(VF_SIZE);
1668         vf_min = getpropertyvec(VF_MIN);
1669         vid_width = vf_size.x;
1670         vid_height = vf_size.y;
1671
1672         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1673         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1674
1675         WaypointSprite_Load();
1676
1677         CSQCPlayer_SetCamera();
1678
1679         if(player_localentnum <= maxclients) // is it a client?
1680                 current_player = player_localentnum - 1;
1681         else // then player_localentnum is the vehicle I'm driving
1682                 current_player = player_localnum;
1683         myteam = entcs_GetTeam(current_player);
1684
1685         if(myteam != prev_myteam)
1686         {
1687                 myteamcolors = colormapPaletteColor(myteam, 1);
1688                 FOREACH(hud_panels, true, it.update_time = time);
1689                 prev_myteam = myteam;
1690         }
1691
1692         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1693
1694         float is_dead = (STAT(HEALTH) <= 0);
1695
1696         // FIXME do we need this hack?
1697         if(isdemo())
1698         {
1699                 // in demos, input_buttons do not work
1700                 button_zoom = (autocvar__togglezoom == "-");
1701         }
1702         else if(button_zoom
1703                 && autocvar_cl_unpress_zoom_on_death
1704                 && (spectatee_status >= 0)
1705                 && (is_dead || intermission))
1706         {
1707                 // no zoom while dead or in intermission please
1708                 localcmd("-zoom\n");
1709                 button_zoom = false;
1710         }
1711
1712         // abused multiple places below
1713         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1714         if(!local_player)
1715                 local_player = this; // fall back!
1716
1717         // event chase camera
1718         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1719         {
1720                 if(STAT(CAMERA_SPECTATOR))
1721                 {
1722                         if(spectatee_status > 0)
1723                         {
1724                                 if(!autocvar_chase_active)
1725                                 {
1726                                         cvar_set("chase_active", "-2");
1727                                         goto skip_eventchase_death;
1728                                 }
1729                         }
1730                         else if(autocvar_chase_active == -2)
1731                                 cvar_set("chase_active", "0");
1732
1733                         if(autocvar_chase_active == -2)
1734                                 goto skip_eventchase_death;
1735                 }
1736                 else if(autocvar_chase_active == -2)
1737                         cvar_set("chase_active", "0");
1738
1739                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1740
1741                 float vehicle_viewdist = 0;
1742                 vector vehicle_viewofs = '0 0 0';
1743
1744                 if(vehicle_chase)
1745                 {
1746                         if(hud != HUD_BUMBLEBEE_GUN)
1747                         {
1748                                 Vehicle info = Vehicles_from(hud);
1749                                 vehicle_viewdist = info.height;
1750                                 vehicle_viewofs = info.view_ofs;
1751                         }
1752                 }
1753
1754                 int eventchase = WantEventchase(this);
1755                 if (eventchase)
1756                 {
1757                         vector current_view_origin_override = '0 0 0';
1758                         vector view_offset_override = '0 0 0';
1759                         float chase_distance_override = 0;
1760                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1761                         if(custom_eventchase)
1762                         {
1763                                 current_view_origin_override = M_ARGV(0, vector);
1764                                 view_offset_override = M_ARGV(1, vector);
1765                                 chase_distance_override = M_ARGV(0, float);
1766                         }
1767                         eventchase_running = true;
1768
1769                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1770                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1771                         if (custom_eventchase)
1772                                 current_view_origin = current_view_origin_override;
1773
1774                         // detect maximum viewoffset and use it
1775                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1776                         if(vehicle_chase)
1777                         {
1778                                 if(vehicle_viewofs)
1779                                         view_offset = vehicle_viewofs;
1780                                 else
1781                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1782                         }
1783                         if (custom_eventchase)
1784                                 view_offset = view_offset_override;
1785
1786                         if(view_offset)
1787                         {
1788                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1789                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1790                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1791                         }
1792
1793                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1794                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1795                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1796                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1797
1798                         // make the camera smooth back
1799                         float chase_distance = autocvar_cl_eventchase_distance;
1800                         if(vehicle_chase)
1801                         {
1802                                 if(vehicle_viewofs)
1803                                         chase_distance = vehicle_viewdist;
1804                                 else
1805                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1806                         }
1807                         if (custom_eventchase)
1808                                 chase_distance = chase_distance_override;
1809
1810                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1811                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1812                         else if(eventchase_current_distance != chase_distance)
1813                                 eventchase_current_distance = chase_distance;
1814
1815                         vector forward, right, up;
1816                         MAKE_VECTORS(view_angles, forward, right, up);
1817
1818                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1819                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1820
1821                         // If the boxtrace fails, revert back to line tracing.
1822                         if(!local_player.viewloc)
1823                         if(trace_startsolid)
1824                         {
1825                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1826                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1827                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
1828                         }
1829                         else { setproperty(VF_ORIGIN, trace_endpos); }
1830
1831                         if(!local_player.viewloc)
1832                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1833                 }
1834
1835                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1836                 {
1837                         eventchase_running = false;
1838                         cvar_set("chase_active", "0");
1839                         eventchase_current_distance = 0; // start from 0 next time
1840                 }
1841         }
1842         // workaround for camera stuck between player's legs when using chase_active 1
1843         // because the engine stops updating the chase_active camera when the game ends
1844         else if(intermission)
1845         {
1846                 cvar_settemp("chase_active", "-1");
1847                 eventchase_current_distance = 0;
1848         }
1849
1850         LABEL(skip_eventchase_death);
1851
1852         // do lockview after event chase camera so that it still applies whenever necessary.
1853         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1854         {
1855                 setproperty(VF_ORIGIN, freeze_org);
1856                 setproperty(VF_ANGLES, freeze_ang);
1857         }
1858         else
1859         {
1860                 freeze_org = getpropertyvec(VF_ORIGIN);
1861                 freeze_ang = getpropertyvec(VF_ANGLES);
1862         }
1863
1864         WarpZone_FixView();
1865         //WarpZone_FixPMove();
1866
1867         vector ov_org = '0 0 0';
1868         vector ov_mid = '0 0 0';
1869         vector ov_worldmin = '0 0 0';
1870         vector ov_worldmax = '0 0 0';
1871         if(autocvar_cl_orthoview)
1872         {
1873                 ov_worldmin = mi_picmin;
1874                 ov_worldmax = mi_picmax;
1875
1876                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1877                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1878                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1879
1880                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1881                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1882
1883                 float ov_nearest = vlen(ov_org - vec3(
1884                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1885                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1886                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1887                 ));
1888
1889                 float ov_furthest = 0;
1890                 float dist = 0;
1891
1892                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1893                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1894                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1895                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1896                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1897                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1898                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1899                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1900
1901                 if(!ov_enabled)
1902                 {
1903                         oldr_nearclip = cvar("r_nearclip");
1904                         oldr_farclip_base = cvar("r_farclip_base");
1905                         oldr_farclip_world = cvar("r_farclip_world");
1906                         oldr_novis = cvar("r_novis");
1907                         oldr_useportalculling = cvar("r_useportalculling");
1908                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1909                 }
1910
1911                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1912                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1913                 cvar_settemp("r_farclip_world", "0");
1914                 cvar_settemp("r_novis", "1");
1915                 cvar_settemp("r_useportalculling", "0");
1916                 cvar_settemp("r_useinfinitefarclip", "0");
1917
1918                 setproperty(VF_ORIGIN, ov_org);
1919                 setproperty(VF_ANGLES, '90 0 0');
1920
1921                 ov_enabled = true;
1922
1923                 #if 0
1924                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1925                         vtos(ov_org),
1926                         vtos(getpropertyvec(VF_ANGLES)),
1927                         ov_distance,
1928                         ov_nearest,
1929                         ov_furthest);
1930                 #endif
1931         }
1932         else
1933         {
1934                 if(ov_enabled)
1935                 {
1936                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1937                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1938                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1939                         cvar_set("r_novis", ftos(oldr_novis));
1940                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1941                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1942                 }
1943                 ov_enabled = false;
1944         }
1945
1946         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1947         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1948         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1949                 viewmodel_draw(viewmodels[slot]);
1950
1951         // Render the Scene
1952         view_origin = getpropertyvec(VF_ORIGIN);
1953         view_angles = getpropertyvec(VF_ANGLES);
1954         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1955
1956 #ifdef BLURTEST
1957         if(time > blurtest_time0 && time < blurtest_time1)
1958         {
1959                 float r, t;
1960
1961                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1962                 r = t * blurtest_radius;
1963                 f = 1 / (t ** blurtest_power) - 1;
1964
1965                 cvar_set("r_glsl_postprocess", "1");
1966                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1967         }
1968         else
1969         {
1970                 cvar_set("r_glsl_postprocess", "0");
1971                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1972         }
1973 #endif
1974
1975         TargetMusic_Advance();
1976         Fog_Force();
1977         fpscounter_update();
1978
1979         if(drawtime == 0)
1980                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1981         else
1982                 drawframetime = bound(0.000001, time - drawtime, 1);
1983         drawtime = time;
1984
1985         // watch for gametype changes here...
1986         // in ParseStuffCMD the cmd isn't executed yet :/
1987         // might even be better to add the gametype to TE_CSQC_INIT...?
1988         if(!postinit)
1989                 PostInit();
1990
1991         if(intermission && !intermission_time)
1992                 intermission_time = time;
1993
1994         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1995         {
1996                 if(calledhooks & HOOK_START)
1997                 {
1998                         localcmd("\ncl_hook_gameend\n");
1999                         calledhooks |= HOOK_END;
2000                 }
2001         }
2002
2003         Announcer();
2004
2005         fov = autocvar_fov;
2006         if(fov <= 59.5)
2007         {
2008                 if(!zoomscript_caught)
2009                 {
2010                         localcmd("+button9\n");
2011                         zoomscript_caught = 1;
2012                 }
2013         }
2014         else
2015         {
2016                 if(zoomscript_caught)
2017                 {
2018                         localcmd("-button9\n");
2019                         zoomscript_caught = 0;
2020                 }
2021         }
2022
2023         if(active_minigame && HUD_MinigameMenu_IsOpened())
2024         {
2025                 if(!minigame_wasactive)
2026                 {
2027                         localcmd("+button12\n");
2028                         minigame_wasactive = true;
2029                 }
2030         }
2031         else if(minigame_wasactive)
2032         {
2033                 localcmd("-button12\n");
2034                 minigame_wasactive = false;
2035         }
2036
2037         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2038
2039         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2040         {
2041                 entity wepent = viewmodels[slot];
2042
2043                 if(wepent.last_switchweapon != wepent.switchweapon)
2044                 {
2045                         weapontime = time;
2046                         wepent.last_switchweapon = wepent.switchweapon;
2047                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2048                         {
2049                                 localcmd("-zoom\n");
2050                                 button_zoom = false;
2051                         }
2052                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2053                         {
2054                                 localcmd("-fire\n");
2055                                 localcmd("-fire2\n");
2056                                 button_attack2 = false;
2057                         }
2058                 }
2059                 if(wepent.last_activeweapon != wepent.activeweapon)
2060                 {
2061                         wepent.last_activeweapon = wepent.activeweapon;
2062
2063                         e = wepent.activeweapon;
2064                         if(e.netname != "")
2065                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2066                         else if(slot == 0)
2067                                 localcmd("\ncl_hook_activeweapon none\n");
2068                 }
2069         }
2070
2071         // ALWAYS Clear Current Scene First
2072         clearscene();
2073
2074         setproperty(VF_ORIGIN, view_origin);
2075         setproperty(VF_ANGLES, view_angles);
2076
2077         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2078         setproperty(VF_SIZE, vf_size);
2079         setproperty(VF_MIN, vf_min);
2080
2081         // Assign Standard Viewflags
2082         // Draw the World (and sky)
2083         setproperty(VF_DRAWWORLD, 1);
2084
2085         // Set the console size vars
2086         vid_conwidth = autocvar_vid_conwidth;
2087         vid_conheight = autocvar_vid_conheight;
2088         vid_pixelheight = autocvar_vid_pixelheight;
2089
2090         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2091         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2092         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2093
2094         if(camera_active) // Camera for demo playback
2095         {
2096                 if(autocvar_camera_enable)
2097                         CSQC_Demo_Camera();
2098                 else
2099                 {
2100                         cvar_set("chase_active", ftos(chase_active_backup));
2101                         cvar_set("cl_demo_mousegrab", "0");
2102                         camera_active = false;
2103                 }
2104         }
2105         else
2106         {
2107 #ifdef CAMERATEST
2108                 if(autocvar_camera_enable)
2109 #else
2110                 if(autocvar_camera_enable && isdemo())
2111 #endif
2112                 {
2113                         // Enable required Darkplaces cvars
2114                         chase_active_backup = autocvar_chase_active;
2115                         cvar_set("chase_active", "2");
2116                         cvar_set("cl_demo_mousegrab", "1");
2117                         camera_active = true;
2118                         camera_mode = false;
2119                 }
2120         }
2121
2122         // Draw the Crosshair
2123         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2124
2125         // Draw the Engine Status Bar (the default Quake HUD)
2126         setproperty(VF_DRAWENGINESBAR, 0);
2127
2128         // Update the mouse position
2129         /*
2130            mousepos_x = vid_conwidth;
2131            mousepos_y = vid_conheight;
2132            mousepos = mousepos*0.5 + getmousepos();
2133          */
2134
2135         IL_EACH(g_drawables, it.draw, it.draw(it));
2136
2137         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2138         renderscene();
2139
2140         // now switch to 2D drawing mode by calling a 2D drawing function
2141         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2142         // next R_RenderScene call
2143         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2144
2145         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2146         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2147         {
2148                 // apply night vision effect
2149                 vector tc_00, tc_01, tc_10, tc_11;
2150                 vector rgb = '0 0 0';
2151
2152                 if(!nightvision_noise)
2153                 {
2154                         nightvision_noise = new(nightvision_noise);
2155                 }
2156                 if(!nightvision_noise2)
2157                 {
2158                         nightvision_noise2 = new(nightvision_noise2);
2159                 }
2160
2161                 // color tint in yellow
2162                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2163
2164                 // draw BG
2165                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2166                 rgb = '1 1 1';
2167                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2168                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2169                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2170                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2171                 tc_11 = tc_01 + tc_10 - tc_00;
2172                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2173                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2174                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2175                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2176                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2177                 R_EndPolygon();
2178
2179                 // draw FG
2180                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2181                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2182                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2183                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2184                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2185                 tc_11 = tc_01 + tc_10 - tc_00;
2186                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2187                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2188                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2189                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2190                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2191                 R_EndPolygon();
2192         }
2193
2194         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2195         {
2196                 string reticle_image = string_null;
2197                 bool wep_zoomed = false;
2198                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2199                 {
2200                         entity wepe = viewmodels[slot];
2201                         Weapon wep = wepe.activeweapon;
2202                         if(wep != WEP_Null && wep.wr_zoom)
2203                         {
2204                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2205                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2206                                         reticle_image = wep.w_reticle;
2207                                 wep_zoomed += do_zoom;
2208                         }
2209                 }
2210                 // Draw the aiming reticle for weapons that use it
2211                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2212                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2213                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2214                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2215                 {
2216                         // no zoom reticle while dead
2217                         reticle_type = 0;
2218                 }
2219                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2220                 {
2221                         if(reticle_image) { reticle_type = 2; }
2222                         else { reticle_type = 0; }
2223                 }
2224                 else if(button_zoom || zoomscript_caught)
2225                 {
2226                         // normal zoom
2227                         reticle_type = 1;
2228                 }
2229
2230                 if(reticle_type)
2231                 {
2232                         if(autocvar_cl_reticle_stretch)
2233                         {
2234                                 reticle_size.x = vid_conwidth;
2235                                 reticle_size.y = vid_conheight;
2236                                 reticle_pos.x = 0;
2237                                 reticle_pos.y = 0;
2238                         }
2239                         else
2240                         {
2241                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2242                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2243                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2244                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2245                         }
2246
2247                         if(zoomscript_caught)
2248                                 f = 1;
2249                         else
2250                                 f = current_zoomfraction;
2251
2252                         if(f)
2253                         {
2254                                 switch(reticle_type)
2255                                 {
2256                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2257                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2258                                 }
2259                         }
2260                 }
2261         }
2262         else
2263         {
2264                 if(reticle_type != 0) { reticle_type = 0; }
2265         }
2266
2267
2268         // improved polyblend
2269         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2270         {
2271                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2272                 vector liquidcolor;
2273
2274                 switch(pointcontents(view_origin))
2275                 {
2276                         case CONTENT_WATER:
2277                                 liquidalpha = autocvar_hud_contents_water_alpha;
2278                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2279                                 incontent = 1;
2280                                 break;
2281
2282                         case CONTENT_LAVA:
2283                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2284                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2285                                 incontent = 1;
2286                                 break;
2287
2288                         case CONTENT_SLIME:
2289                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2290                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2291                                 incontent = 1;
2292                                 break;
2293
2294                         default:
2295                                 liquidalpha = 0;
2296                                 liquidcolor = '0 0 0';
2297                                 incontent = 0;
2298                                 break;
2299                 }
2300
2301                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2302                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2303                         contentfadetime = autocvar_hud_contents_fadeintime;
2304                         liquidalpha_prev = liquidalpha;
2305                         liquidcolor_prev = liquidcolor;
2306                 }
2307                 else
2308                         contentfadetime = autocvar_hud_contents_fadeouttime;
2309
2310                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2311                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2312
2313                 if(contentavgalpha)
2314                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2315
2316                 if(autocvar_hud_postprocessing)
2317                 {
2318                         if(autocvar_hud_contents_blur && contentavgalpha)
2319                         {
2320                                 content_blurpostprocess.x = 1;
2321                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2322                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2323                         }
2324                         else
2325                         {
2326                                 content_blurpostprocess.x = 0;
2327                                 content_blurpostprocess.y = 0;
2328                                 content_blurpostprocess.z = 0;
2329                         }
2330                 }
2331         }
2332
2333         if(autocvar_hud_damage && !STAT(FROZEN))
2334         {
2335                 splash_size.x = max(vid_conwidth, vid_conheight);
2336                 splash_size.y = max(vid_conwidth, vid_conheight);
2337                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2338                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2339
2340                 float myhealth_flash_temp;
2341                 myhealth = STAT(HEALTH);
2342
2343                 // fade out
2344                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2345                 // add new damage
2346                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2347
2348                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2349                 pain_threshold = autocvar_hud_damage_pain_threshold;
2350                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2351                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2352
2353                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2354                 {
2355                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2356                 }
2357
2358                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2359
2360                 if(myhealth_prev < 1)
2361                 {
2362                         if(myhealth >= 1)
2363                         {
2364                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2365                                 myhealth_flash_temp = 0;
2366                         }
2367                         else
2368                         {
2369                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2370                         }
2371                 }
2372
2373                 if(spectatee_status == -1 || intermission)
2374                 {
2375                         myhealth_flash = 0; // observing, or match ended
2376                         myhealth_flash_temp = 0;
2377                 }
2378
2379                 myhealth_prev = myhealth;
2380
2381                 // IDEA: change damage color/picture based on player model for robot/alien species?
2382                 // pro: matches model better
2383                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2384                 // maybe different reddish pics?
2385                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2386                 {
2387                         if(autocvar_cl_gentle_damage == 2)
2388                         {
2389                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2390                                         myhealth_gentlergb = randomvec();
2391                         }
2392                         else
2393                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2394
2395                         if(myhealth_flash_temp > 0)
2396                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2397                 }
2398                 else if(myhealth_flash_temp > 0)
2399                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2400
2401                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2402                 {
2403                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2404                         {
2405                                 damage_blurpostprocess.x = 1;
2406                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2407                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2408                         }
2409                         else
2410                         {
2411                                 damage_blurpostprocess.x = 0;
2412                                 damage_blurpostprocess.y = 0;
2413                                 damage_blurpostprocess.z = 0;
2414                         }
2415                 }
2416         }
2417
2418         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2419         float e2 = (autocvar_hud_powerup != 0);
2420         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2421         {
2422                 // enable or disable rendering types if they are used or not
2423                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2424                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2425
2426                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2427                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2428                 {
2429                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2430                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2431                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2432                         {
2433                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2434                                 old_blurradius = blurradius;
2435                                 old_bluralpha = bluralpha;
2436                         }
2437                 }
2438                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2439                 {
2440                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2441                         old_blurradius = 0;
2442                         old_bluralpha = 0;
2443                 }
2444
2445                 // edge detection postprocess handling done second (used by hud_powerup)
2446                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2447                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2448                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2449
2450                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2451
2452                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2453                 {
2454                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2455                         {
2456                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2457                                 old_sharpen_intensity = sharpen_intensity;
2458                         }
2459                 }
2460                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2461                 {
2462                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2463                         old_sharpen_intensity = 0;
2464                 }
2465
2466                 if(cvar("r_glsl_postprocess") == 0)
2467                         cvar_set("r_glsl_postprocess", "2");
2468         }
2469         else if(cvar("r_glsl_postprocess") == 2)
2470                 cvar_set("r_glsl_postprocess", "0");
2471
2472         /*if(ISGAMETYPE(CTF))
2473           {
2474           ctf_view();
2475           } else */
2476
2477         // draw 2D entities
2478         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2479         Draw_ShowNames_All();
2480 #if ENABLE_DEBUGDRAW
2481         Debug_Draw();
2482 #endif
2483
2484         scoreboard_active = Scoreboard_WouldDraw();
2485
2486         HUD_Draw(this); // this parameter for deep vehicle function
2487
2488         if(NextFrameCommand)
2489         {
2490                 localcmd("\n", NextFrameCommand, "\n");
2491                 NextFrameCommand = string_null;
2492         }
2493
2494         // we must do this check AFTER a frame was rendered, or it won't work
2495         if(cs_project_is_b0rked == 0)
2496         {
2497                 string w0, h0;
2498                 w0 = ftos(autocvar_vid_conwidth);
2499                 h0 = ftos(autocvar_vid_conheight);
2500                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2501                 //setproperty(VF_FOV, '90 90 0');
2502                 setproperty(VF_ORIGIN, '0 0 0');
2503                 setproperty(VF_ANGLES, '0 0 0');
2504                 setproperty(VF_PERSPECTIVE, 1);
2505                 vector forward, right, up;
2506                 MAKE_VECTORS('0 0 0', forward, right, up);
2507                 vector v1, v2;
2508                 cvar_set("vid_conwidth", "800");
2509                 cvar_set("vid_conheight", "600");
2510                 v1 = cs_project(forward);
2511                 cvar_set("vid_conwidth", "640");
2512                 cvar_set("vid_conheight", "480");
2513                 v2 = cs_project(forward);
2514                 if(v1 == v2)
2515                         cs_project_is_b0rked = 1;
2516                 else
2517                         cs_project_is_b0rked = -1;
2518                 cvar_set("vid_conwidth", w0);
2519                 cvar_set("vid_conheight", h0);
2520         }
2521
2522         HUD_Mouse(local_player);
2523
2524         cl_notice_run();
2525         unpause_update();
2526         Net_Flush();
2527
2528         // let's reset the view back to normal for the end
2529         setproperty(VF_MIN, '0 0 0');
2530         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2531
2532         IL_ENDFRAME();
2533 }
2534
2535
2536 // following vectors must be global to allow seamless switching between camera modes
2537 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2538 void CSQC_Demo_Camera()
2539 {
2540         float speed, attenuation, dimensions;
2541         vector tmp, delta;
2542
2543         if( autocvar_camera_reset || !camera_mode )
2544         {
2545                 camera_offset = '0 0 0';
2546                 current_angles = '0 0 0';
2547                 camera_direction = '0 0 0';
2548                 camera_offset.z += 30;
2549                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2550                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2551                 current_origin = view_origin;
2552                 current_camera_offset  = camera_offset;
2553                 cvar_set("camera_reset", "0");
2554                 camera_mode = CAMERA_CHASE;
2555         }
2556
2557         // Camera angles
2558         if( camera_roll )
2559                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2560
2561         if(autocvar_camera_look_player)
2562         {
2563                 vector dir;
2564                 float n;
2565
2566                 dir = normalize(view_origin - current_position);
2567                 n = mouse_angles.z;
2568                 mouse_angles = vectoangles(dir);
2569                 mouse_angles.x = mouse_angles.x * -1;
2570                 mouse_angles.z = n;
2571         }
2572         else
2573         {
2574                 tmp = getmousepos() * 0.1;
2575                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2576                 {
2577                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2578                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2579                 }
2580         }
2581
2582         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2583         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2584         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2585         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2586
2587         // Fix difference when angles don't have the same sign
2588         delta = '0 0 0';
2589         if(mouse_angles.y < -60 && current_angles.y > 60)
2590                 delta = '0 360 0';
2591         if(mouse_angles.y > 60 && current_angles.y < -60)
2592                 delta = '0 -360 0';
2593
2594         if(autocvar_camera_look_player)
2595                 attenuation = autocvar_camera_look_attenuation;
2596         else
2597                 attenuation = autocvar_camera_speed_attenuation;
2598
2599         attenuation = 1 / max(1, attenuation);
2600         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2601
2602         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2603         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2604         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2605         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2606
2607         // Camera position
2608         tmp = '0 0 0';
2609         dimensions = 0;
2610
2611         if( camera_direction.x )
2612         {
2613                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2614                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2615                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2616                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2617                 ++dimensions;
2618         }
2619
2620         if( camera_direction.y )
2621         {
2622                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2623                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2624                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2625                 ++dimensions;
2626         }
2627
2628         if( camera_direction.z )
2629         {
2630                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2631                 ++dimensions;
2632         }
2633
2634         if(autocvar_camera_free)
2635                 speed = autocvar_camera_speed_free;
2636         else
2637                 speed = autocvar_camera_speed_chase;
2638
2639         if(dimensions)
2640         {
2641                 speed = speed * sqrt(1 / dimensions);
2642                 camera_offset += tmp * speed;
2643         }
2644
2645         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2646
2647         // Camera modes
2648         if( autocvar_camera_free )
2649         {
2650                 if ( camera_mode == CAMERA_CHASE )
2651                 {
2652                         current_camera_offset = current_origin + current_camera_offset;
2653                         camera_offset = current_origin + camera_offset;
2654                 }
2655
2656                 camera_mode = CAMERA_FREE;
2657                 current_position = current_camera_offset;
2658         }
2659         else
2660         {
2661                 if ( camera_mode == CAMERA_FREE )
2662                 {
2663                         current_origin = view_origin;
2664                         camera_offset = camera_offset - current_origin;
2665                         current_camera_offset = current_camera_offset - current_origin;
2666                 }
2667
2668                 camera_mode = CAMERA_CHASE;
2669
2670                 if(autocvar_camera_chase_smoothly)
2671                         current_origin += (view_origin - current_origin) * attenuation;
2672                 else
2673                         current_origin = view_origin;
2674
2675                 current_position = current_origin + current_camera_offset;
2676         }
2677
2678         setproperty(VF_ANGLES, current_angles);
2679         setproperty(VF_ORIGIN, current_position);
2680 }