qcsrc/common/ent_cs.qc

   1 #include "ent_cs.qh"
   2
   3 #if defined(CSQC)
   4         #include <common/gamemodes/_mod.qh>
   5         #include <common/resources.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8         #include <common/gamemodes/_mod.qh>
   9         #include <common/resources.qh>
  10         #include <server/resources.qh>
  11 #endif
  12
  13 REGISTRY(EntCSProps, BITS(16) - 1)
  14 REGISTER_REGISTRY(EntCSProps)
  15 REGISTRY_SORT(EntCSProps)
  16 REGISTRY_CHECK(EntCSProps)
  17
  18 REGISTRY_DEFINE_GET(EntCSProps, NULL)
  19 STATIC_INIT(EntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
  20
  21 // these entcs_props ids need to be referenced directly
  22 int ENTCS_PROP_ENTNUM_id = 0;
  23 int ENTCS_PROP_ORIGIN_id = 0;
  24 STATIC_INIT(EntCSProps_setglobalids)
  25 {
  26         FOREACH(EntCSProps, true, {
  27                 if (it.registered_id == "ENTCS_PROP_ENTNUM")
  28                         ENTCS_PROP_ENTNUM_id = it.m_id;
  29                 if (it.registered_id == "ENTCS_PROP_ORIGIN")
  30                         ENTCS_PROP_ORIGIN_id = it.m_id;
  31         });
  32 }
  33
  34 #ifdef SVQC
  35 // Force an origin update, for player sounds
  36 void entcs_force_origin(entity player)
  37 {
  38         CS(player).entcs.m_forceupdate = BIT(ENTCS_PROP_ORIGIN_id);
  39 }
  40 #endif
  41
  42 .bool m_public;
  43 .bool(entity ent, entity player) m_check;
  44 .void(entity ent, entity player) m_set;
  45 .void(int chan, entity ent) m_send;
  46 .void(entity ent) m_receive;
  47
  48 #ifdef SVQC
  49 #define _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  50         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop_pl)); } \
  51         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  52         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  53                 this.m_public = ispublic; \
  54                 this.m_check = id##_check; \
  55                 this.m_set = id##_set; \
  56                 this.m_send = id##_send; \
  57         }
  58
  59 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  60         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop_pl)); } \
  61         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  62
  63 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  64         bool id##_check(entity ent, entity player) { \
  65                 return (floor(ent.(checkprop)) / decfactor != floor(player.(checkprop_pl)) / decfactor); \
  66         } \
  67         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  68
  69 #elif defined(CSQC)
  70 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  71         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  72         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  73                 this.m_public = ispublic; \
  74                 this.m_receive = id##_receive; \
  75         }
  76
  77 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  78         ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  79 #endif
  80
  81 #ifdef SVQC
  82 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  83         bool id##_check(entity ent, entity player) { \
  84                 return (floor(GetResource(ent, checkprop) / decfactor) != floor(GetResource(player, checkprop) / decfactor)); \
  85         } \
  86         void id##_set(entity ent, entity player) { SetResourceExplicit(ent, checkprop, GetResource(player, checkprop)); } \
  87         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  88         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  89                 this.m_public = ispublic; \
  90                 this.m_check = id##_check; \
  91                 this.m_set = id##_set; \
  92                 this.m_send = id##_send; \
  93         }
  94 #elif defined(CSQC)
  95 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  96         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  97         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  98                 this.m_public = ispublic; \
  99                 this.m_receive = id##_receive; \
 100         }
 101 #endif
 102
 103 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
 104         var = x; \
 105 MACRO_END
 106
 107 /** the engine player name strings are mutable! */
 108 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
 109         strcpy(var, x); \
 110 MACRO_END
 111
 112 ENTCS_PROP(ENTNUM, false, sv_entnum, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
 113
 114 ENTCS_PROP(ORIGIN, false, origin, origin, ENTCS_SET_NORMAL,
 115         { WriteVector(chan, ent.origin); },
 116         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
 117
 118 #define DEC_FACTOR (360 / 32)
 119 ENTCS_PROP_CODED(ANGLES, false, angles_y, angles_y, ENTCS_SET_NORMAL, DEC_FACTOR,
 120         { WriteByte(chan, ent.angles.y / DEC_FACTOR); },
 121         { vector v = '0 0 0'; v.y = ReadByte() * DEC_FACTOR; ent.angles = v; })
 122 #undef DEC_FACTOR
 123
 124 // FIXME: use a better scale?
 125 #define DEC_FACTOR 10
 126 ENTCS_PROP_RESOURCE(HEALTH, false, RES_HEALTH, ENTCS_SET_NORMAL, DEC_FACTOR,
 127         { WriteByte(chan, bound(0, GetResource(ent, RES_HEALTH) / DEC_FACTOR, 255)); },
 128         { ent.healthvalue = ReadByte() * DEC_FACTOR; })
 129
 130 ENTCS_PROP_RESOURCE(ARMOR, false, RES_ARMOR, ENTCS_SET_NORMAL, DEC_FACTOR,
 131         { WriteByte(chan, bound(0, GetResource(ent, RES_ARMOR) / DEC_FACTOR, 255)); },
 132         { SetResourceExplicit(ent, RES_ARMOR, ReadByte() * DEC_FACTOR); })
 133 #undef DEC_FACTOR
 134
 135 ENTCS_PROP(NAME, true, netname, netname, ENTCS_SET_MUTABLE_STRING,
 136         { WriteString(chan, ent.netname); },
 137         { strcpy(ent.netname, ReadString()); })
 138
 139 ENTCS_PROP(MODEL, true, model, model, ENTCS_SET_NORMAL,
 140         { WriteString(chan, ent.model); },
 141         { strcpy(ent.model, ReadString()); })
 142
 143 ENTCS_PROP(SKIN, true, skin, skin, ENTCS_SET_NORMAL,
 144         { WriteByte(chan, ent.skin); },
 145         { ent.skin = ReadByte(); })
 146
 147 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, clientcolors, ENTCS_SET_NORMAL,
 148         { WriteByte(chan, ent.clientcolors); },
 149         { ent.colormap = ReadByte(); })
 150
 151 ENTCS_PROP(FRAGS, true, frags, frags, ENTCS_SET_NORMAL,
 152         { WriteShort(chan, ent.frags); },
 153         { ent.frags = ReadShort(); })
 154
 155 // use sv_solid to avoid changing solidity state of entcs entities
 156 ENTCS_PROP(SOLID, true, sv_solid, solid, ENTCS_SET_NORMAL,
 157         { WriteByte(chan, ent.sv_solid); },
 158         { ent.sv_solid = ReadByte(); })
 159
 160 #ifdef SVQC
 161
 162         int ENTCS_PUBLICMASK = 0;
 163         STATIC_INIT(ENTCS_PUBLICMASK)
 164         {
 165                 FOREACH(EntCSProps, it.m_public,
 166                 {
 167                         ENTCS_PUBLICMASK |= BIT(it.m_id);
 168                 });
 169         }
 170
 171         bool _entcs_send(entity this, entity to, int sf, int chan)
 172         {
 173                 entity player = this.owner;
 174                 sf |= BIT(ENTCS_PROP_ENTNUM_id); // assume private
 175                 do {
 176                         if (IS_PLAYER(player))
 177                         {
 178                                 if (radar_showenemies) break;
 179                                 if (SAME_TEAM(to, player)) break;
 180                                 if (!(IS_PLAYER(to) || to.caplayer) && time > game_starttime) break;
 181                         }
 182                         sf &= ENTCS_PUBLICMASK; // no private updates
 183                 } while (0);
 184
 185                 sf |= this.m_forceupdate;
 186                 this.m_forceupdate = 0;
 187                 if (chan == MSG_ENTITY)
 188                         WriteHeader(chan, ENT_CLIENT_ENTCS);
 189                 else
 190                         WriteHeader(chan, CLIENT_ENTCS);
 191                 WriteByte(chan, etof(player) - 1);
 192                 WriteShort(chan, sf);
 193                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 194                 {
 195                         it.m_send(chan, this);
 196                 });
 197                 return true;
 198         }
 199
 200         bool entcs_send(entity this, entity to, int sf)
 201         {
 202                 return _entcs_send(this, to, sf, MSG_ENTITY);
 203         }
 204
 205         void entcs_think(entity this)
 206         {
 207                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
 208                 entity player = this.owner;
 209                 FOREACH(EntCSProps, it.m_check(this, player),
 210                 {
 211                         it.m_set(this, player);
 212                         this.SendFlags |= BIT(it.m_id);
 213                 });
 214                 setorigin(this, this.origin); // relink
 215         }
 216
 217         void entcs_attach(entity player)
 218         {
 219                 entity e = CS(player).entcs = new(entcs_sender);
 220                 e.owner = player;
 221                 setthink(e, entcs_think);
 222                 e.nextthink = time;
 223                 Net_LinkEntity(e, false, 0, entcs_send);
 224                 // NOTE: the following code block has been disabled as a workaround for https://gitlab.com/xonotic/xonotic-data.pk3dir/-/issues/1824
 225 #if 0
 226                 if (!IS_REAL_CLIENT(player)) return;
 227                 FOREACH_CLIENT(true, {
 228                         assert(CS(it).entcs);
 229                         _entcs_send(CS(it).entcs, msg_entity = player, BITS(23), MSG_ONE);
 230                 });
 231 #endif
 232         }
 233
 234         void entcs_detach(entity player)
 235         {
 236                 if (!CS(player).entcs) return;
 237                 delete(CS(player).entcs);
 238                 CS(player).entcs = NULL;
 239         }
 240
 241 #endif
 242
 243 #ifdef CSQC
 244
 245         void Ent_RemoveEntCS(entity this)
 246         {
 247                 int n = this.sv_entnum;
 248                 entity e = entcs_receiver(n);
 249                 entcs_receiver(n, NULL);
 250                 strfree(e.netname);
 251                 strfree(e.model);
 252                 if (e != this) delete(e);
 253         }
 254
 255         void entcs_think(entity this)
 256         {
 257                 entity e = CSQCModel_server2csqc(this.sv_entnum);
 258                 if (e == NULL)
 259                 {
 260                         this.has_origin = this.has_sv_origin;
 261                         return;
 262                 }
 263                 this.has_origin = true;
 264                 this.origin = e.origin;
 265                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
 266                 if (this.model != e.model)
 267                 {
 268                         strcpy(this.model, e.model);
 269                 }
 270         }
 271
 272         bool ReadEntcs(entity this)
 273         {
 274                 int n = ReadByte();
 275                 entity e = entcs_receiver(n);
 276                 if (e == NULL)
 277                 {
 278                         if (!this)
 279                                 // initial = temp
 280                                 e = new_pure(ENT_CLIENT_ENTCS);
 281                         else
 282                                 // initial = linked
 283                                 e = this;
 284                         setthink(e, entcs_think);
 285                         entcs_receiver(n, e);
 286                 }
 287                 else if (e != this && this)
 288                 {
 289                         // upgrade to linked
 290                         delete(e);
 291                         e = this;
 292                         setthink(e, entcs_think);
 293                         entcs_receiver(n, e);
 294                 }
 295
 296                 InterpolateOrigin_Undo(e);
 297                 e.sv_entnum = n;
 298                 int sf = ReadShort();
 299                 e.has_sv_origin = false;
 300                 e.m_entcs_private = boolean(sf & BIT(ENTCS_PROP_ENTNUM_id));
 301                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 302                 {
 303                         it.m_receive(e);
 304                 });
 305                 e.iflags |= IFLAG_ORIGIN;
 306                 InterpolateOrigin_Note(e);
 307                 getthink(e)(e);
 308                 return true;
 309         }
 310
 311         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
 312         {
 313                 if (isnew)
 314                 {
 315                         make_pure(this);
 316                         this.entremove = Ent_RemoveEntCS;
 317                 }
 318                 return ReadEntcs(this);
 319         }
 320
 321         NET_HANDLE(CLIENT_ENTCS, bool isnew)
 322         {
 323                 return ReadEntcs(NULL);
 324         }
 325
 326 #endif