qcsrc/common/ent_cs.qc

   1 #include "ent_cs.qh"
   2
   3 #if defined(CSQC)
   4         #include <common/gamemodes/_mod.qh>
   5         #include <common/resources.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8         #include <common/gamemodes/_mod.qh>
   9         #include <common/resources.qh>
  10         #include <server/resources.qh>
  11 #endif
  12
  13 REGISTRY(EntCSProps, BITS(16) - 1)
  14 REGISTER_REGISTRY(EntCSProps)
  15 REGISTRY_SORT(EntCSProps)
  16 REGISTRY_CHECK(EntCSProps)
  17
  18 REGISTRY_DEFINE_GET(EntCSProps, NULL)
  19 STATIC_INIT(EntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
  20
  21 // these entcs_props ids need to be referenced directly
  22 int ENTCS_PROP_ENTNUM_id = 0;
  23 int ENTCS_PROP_ORIGIN_id = 0;
  24 int ENTCS_PROP_HEALTH_id = 0;
  25 STATIC_INIT(EntCSProps_setglobalids)
  26 {
  27         FOREACH(EntCSProps, true, {
  28                 if (it.registered_id == "ENTCS_PROP_ENTNUM") ENTCS_PROP_ENTNUM_id = it.m_id;
  29                 if (it.registered_id == "ENTCS_PROP_ORIGIN") ENTCS_PROP_ORIGIN_id = it.m_id;
  30                 if (it.registered_id == "ENTCS_PROP_HEALTH") ENTCS_PROP_HEALTH_id = it.m_id;
  31         });
  32 }
  33
  34 #ifdef SVQC
  35 // Force an origin update, for player sounds
  36 void entcs_force_origin(entity player)
  37 {
  38         CS(player).entcs.m_forceupdate = BIT(ENTCS_PROP_ORIGIN_id);
  39 }
  40 #endif
  41
  42 .bool m_public;
  43 .bool(entity ent, entity player) m_check;
  44 .void(entity ent, entity player) m_set;
  45 .void(int chan, entity ent) m_send;
  46 .void(entity ent) m_receive;
  47
  48 #ifdef SVQC
  49 #define _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  50         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop_pl)); } \
  51         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  52         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  53                 this.m_public = ispublic; \
  54                 this.m_check = id##_check; \
  55                 this.m_set = id##_set; \
  56                 this.m_send = id##_send; \
  57         }
  58
  59 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  60         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop_pl)); } \
  61         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  62
  63 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  64         bool id##_check(entity ent, entity player) { \
  65                 return (floor(ent.(checkprop)) / decfactor != floor(player.(checkprop_pl)) / decfactor); \
  66         } \
  67         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  68
  69 #elif defined(CSQC)
  70 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  71         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  72         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  73                 this.m_public = ispublic; \
  74                 this.m_receive = id##_receive; \
  75         }
  76
  77 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  78         ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  79 #endif
  80
  81 #ifdef SVQC
  82 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  83         bool id##_check(entity ent, entity player) { \
  84                 return (floor(GetResource(ent, checkprop) / decfactor) != floor(GetResource(player, checkprop) / decfactor)); \
  85         } \
  86         void id##_set(entity ent, entity player) { SetResourceExplicit(ent, checkprop, GetResource(player, checkprop)); } \
  87         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  88         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  89                 this.m_public = ispublic; \
  90                 this.m_check = id##_check; \
  91                 this.m_set = id##_set; \
  92                 this.m_send = id##_send; \
  93         }
  94 #elif defined(CSQC)
  95 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  96         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  97         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  98                 this.m_public = ispublic; \
  99                 this.m_receive = id##_receive; \
 100         }
 101 #endif
 102
 103 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
 104         var = x; \
 105 MACRO_END
 106
 107 /** the engine player name strings are mutable! */
 108 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
 109         strcpy(var, x); \
 110 MACRO_END
 111
 112 ENTCS_PROP(ENTNUM, false, sv_entnum, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
 113
 114 ENTCS_PROP(ORIGIN, false, origin, origin, ENTCS_SET_NORMAL,
 115         { WriteVector(chan, ent.origin); },
 116         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
 117
 118 #define DEC_FACTOR (360 / 32)
 119 ENTCS_PROP_CODED(ANGLES, false, angles_y, angles_y, ENTCS_SET_NORMAL, DEC_FACTOR,
 120         { WriteByte(chan, ent.angles.y / DEC_FACTOR); },
 121         { vector v = '0 0 0'; v.y = ReadByte() * DEC_FACTOR; ent.angles = v; })
 122 #undef DEC_FACTOR
 123
 124 // FIXME: use a better scale?
 125 #define DEC_FACTOR 10
 126 ENTCS_PROP_RESOURCE(HEALTH, false, RES_HEALTH, ENTCS_SET_NORMAL, DEC_FACTOR,
 127         { WriteByte(chan, bound(0, GetResource(ent, RES_HEALTH) / DEC_FACTOR, 255)); },
 128         { ent.healthvalue = ReadByte() * DEC_FACTOR; })
 129
 130 ENTCS_PROP_RESOURCE(ARMOR, false, RES_ARMOR, ENTCS_SET_NORMAL, DEC_FACTOR,
 131         { WriteByte(chan, bound(0, GetResource(ent, RES_ARMOR) / DEC_FACTOR, 255)); },
 132         { SetResourceExplicit(ent, RES_ARMOR, ReadByte() * DEC_FACTOR); })
 133 #undef DEC_FACTOR
 134
 135 ENTCS_PROP(NAME, true, netname, netname, ENTCS_SET_MUTABLE_STRING,
 136         { WriteString(chan, ent.netname); },
 137         { strcpy(ent.netname, ReadString()); })
 138
 139 ENTCS_PROP(MODEL, true, model, model, ENTCS_SET_NORMAL,
 140         { WriteString(chan, ent.model); },
 141         { strcpy(ent.model, ReadString()); })
 142
 143 ENTCS_PROP(SKIN, true, skin, skin, ENTCS_SET_NORMAL,
 144         { WriteByte(chan, ent.skin); },
 145         { ent.skin = ReadByte(); })
 146
 147 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, clientcolors, ENTCS_SET_NORMAL,
 148         { WriteByte(chan, ent.clientcolors); },
 149         { ent.colormap = ReadByte(); })
 150
 151 ENTCS_PROP(FRAGS, true, frags, frags, ENTCS_SET_NORMAL,
 152         { WriteShort(chan, ent.frags); },
 153         { ent.frags = ReadShort(); })
 154
 155 ENTCS_PROP(COUNTRYCODE, true, countrycode, countrycode, ENTCS_SET_NORMAL,
 156         { WriteByte(chan, ent.countrycode); },
 157         { ent.countrycode = ReadByte(); })
 158
 159 // use sv_solid to avoid changing solidity state of entcs entities
 160 ENTCS_PROP(SOLID, true, sv_solid, solid, ENTCS_SET_NORMAL,
 161         { WriteByte(chan, ent.sv_solid); },
 162         { ent.sv_solid = ReadByte(); })
 163
 164 // z411 weapon
 165 ENTCS_PROP(ACTIVEWEPID, false, activewepid, activewepid, ENTCS_SET_NORMAL,
 166         { WriteByte(chan, ent.activewepid); },
 167         { ent.activewepid = ReadByte(); })
 168
 169
 170 #ifdef SVQC
 171
 172         int ENTCS_PUBLICMASK = 0, ENTCS_PRIVATEMASK = 0;
 173         STATIC_INIT(ENTCS_PUBLICMASK)
 174         {
 175                 FOREACH(EntCSProps, true,
 176                 {
 177                         if (it.m_public)
 178                                 ENTCS_PUBLICMASK |= BIT(it.m_id);
 179                         else
 180                                 ENTCS_PRIVATEMASK |= BIT(it.m_id);
 181                 });
 182         }
 183
 184         void entcs_update_players(entity player)
 185         {
 186                 FOREACH_CLIENT(it != player && IS_PLAYER(it),
 187                 {
 188                         CS(it).entcs.SendFlags |= ENTCS_PRIVATEMASK;
 189                 });
 190         }
 191
 192         bool _entcs_send(entity this, entity to, int sf, int chan)
 193         {
 194                 entity player = this.owner;
 195                 sf |= BIT(ENTCS_PROP_ENTNUM_id); // assume private
 196                 do {
 197                         if (IS_PLAYER(player))
 198                         {
 199                                 if (radar_showenemies) break;
 200                                 if (SAME_TEAM(to, player)) break;
 201                                 if (!(IS_PLAYER(to) || to.caplayer)) break;
 202                         }
 203                         sf &= ENTCS_PUBLICMASK; // no private updates
 204                 } while (0);
 205
 206                 sf |= this.m_forceupdate;
 207                 this.m_forceupdate = 0;
 208                 if (chan == MSG_ENTITY)
 209                         WriteHeader(chan, ENT_CLIENT_ENTCS);
 210                 else
 211                         WriteHeader(chan, CLIENT_ENTCS);
 212                 WriteByte(chan, etof(player) - 1);
 213                 WriteShort(chan, sf);
 214                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 215                 {
 216                         it.m_send(chan, this);
 217                 });
 218                 return true;
 219         }
 220
 221         bool entcs_send(entity this, entity to, int sf)
 222         {
 223                 return _entcs_send(this, to, sf, MSG_ENTITY);
 224         }
 225
 226         void entcs_think(entity this)
 227         {
 228                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
 229                 entity player = this.owner;
 230                 FOREACH(EntCSProps, it.m_check(this, player),
 231                 {
 232                         it.m_set(this, player);
 233                         this.SendFlags |= BIT(it.m_id);
 234                 });
 235
 236                 if (intermission_running)
 237                 {
 238                         // health is set to special values after the game ends, ignore any change
 239                         this.SendFlags &= ~BIT(ENTCS_PROP_HEALTH_id);
 240                 }
 241
 242                 // always send origin of players even if they stand still otherwise
 243                 // if a teammate isn't in my pvs and his health (or view angle or name
 244                 // etc...) changes then his tag disappears
 245                 if (IS_PLAYER(this.owner))
 246                         this.SendFlags |= BIT(ENTCS_PROP_ORIGIN_id);
 247
 248                 // not needed, origin is just data to be sent
 249                 //setorigin(this, this.origin); // relink
 250         }
 251
 252         void entcs_attach(entity player)
 253         {
 254                 entity e = CS(player).entcs = new_pure(entcs_sender);
 255                 e.owner = player;
 256                 setthink(e, entcs_think);
 257                 e.nextthink = time;
 258                 Net_LinkEntity(e, false, 0, entcs_send);
 259                 // NOTE: the following code block has been disabled as a workaround for https://gitlab.com/xonotic/xonotic-data.pk3dir/-/issues/1824
 260 #if 0
 261                 if (!IS_REAL_CLIENT(player)) return;
 262                 FOREACH_CLIENT(true, {
 263                         assert(CS(it).entcs);
 264                         _entcs_send(CS(it).entcs, msg_entity = player, BITS(23), MSG_ONE);
 265                 });
 266 #endif
 267         }
 268
 269         void entcs_detach(entity player)
 270         {
 271                 if (!CS(player).entcs) return;
 272                 delete(CS(player).entcs);
 273                 CS(player).entcs = NULL;
 274         }
 275
 276 #endif
 277
 278 #ifdef CSQC
 279
 280         void Ent_RemoveEntCS(entity this)
 281         {
 282                 int n = this.sv_entnum;
 283                 entity e = entcs_receiver(n);
 284                 entcs_receiver(n, NULL);
 285                 strfree(e.netname);
 286                 strfree(e.model);
 287                 if (e != this) delete(e);
 288         }
 289
 290         void entcs_think(entity this)
 291         {
 292                 entity e = CSQCModel_server2csqc(this.sv_entnum);
 293                 if (e == NULL)
 294                 {
 295                         // player model is NOT in client's PVS
 296                         InterpolateOrigin_Do(this);
 297                         this.has_origin = this.has_sv_origin;
 298                         return;
 299                 }
 300                 this.has_origin = true;
 301                 // when a player model is in client's PVS we use its origin directly
 302                 // (entcs networked origin is overriden)
 303                 this.origin = e.origin;
 304                 InterpolateOrigin_Reset(this);
 305                 setorigin(this, this.origin);
 306                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
 307                 if (this.model != e.model)
 308                 {
 309                         strcpy(this.model, e.model);
 310                 }
 311         }
 312
 313         bool ReadEntcs(entity this)
 314         {
 315                 int n = ReadByte();
 316                 entity e = entcs_receiver(n);
 317                 if (e == NULL)
 318                 {
 319                         if (!this)
 320                                 // initial = temp
 321                                 e = new_pure(ENT_CLIENT_ENTCS);
 322                         else
 323                                 // initial = linked
 324                                 e = this;
 325                         setthink(e, entcs_think);
 326                         entcs_receiver(n, e);
 327                 }
 328                 else if (e != this && this)
 329                 {
 330                         // upgrade to linked
 331                         delete(e);
 332                         e = this;
 333                         setthink(e, entcs_think);
 334                         entcs_receiver(n, e);
 335                 }
 336
 337                 InterpolateOrigin_Undo(e);
 338                 e.sv_entnum = n;
 339                 int sf = ReadShort();
 340                 e.has_sv_origin = false;
 341                 e.m_entcs_private = boolean(sf & BIT(ENTCS_PROP_ENTNUM_id));
 342                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 343                 {
 344                         it.m_receive(e);
 345                 });
 346                 e.iflags |= IFLAG_ORIGIN;
 347                 InterpolateOrigin_Note(e);
 348                 getthink(e)(e);
 349                 return true;
 350         }
 351
 352         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
 353         {
 354                 if (isnew)
 355                 {
 356                         make_pure(this);
 357                         this.entremove = Ent_RemoveEntCS;
 358                 }
 359                 return ReadEntcs(this);
 360         }
 361
 362         NET_HANDLE(CLIENT_ENTCS, bool isnew)
 363         {
 364                 return ReadEntcs(NULL);
 365         }
 366
 367 #endif