qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3         #include <common/util.qh>
   4         #include <common/weapons/_all.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7         #include <common/util.qh>
   8         #include <common/monsters/_mod.qh>
   9 #endif
  10
  11 int autocvar_g_mapinfo_q3compat = 1;
  12
  13 #ifdef SVQC
  14         bool autocvar_g_mapinfo_ignore_warnings;
  15         #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
  16 #else
  17         #define WARN_COND false
  18 #endif
  19
  20 // generic string stuff
  21
  22 int _MapInfo_Cache_Active;
  23 int _MapInfo_Cache_DB_NameToIndex;
  24 int _MapInfo_Cache_Buf_IndexToMapData;
  25
  26 void MapInfo_Cache_Destroy()
  27 {
  28         if(!_MapInfo_Cache_Active)
  29                 return;
  30
  31         db_close(_MapInfo_Cache_DB_NameToIndex);
  32         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  33         _MapInfo_Cache_Active = 0;
  34 }
  35
  36 void MapInfo_Cache_Create()
  37 {
  38         MapInfo_Cache_Destroy();
  39         _MapInfo_Cache_DB_NameToIndex = db_create();
  40         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  41         _MapInfo_Cache_Active = 1;
  42 }
  43
  44 void MapInfo_Cache_Invalidate()
  45 {
  46         if(!_MapInfo_Cache_Active)
  47                 return;
  48
  49         MapInfo_Cache_Create();
  50 }
  51
  52 void MapInfo_Cache_Store()
  53 {
  54         float i;
  55         string s;
  56         if(!_MapInfo_Cache_Active)
  57                 return;
  58
  59         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  60         if(s == "")
  61         {
  62                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  63                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  64         }
  65         else
  66                 i = stof(s);
  67
  68         // now store all the stuff
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  76         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  77 }
  78
  79 float MapInfo_Cache_Retrieve(string map)
  80 {
  81         float i;
  82         string s;
  83         if(!_MapInfo_Cache_Active)
  84                 return 0;
  85
  86         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  87         if(s == "")
  88                 return 0;
  89         i = stof(s);
  90
  91         // now retrieve all the stuff
  92         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  93         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  94         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  96         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  97         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  98         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  99         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 100
 101         return 1;
 102 }
 103
 104 // GLOB HANDLING (for all BSP files)
 105 float _MapInfo_globopen;
 106 float _MapInfo_globcount;
 107 float _MapInfo_globhandle;
 108 string _MapInfo_GlobItem(float i)
 109 {
 110         string s;
 111         if(!_MapInfo_globopen)
 112                 return string_null;
 113         s = search_getfilename(_MapInfo_globhandle, i);
 114         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 115 }
 116
 117 void MapInfo_Enumerate()
 118 {
 119         if(_MapInfo_globopen)
 120         {
 121                 search_end(_MapInfo_globhandle);
 122                 _MapInfo_globopen = 0;
 123         }
 124         MapInfo_Cache_Invalidate();
 125         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 126         if(_MapInfo_globhandle >= 0)
 127         {
 128                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 129                 _MapInfo_globopen = 1;
 130         }
 131         else
 132                 _MapInfo_globcount = 0;
 133 }
 134
 135 // filter the info by game type mask (updates MapInfo_count)
 136 //
 137 float _MapInfo_filtered;
 138 float _MapInfo_filtered_allocated;
 139 float MapInfo_FilterList_Lookup(float i)
 140 {
 141         return stof(bufstr_get(_MapInfo_filtered, i));
 142 }
 143
 144 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 145 {
 146         string h;
 147         h = bufstr_get(_MapInfo_filtered, i);
 148         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 149         bufstr_set(_MapInfo_filtered, j, h);
 150 }
 151
 152 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 153 {
 154         string a, b;
 155         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 156         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 157         return strcasecmp(a, b);
 158 }
 159
 160 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 161 {
 162         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 163 }
 164 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 165 {
 166         float i, j;
 167         if (!_MapInfo_filtered_allocated)
 168         {
 169                 _MapInfo_filtered_allocated = 1;
 170                 _MapInfo_filtered = buf_create();
 171         }
 172         MapInfo_count = 0;
 173         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 174         {
 175                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 176                         if(pAbortOnGenerate)
 177                         {
 178                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 179                                 MapInfo_progress = i / _MapInfo_globcount;
 180                                 return 0;
 181                         }
 182                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 183                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 184                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 185                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 186                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 187         }
 188         MapInfo_count = j + 1;
 189         MapInfo_ClearTemps();
 190
 191         // sometimes the glob isn't sorted nicely, so fix it here...
 192         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 193
 194         return 1;
 195 }
 196 void MapInfo_FilterString(string sf)
 197 {
 198         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 199         float i, j;
 200         string title;
 201
 202         for(i = 0, j = -1; i < MapInfo_count; ++i)
 203         {
 204                 if (MapInfo_Get_ByID(i))
 205                 {
 206                         // prepare for keyword filter
 207                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 208                                 title = MapInfo_Map_title;
 209                         else
 210                                 title = MapInfo_Map_bspname;
 211                         // keyword filter
 212                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 213                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 214                 }
 215         }
 216         MapInfo_count = j + 1;
 217         MapInfo_ClearTemps();
 218
 219         // sometimes the glob isn't sorted nicely, so fix it here...
 220         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 221 }
 222
 223 void MapInfo_Filter_Free()
 224 {
 225         if(_MapInfo_filtered_allocated)
 226         {
 227                 buf_del(_MapInfo_filtered);
 228                 _MapInfo_filtered_allocated = 0;
 229         }
 230 }
 231
 232 // load info about the i-th map into the MapInfo_Map_* globals
 233 string MapInfo_BSPName_ByID(float i)
 234 {
 235         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 236 }
 237
 238 string unquote(string s)
 239 {
 240         float l = strlen(s);
 241         for(float i = 0; i < l; ++i)
 242         {
 243                 string ch = substring(s, i, 1);
 244                 if((ch != " ") && (ch != "\""))
 245                 {
 246                         for(float j = l - i - 1; j > 0; --j)
 247                         {
 248                                 ch = substring(s, i+j, 1);
 249                                 if(ch != " ") if(ch != "\"")
 250                                         return substring(s, i, j+1);
 251                         }
 252                         return substring(s, i, 1);
 253                 }
 254         }
 255         return "";
 256 }
 257
 258 bool MapInfo_Get_ByID(int i)
 259 {
 260         return MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL) ? true : false;
 261 }
 262
 263 string _MapInfo_Map_worldspawn_music;
 264
 265 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 266 {
 267         string fn;
 268         float fh;
 269         string s, k, v;
 270         vector o;
 271         float i;
 272         float inWorldspawn;
 273         float r;
 274         float diameter, spawnpoints;
 275         float spawnplaces;
 276         bool is_q3df_map = false;
 277         vector mapMins, mapMaxs;
 278
 279         if(autocvar_g_mapinfo_q3compat >= 2) // generate mapinfo using arena data
 280         {
 281                 // try for .arena or .defi files, as they may have more accurate information
 282                 // supporting .arena AND .defi for the same map
 283                 bool success = false;
 284                 fh = -1;
 285                 fn = _MapInfo_FindArenaFile(pFilename, ".arena");
 286                 if(fn != "" && (fh = fopen(fn, FILE_READ)) >= 0)
 287                 {
 288                         success = _MapInfo_ParseArena(fn, fh, pFilename, NULL, false, true);
 289                         fclose(fh);
 290                 }
 291                 fn = _MapInfo_FindArenaFile(pFilename, ".defi");
 292                 if(fn != "" && (fh = fopen(fn, FILE_READ)) >= 0)
 293                 {
 294                         success |= _MapInfo_ParseArena(fn, fh, pFilename, NULL, true, true);
 295                         fclose(fh);
 296                 }
 297                 if (success && autocvar_g_mapinfo_q3compat == 3)
 298                         return 3; // skip entity analysis
 299         }
 300
 301         r = 1;
 302         fn = strcat("maps/", pFilename, ".ent");
 303         fh = fopen(fn, FILE_READ);
 304         if(fh < 0)
 305         {
 306                 r = 2;
 307                 fn = strcat("maps/", pFilename, ".bsp");
 308                 fh = fopen(fn, FILE_READ);
 309         }
 310         if(fh < 0)
 311                 return 0;
 312         LOG_INFO("Generating ", pFilename, ".mapinfo: analyzing ", fn);
 313
 314         inWorldspawn = 2;
 315         spawnpoints = 0;
 316         spawnplaces = 0;
 317         _MapInfo_Map_worldspawn_music = "";
 318         mapMins = '0 0 0';
 319         mapMaxs = '0 0 0';
 320
 321         for (;;)
 322         {
 323                 if (!((s = fgets(fh))))
 324                         break;
 325                 if(inWorldspawn == 1)
 326                         if(startsWith(s, "}"))
 327                                 inWorldspawn = 0;
 328                 k = unquote(car(s));
 329                 v = unquote(cdr(s));
 330                 if(inWorldspawn)
 331                 {
 332                         if(k == "classname" && v == "worldspawn")
 333                                 inWorldspawn = 1;
 334                         else if(k == "author")
 335                                 MapInfo_Map_author = v;
 336                         else if(k == "_description")
 337                                 MapInfo_Map_description = v;
 338                         else if(k == "music")
 339                                 _MapInfo_Map_worldspawn_music = v;
 340                         else if(k == "noise")
 341                                 _MapInfo_Map_worldspawn_music = v;
 342                         else if(k == "message" && (!MapInfo_Map_title || MapInfo_Map_title == "<TITLE>") && v != "")
 343                                 MapInfo_Map_title = v;
 344                 }
 345                 else
 346                 {
 347                         if(k == "origin")
 348                         {
 349                                 o = stov(strcat("'", v, "'"));
 350                                 mapMins.x = min(mapMins.x, o.x);
 351                                 mapMins.y = min(mapMins.y, o.y);
 352                                 mapMins.z = min(mapMins.z, o.z);
 353                                 mapMaxs.x = max(mapMaxs.x, o.x);
 354                                 mapMaxs.y = max(mapMaxs.y, o.y);
 355                                 mapMaxs.z = max(mapMaxs.z, o.z);
 356                         }
 357                         else if(k == "race_place")
 358                         {
 359                                 if(stof(v) > 0)
 360                                         spawnplaces = 1;
 361                         }
 362                         else if(k == "classname")
 363                         {
 364                                 if(v == "info_player_team1")
 365                                         ++spawnpoints;
 366                                 else if(v == "info_player_team2")
 367                                         ++spawnpoints;
 368                                 else if(v == "info_player_start")
 369                                         ++spawnpoints;
 370                                 else if(v == "info_player_deathmatch")
 371                                         ++spawnpoints;
 372                                 else if(v == "weapon_nex")
 373                                         { }
 374                                 else if(v == "weapon_railgun")
 375                                         { }
 376                                 else if(startsWith(v, "weapon_"))
 377                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 378                                 else if(startsWith(v, "turret_"))
 379                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 380                                 else if(startsWith(v, "vehicle_"))
 381                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 382                                 else if(startsWith(v, "monster_"))
 383                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 384                                 else if(v == "target_music" || v == "trigger_music")
 385                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 386                                 else if(v == "target_stopTimer")
 387                                         is_q3df_map = true; // don't support standard gametypes UNLESS we found them in .arena
 388                                 else
 389                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 390                         }
 391                 }
 392         }
 393         if(inWorldspawn)
 394         {
 395                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 396                 return 0;
 397         }
 398         diameter = vlen(mapMaxs - mapMins);
 399
 400         int twoBaseModes = 0;
 401         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 402         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 403         {
 404                 // we have a symmetrical map, don't add the modes without bases
 405         }
 406         else if(!is_q3df_map)
 407         {
 408                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 409         }
 410
 411         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 412         if(!spawnplaces)
 413         {
 414                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 415                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 416         }
 417
 418         LOG_TRACE("-> diameter ",    ftos(diameter));
 419         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 420         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 421
 422         fclose(fh);
 423
 424         return r;
 425 }
 426
 427 void _MapInfo_Map_Reset()
 428 {
 429         MapInfo_Map_title = "<TITLE>";
 430         MapInfo_Map_titlestring = "<TITLE>";
 431         MapInfo_Map_description = "<DESCRIPTION>";
 432         MapInfo_Map_author = "<AUTHOR>";
 433         MapInfo_Map_supportedGametypes = 0;
 434         MapInfo_Map_supportedFeatures = 0;
 435         MapInfo_Map_flags = 0;
 436         MapInfo_Map_clientstuff = "";
 437         MapInfo_Map_fog = "";
 438         MapInfo_Map_mins = '0 0 0';
 439         MapInfo_Map_maxs = '0 0 0';
 440 }
 441
 442 string _MapInfo_GetDefault(Gametype t)
 443 {
 444         return t.m_legacydefaults;
 445 }
 446
 447 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 448 {
 449         string sa;
 450         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 451         if(!(pThisType.m_flags & pWantedType.m_flags))
 452                 return;
 453
 454         if(load_default)
 455                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 456
 457         if(!pWantedType.frags) // these modes don't use fraglimit
 458         {
 459                 cvar_set("fraglimit", "0");
 460         }
 461         else
 462         {
 463                 sa = car(s);
 464                 if(sa != "")
 465                         cvar_set("fraglimit", sa);
 466                 s = cdr(s);
 467         }
 468
 469         sa = car(s);
 470         if(sa != "")
 471                 cvar_set("timelimit", sa);
 472         s = cdr(s);
 473
 474         if(pWantedType.m_setTeams)
 475         {
 476                 sa = car(s);
 477                 if(sa != "")
 478                         pWantedType.m_setTeams(sa);
 479                 s = cdr(s);
 480         }
 481
 482         // rc = timelimit timelimit_qualification laps laps_teamplay
 483         if(pWantedType == MAPINFO_TYPE_RACE)
 484         {
 485                 cvar_set("fraglimit", "0"); // special case!
 486
 487                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 488                 cvar_set("g_race_qualifying_timelimit", sa);
 489                 s = cdr(s);
 490
 491                 sa = car(s);
 492                 if(sa != "")
 493                         if(cvar("g_race_teams") < 2)
 494                                 cvar_set("fraglimit", sa);
 495                 s = cdr(s);
 496
 497                 sa = car(s);
 498                 if(sa != "")
 499                         if(cvar("g_race_teams") >= 2)
 500                                 cvar_set("fraglimit", sa);
 501                 s = cdr(s);
 502         }
 503
 504         if(!pWantedType.frags) // these modes don't use fraglimit
 505         {
 506                 cvar_set("leadlimit", "0");
 507         }
 508         else
 509         {
 510                 sa = car(s);
 511                 if(sa != "")
 512                         cvar_set("leadlimit", sa);
 513                 s = cdr(s);
 514         }
 515 }
 516
 517 string _MapInfo_GetDefaultEx(Gametype t)
 518 {
 519         return t ? t.model2 : "";
 520 }
 521
 522 float _MapInfo_GetTeamPlayBool(Gametype t)
 523 {
 524         return t ? t.team : false;
 525 }
 526
 527 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 528 {
 529         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 530         if (!(pThisType.m_flags & pWantedType.m_flags))
 531                 return;
 532
 533         // reset all the cvars to their defaults
 534
 535         cvar_set("timelimit", cvar_defstring("timelimit"));
 536         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 537         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 538         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 539
 540         string fraglimit_normal = string_null;
 541         string fraglimit_teams = string_null;
 542
 543         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 544                 string sa = car(s);
 545                 if (sa == "") continue;
 546                 int p = strstrofs(sa, "=", 0);
 547                 if (p < 0) {
 548                         if(WARN_COND)
 549                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 550                         continue;
 551                 }
 552                 string k = substring(sa, 0, p);
 553                 string v = substring(sa, p + 1, -1);
 554                 bool handled = true;
 555                 switch (k) {
 556                         case "timelimit":
 557                         {
 558                                 cvar_set("timelimit", v);
 559                                 break;
 560                         }
 561                         case "leadlimit":
 562                         {
 563                                 cvar_set("leadlimit", v);
 564                                 break;
 565                         }
 566                         case "pointlimit":
 567                         case "fraglimit":
 568                         case "lives":
 569                         case "laplimit":
 570                         case "caplimit":
 571                         {
 572                                 fraglimit_normal = v;
 573                                 break;
 574                         }
 575                         case "teampointlimit":
 576                         case "teamlaplimit":
 577                         {
 578                                 fraglimit_teams = v;
 579                                 break;
 580                         }
 581                         default:
 582                         {
 583                             handled = false;
 584                             break;
 585                         }
 586                 }
 587                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 588                 if (!handled && WARN_COND)
 589             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 590         }
 591
 592         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 593         {
 594                 if(fraglimit_teams)
 595                         cvar_set("fraglimit", fraglimit_teams);
 596         }
 597         else
 598         {
 599                 if(fraglimit_normal)
 600                         cvar_set("fraglimit", fraglimit_normal);
 601         }
 602 }
 603
 604 Gametype MapInfo_Type_FromString(string gtype, bool dowarn, bool is_q3compat)
 605 {
 606         string replacement = "";
 607
 608         switch (gtype)
 609         {
 610                 case "nexball":   replacement = "nb"; break;
 611                 case "freezetag": replacement = "ft"; break;
 612                 case "keepaway":  replacement = "ka"; break;
 613                 case "invasion":  replacement = "inv"; break;
 614                 case "assault":   replacement = "as"; break;
 615                 case "race":      replacement = "rc"; break;
 616                 // Q3/QL compat, see DoesQ3ARemoveThisEntity() in quake3.qc for complete lists
 617                 case "ffa":       replacement = "dm"; break;
 618                 case "cctf": // from ThreeWave, maps with this should all have "ctf" too
 619                 case "oneflag":   replacement = "ctf"; break;
 620                 case "tourney":   replacement = "duel"; break;
 621                 case "arena": // which Q3 mod is this from? In Nexuiz it was 'duel with rounds'.
 622                         if(is_q3compat) { replacement = "ca"; } break;
 623         }
 624         if (replacement != "")
 625         {
 626                 if (dowarn && WARN_COND)
 627                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
 628                 gtype = replacement;
 629         }
 630         FOREACH(Gametypes, it.mdl == gtype, return it);
 631         return NULL;
 632 }
 633
 634 string MapInfo_Type_Description(Gametype t)
 635 {
 636         return t ? t.gametype_description : "";
 637 }
 638
 639 string MapInfo_Type_ToString(Gametype t)
 640 {
 641         return t ? t.mdl : "";
 642 }
 643
 644 string MapInfo_Type_ToText(Gametype t)
 645 {
 646         /* xgettext:no-c-format */
 647         return t ? t.message : _("@!#%'n Tuba Throwing");
 648 }
 649
 650 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 651 {
 652         string t;
 653         float o;
 654         // tabs are invalid, treat them as "empty"
 655         s = strreplace("\t", "", s);
 656
 657         t = car(s); s = cdr(s);
 658
 659         // limited support of "" and comments
 660         //   remove trailing and leading " of t
 661         if(substring(t, 0, 1) == "\"")
 662         {
 663                 if(substring(t, -1, 1) == "\"")
 664                         t = substring(t, 1, -2);
 665         }
 666
 667         //   remove leading " of s
 668         if(substring(s, 0, 1) == "\"")
 669         {
 670                 s = substring(s, 1, -1);
 671         }
 672         //   remove trailing " of s, and all that follows (cvar description)
 673         o = strstrofs(s, "\"", 0);
 674         if(o >= 0)
 675                 s = substring(s, 0, o);
 676
 677         //   remove // comments
 678         o = strstrofs(s, "//", 0);
 679         if(o >= 0)
 680                 s = substring(s, 0, o);
 681
 682         //   remove trailing spaces
 683         while(substring(s, -1, 1) == " ")
 684                 s = substring(s, 0, -2);
 685
 686         if(t == "#include")
 687         {
 688                 if(recurse > 0)
 689                 {
 690                         float fh = fopen(s, FILE_READ);
 691                         if(fh < 0)
 692                         {
 693                                 if(WARN_COND)
 694                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 695                         }
 696                         else
 697                         {
 698                                 while((s = fgets(fh)))
 699                                 {
 700                                         s = strreplace("\t", "", s); // treat tabs as "empty", perform here first to ensure coments are detected
 701                                         // catch different sorts of comments
 702                                         if(s == "")                    // empty lines
 703                                                 continue;
 704                                         if(substring(s, 0, 1) == "#")  // UNIX style
 705                                                 continue;
 706                                         if(substring(s, 0, 2) == "//") // C++ style
 707                                                 continue;
 708                                         if(substring(s, 0, 1) == "_")  // q3map style
 709                                                 continue;
 710
 711                                         if(substring(s, 0, 4) == "set ")
 712                                                 s = substring(s, 4, -1);
 713                                         if(substring(s, 0, 5) == "seta ")
 714                                                 s = substring(s, 5, -1);
 715
 716                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 717                                 }
 718                                 fclose(fh);
 719                         }
 720                 }
 721                 else if(WARN_COND)
 722                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 723         }
 724         else if(t == ""
 725                 || !cvar_value_issafe(t)
 726                 || !cvar_value_issafe(s)
 727                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 728         {
 729                 if (WARN_COND)
 730                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 731         }
 732         else if(matchacl(acl, t) <= 0)
 733         {
 734                 if (WARN_COND)
 735                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 736         }
 737         else
 738         {
 739                 if(type == 0) // server set
 740                 {
 741                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 742                 #if 0
 743                         if(cvar("g_campaign"))
 744                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 745                         else
 746                 #endif
 747                                 cvar_settemp(t, s);
 748                 }
 749                 else
 750                 {
 751                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 752                         MapInfo_Map_clientstuff = strcat(
 753                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 754                                         );
 755                 }
 756         }
 757 }
 758
 759 /// Removes author string from title (if found)
 760 /// and copies it to MapInfo_Map_author if that wasn't set.
 761 string MapInfo_title_sans_author(string title)
 762 {
 763         int offset;
 764
 765         if ((offset = strstrofs(title, " by ", 0)) >= 0)
 766         {
 767                 if (MapInfo_Map_author == "<AUTHOR>")
 768                         MapInfo_Map_author = substring(title, offset + 4, strlen(title) - (offset + 4));
 769                 title = substring(title, 0, offset);
 770         }
 771
 772         return title != "" ? title : "<TITLE>";
 773 }
 774
 775 bool MapInfo_isRedundant(string fn, string t)
 776 {
 777         // normalize file name
 778         fn = strreplace("_", "", fn);
 779         fn = strreplace("-", "", fn);
 780
 781         // normalize visible title
 782         t = strreplace(":", "", t);
 783         t = strreplace(" ", "", t);
 784         t = strreplace("_", "", t);
 785         t = strreplace("-", "", t);
 786         t = strreplace("'", "", t);
 787         t = strdecolorize(t);
 788
 789         // we allow the visible title to have punctuation the file name does
 790         // not, but not vice versa
 791         if(!strcasecmp(fn, t))
 792                 return true;
 793
 794         return false;
 795 }
 796
 797 bool _MapInfo_ParseArena(string arena_filename, int fh, string pFilename, Gametype pGametypeToSet, bool isdefi, bool isgenerator)
 798 {
 799         // NOTE: .arena files can hold more than 1 map's information!
 800         // to handle this, we're going to store gathered information in local variables and save it if we encounter the correct map name
 801         bool in_brackets = false; // testing a potential mapinfo section (within brackets)
 802         bool dosave = false;
 803         string stored_Map_description = "";
 804         string stored_Map_title = "";
 805         string stored_Map_author = "";
 806         int stored_supportedGametypes = 0;
 807         int stored_supportedFeatures = 0;
 808         int stored_flags = 0;
 809         string t, s;
 810
 811         if (isgenerator)
 812                 LOG_INFO("Generating ", pFilename, ".mapinfo: analyzing ", arena_filename);
 813
 814         for (;;)
 815         {
 816                 if (!((s = fgets(fh))))
 817                         break;
 818
 819                 // catch different sorts of comments
 820                 if(s == "")                    // empty lines
 821                         continue;
 822                 if(substring(s, 0, 2) == "//") // C++ style
 823                         continue;
 824                 if(strstrofs(s, "{", 0) >= 0)
 825                 {
 826                         if(in_brackets)
 827                                 return false; // edge case? already in a bracketed section!
 828                         in_brackets = true;
 829                         continue;
 830                 }
 831                 else if(!in_brackets)
 832                 {
 833                         // if we're not inside a bracket, don't process map info
 834                         continue;
 835                 }
 836                 if(strstrofs(s, "}", 0) >= 0)
 837                 {
 838                         if(!in_brackets)
 839                                 return false; // no starting bracket! let the mapinfo generation system handle it
 840                         in_brackets = false;
 841                         if(dosave)
 842                         {
 843                                 MapInfo_Map_description = stored_Map_description;
 844                                 if(stored_Map_title != "")
 845                                         MapInfo_Map_title = stored_Map_title;
 846                                 MapInfo_Map_author = stored_Map_author;
 847                                 // might have .arena AND .defi for the same map so these bitfields are OR'd
 848                                 if(isgenerator)
 849                                         MapInfo_Map_supportedGametypes |= stored_supportedGametypes;
 850                                 else
 851                                 {
 852                                         FOREACH(Gametypes, it.m_flags & stored_supportedGametypes,
 853                                         {
 854                                                 _MapInfo_Map_ApplyGametype ("", pGametypeToSet, it, true);
 855                                         });
 856                                 }
 857                                 MapInfo_Map_supportedFeatures |= stored_supportedFeatures;
 858                                 MapInfo_Map_flags |= stored_flags;
 859                                 return true; // no need to continue through the file, we have our map!
 860                         }
 861                         else
 862                         {
 863                                 // discard any gathered locals, we're not using the correct map!
 864                                 stored_Map_description = "";
 865                                 stored_Map_title = "";
 866                                 stored_Map_author = "";
 867                                 stored_supportedGametypes = 0;
 868                                 stored_supportedFeatures = 0;
 869                                 stored_flags = 0;
 870                                 continue;
 871                         }
 872                 }
 873
 874                 s = strreplace("\t", " ", s);
 875
 876                 float p = strstrofs(s, "//", 0);
 877                 if(p >= 0)
 878                         s = substring(s, 0, p);
 879
 880                 // perform an initial trim to ensure the first argument is properly obtained
 881                 //   remove leading spaces
 882                 while(substring(s, 0, 1) == " ")
 883                         s = substring(s, 1, -1);
 884
 885                 t = car(s); s = cdr(s);
 886                 t = strtolower(t); // apparently some q3 maps use capitalized parameters
 887
 888                 //   remove trailing spaces
 889                 while(substring(t, -1, 1) == " ")
 890                         t = substring(t, 0, -2);
 891
 892                 //   remove trailing spaces
 893                 while(substring(s, -1, 1) == " ")
 894                         s = substring(s, 0, -2);
 895                 //   remove leading spaces
 896                 while(substring(s, 0, 1) == " ")
 897                         s = substring(s, 1, -1);
 898                 // limited support of ""
 899                 //   remove trailing and leading " of s
 900                 if(substring(s, 0, 1) == "\"")
 901                 {
 902                         if(substring(s, -1, 1) == "\"")
 903                                 s = substring(s, 1, -2);
 904                 }
 905                 if(t == "longname")
 906                         stored_Map_title = s;
 907                 else if(t == "author")
 908                         stored_Map_author = s;
 909                 else if(t == "type")
 910                 {
 911                         // if there is a valid gametype in this .arena file, include it in the menu
 912                         stored_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 913                         // type in quake 3 holds all the supported gametypes, so we must loop through all of them
 914                         // TODO: handle support here better to include more Xonotic teamplay modes
 915                         string types = s;
 916                         types = strreplace("team", "tdm ft", types);
 917                         types = strreplace("ffa", "dm lms ka", types);
 918                         types = strreplace("tourney", "duel", types); // QL used duel so the following check must support it
 919                         if(strstrofs(types, "duel", 0) < 0 && strstrofs(types, "tdm", 0) >= 0) // larger team map, support additional gamemodes!
 920                                 types = cons(types, "ca kh");
 921                         FOREACH_WORD(types, true,
 922                         {
 923                                 Gametype f = MapInfo_Type_FromString(it, false, true);
 924                                 if(f)
 925                                         stored_supportedGametypes |= f.m_flags;
 926                         });
 927                 }
 928                 else if(t == "style" && isdefi)
 929                 {
 930                         // we have a defrag map on our hands, add CTS!
 931                         // TODO: styles
 932                         stored_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 933                 }
 934                 else if(t == "map")
 935                 {
 936                         if(strtolower(s) == strtolower(pFilename))
 937                                 dosave = true; // yay, found our map!
 938                 }
 939                 else if(t == "quote")
 940                         stored_Map_description = s;
 941                 // TODO: fraglimit
 942         }
 943
 944         // if the map wasn't found in the .arena, fall back to generated .mapinfo
 945         return false;
 946 }
 947
 948 string _MapInfo_CheckArenaFile(string pFilename, string pMapname)
 949 {
 950         // returns the file name if valid, otherwise returns ""
 951         // a string is returned to optimise the use cases where a filename is also returned
 952         int fh = fopen(pFilename, FILE_READ);
 953         if(fh < 0)
 954                 return "";
 955         for(string s; (s = fgets(fh)); )
 956         {
 957                 s = strreplace("\t", "", s);
 958                 while(substring(s, 0, 1) == " ")
 959                         s = substring(s, 1, -1);
 960                 if(substring(s, 0, 2) == "//")
 961                         continue;
 962                 if(s == "")
 963                         continue;
 964                 int offset = strstrofs(s, "map", 0);
 965                 if(offset >= 0)
 966                 {
 967                         if(strstrofs(strtolower(s), strcat("\"", strtolower(pMapname), "\""), offset) >= 0) // quake 3 is case insensitive
 968                         {
 969                                 fclose(fh);
 970                                 return pFilename; // FOUND IT!
 971                         }
 972                 }
 973         }
 974         fclose(fh);
 975         return ""; // file did not contain a "map" field matching our map name
 976 }
 977
 978 string _MapInfo_FindArenaFile(string pFilename, string extension)
 979 {
 980         string fallback = strcat("scripts/", pFilename, extension);
 981         if(!checkextension("DP_QC_FS_SEARCH_PACKFILE"))
 982                 return _MapInfo_CheckArenaFile(fallback, pFilename);
 983         string base_pack = whichpack(strcat("maps/", pFilename, ".bsp"));
 984         if(base_pack == "") // this map isn't packaged!
 985                 return _MapInfo_CheckArenaFile(fallback, pFilename);
 986
 987         int glob = search_packfile_begin(strcat("scripts/*", extension), true, true, base_pack);
 988         if(glob < 0)
 989                 return _MapInfo_CheckArenaFile(fallback, pFilename);
 990         int n = search_getsize(glob);
 991         for(int j = 0; j < n; ++j)
 992         {
 993                 string file = search_getfilename(glob, j);
 994                 if(_MapInfo_CheckArenaFile(file, pFilename) != "")
 995                 {
 996                         search_end(glob);
 997                         return file;
 998                 }
 999         }
1000
1001         search_end(glob);
1002         return ""; // if we get here, a valid .arena file could not be found
1003 }
1004
1005 // load info about a map by name into the MapInfo_Map_* globals
1006 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
1007 {
1008         string fn;
1009         string s, t;
1010         float fh;
1011         int f, i;
1012         float r, n;
1013         string acl;
1014
1015         acl = MAPINFO_SETTEMP_ACL_USER;
1016
1017         if(strstrofs(pFilename, "/", 0) >= 0)
1018         {
1019                 LOG_WARN("Invalid character in map name, ignored");
1020                 return 0;
1021         }
1022
1023         if(pGametypeToSet == NULL)
1024                 if(MapInfo_Cache_Retrieve(pFilename))
1025                         return 1;
1026
1027         r = 1;
1028
1029         MapInfo_Map_bspname = pFilename;
1030
1031         // default all generic fields so they have "good" values in case something fails
1032         fn = strcat("maps/", pFilename, ".mapinfo");
1033         fh = fopen(fn, FILE_READ);
1034         if(fh < 0)
1035         {
1036                 if(autocvar_g_mapinfo_q3compat == 1) // use arena data instead of generating a mapinfo file
1037                 {
1038                         // supporting .arena AND .defi for the same map
1039                         bool success = false;
1040                         fn = _MapInfo_FindArenaFile(pFilename, ".arena");
1041                         if(fn != "" && (fh = fopen(fn, FILE_READ)) >= 0)
1042                         {
1043                                 _MapInfo_Map_Reset();
1044                                 success = _MapInfo_ParseArena(fn, fh, pFilename, pGametypeToSet, false, false);
1045                                 fclose(fh);
1046                         }
1047                         fn = _MapInfo_FindArenaFile(pFilename, ".defi");
1048                         if(fn != "" && (fh = fopen(fn, FILE_READ)) >= 0)
1049                         {
1050                                 if(!success)
1051                                         _MapInfo_Map_Reset();
1052                                 success |= _MapInfo_ParseArena(fn, fh, pFilename, pGametypeToSet, true, false);
1053                                 fclose(fh);
1054                         }
1055                         if(success)
1056                                 goto mapinfo_handled; // skip generation
1057                 }
1058
1059                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
1060                 fh = fopen(fn, FILE_READ);
1061                 if(fh < 0)
1062                 {
1063                         if(!pAllowGenerate)
1064                                 return 0;
1065                         _MapInfo_Map_Reset();
1066                         r = _MapInfo_Generate(pFilename);
1067                         if(!r)
1068                                 return 0;
1069                         MapInfo_Map_title = MapInfo_title_sans_author(MapInfo_Map_title);
1070                         fh = fopen(fn, FILE_WRITE);
1071                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
1072                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
1073                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
1074                         if(_MapInfo_Map_worldspawn_music != "")
1075                         {
1076                                 if(strcasecmp(substring(_MapInfo_Map_worldspawn_music, -4, 4), ".wav") == 0 || strcasecmp(substring(_MapInfo_Map_worldspawn_music, -4, 4), ".ogg") == 0)
1077                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, -4), "\n"));
1078                                 else
1079                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
1080                         }
1081                         else
1082                         {
1083                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
1084                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
1085                                 for (;;)
1086                                 {
1087                                         i = floor(random() * n);
1088                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
1089                                                 break;
1090                                 }
1091                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
1092                         }
1093                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
1094                                 fputs(fh, "has weapons\n");
1095                         else
1096                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
1097                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
1098                                 fputs(fh, "has turrets\n");
1099                         else
1100                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
1101                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
1102                                 fputs(fh, "has vehicles\n");
1103                         else
1104                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
1105                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
1106                                 fputs(fh, "frustrating\n");
1107
1108                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
1109                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
1110                         });
1111
1112                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
1113                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
1114                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
1115                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1116                         fputs(fh, "// optional: hidden\n");
1117
1118                         fclose(fh);
1119                         r = 2;
1120                         // return r;
1121                         fh = fopen(fn, FILE_READ);
1122                         if(fh < 0)
1123                                 error("... but I just wrote it!");
1124                 }
1125
1126                 if(WARN_COND)
1127                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
1128         }
1129
1130         _MapInfo_Map_Reset();
1131         for (;;)
1132         {
1133                 if (!((s = fgets(fh))))
1134                         break;
1135
1136                 // catch different sorts of comments
1137                 if(s == "")                    // empty lines
1138                         continue;
1139                 if(substring(s, 0, 1) == "#")  // UNIX style
1140                         continue;
1141                 if(substring(s, 0, 2) == "//") // C++ style
1142                         continue;
1143                 if(substring(s, 0, 1) == "_")  // q3map style
1144                         continue;
1145
1146                 float p = strstrofs(s, "//", 0);
1147                 if(p >= 0)
1148                         s = substring(s, 0, p);
1149
1150                 t = car(s); s = cdr(s);
1151                 if(t == "title")
1152                         MapInfo_Map_title = s;
1153                 else if(t == "description")
1154                         MapInfo_Map_description = s;
1155                 else if(t == "author")
1156                         MapInfo_Map_author = s;
1157                 else if(t == "has")
1158                 {
1159                         t = car(s); // s = cdr(s);
1160                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1161                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1162                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1163                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1164                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1165                         else if(WARN_COND)
1166                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
1167                 }
1168                 else if(t == "hidden")
1169                 {
1170                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1171                 }
1172                 else if(t == "forbidden")
1173                 {
1174                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1175                 }
1176                 else if(t == "frustrating")
1177                 {
1178                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1179                 }
1180                 else if(t == "donotwant" || t == "noautomaplist")
1181                 {
1182                         MapInfo_Map_flags |= MAPINFO_FLAG_DONOTWANT;
1183                 }
1184                 else if(t == "gameversion_min")
1185                 {
1186                         if (cvar("gameversion") < stof(s))
1187                                 MapInfo_Map_flags |= MAPINFO_FLAG_DONOTWANT;
1188                 }
1189                 else if(t == "type")
1190                 {
1191                         t = car(s); s = cdr(s);
1192                         Gametype f = MapInfo_Type_FromString(t, true, false);
1193                         //if(WARN_COND)
1194                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
1195                         if(f)
1196                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1197                         else if(WARN_COND)
1198                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1199                 }
1200                 else if(t == "gametype")
1201                 {
1202                         t = car(s); s = cdr(s);
1203                         Gametype f = MapInfo_Type_FromString(t, true, false);
1204                         if(f)
1205                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1206                         else if(WARN_COND)
1207                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1208                 }
1209                 else if(t == "size")
1210                 {
1211                         float a, b, c, d, e;
1212                         t = car(s); s = cdr(s); a = stof(t);
1213                         t = car(s); s = cdr(s); b = stof(t);
1214                         t = car(s); s = cdr(s); c = stof(t);
1215                         t = car(s); s = cdr(s); d = stof(t);
1216                         t = car(s); s = cdr(s); e = stof(t);
1217                         if(s == "")
1218                         {
1219                                 if(WARN_COND)
1220                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1221                         }
1222                         else
1223                         {
1224                                 t = car(s); s = cdr(s); f = stof(t);
1225                                 if(s != "")
1226                                 {
1227                                         if(WARN_COND)
1228                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1229                                 }
1230                                 else
1231                                 {
1232                                         if(a >= d || b >= e || c >= f)
1233                                         {
1234                                                 if(WARN_COND)
1235                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
1236                                         }
1237                                         else
1238                                         {
1239                                                 MapInfo_Map_mins.x = a;
1240                                                 MapInfo_Map_mins.y = b;
1241                                                 MapInfo_Map_mins.z = c;
1242                                                 MapInfo_Map_maxs.x = d;
1243                                                 MapInfo_Map_maxs.y = e;
1244                                                 MapInfo_Map_maxs.z = f;
1245                                         }
1246                                 }
1247                         }
1248                 }
1249                 else if(t == "settemp_for_type")
1250                 {
1251                         t = car(s); s = cdr(s);
1252                         bool all = t == "all";
1253                         Gametype f = NULL;
1254                         if(all || (f = MapInfo_Type_FromString(t, true, false)))
1255                         {
1256                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1257                                 {
1258                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1259                                 }
1260                         }
1261                         else
1262                         {
1263                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
1264                         }
1265                 }
1266                 else if(t == "clientsettemp_for_type")
1267                 {
1268                         t = car(s); s = cdr(s);
1269                         bool all = t == "all";
1270                         Gametype f = NULL;
1271                         if(all || (f = MapInfo_Type_FromString(t, true, false)))
1272                         {
1273                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1274                                 {
1275                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1276                                 }
1277                         }
1278                         else
1279                         {
1280                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1281                         }
1282                 }
1283                 else if(t == "fog")
1284                 {
1285                         if (!cvar_value_issafe(s))
1286                         {
1287                                 if(WARN_COND)
1288                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1289                         }
1290                         else
1291                                 MapInfo_Map_fog = s;
1292                 }
1293                 else if(t == "cdtrack")
1294                 {
1295                         t = car(s); s = cdr(s);
1296                         // We do this only if pGametypeToSet even though this
1297                         // content is theoretically game type independent,
1298                         // because MapInfo_Map_clientstuff contains otherwise
1299                         // game type dependent stuff. That way this value stays
1300                         // empty when not setting a game type to not set any
1301                         // false expectations.
1302                         if(pGametypeToSet)
1303                         {
1304                                 if (!cvar_value_issafe(t))
1305                                 {
1306                                         if(WARN_COND)
1307                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1308                                 }
1309                                 else
1310                                         MapInfo_Map_clientstuff = strcat(
1311                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1312                                         );
1313                         }
1314                 }
1315                 else if(WARN_COND)
1316                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1317         }
1318         fclose(fh);
1319
1320 LABEL(mapinfo_handled)
1321 #ifdef SVQC
1322         // if the map is currently loaded we can read worldspawn fields directly
1323         if (pFilename == mi_shortname)
1324         {
1325                 if (MapInfo_Map_title == "<TITLE>")
1326                         if (world.message != "")
1327                                 MapInfo_Map_title = world.message;
1328         }
1329 #endif
1330         // Could skip removing author from title when it's source is .mapinfo
1331         // but must always do it for world.message and .arena/.defi as VQ3 didn't support author
1332         // so mappers tended to put it in world.message and/or longname.
1333         MapInfo_Map_title = MapInfo_title_sans_author(MapInfo_Map_title); // may set author if not set
1334
1335         if(MapInfo_Map_title == "<TITLE>")
1336                 MapInfo_Map_titlestring = strcat("^2", MapInfo_Map_bspname);
1337         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1338                 MapInfo_Map_titlestring = strcat("^2", MapInfo_Map_title);
1339         else
1340                 MapInfo_Map_titlestring = sprintf("^2%s ^7// ^2%s", MapInfo_Map_bspname, MapInfo_Map_title);
1341
1342         MapInfo_Cache_Store();
1343         if(MapInfo_Map_supportedGametypes != 0)
1344                 return r;
1345         if (WARN_COND)
1346                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1347         return 0;
1348 }
1349 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1350 {
1351         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1352
1353         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1354
1355         if(pGametypeToSet)
1356         {
1357                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1358                 {
1359                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1360                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1361                         //return;
1362                 }
1363         }
1364
1365         return r;
1366 }
1367
1368 bool MapReadSizes(string map)
1369 {
1370         // TODO: implement xonotic#28 / xonvote 172 (sizes in mapinfo)
1371         string readsize_msg = strcat("MapReadSizes ", map);
1372         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1373         if(fh >= 0)
1374         {
1375                 map_minplayers = stoi(fgets(fh));
1376                 map_maxplayers = stoi(fgets(fh));
1377                 fclose(fh);
1378                 LOG_TRACEF(readsize_msg, ": ok, min %d max %d", map_minplayers, map_maxplayers);
1379                 return true;
1380         }
1381         LOG_TRACE(readsize_msg, ": not found");
1382         return false;
1383 }
1384
1385 float MapInfo_FindName(string s)
1386 {
1387         // if there is exactly one map of prefix s, return it
1388         // if not, return the null string
1389         // note that DP sorts glob results... so I can use a binary search
1390         float l, r, m, cmp;
1391         l = 0;
1392         r = MapInfo_count;
1393         // invariants: r is behind s, l-1 is equal or before
1394         while(l != r)
1395         {
1396                 m = floor((l + r) / 2);
1397                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1398                 cmp = strcasecmp(MapInfo_FindName_match, s);
1399                 if(cmp == 0)
1400                         return m; // found and good
1401                 if(cmp < 0)
1402                         l = m + 1; // l-1 is before s
1403                 else
1404                         r = m; // behind s
1405         }
1406         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1407         MapInfo_FindName_firstResult = l;
1408         // r == l, so: l is behind s, l-1 is before
1409         // SO: if there is any, l is the one with the right prefix
1410         //     and l+1 may be one too
1411         if(l == MapInfo_count)
1412         {
1413                 MapInfo_FindName_match = string_null;
1414                 MapInfo_FindName_firstResult = -1;
1415                 return -1; // no MapInfo_FindName_match, behind last item
1416         }
1417         if(!startsWithNocase(MapInfo_FindName_match, s))
1418         {
1419                 MapInfo_FindName_match = string_null;
1420                 MapInfo_FindName_firstResult = -1;
1421                 return -1; // wrong prefix
1422         }
1423         if(l == MapInfo_count - 1)
1424                 return l; // last one, nothing can follow => unique
1425         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1426         {
1427                 MapInfo_FindName_match = string_null;
1428                 return -1; // ambigous MapInfo_FindName_match
1429         }
1430         return l;
1431 }
1432
1433 string MapInfo_FixName(string s)
1434 {
1435         MapInfo_FindName(s);
1436         return MapInfo_FindName_match;
1437 }
1438
1439 int MapInfo_CurrentFeatures()
1440 {
1441         int req = 0;
1442     // TODO: find a better way to check if weapons are required on the map
1443         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || !cvar("g_melee_only")
1444                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1445                 req |= MAPINFO_FEATURE_WEAPONS;
1446         return req;
1447 }
1448
1449 Gametype MapInfo_CurrentGametype()
1450 {
1451         Gametype prev = MapInfo_Type_FromString(cvar_string("gamecfg"), false, false);
1452         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1453         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1454 }
1455
1456 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1457 {
1458         if(!MapInfo_Get_ByName(s, 1, NULL))
1459                 return 0;
1460         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1461                 return 0;
1462         if (gametype_only)
1463                 return 1;
1464         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1465                 return 0;
1466         return 1;
1467 }
1468
1469 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1470 {
1471         float r;
1472         r = _MapInfo_CheckMap(s, false);
1473         MapInfo_ClearTemps();
1474         return r;
1475 }
1476
1477 void MapInfo_SwitchGameType(Gametype t)
1478 {
1479         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1480 }
1481
1482 void MapInfo_LoadMap(string s, float reinit)
1483 {
1484         MapInfo_Map_supportedGametypes = 0;
1485         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1486         //if(!MapInfo_CheckMap(s))
1487         //{
1488         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1489         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1490         //}
1491
1492         LOG_INFO("Switching to map ", s);
1493
1494         cvar_settemp_restore();
1495         if(reinit)
1496                 localcmd(strcat("\nmap ", s, "\n"));
1497         else
1498                 localcmd(strcat("\nchangelevel ", s, "\n"));
1499 }
1500
1501 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1502 {
1503         string out;
1504
1505         // to make absolutely sure:
1506         MapInfo_Enumerate();
1507         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1508
1509         out = "";
1510         for(float i = 0; i < MapInfo_count; ++i)
1511                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1512         return substring(out, 1, strlen(out) - 1);
1513 }
1514
1515 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1516 {
1517         string out;
1518
1519         // to make absolutely sure:
1520         MapInfo_Enumerate();
1521         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1522
1523         out = "";
1524         for(float i = 0; i < MapInfo_count; ++i)
1525                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1526
1527         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1528
1529         return substring(out, 1, strlen(out) - 1);
1530 }
1531
1532 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1533 {
1534         MapInfo_SwitchGameType(t);
1535         cvar_set("gamecfg", t.mdl);
1536         MapInfo_LoadedGametype = t;
1537 }
1538
1539 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1540 {
1541         Gametype t = MapInfo_CurrentGametype();
1542         MapInfo_LoadMapSettings_SaveGameType(t);
1543
1544         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1545         {
1546                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1547                 {
1548                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1549                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1550                         return; // do not call Get_ByName!
1551                 }
1552
1553                 if(MapInfo_Map_supportedGametypes == 0)
1554                 {
1555                         RandomSelection_Init();
1556                         FOREACH(Gametypes, it.m_priority == 2,
1557                         {
1558                                 MapInfo_Map_supportedGametypes |= it.m_flags;
1559                                 RandomSelection_AddEnt(it, 1, 1);
1560                         });
1561                         if(RandomSelection_chosen_ent)
1562                                 t = RandomSelection_chosen_ent;
1563                         LOG_SEVEREF("Mapinfo system is not functional at all. Falling back to a preferred mode (%s).", t.mdl);
1564                         MapInfo_LoadMapSettings_SaveGameType(t);
1565                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1566                         return; // do not call Get_ByName!
1567                 }
1568
1569 #if 0
1570                 // find the lowest bit in the supported gametypes
1571                 // unnecessary now that we select one at random
1572                 int _t = 1;
1573                 while(!(MapInfo_Map_supportedGametypes & 1))
1574                 {
1575                         _t <<= 1;
1576                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1577                 }
1578 #endif
1579                 RandomSelection_Init();
1580                 Gametype t_prev = t;
1581                 FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags,
1582                 {
1583                         RandomSelection_AddEnt(it, 1, it.m_priority);
1584                 });
1585                 if(RandomSelection_chosen_ent)
1586                         t = RandomSelection_chosen_ent;
1587
1588                 // t is now a supported mode!
1589                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1590                 MapInfo_LoadMapSettings_SaveGameType(t);
1591         }
1592         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1593                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1594         }
1595         MapInfo_Get_ByName(s, 1, t);
1596 }
1597
1598 void MapInfo_ClearTemps()
1599 {
1600         MapInfo_Map_bspname = string_null;
1601         MapInfo_Map_title = string_null;
1602         MapInfo_Map_titlestring = string_null;
1603         MapInfo_Map_description = string_null;
1604         MapInfo_Map_author = string_null;
1605         MapInfo_Map_clientstuff = string_null;
1606         MapInfo_Map_supportedGametypes = 0;
1607         MapInfo_Map_supportedFeatures = 0;
1608 }
1609
1610 void MapInfo_Shutdown()
1611 {
1612         MapInfo_ClearTemps();
1613         MapInfo_Filter_Free();
1614         MapInfo_Cache_Destroy();
1615         if(_MapInfo_globopen)
1616         {
1617                 search_end(_MapInfo_globhandle);
1618                 _MapInfo_globhandle = -1;
1619                 _MapInfo_globopen = false;
1620         }
1621 }
1622
1623 int MapInfo_ForbiddenFlags()
1624 {
1625         int f = MAPINFO_FLAG_FORBIDDEN;
1626
1627 #ifdef GAMEQC
1628         if (!cvar("g_maplist_allow_hidden"))
1629 #endif
1630                 f |= MAPINFO_FLAG_HIDDEN;
1631
1632         if (!cvar("g_maplist_allow_frustrating"))
1633                 f |= MAPINFO_FLAG_FRUSTRATING;
1634
1635         return f;
1636 }
1637
1638 int MapInfo_RequiredFlags()
1639 {
1640         int f = 0;
1641
1642         if(cvar("g_maplist_allow_frustrating") > 1)
1643                 f |= MAPINFO_FLAG_FRUSTRATING;
1644
1645         return f;
1646 }