qcsrc/common/ent_cs.qc

   1 #include "ent_cs.qh"
   2
   3 #if defined(CSQC)
   4         #include <common/gamemodes/_mod.qh>
   5         #include <common/resources.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8         #include <common/gamemodes/_mod.qh>
   9         #include <common/resources.qh>
  10         #include <server/resources.qh>
  11 #endif
  12
  13 REGISTRY(EntCSProps, BITS(16) - 1)
  14 REGISTER_REGISTRY(EntCSProps)
  15 REGISTRY_SORT(EntCSProps)
  16 REGISTRY_CHECK(EntCSProps)
  17
  18 REGISTRY_DEFINE_GET(EntCSProps, NULL)
  19 STATIC_INIT(EntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
  20
  21 // these entcs_props ids need to be referenced directly
  22 int ENTCS_PROP_ENTNUM_id = 0;
  23 int ENTCS_PROP_ORIGIN_id = 0;
  24 STATIC_INIT(EntCSProps_setglobalids)
  25 {
  26         FOREACH(EntCSProps, true, {
  27                 if (it.registered_id == "ENTCS_PROP_ENTNUM")
  28                         ENTCS_PROP_ENTNUM_id = it.m_id;
  29                 if (it.registered_id == "ENTCS_PROP_ORIGIN")
  30                         ENTCS_PROP_ORIGIN_id = it.m_id;
  31         });
  32 }
  33
  34 #ifdef SVQC
  35 // Force an origin update, for player sounds
  36 void entcs_force_origin(entity player)
  37 {
  38         CS(player).entcs.m_forceupdate = BIT(ENTCS_PROP_ORIGIN_id);
  39 }
  40 #endif
  41
  42 .bool m_public;
  43 .bool(entity ent, entity player) m_check;
  44 .void(entity ent, entity player) m_set;
  45 .void(int chan, entity ent) m_send;
  46 .void(entity ent) m_receive;
  47
  48 #ifdef SVQC
  49 #define _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  50         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop_pl)); } \
  51         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  52         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  53                 this.m_public = ispublic; \
  54                 this.m_check = id##_check; \
  55                 this.m_set = id##_set; \
  56                 this.m_send = id##_send; \
  57         }
  58
  59 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  60         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop_pl)); } \
  61         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  62
  63 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  64         bool id##_check(entity ent, entity player) { \
  65                 return (floor(ent.(checkprop)) / decfactor != floor(player.(checkprop_pl)) / decfactor); \
  66         } \
  67         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  68
  69 #elif defined(CSQC)
  70 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  71         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  72         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  73                 this.m_public = ispublic; \
  74                 this.m_receive = id##_receive; \
  75         }
  76
  77 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  78         ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  79 #endif
  80
  81 #ifdef SVQC
  82 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  83         bool id##_check(entity ent, entity player) { \
  84                 return (floor(GetResource(ent, checkprop) / decfactor) != floor(GetResource(player, checkprop) / decfactor)); \
  85         } \
  86         void id##_set(entity ent, entity player) { SetResourceExplicit(ent, checkprop, GetResource(player, checkprop)); } \
  87         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  88         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  89                 this.m_public = ispublic; \
  90                 this.m_check = id##_check; \
  91                 this.m_set = id##_set; \
  92                 this.m_send = id##_send; \
  93         }
  94 #elif defined(CSQC)
  95 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  96         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  97         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  98                 this.m_public = ispublic; \
  99                 this.m_receive = id##_receive; \
 100         }
 101 #endif
 102
 103 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
 104         var = x; \
 105 MACRO_END
 106
 107 /** the engine player name strings are mutable! */
 108 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
 109         strcpy(var, x); \
 110 MACRO_END
 111
 112 ENTCS_PROP(ENTNUM, false, sv_entnum, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
 113
 114 ENTCS_PROP(ORIGIN, false, origin, origin, ENTCS_SET_NORMAL,
 115         { WriteVector(chan, ent.origin); },
 116         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
 117
 118 #define DEC_FACTOR (360 / 32)
 119 ENTCS_PROP_CODED(ANGLES, false, angles_y, angles_y, ENTCS_SET_NORMAL, DEC_FACTOR,
 120         { WriteByte(chan, ent.angles.y / DEC_FACTOR); },
 121         { vector v = '0 0 0'; v.y = ReadByte() * DEC_FACTOR; ent.angles = v; })
 122 #undef DEC_FACTOR
 123
 124 // FIXME: use a better scale?
 125 #define DEC_FACTOR 10
 126 ENTCS_PROP_RESOURCE(HEALTH, false, RES_HEALTH, ENTCS_SET_NORMAL, DEC_FACTOR,
 127         { WriteByte(chan, bound(0, GetResource(ent, RES_HEALTH) / DEC_FACTOR, 255)); },
 128         { ent.healthvalue = ReadByte() * DEC_FACTOR; })
 129
 130 ENTCS_PROP_RESOURCE(ARMOR, false, RES_ARMOR, ENTCS_SET_NORMAL, DEC_FACTOR,
 131         { WriteByte(chan, bound(0, GetResource(ent, RES_ARMOR) / DEC_FACTOR, 255)); },
 132         { SetResourceExplicit(ent, RES_ARMOR, ReadByte() * DEC_FACTOR); })
 133 #undef DEC_FACTOR
 134
 135 ENTCS_PROP(NAME, true, netname, netname, ENTCS_SET_MUTABLE_STRING,
 136         { WriteString(chan, ent.netname); },
 137         { strcpy(ent.netname, ReadString()); })
 138
 139 ENTCS_PROP(MODEL, true, model, model, ENTCS_SET_NORMAL,
 140         { WriteString(chan, ent.model); },
 141         { strcpy(ent.model, ReadString()); })
 142
 143 ENTCS_PROP(SKIN, true, skin, skin, ENTCS_SET_NORMAL,
 144         { WriteByte(chan, ent.skin); },
 145         { ent.skin = ReadByte(); })
 146
 147 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, clientcolors, ENTCS_SET_NORMAL,
 148         { WriteByte(chan, ent.clientcolors); },
 149         { ent.colormap = ReadByte(); })
 150
 151 ENTCS_PROP(FRAGS, true, frags, frags, ENTCS_SET_NORMAL,
 152         { WriteShort(chan, ent.frags); },
 153         { ent.frags = ReadShort(); })
 154
 155 ENTCS_PROP(COUNTRYCODE, true, countrycode, countrycode, ENTCS_SET_NORMAL,
 156         { WriteByte(chan, ent.countrycode); },
 157         { ent.countrycode = ReadByte(); })
 158
 159 // use sv_solid to avoid changing solidity state of entcs entities
 160 ENTCS_PROP(SOLID, true, sv_solid, solid, ENTCS_SET_NORMAL,
 161         { WriteByte(chan, ent.sv_solid); },
 162         { ent.sv_solid = ReadByte(); })
 163
 164 // z411 weapon
 165 ENTCS_PROP(ACTIVEWEPID, false, activewepid, activewepid, ENTCS_SET_NORMAL,
 166         { WriteByte(chan, ent.activewepid); },
 167         { ent.activewepid = ReadByte(); })
 168
 169 #ifdef SVQC
 170
 171         int ENTCS_PUBLICMASK = 0;
 172         STATIC_INIT(ENTCS_PUBLICMASK)
 173         {
 174                 FOREACH(EntCSProps, it.m_public,
 175                 {
 176                         ENTCS_PUBLICMASK |= BIT(it.m_id);
 177                 });
 178         }
 179
 180         bool _entcs_send(entity this, entity to, int sf, int chan)
 181         {
 182                 entity player = this.owner;
 183                 sf |= BIT(ENTCS_PROP_ENTNUM_id); // assume private
 184                 do {
 185                         if (IS_PLAYER(player))
 186                         {
 187                                 if (radar_showenemies) break;
 188                                 if (SAME_TEAM(to, player)) break;
 189                                 if (!(IS_PLAYER(to) || to.caplayer) && time > game_starttime) break;
 190                         }
 191                         sf &= ENTCS_PUBLICMASK; // no private updates
 192                 } while (0);
 193
 194                 sf |= this.m_forceupdate;
 195                 this.m_forceupdate = 0;
 196                 if (chan == MSG_ENTITY)
 197                         WriteHeader(chan, ENT_CLIENT_ENTCS);
 198                 else
 199                         WriteHeader(chan, CLIENT_ENTCS);
 200                 WriteByte(chan, etof(player) - 1);
 201                 WriteShort(chan, sf);
 202                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 203                 {
 204                         it.m_send(chan, this);
 205                 });
 206                 return true;
 207         }
 208
 209         bool entcs_send(entity this, entity to, int sf)
 210         {
 211                 return _entcs_send(this, to, sf, MSG_ENTITY);
 212         }
 213
 214         void entcs_think(entity this)
 215         {
 216                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
 217                 entity player = this.owner;
 218                 FOREACH(EntCSProps, it.m_check(this, player),
 219                 {
 220                         it.m_set(this, player);
 221                         this.SendFlags |= BIT(it.m_id);
 222                 });
 223                 setorigin(this, this.origin); // relink
 224         }
 225
 226         void entcs_attach(entity player)
 227         {
 228                 entity e = CS(player).entcs = new(entcs_sender);
 229                 e.owner = player;
 230                 setthink(e, entcs_think);
 231                 e.nextthink = time;
 232                 Net_LinkEntity(e, false, 0, entcs_send);
 233                 // NOTE: the following code block has been disabled as a workaround for https://gitlab.com/xonotic/xonotic-data.pk3dir/-/issues/1824
 234 #if 0
 235                 if (!IS_REAL_CLIENT(player)) return;
 236                 FOREACH_CLIENT(true, {
 237                         assert(CS(it).entcs);
 238                         _entcs_send(CS(it).entcs, msg_entity = player, BITS(23), MSG_ONE);
 239                 });
 240 #endif
 241         }
 242
 243         void entcs_detach(entity player)
 244         {
 245                 if (!CS(player).entcs) return;
 246                 delete(CS(player).entcs);
 247                 CS(player).entcs = NULL;
 248         }
 249
 250 #endif
 251
 252 #ifdef CSQC
 253
 254         void Ent_RemoveEntCS(entity this)
 255         {
 256                 int n = this.sv_entnum;
 257                 entity e = entcs_receiver(n);
 258                 entcs_receiver(n, NULL);
 259                 strfree(e.netname);
 260                 strfree(e.model);
 261                 if (e != this) delete(e);
 262         }
 263
 264         void entcs_think(entity this)
 265         {
 266                 entity e = CSQCModel_server2csqc(this.sv_entnum);
 267                 if (e == NULL)
 268                 {
 269                         this.has_origin = this.has_sv_origin;
 270                         return;
 271                 }
 272                 this.has_origin = true;
 273                 this.origin = e.origin;
 274                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
 275                 if (this.model != e.model)
 276                 {
 277                         strcpy(this.model, e.model);
 278                 }
 279         }
 280
 281         bool ReadEntcs(entity this)
 282         {
 283                 int n = ReadByte();
 284                 entity e = entcs_receiver(n);
 285                 if (e == NULL)
 286                 {
 287                         if (!this)
 288                                 // initial = temp
 289                                 e = new_pure(ENT_CLIENT_ENTCS);
 290                         else
 291                                 // initial = linked
 292                                 e = this;
 293                         setthink(e, entcs_think);
 294                         entcs_receiver(n, e);
 295                 }
 296                 else if (e != this && this)
 297                 {
 298                         // upgrade to linked
 299                         delete(e);
 300                         e = this;
 301                         setthink(e, entcs_think);
 302                         entcs_receiver(n, e);
 303                 }
 304
 305                 InterpolateOrigin_Undo(e);
 306                 e.sv_entnum = n;
 307                 int sf = ReadShort();
 308                 e.has_sv_origin = false;
 309                 e.m_entcs_private = boolean(sf & BIT(ENTCS_PROP_ENTNUM_id));
 310                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 311                 {
 312                         it.m_receive(e);
 313                 });
 314                 e.iflags |= IFLAG_ORIGIN;
 315                 InterpolateOrigin_Note(e);
 316                 getthink(e)(e);
 317                 return true;
 318         }
 319
 320         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
 321         {
 322                 if (isnew)
 323                 {
 324                         make_pure(this);
 325                         this.entremove = Ent_RemoveEntCS;
 326                 }
 327                 return ReadEntcs(this);
 328         }
 329
 330         NET_HANDLE(CLIENT_ENTCS, bool isnew)
 331         {
 332                 return ReadEntcs(NULL);
 333         }
 334
 335 #endif