qcsrc/common/gamemodes/gamemode/keepaway/keepaway.qc

   1 #include "keepaway.qh"
   2
   3 // TODO: keepaway
   4 #ifdef SVQC
   5 #include <common/effects/all.qh>
   6
   7 .entity ballcarried;
   8
   9 int autocvar_g_keepaway_ballcarrier_effects;
  10 float autocvar_g_keepaway_ballcarrier_damage;
  11 float autocvar_g_keepaway_ballcarrier_force;
  12 float autocvar_g_keepaway_ballcarrier_highspeed;
  13 float autocvar_g_keepaway_ballcarrier_selfdamage;
  14 float autocvar_g_keepaway_ballcarrier_selfforce;
  15 float autocvar_g_keepaway_noncarrier_damage;
  16 float autocvar_g_keepaway_noncarrier_force;
  17 float autocvar_g_keepaway_noncarrier_selfdamage;
  18 float autocvar_g_keepaway_noncarrier_selfforce;
  19 bool autocvar_g_keepaway_noncarrier_warn;
  20 int autocvar_g_keepaway_score_bckill;
  21 int autocvar_g_keepaway_score_killac;
  22 int autocvar_g_keepaway_score_timepoints;
  23 float autocvar_g_keepaway_score_timeinterval;
  24 float autocvar_g_keepawayball_damageforcescale;
  25 int autocvar_g_keepawayball_effects;
  26 float autocvar_g_keepawayball_respawntime;
  27 int autocvar_g_keepawayball_trail_color;
  28
  29 bool ka_ballcarrier_waypointsprite_visible_for_player(entity this, entity player, entity view) // runs on waypoints which are attached to ballcarriers, updates once per frame
  30 {
  31         if(view.ballcarried)
  32                 if(IS_SPEC(player))
  33                         return false; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
  34
  35         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
  36
  37         return true;
  38 }
  39
  40 void ka_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  41 {
  42         if(autocvar_sv_eventlog)
  43                 GameLogEcho(strcat(":ka:", mode, ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  44 }
  45
  46 void ka_TouchEvent(entity this, entity toucher);
  47 void ka_RespawnBall(entity this) // runs whenever the ball needs to be relocated
  48 {
  49         if(game_stopped) return;
  50         vector oldballorigin = this.origin;
  51
  52         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  53         {
  54                 entity spot = SelectSpawnPoint(this, true);
  55                 setorigin(this, spot.origin);
  56                 this.angles = spot.angles;
  57         }
  58
  59         makevectors(this.angles);
  60         set_movetype(this, MOVETYPE_BOUNCE);
  61         this.velocity = '0 0 200';
  62         this.angles = '0 0 0';
  63         this.effects = autocvar_g_keepawayball_effects;
  64         settouch(this, ka_TouchEvent);
  65         setthink(this, ka_RespawnBall);
  66         this.nextthink = time + autocvar_g_keepawayball_respawntime;
  67         navigation_dynamicgoal_set(this, NULL);
  68
  69         Send_Effect(EFFECT_ELECTRO_COMBO, oldballorigin, '0 0 0', 1);
  70         Send_Effect(EFFECT_ELECTRO_COMBO, this.origin, '0 0 0', 1);
  71
  72         WaypointSprite_Spawn(WP_KaBall, 0, 0, this, '0 0 64', NULL, this.team, this, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
  73         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
  74
  75         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  76 }
  77
  78 void ka_TimeScoring(entity this)
  79 {
  80         if(this.owner.ballcarried)
  81         { // add points for holding the ball after a certain amount of time
  82                 if(autocvar_g_keepaway_score_timepoints)
  83                         GameRules_scoring_add(this.owner, SCORE, autocvar_g_keepaway_score_timepoints);
  84
  85                 GameRules_scoring_add(this.owner, KEEPAWAY_BCTIME, (autocvar_g_keepaway_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
  86                 this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
  87         }
  88 }
  89
  90 void ka_TouchEvent(entity this, entity toucher) // runs any time that the ball comes in contact with something
  91 {
  92         if(game_stopped) return;
  93         if(!this) return;
  94         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  95         { // The ball fell off the map, respawn it since players can't get to it
  96                 ka_RespawnBall(this);
  97                 return;
  98         }
  99         if(IS_DEAD(toucher)) { return; }
 100         if(STAT(FROZEN, toucher)) { return; }
 101         if (!IS_PLAYER(toucher))
 102         {  // The ball just touched an object, most likely the world
 103                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, '0 0 0', 1);
 104                 sound(this, CH_TRIGGER, SND_KA_TOUCH, VOL_BASE, ATTEN_NORM);
 105                 return;
 106         }
 107         else if(this.wait > time) { return; }
 108
 109         // attach the ball to the player
 110         this.owner = toucher;
 111         toucher.ballcarried = this;
 112         GameRules_scoring_vip(toucher, true);
 113         setattachment(this, toucher, "");
 114         setorigin(this, '0 0 0');
 115
 116         // make the ball invisible/unable to do anything/set up time scoring
 117         this.velocity = '0 0 0';
 118         set_movetype(this, MOVETYPE_NONE);
 119         this.effects |= EF_NODRAW;
 120         settouch(this, func_null);
 121         setthink(this, ka_TimeScoring);
 122         this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
 123         this.takedamage = DAMAGE_NO;
 124         navigation_dynamicgoal_unset(this);
 125
 126         // apply effects to player
 127         toucher.glow_color = autocvar_g_keepawayball_trail_color;
 128         toucher.glow_trail = true;
 129         toucher.effects |= autocvar_g_keepaway_ballcarrier_effects;
 130
 131         // messages and sounds
 132         ka_EventLog("pickup", toucher);
 133         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_PICKUP, toucher.netname);
 134         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, toucher.netname);
 135         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
 136         sound(this.owner, CH_TRIGGER, SND_KA_PICKEDUP, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 137
 138         // scoring
 139         GameRules_scoring_add(toucher, KEEPAWAY_PICKUPS, 1);
 140
 141         // waypoints
 142         WaypointSprite_AttachCarrier(WP_KaBallCarrier, toucher, RADARICON_FLAGCARRIER);
 143         toucher.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
 144         WaypointSprite_UpdateRule(toucher.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 145         WaypointSprite_Ping(toucher.waypointsprite_attachedforcarrier);
 146         WaypointSprite_Kill(this.waypointsprite_attachedforcarrier);
 147 }
 148
 149 void ka_DropEvent(entity plyr) // runs any time that a player is supposed to lose the ball
 150 {
 151         entity ball;
 152         ball = plyr.ballcarried;
 153
 154         if(!ball) { return; }
 155
 156         // reset the ball
 157         setattachment(ball, NULL, "");
 158         set_movetype(ball, MOVETYPE_BOUNCE);
 159         ball.wait = time + 1;
 160         settouch(ball, ka_TouchEvent);
 161         setthink(ball, ka_RespawnBall);
 162         ball.nextthink = time + autocvar_g_keepawayball_respawntime;
 163         ball.takedamage = DAMAGE_YES;
 164         ball.effects &= ~EF_NODRAW;
 165         setorigin(ball, plyr.origin + '0 0 10');
 166         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 167         entity e = ball.owner;
 168         ball.owner = NULL;
 169         e.ballcarried = NULL;
 170         GameRules_scoring_vip(e, false);
 171         navigation_dynamicgoal_set(ball, e);
 172
 173         // reset the player effects
 174         plyr.glow_trail = false;
 175         plyr.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 176
 177         // messages and sounds
 178         ka_EventLog("dropped", plyr);
 179         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_DROPPED, plyr.netname);
 180         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, plyr.netname);
 181         sound(NULL, CH_TRIGGER, SND_KA_DROPPED, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 182
 183         // scoring
 184         // GameRules_scoring_add(plyr, KEEPAWAY_DROPS, 1); Not anymore, this is 100% the same as pickups and is useless.
 185
 186         // waypoints
 187         WaypointSprite_Spawn(WP_KaBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
 188         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 189         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 190         WaypointSprite_Kill(plyr.waypointsprite_attachedforcarrier);
 191 }
 192
 193 /** used to clear the ballcarrier whenever the match switches from warmup to normal */
 194 void ka_Reset(entity this)
 195 {
 196         if((this.owner) && (IS_PLAYER(this.owner)))
 197                 ka_DropEvent(this.owner);
 198
 199         if(time < game_starttime)
 200         {
 201                 setthink(this, ka_RespawnBall);
 202                 settouch(this, func_null);
 203                 this.nextthink = game_starttime;
 204         }
 205         else
 206                 ka_RespawnBall(this);
 207 }
 208
 209
 210 // ================
 211 // Bot player logic
 212 // ================
 213
 214 void havocbot_goalrating_ball(entity this, float ratingscale, vector org)
 215 {
 216         float t;
 217         entity ball_owner;
 218         ball_owner = ka_ball.owner;
 219
 220         if (ball_owner == this)
 221                 return;
 222
 223         // If ball is carried by player then hunt them down.
 224         if (ball_owner)
 225         {
 226                 t = (GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR)) / (GetResourceAmount(ball_owner, RESOURCE_HEALTH) + GetResourceAmount(ball_owner, RESOURCE_ARMOR));
 227                 navigation_routerating(this, ball_owner, t * ratingscale, 2000);
 228         }
 229         else // Ball has been dropped so collect.
 230                 navigation_routerating(this, ka_ball, ratingscale, 2000);
 231 }
 232
 233 void havocbot_role_ka_carrier(entity this)
 234 {
 235         if (IS_DEAD(this))
 236                 return;
 237
 238         if (navigation_goalrating_timeout(this))
 239         {
 240                 navigation_goalrating_start(this);
 241                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 242                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 243                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 244                 navigation_goalrating_end(this);
 245
 246                 navigation_goalrating_timeout_set(this);
 247         }
 248
 249         if (!this.ballcarried)
 250         {
 251                 this.havocbot_role = havocbot_role_ka_collector;
 252                 navigation_goalrating_timeout_expire(this, 2);
 253         }
 254 }
 255
 256 void havocbot_role_ka_collector(entity this)
 257 {
 258         if (IS_DEAD(this))
 259                 return;
 260
 261         if (navigation_goalrating_timeout(this))
 262         {
 263                 navigation_goalrating_start(this);
 264                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 265                 havocbot_goalrating_enemyplayers(this, 500, this.origin, 10000);
 266                 havocbot_goalrating_ball(this, 20000, this.origin);
 267                 navigation_goalrating_end(this);
 268
 269                 navigation_goalrating_timeout_set(this);
 270         }
 271
 272         if (this.ballcarried)
 273         {
 274                 this.havocbot_role = havocbot_role_ka_carrier;
 275                 navigation_goalrating_timeout_expire(this, 2);
 276         }
 277 }
 278
 279
 280 // ==============
 281 // Hook Functions
 282 // ==============
 283
 284 MUTATOR_HOOKFUNCTION(ka, PlayerDies)
 285 {
 286         entity frag_attacker = M_ARGV(1, entity);
 287         entity frag_target = M_ARGV(2, entity);
 288
 289         if((frag_attacker != frag_target) && (IS_PLAYER(frag_attacker)))
 290         {
 291                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 292                         GameRules_scoring_add(frag_attacker, KEEPAWAY_CARRIERKILLS, 1);
 293                         if(autocvar_g_keepaway_score_bckill) // add bckills to the score
 294                                 GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_bckill);
 295                 }
 296                 else if(!frag_attacker.ballcarried)
 297                         if(autocvar_g_keepaway_noncarrier_warn)
 298                                 Send_Notification(NOTIF_ONE_ONLY, frag_attacker, MSG_CENTER, CENTER_KEEPAWAY_WARN);
 299
 300                 if(frag_attacker.ballcarried) // add to amount of kills while ballcarrier
 301                         GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_killac);
 302         }
 303
 304         if(frag_target.ballcarried) { ka_DropEvent(frag_target); } // a player with the ball has died, drop it
 305 }
 306
 307 MUTATOR_HOOKFUNCTION(ka, GiveFragsForKill)
 308 {
 309         M_ARGV(2, float) = 0; // no frags counted in keepaway
 310         return true; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 311 }
 312
 313 MUTATOR_HOOKFUNCTION(ka, PlayerPreThink)
 314 {
 315         entity player = M_ARGV(0, entity);
 316
 317         // clear the item used for the ball in keepaway
 318         player.items &= ~IT_KEY1;
 319
 320         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 321         if(player.ballcarried)
 322                 player.items |= IT_KEY1;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(ka, PlayerUseKey)
 326 {
 327         entity player = M_ARGV(0, entity);
 328
 329         if(MUTATOR_RETURNVALUE == 0)
 330         if(player.ballcarried)
 331         {
 332                 ka_DropEvent(player);
 333                 return true;
 334         }
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(ka, Damage_Calculate) // for changing damage and force values that are applied to players in g_damage.qc
 338 {
 339         entity frag_attacker = M_ARGV(1, entity);
 340         entity frag_target = M_ARGV(2, entity);
 341         float frag_damage = M_ARGV(4, float);
 342         vector frag_force = M_ARGV(6, vector);
 343
 344         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 345         {
 346                 if(frag_target == frag_attacker) // damage done to yourself
 347                 {
 348                         frag_damage *= autocvar_g_keepaway_ballcarrier_selfdamage;
 349                         frag_force *= autocvar_g_keepaway_ballcarrier_selfforce;
 350                 }
 351                 else // damage done to noncarriers
 352                 {
 353                         frag_damage *= autocvar_g_keepaway_ballcarrier_damage;
 354                         frag_force *= autocvar_g_keepaway_ballcarrier_force;
 355                 }
 356         }
 357         else if (!frag_target.ballcarried) // if the target is a noncarrier
 358         {
 359                 if(frag_target == frag_attacker) // damage done to yourself
 360                 {
 361                         frag_damage *= autocvar_g_keepaway_noncarrier_selfdamage;
 362                         frag_force *= autocvar_g_keepaway_noncarrier_selfforce;
 363                 }
 364                 else // damage done to other noncarriers
 365                 {
 366                         frag_damage *= autocvar_g_keepaway_noncarrier_damage;
 367                         frag_force *= autocvar_g_keepaway_noncarrier_force;
 368                 }
 369         }
 370
 371         M_ARGV(4, float) = frag_damage;
 372         M_ARGV(6, vector) = frag_force;
 373 }
 374
 375 MUTATOR_HOOKFUNCTION(ka, ClientDisconnect)
 376 {
 377         entity player = M_ARGV(0, entity);
 378
 379         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 380 }
 381
 382 MUTATOR_HOOKFUNCTION(ka, MakePlayerObserver)
 383 {
 384         entity player = M_ARGV(0, entity);
 385
 386         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 387 }
 388
 389 MUTATOR_HOOKFUNCTION(ka, PlayerPowerups)
 390 {
 391         entity player = M_ARGV(0, entity);
 392
 393         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 394         // So bare with me until I can fix a certain bug with ka_ballcarrier_waypointsprite_visible_for_player()
 395
 396         player.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 397
 398         if(player.ballcarried)
 399                 player.effects |= autocvar_g_keepaway_ballcarrier_effects;
 400 }
 401
 402
 403 MUTATOR_HOOKFUNCTION(ka, PlayerPhysics_UpdateStats)
 404 {
 405         entity player = M_ARGV(0, entity);
 406         // these automatically reset, no need to worry
 407
 408         if(player.ballcarried)
 409                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_keepaway_ballcarrier_highspeed;
 410 }
 411
 412 MUTATOR_HOOKFUNCTION(ka, BotShouldAttack)
 413 {
 414         entity bot = M_ARGV(0, entity);
 415         entity targ = M_ARGV(1, entity);
 416
 417         // if neither player has ball then don't attack unless the ball is on the ground
 418         if(!targ.ballcarried && !bot.ballcarried && ka_ball.owner)
 419                 return true;
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(ka, HavocBot_ChooseRole)
 423 {
 424         entity bot = M_ARGV(0, entity);
 425
 426         if (bot.ballcarried)
 427                 bot.havocbot_role = havocbot_role_ka_carrier;
 428         else
 429                 bot.havocbot_role = havocbot_role_ka_collector;
 430         return true;
 431 }
 432
 433 MUTATOR_HOOKFUNCTION(ka, DropSpecialItems)
 434 {
 435         entity frag_target = M_ARGV(0, entity);
 436
 437         if(frag_target.ballcarried)
 438                 ka_DropEvent(frag_target);
 439 }
 440
 441 .bool pushable;
 442
 443 // ==============
 444 // Initialization
 445 // ==============
 446
 447 MODEL(KA_BALL, "models/orbs/orbblue.md3");
 448
 449 void ka_SpawnBall() // loads various values for the ball, runs only once at start of match
 450 {
 451         entity e = new(keepawayball);
 452         setmodel(e, MDL_KA_BALL);
 453         setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
 454         e.damageforcescale = autocvar_g_keepawayball_damageforcescale;
 455         e.takedamage = DAMAGE_YES;
 456         e.solid = SOLID_TRIGGER;
 457         set_movetype(e, MOVETYPE_BOUNCE);
 458         e.glow_color = autocvar_g_keepawayball_trail_color;
 459         e.glow_trail = true;
 460         e.flags = FL_ITEM;
 461         IL_PUSH(g_items, e);
 462         e.pushable = true;
 463         e.reset = ka_Reset;
 464         settouch(e, ka_TouchEvent);
 465         e.owner = NULL;
 466         ka_ball = e;
 467         navigation_dynamicgoal_init(ka_ball, false);
 468
 469         InitializeEntity(e, ka_RespawnBall, INITPRIO_SETLOCATION); // is this the right priority? Neh, I have no idea.. Well-- it works! So.
 470 }
 471
 472 void ka_Initialize() // run at the start of a match, initiates game mode
 473 {
 474         ka_SpawnBall();
 475 }
 476 #endif