qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, written by Samual
   3 //  Last updated: February 19th, 2012
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 // used by curl command
  21 void Curl_URI_Get_Callback(float id, float status, string data)
  22 {
  23         float i;
  24         float do_exec;
  25         string do_cvar;
  26         i = id - URI_GET_CURL;
  27         do_exec = curl_uri_get_exec[i];
  28         do_cvar = curl_uri_get_cvar[i];
  29         if(status != 0)
  30         {
  31                 dprintf("error: status is %d\n", status);
  32                 if(do_cvar)
  33                         strunzone(do_cvar);
  34                 return;
  35         }
  36         if(do_exec)
  37                 localcmd(data);
  38         if(do_cvar)
  39         {
  40                 cvar_set(do_cvar, data);
  41                 strunzone(do_cvar);
  42         }
  43         if(!do_exec)
  44                 if (!do_cvar)
  45                         print(data);
  46 }
  47
  48
  49 // =======================
  50 //  Command Sub-Functions
  51 // =======================
  52
  53 void GenericCommand_addtolist(float request, float argc)
  54 {
  55         switch(request)
  56         {
  57                 case CMD_REQUEST_COMMAND:
  58                 {
  59                         float i;
  60
  61                         if(argc >= 2)
  62                         {
  63                                 string original_cvar = argv(1);
  64                                 string tmp_string = argv(2);
  65
  66                                 if(cvar_string(original_cvar) == "") // cvar was empty
  67                                 {
  68                                         cvar_set(original_cvar, tmp_string);
  69                                 }
  70                                 else // add it to the end of the list if the list doesn't already have it
  71                                 {
  72                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
  73
  74                                         for(i = 0; i < argc; ++i)
  75                                                 if(argv(i) == tmp_string)
  76                                                         return; // already in list
  77
  78                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
  79                                 }
  80                                 return;
  81                         }
  82                 }
  83
  84                 default:
  85                         print("Incorrect parameters for ^2addtolist^7\n");
  86                 case CMD_REQUEST_USAGE:
  87                 {
  88                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value\n"));
  89                         print("  Where 'variable' is what to add 'value' to.\n");
  90                         print("See also: ^2removefromlist^7\n");
  91                         return;
  92                 }
  93         }
  94 }
  95
  96 void GenericCommand_qc_curl(float request, float argc)
  97 {
  98         switch(request)
  99         {
 100                 case CMD_REQUEST_COMMAND:
 101                 {
 102                         float do_exec;
 103                         string do_cvar;
 104                         float key;
 105                         float i, j;
 106                         string url;
 107                         float buf;
 108                         float r;
 109
 110                         do_exec = FALSE;
 111                         do_cvar = string_null;
 112                         key = -1;
 113
 114                         for(i = 1; i+1 < argc; ++i)
 115                         {
 116                                 if(argv(i) == "--cvar" && i+2 < argc)
 117                                 {
 118                                         ++i;
 119                                         do_cvar = strzone(argv(i));
 120                                         continue;
 121                                 }
 122                                 if(argv(i) == "--exec")
 123                                 {
 124                                         do_exec = TRUE;
 125                                         continue;
 126                                 }
 127                                 if(argv(i) == "--key" && i+2 < argc)
 128                                 {
 129                                         ++i;
 130                                         key = stof(argv(i));
 131                                         continue;
 132                                 }
 133                                 break;
 134                         }
 135
 136                         // now, argv(i) is the URL
 137                         // following args may be POST parameters
 138                         url = argv(i);
 139                         ++i;
 140                         buf = buf_create();
 141                         j = 0;
 142                         for(; i+1 < argc; i += 2)
 143                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 144                         if(i < argc)
 145                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 146
 147                         if(j == 0) // no args: GET
 148                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 149                         else // with args: POST
 150                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 151
 152                         if(r)
 153                         {
 154                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 155                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 156                                 curl_uri_get_pos = (curl_uri_get_pos + 1) % (URI_GET_CURL_END - URI_GET_CURL + 1);
 157                         }
 158                         else
 159                                 print(_("error creating curl handle\n"));
 160
 161                         buf_del(buf);
 162
 163                         return;
 164                 }
 165
 166                 default:
 167                 case CMD_REQUEST_USAGE:
 168                 {
 169                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " qc_curl [--key N] [--cvar] [--exec] URL [postargs...]"));
 170                         return;
 171                 }
 172         }
 173 }
 174
 175 void GenericCommand_dumpcommands(float request)
 176 {
 177         switch(request)
 178         {
 179                 case CMD_REQUEST_COMMAND:
 180                 {
 181                         float fh;
 182                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
 183                         fh = fopen(filename, FILE_WRITE);
 184
 185                         if(fh >= 0)
 186                         {
 187                                 #ifdef SVQC
 188                                         CMD_Write("dump of server console commands:\n");
 189                                         GameCommand_macro_write_aliases(fh);
 190
 191                                         CMD_Write("\ndump of networked client only commands:\n");
 192                                         ClientCommand_macro_write_aliases(fh);
 193
 194                                         CMD_Write("\ndump of common commands:\n");
 195                                         CommonCommand_macro_write_aliases(fh);
 196
 197                                         CMD_Write("\ndump of ban commands:\n");
 198                                         BanCommand_macro_write_aliases(fh);
 199                                 #endif
 200
 201                                 #ifdef CSQC
 202                                         CMD_Write("dump of client commands:\n");
 203                                         LocalCommand_macro_write_aliases(fh);
 204                                 #endif
 205
 206                                 CMD_Write("\ndump of generic commands:\n");
 207                                 GenericCommand_macro_write_aliases(fh);
 208
 209                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
 210
 211                                 fclose(fh);
 212                         }
 213                         else
 214                         {
 215                                 print("^1Error: ^7Could not dump to file!\n");
 216                         }
 217                         return;
 218                 }
 219
 220                 default:
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
 224                         print("  No arguments required.\n");
 225                         return;
 226                 }
 227         }
 228 }
 229
 230 void GenericCommand_dumpnotifs(float request)
 231 {
 232         switch(request)
 233         {
 234                 case CMD_REQUEST_COMMAND:
 235                 {
 236                         #ifndef MENUQC
 237                         float fh, alsoprint = FALSE;
 238                         string filename = argv(1);
 239
 240                         if(filename == "")
 241                         {
 242                                 filename = "notifications_dump.cfg";
 243                                 alsoprint = FALSE;
 244                         }
 245                         else if(filename == "-")
 246                         {
 247                                 filename = "notifications_dump.cfg";
 248                                 alsoprint = TRUE;
 249                         }
 250                         fh = fopen(filename, FILE_WRITE);
 251
 252                         if(fh >= 0)
 253                         {
 254                                 Dump_Notifications(fh, alsoprint);
 255                                 printf("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 256                                 fclose(fh);
 257                         }
 258                         else
 259                         {
 260                                 printf("^1Error: ^7Could not open file '%s'!\n", filename);
 261                         }
 262                         #else
 263                         print(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 264                         #endif
 265                         return;
 266                 }
 267
 268                 default:
 269                 case CMD_REQUEST_USAGE:
 270                 {
 271                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 272                         print("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 273                         print("  if supplied with '-' output to console as well as default,\n");
 274                         print("  if left blank, it will only write to default.\n");
 275                         return;
 276                 }
 277         }
 278 }
 279
 280 void GenericCommand_dumpweapons(float request) // WEAPONTODO: make this work with other progs than just server
 281 {
 282         switch(request)
 283         {
 284                 case CMD_REQUEST_COMMAND:
 285                 {
 286                         #ifdef SVQC
 287                         wep_config_file = -1;
 288                         wep_config_alsoprint = -1;
 289                         string filename = argv(1);
 290
 291                         if(filename == "")
 292                         {
 293                                 filename = "weapons_dump.cfg";
 294                                 wep_config_alsoprint = FALSE;
 295                         }
 296                         else if(filename == "-")
 297                         {
 298                                 filename = "weapons_dump.cfg";
 299                                 wep_config_alsoprint = TRUE;
 300                         }
 301                         wep_config_file = fopen(filename, FILE_WRITE);
 302
 303                         if(wep_config_file >= 0)
 304                         {
 305                                 Dump_Weapon_Settings();
 306                                 print(sprintf("Dumping weapons... File located in ^2data/data/%s^7.\n", filename));
 307                                 fclose(wep_config_file);
 308                                 wep_config_file = -1;
 309                                 wep_config_alsoprint = -1;
 310                         }
 311                         else
 312                         {
 313                                 print(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
 314                         }
 315                         #else
 316                         print(_("Weapons dump command only works with sv_cmd.\n"));
 317                         #endif
 318                         return;
 319                 }
 320
 321                 default:
 322                 case CMD_REQUEST_USAGE:
 323                 {
 324                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpweapons [filename]"));
 325                         print("  Where 'filename' is the file to write (default is weapons_dump.cfg),\n");
 326                         print("  if supplied with '-' output to console as well as default,\n");
 327                         print("  if left blank, it will only write to default.\n");
 328                         return;
 329                 }
 330         }
 331 }
 332
 333 void GenericCommand_dumpturrets(float request)
 334 {
 335         switch(request)
 336         {
 337                 case CMD_REQUEST_COMMAND:
 338                 {
 339                         #ifdef SVQC
 340                         tur_config_file = -1;
 341                         tur_config_alsoprint = -1;
 342                         string filename = argv(1);
 343
 344                         if(filename == "")
 345                         {
 346                                 filename = "turrets_dump.cfg";
 347                                 tur_config_alsoprint = FALSE;
 348                         }
 349                         else if(filename == "-")
 350                         {
 351                                 filename = "turrets_dump.cfg";
 352                                 tur_config_alsoprint = TRUE;
 353                         }
 354                         tur_config_file = fopen(filename, FILE_WRITE);
 355
 356                         if(tur_config_file >= 0)
 357                         {
 358                                 Dump_Turret_Settings();
 359                                 print(sprintf("Dumping turrets... File located in ^2data/data/%s^7.\n", filename));
 360                                 fclose(tur_config_file);
 361                                 tur_config_file = -1;
 362                                 tur_config_alsoprint = -1;
 363                         }
 364                         else
 365                         {
 366                                 print(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
 367                         }
 368                         #else
 369                         print(_("Turrets dump command only works with sv_cmd.\n"));
 370                         #endif
 371                         return;
 372                 }
 373
 374                 default:
 375                 case CMD_REQUEST_USAGE:
 376                 {
 377                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpturrets [filename]"));
 378                         print("  Where 'filename' is the file to write (default is turrets_dump.cfg),\n");
 379                         print("  if supplied with '-' output to console as well as default,\n");
 380                         print("  if left blank, it will only write to default.\n");
 381                         return;
 382                 }
 383         }
 384 }
 385
 386 void GenericCommand_maplist(float request, float argc)
 387 {
 388         switch(request)
 389         {
 390                 case CMD_REQUEST_COMMAND:
 391                 {
 392                         string tmp_string;
 393                         float i;
 394
 395                         switch(argv(1))
 396                         {
 397                                 case "add": // appends new maps to the maplist
 398                                 {
 399                                         if(argc == 3)
 400                                         {
 401                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 402                                                 {
 403                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 404                                                         break;
 405                                                 }
 406
 407                                                 if(cvar_string("g_maplist") == "")
 408                                                         cvar_set("g_maplist", argv(2));
 409                                                 else
 410                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 411
 412                                                 return;
 413                                         }
 414                                         break; // go to usage
 415                                 }
 416
 417                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 418                                 {
 419                                         MapInfo_Enumerate();
 420                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 421                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 422
 423                                         tmp_string = "";
 424                                         for(i = 0; i < argc; ++i)
 425                                                 if(MapInfo_CheckMap(argv(i)))
 426                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 427
 428                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 429                                         cvar_set("g_maplist", tmp_string);
 430
 431                                         return;
 432                                 }
 433
 434                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 435                                 {
 436                                         if(argc == 3)
 437                                         {
 438                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 439
 440                                                 tmp_string = "";
 441                                                 for(i = 0; i < argc; ++i)
 442                                                         if(argv(i) != argv(2))
 443                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 444
 445                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 446                                                 cvar_set("g_maplist", tmp_string);
 447
 448                                                 return;
 449                                         }
 450                                         break; // go to usage
 451                                 }
 452
 453                                 case "shuffle": // randomly shuffle the maplist
 454                                 {
 455                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 456                                         return;
 457                                 }
 458
 459                                 default: break;
 460                         }
 461                 }
 462
 463                 default:
 464                         print("Incorrect parameters for ^2maplist^7\n");
 465                 case CMD_REQUEST_USAGE:
 466                 {
 467                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]\n"));
 468                         print("  Where 'action' is the command to complete,\n");
 469                         print("  and 'map' is what it acts upon (if required).\n");
 470                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
 471                         return;
 472                 }
 473         }
 474 }
 475
 476 void GenericCommand_nextframe(float request, float arguments, string command)
 477 {
 478         switch(request)
 479         {
 480                 case CMD_REQUEST_COMMAND:
 481                 {
 482                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 483                         return;
 484                 }
 485
 486                 default:
 487                 case CMD_REQUEST_USAGE:
 488                 {
 489                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command...\n"));
 490                         print("  Where command will be executed next frame of this VM\n");
 491                         return;
 492                 }
 493         }
 494 }
 495
 496 void GenericCommand_removefromlist(float request, float argc)
 497 {
 498         switch(request)
 499         {
 500                 case CMD_REQUEST_COMMAND:
 501                 {
 502                         if(argc == 3)
 503                         {
 504                                 float i;
 505                                 string original_cvar = argv(1);
 506                                 string removal = argv(2);
 507                                 string tmp_string;
 508
 509                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
 510
 511                                 tmp_string = "";
 512                                 for(i = 0; i < argc; ++i)
 513                                         if(argv(i) != removal)
 514                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 515
 516                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 517                                 cvar_set(original_cvar, tmp_string);
 518
 519                                 return;
 520                         }
 521                 }
 522
 523                 default:
 524                         print("Incorrect parameters for ^2removefromlist^7\n");
 525                 case CMD_REQUEST_USAGE:
 526                 {
 527                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value\n"));
 528                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
 529                         print("See also: ^2addtolist^7\n");
 530                         return;
 531                 }
 532         }
 533 }
 534
 535 void GenericCommand_restartnotifs(float request)
 536 {
 537         switch(request)
 538         {
 539                 case CMD_REQUEST_COMMAND:
 540                 {
 541                         #ifndef MENUQC
 542                         printf(
 543                                 strcat(
 544                                         "Restart_Notifications(): Restarting %d notifications... ",
 545                                         "Counts: MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
 546                                 ),
 547                                 (
 548                                         NOTIF_ANNCE_COUNT +
 549                                         NOTIF_INFO_COUNT +
 550                                         NOTIF_CENTER_COUNT +
 551                                         NOTIF_MULTI_COUNT +
 552                                         NOTIF_CHOICE_COUNT
 553                                 ),
 554                                 NOTIF_ANNCE_COUNT,
 555                                 NOTIF_INFO_COUNT,
 556                                 NOTIF_CENTER_COUNT,
 557                                 NOTIF_MULTI_COUNT,
 558                                 NOTIF_CHOICE_COUNT
 559                         );
 560                         Destroy_All_Notifications();
 561                         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 562                         #else
 563                         print(_("Notification restart command only works with cl_cmd and sv_cmd.\n"));
 564                         #endif
 565                         return;
 566                 }
 567
 568                 default:
 569                 case CMD_REQUEST_USAGE:
 570                 {
 571                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " restartnotifs"));
 572                         print("  No arguments required.\n");
 573                         return;
 574                 }
 575         }
 576 }
 577
 578 void GenericCommand_settemp(float request, float argc)
 579 {
 580         switch(request)
 581         {
 582                 case CMD_REQUEST_COMMAND:
 583                 {
 584                         if(argc >= 3)
 585                         {
 586                                 float f = cvar_settemp(argv(1), argv(2));
 587                                 if(f == 1)
 588                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 589                                 else if(f == -1)
 590                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 591                                 // else cvar_settemp itself errors out
 592
 593                                 return;
 594                         }
 595                 }
 596
 597                 default:
 598                         print("Incorrect parameters for ^2settemp^7\n");
 599                 case CMD_REQUEST_USAGE:
 600                 {
 601                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 602                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 603                         print("See also: ^2settemp_restore^7\n");
 604                         return;
 605                 }
 606         }
 607 }
 608
 609 void GenericCommand_settemp_restore(float request, float argc)
 610 {
 611         switch(request)
 612         {
 613                 case CMD_REQUEST_COMMAND:
 614                 {
 615                         float i = cvar_settemp_restore();
 616
 617                         if(i)
 618                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 619                         else
 620                                 dprint("Nothing to restore.\n");
 621
 622                         return;
 623                 }
 624
 625                 default:
 626                 case CMD_REQUEST_USAGE:
 627                 {
 628                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 629                         print("  No arguments required.\n");
 630                         print("See also: ^2settemp^7\n");
 631                         return;
 632                 }
 633         }
 634 }
 635
 636 void GenericCommand_runtest(float request, float argc)
 637 {
 638         switch(request)
 639         {
 640                 case CMD_REQUEST_COMMAND:
 641                 {
 642                         if(argc > 1)
 643                         {
 644                                 float i;
 645                                 for(i = 1; i < argc; ++i)
 646                                         TEST_Run(argv(i));
 647                         }
 648                         else
 649                                 TEST_RunAll();
 650                         return;
 651                 }
 652
 653                 default:
 654                 case CMD_REQUEST_USAGE:
 655                 {
 656                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " [function to run]"));
 657                         return;
 658                 }
 659         }
 660 }
 661
 662 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 663 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 664 void GenericCommand_(float request)
 665 {
 666         switch(request)
 667         {
 668                 case CMD_REQUEST_COMMAND:
 669                 {
 670
 671                         return;
 672                 }
 673
 674                 default:
 675                 case CMD_REQUEST_USAGE:
 676                 {
 677                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
 678                         print("  No arguments required.\n");
 679                         return;
 680                 }
 681         }
 682 }
 683 */
 684
 685 // ==================================
 686 //  Macro system for server commands
 687 // ==================================
 688
 689 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 690 #define GENERIC_COMMANDS(request,arguments,command) \
 691         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
 692         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
 693         GENERIC_COMMAND("dumpnotifs", GenericCommand_dumpnotifs(request), "Dump all notifications into notifications_dump.txt") \
 694         GENERIC_COMMAND("dumpturrets", GenericCommand_dumpturrets(request), "Dump all turrets into turrets_dump.txt") \
 695         GENERIC_COMMAND("dumpweapons", GenericCommand_dumpweapons(request), "Dump all weapons into weapons_dump.txt") \
 696         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 697         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
 698         GENERIC_COMMAND("qc_curl", GenericCommand_qc_curl(request, arguments), "Queries a URL") \
 699         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
 700         GENERIC_COMMAND("restartnotifs", GenericCommand_restartnotifs(request), "Re-initialize all notifications") \
 701         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 702         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 703         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 704         GENERIC_COMMAND("runtest", GenericCommand_runtest(request, arguments), "Run unit tests") \
 705         /* nothing */
 706
 707 void GenericCommand_macro_help()
 708 {
 709         #define GENERIC_COMMAND(name,function,description) \
 710                 { print("  ^2", name, "^7: ", description, "\n"); }
 711
 712         GENERIC_COMMANDS(0, 0, "")
 713         #undef GENERIC_COMMAND
 714
 715         return;
 716 }
 717
 718 float GenericCommand_macro_command(float argc, string command)
 719 {
 720         #define GENERIC_COMMAND(name,function,description) \
 721                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 722
 723         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 724         #undef GENERIC_COMMAND
 725
 726         return FALSE;
 727 }
 728
 729 float GenericCommand_macro_usage(float argc)
 730 {
 731         #define GENERIC_COMMAND(name,function,description) \
 732                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 733
 734         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 735         #undef GENERIC_COMMAND
 736
 737         return FALSE;
 738 }
 739
 740 void GenericCommand_macro_write_aliases(float fh)
 741 {
 742         #define GENERIC_COMMAND(name,function,description) \
 743                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
 744
 745         GENERIC_COMMANDS(0, 0, "")
 746         #undef GENERIC_COMMAND
 747
 748         return;
 749 }
 750
 751
 752 // ===========================================
 753 //  Main Common Function For Generic Commands
 754 // ===========================================
 755 // Commands spread out among all programs (menu, client, and server)
 756
 757 float GenericCommand(string command)
 758 {
 759         float argc = tokenize_console(command);
 760         float n, j, f, i;
 761         string s, s2, c;
 762         vector rgb;
 763
 764         // Guide for working with argc arguments by example:
 765         // argc:   1    - 2      - 3     - 4
 766         // argv:   0    - 1      - 2     - 3
 767         // cmd     vote - master - login - password
 768
 769         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 770         {
 771                 return TRUE; // handled by one of the above GenericCommand_* functions
 772         }
 773         else if(argc >= 3 && argv(0) == "red")
 774         {
 775                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 776                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
 777                 return TRUE;
 778         }
 779         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 780         {
 781                 // other test case
 782                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 783
 784                 n = floor(random() * 6 + 2);
 785
 786                 s2 = "";
 787                 for(i = 0; i < n; ++i)
 788                 {
 789                         s2 = strcat(s2, "AH");
 790                 }
 791
 792                 if(random() < 0.1)
 793                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 794
 795                 if(s == "")
 796                         s = s2;
 797                 else
 798                         if(random() < 0.8)
 799                                 s = strcat(s, " ", s2);
 800                         else
 801                                 s = strcat(s2, " ", s);
 802
 803                 s2 = substring(s, strlen(s) - 2, 2);
 804                 if(s2 == "AH" || s2 == "AY")
 805                         s = strcat(s, "))");
 806                 else
 807                         s = strcat(s, " ))");
 808
 809                 if(random() < 0.1)
 810                         s = substring(s, 0, strlen(s) - 1);
 811
 812                 if(random() < 0.1)
 813                         s = strconv(1, 0, 0, s);
 814
 815                 localcmd(strcat(argv(1), " ", s));
 816
 817                 return TRUE;
 818         }
 819         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 820         {
 821                 // test case for terencehill's color codes
 822                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 823                 s2 = "";
 824
 825                 n = strlen(s);
 826                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 827                 f = random() * 6;
 828
 829                 for(i = 0; i < n; ++i)
 830                 {
 831                         c = substring(s, i, 1);
 832
 833                         if(c == ";")
 834                                 c = ":";
 835                         else if(c == "^")
 836                         {
 837                                 c = "^^";
 838                                 if(substring(s, i+1, 1) == "^")
 839                                         ++i;
 840                         }
 841
 842                         if(c != " ")
 843                         {
 844                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 845                                 c = strcat(rgb_to_hexcolor(rgb), c);
 846                         }
 847                         s2 = strcat(s2, c);
 848                 }
 849
 850                 localcmd(strcat(argv(1), " ", s2));
 851
 852                 return TRUE;
 853         }
 854
 855         return FALSE;
 856 }