qcsrc/common/gamemodes/gamemode/cts/sv_cts.qc

   1 #include "sv_cts.qh"
   2
   3 #include <server/client.qh>
   4 #include <server/race.qh>
   5 #include <server/world.qh>
   6 #include <server/gamelog.qh>
   7 #include <server/intermission.qh>
   8 #include <server/items/spawning.qh>
   9 #include <server/weapons/common.qh>
  10 #include <common/mapobjects/triggers.qh>
  11
  12 float autocvar_g_cts_finish_kill_delay;
  13 bool autocvar_g_cts_selfdamage;
  14 bool autocvar_g_cts_removeprojectiles;
  15
  16 // legacy bot roles
  17 .float race_checkpoint;
  18 void havocbot_role_cts(entity this)
  19 {
  20         if(IS_DEAD(this))
  21                 return;
  22
  23         if (navigation_goalrating_timeout(this))
  24         {
  25                 navigation_goalrating_start(this);
  26
  27                 bool raw_touch_check = true;
  28                 int cp = this.race_checkpoint;
  29
  30                 LABEL(search_racecheckpoints)
  31                 IL_EACH(g_racecheckpoints, true,
  32                 {
  33                         if(it.cnt == cp || cp == -1)
  34                         {
  35                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  36                                 // e.g. checkpoint in front of Stormkeep's warpzone
  37                                 // the same workaround is applied in Race game mode
  38                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  39                                 {
  40                                         cp = race_NextCheckpoint(cp);
  41                                         raw_touch_check = false;
  42                                         goto search_racecheckpoints;
  43                                 }
  44                                 navigation_routerating(this, it, 1000000, 5000);
  45                         }
  46                 });
  47
  48                 navigation_goalrating_end(this);
  49
  50                 navigation_goalrating_timeout_set(this);
  51         }
  52 }
  53
  54 void cts_ScoreRules()
  55 {
  56     GameRules_score_enabled(false);
  57     GameRules_scoring(0, 0, 0, {
  58         if (g_race_qualifying) {
  59             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  60         } else {
  61             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  62             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  63             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  64         }
  65     });
  66 }
  67
  68 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  69 {
  70         if(autocvar_sv_eventlog)
  71                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  72 }
  73
  74 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  75 {
  76         entity player = M_ARGV(0, entity);
  77         float dt = M_ARGV(1, float);
  78
  79         player.race_movetime_frac += dt;
  80         float f = floor(player.race_movetime_frac);
  81         player.race_movetime_frac -= f;
  82         player.race_movetime_count += f;
  83         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  84
  85         if(IS_PLAYER(player))
  86         {
  87                 if (player.race_penalty)
  88                         if (time > player.race_penalty)
  89                                 player.race_penalty = 0;
  90                 if(player.race_penalty)
  91                 {
  92                         player.velocity = '0 0 0';
  93                         set_movetype(player, MOVETYPE_NONE);
  94                         player.disableclientprediction = 2;
  95                 }
  96         }
  97
  98         // force kbd movement for fairness
  99         float wishspeed;
 100         vector wishvel;
 101
 102         // if record times matter
 103         // ensure nothing EVIL is being done (i.e. div0_evade)
 104         // this hinders joystick users though
 105         // but it still gives SOME analog control
 106         wishvel.x = fabs(CS(player).movement.x);
 107         wishvel.y = fabs(CS(player).movement.y);
 108         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 109         {
 110                 wishvel.z = 0;
 111                 wishspeed = vlen(wishvel);
 112                 if(wishvel.x >= 2 * wishvel.y)
 113                 {
 114                         // pure X motion
 115                         if(CS(player).movement.x > 0)
 116                                 CS(player).movement_x = wishspeed;
 117                         else
 118                                 CS(player).movement_x = -wishspeed;
 119                         CS(player).movement_y = 0;
 120                 }
 121                 else if(wishvel.y >= 2 * wishvel.x)
 122                 {
 123                         // pure Y motion
 124                         CS(player).movement_x = 0;
 125                         if(CS(player).movement.y > 0)
 126                                 CS(player).movement_y = wishspeed;
 127                         else
 128                                 CS(player).movement_y = -wishspeed;
 129                 }
 130                 else
 131                 {
 132                         // diagonal
 133                         if(CS(player).movement.x > 0)
 134                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 135                         else
 136                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 137                         if(CS(player).movement.y > 0)
 138                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 139                         else
 140                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 141                 }
 142         }
 143 }
 144
 145 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 146 {
 147         float s;
 148
 149         Score_NicePrint(NULL);
 150
 151         race_ClearRecords();
 152         PlayerScore_Sort(race_place, 0, true, false);
 153
 154         FOREACH_CLIENT(true, {
 155                 if(it.race_place)
 156                 {
 157                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 158                         if(!s)
 159                                 it.race_place = 0;
 160                 }
 161                 cts_EventLog(ftos(it.race_place), it);
 162         });
 163
 164         if(g_race_qualifying == 2)
 165         {
 166                 g_race_qualifying = 0;
 167                 independent_players = 0;
 168                 cvar_set("fraglimit", ftos(race_fraglimit));
 169                 cvar_set("leadlimit", ftos(race_leadlimit));
 170                 cvar_set("timelimit", ftos(race_timelimit));
 171                 cts_ScoreRules();
 172         }
 173 }
 174
 175 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 176 {
 177         entity player = M_ARGV(0, entity);
 178
 179         race_PreparePlayer(player);
 180         player.race_checkpoint = -1;
 181
 182         race_SendAll(player, false);
 183 }
 184
 185 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 186 {
 187         entity player = M_ARGV(0, entity);
 188
 189         if(autocvar_g_allow_checkpoints)
 190                 race_PreparePlayer(player); // nice try
 191 }
 192
 193 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 194 {
 195         entity player = M_ARGV(0, entity);
 196
 197         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 198                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 199         else
 200                 player.frags = FRAGS_SPECTATOR;
 201
 202         race_PreparePlayer(player);
 203         player.race_checkpoint = -1;
 204 }
 205
 206 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 207 {
 208         entity player = M_ARGV(0, entity);
 209         entity spawn_spot = M_ARGV(1, entity);
 210
 211         if(spawn_spot.target == "")
 212                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 213                 race_PreparePlayer(player);
 214
 215         // if we need to respawn, do it right
 216         player.race_respawn_checkpoint = player.race_checkpoint;
 217         player.race_respawn_spotref = spawn_spot;
 218
 219         player.race_place = 0;
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 223 {
 224         entity player = M_ARGV(0, entity);
 225
 226         if(IS_PLAYER(player))
 227         if(!game_stopped)
 228         {
 229                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 230                         race_PreparePlayer(player);
 231                 else // respawn
 232                         race_RetractPlayer(player);
 233
 234                 race_AbandonRaceCheck(player);
 235         }
 236 }
 237
 238 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 239 {
 240         entity frag_target = M_ARGV(2, entity);
 241
 242         frag_target.respawn_flags |= RESPAWN_FORCE;
 243         race_AbandonRaceCheck(frag_target);
 244
 245         if(autocvar_g_cts_removeprojectiles)
 246         {
 247                 IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
 248                 {
 249                         delete(it);
 250                 });
 251         }
 252 }
 253
 254 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 255 {
 256         entity bot = M_ARGV(0, entity);
 257
 258         bot.havocbot_role = havocbot_role_cts;
 259         return true;
 260 }
 261
 262 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 263 {
 264         entity player = M_ARGV(0, entity);
 265
 266         race_checkAndWriteName(player);
 267         race_SpeedAwardFrame(player);
 268 }
 269
 270 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 271 {
 272         // no weapon dropping in CTS
 273         return true;
 274 }
 275
 276 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 277 {
 278         entity item = M_ARGV(0, entity);
 279
 280         if (Item_IsLoot(item))
 281         {
 282                 return true;
 283         }
 284 }
 285
 286 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 287 {
 288         entity frag_attacker = M_ARGV(1, entity);
 289         entity frag_target = M_ARGV(2, entity);
 290         float frag_deathtype = M_ARGV(3, float);
 291         float frag_damage = M_ARGV(4, float);
 292
 293         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 294         if(!autocvar_g_cts_selfdamage)
 295         {
 296                 frag_damage = 0;
 297                 M_ARGV(4, float) = frag_damage;
 298         }
 299 }
 300
 301 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 302 {
 303         return true; // in CTS, you don't lose score by observing
 304 }
 305
 306 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 307 {
 308         int record_page = M_ARGV(0, int);
 309         string ret_string = M_ARGV(1, string);
 310
 311         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 312         {
 313                 if(MapInfo_Get_ByID(i))
 314                 {
 315                         float r = race_readTime(MapInfo_Map_bspname, 1);
 316
 317                         if(!r)
 318                                 continue;
 319
 320                         string h = race_readName(MapInfo_Map_bspname, 1);
 321                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 322                 }
 323         }
 324
 325         M_ARGV(1, string) = ret_string;
 326 }
 327
 328 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 329 {
 330         M_ARGV(1, float) = 0; // kill delay
 331 }
 332
 333 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 334 {
 335         entity player = M_ARGV(0, entity);
 336
 337         // useful to prevent cheating by running back to the start line and starting out with more speed
 338         if(autocvar_g_cts_finish_kill_delay)
 339                 ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
 340 }
 341
 342 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 343 {
 344         return true; // doesn't work so well (but isn't cts a teamless mode?)
 345 }
 346
 347 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 348 {
 349         entity player = M_ARGV(0, entity);
 350
 351         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 352 }
 353
 354 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 355 {
 356         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 357         M_ARGV(3, bool) = true; // want mutator blocked
 358         return true;
 359 }
 360
 361 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 362 {
 363         return true;
 364 }
 365
 366 void cts_Initialize()
 367 {
 368         record_type = CTS_RECORD;
 369         cts_ScoreRules();
 370 }