qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(!s) // empty string is NOT valid here!
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(!s)
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         s = search_getfilename(_MapInfo_globhandle, i);
  93         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  94 }
  95
  96 void MapInfo_Enumerate()
  97 {
  98         if(_MapInfo_globopen)
  99                 search_end(_MapInfo_globhandle);
 100         MapInfo_Cache_Invalidate();
 101         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 102         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 103         _MapInfo_globopen = 1;
 104 }
 105
 106 // filter the info by game type mask (updates MapInfo_count)
 107 //
 108 float _MapInfo_filtered;
 109 float _MapInfo_filtered_allocated;
 110 float MapInfo_FilterList_Lookup(float i)
 111 {
 112         return stof(bufstr_get(_MapInfo_filtered, i));
 113 }
 114
 115 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 116 {
 117         string h;
 118         h = bufstr_get(_MapInfo_filtered, i);
 119         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 120         bufstr_set(_MapInfo_filtered, j, h);
 121 }
 122
 123 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 124 {
 125         string a, b;
 126         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 127         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 128         return strcasecmp(a, b);
 129 }
 130
 131 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 132 {
 133         float i, j;
 134         if not(_MapInfo_filtered_allocated)
 135         {
 136                 _MapInfo_filtered_allocated = 1;
 137                 _MapInfo_filtered = buf_create();
 138         }
 139         MapInfo_count = 0;
 140         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 141         {
 142                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 143                         if(pAbortOnGenerate)
 144                         {
 145                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 146                                 MapInfo_progress = i / _MapInfo_globcount;
 147                                 return 0;
 148                         }
 149                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 150                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 151                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 152                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 153                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 154         }
 155         MapInfo_count = j + 1;
 156         MapInfo_ClearTemps();
 157
 158         // sometimes the glob isn't sorted nicely, so fix it here...
 159         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 160
 161         return 1;
 162 }
 163
 164 void MapInfo_Filter_Free()
 165 {
 166         if(_MapInfo_filtered_allocated)
 167         {
 168                 buf_del(_MapInfo_filtered);
 169                 _MapInfo_filtered_allocated = 0;
 170         }
 171 }
 172
 173 // load info about the i-th map into the MapInfo_Map_* globals
 174 string MapInfo_BSPName_ByID(float i)
 175 {
 176         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 177 }
 178
 179 string unquote(string s)
 180 {
 181         float i, j, l;
 182         l = strlen(s);
 183         j = -1;
 184         for(i = 0; i < l; ++i)
 185         {
 186                 string ch;
 187                 ch = substring(s, i, 1);
 188                 if(ch != " ") if(ch != "\"")
 189                 {
 190                         for(j = strlen(s) - i - 1; j > 0; --j)
 191                         {
 192                                 ch = substring(s, i+j, 1);
 193                                 if(ch != " ") if(ch != "\"")
 194                                         return substring(s, i, j+1);
 195                         }
 196                         return substring(s, i, 1);
 197                 }
 198         }
 199         return "";
 200 }
 201
 202 float MapInfo_Get_ByID(float i)
 203 {
 204         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 205                 return 1;
 206         return 0;
 207 }
 208
 209 string _MapInfo_Map_worldspawn_music;
 210
 211 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 212 {
 213         string fn;
 214         float fh;
 215         string s, k, v;
 216         vector o;
 217         float i;
 218         float inWorldspawn;
 219         float r;
 220         float twoBaseModes;
 221         float diameter, spawnpoints;
 222         float spawnplaces;
 223
 224         vector mapMins, mapMaxs;
 225
 226         r = 1;
 227         fn = strcat("maps/", pFilename, ".ent");
 228         fh = fopen(fn, FILE_READ);
 229         if(fh < 0)
 230         {
 231                 r = 2;
 232                 fn = strcat("maps/", pFilename, ".bsp");
 233                 fh = fopen(fn, FILE_READ);
 234         }
 235         if(fh < 0)
 236                 return 0;
 237         print("Analyzing ", fn, " to generate initial mapinfo\n");
 238
 239         inWorldspawn = 2;
 240         MapInfo_Map_flags = 0;
 241         MapInfo_Map_supportedGametypes = 0;
 242         spawnpoints = 0;
 243         spawnplaces = 0;
 244         _MapInfo_Map_worldspawn_music = "";
 245
 246         for(;;)
 247         {
 248                 if not((s = fgets(fh)))
 249                         break;
 250                 if(inWorldspawn == 1)
 251                         if(startsWith(s, "}"))
 252                                 inWorldspawn = 0;
 253                 k = unquote(car(s));
 254                 v = unquote(cdr(s));
 255                 if(inWorldspawn)
 256                 {
 257                         if(k == "classname" && v == "worldspawn")
 258                                 inWorldspawn = 1;
 259                         else if(k == "author")
 260                                 MapInfo_Map_author = v;
 261                         else if(k == "_description")
 262                                 MapInfo_Map_description = v;
 263                         else if(k == "music")
 264                                 _MapInfo_Map_worldspawn_music = v;
 265                         else if(k == "noise")
 266                                 _MapInfo_Map_worldspawn_music = v;
 267                         else if(k == "message")
 268                         {
 269                                 i = strstrofs(v, " by ", 0);
 270                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 271                                 {
 272                                         MapInfo_Map_title = substring(v, 0, i);
 273                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 274                                 }
 275                                 else
 276                                         MapInfo_Map_title = v;
 277                         }
 278                 }
 279                 else
 280                 {
 281                         if(k == "origin")
 282                         {
 283                                 o = stov(strcat("'", v, "'"));
 284                                 mapMins_x = min(mapMins_x, o_x);
 285                                 mapMins_y = min(mapMins_y, o_y);
 286                                 mapMins_z = min(mapMins_z, o_z);
 287                                 mapMaxs_x = max(mapMaxs_x, o_x);
 288                                 mapMaxs_y = max(mapMaxs_y, o_y);
 289                                 mapMaxs_z = max(mapMaxs_z, o_z);
 290                         }
 291                         else if(k == "race_place")
 292                         {
 293                                 if(stof(v) > 0)
 294                                         spawnplaces = 1;
 295                         }
 296                         else if(k == "classname")
 297                         {
 298                                 if(v == "dom_controlpoint")
 299                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 300                                 else if(v == "item_flag_team2")
 301                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 302                                 else if(v == "team_CTF_blueflag")
 303                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 304                                 else if(v == "runematch_spawn_point")
 305                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 306                                 else if(v == "target_assault_roundend")
 307                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 308                                 else if(v == "onslaught_generator")
 309                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 310                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 312                                 else if(v == "info_player_team1")
 313                                         ++spawnpoints;
 314                                 else if(v == "info_player_team2")
 315                                         ++spawnpoints;
 316                                 else if(v == "info_player_start")
 317                                         ++spawnpoints;
 318                                 else if(v == "info_player_deathmatch")
 319                                         ++spawnpoints;
 320                                 else if(v == "trigger_race_checkpoint")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 322                                 else if(v == "target_startTimer")
 323                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 324                                 else if(v == "weapon_nex")
 325                                         { }
 326                                 else if(v == "weapon_railgun")
 327                                         { }
 328                                 else if(startsWith(v, "weapon_"))
 329                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 330                                 else if(startsWith(v, "turret_"))
 331                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 332                                 else if(startsWith(v, "vehicle_"))
 333                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 334                                 else if(v == "target_music" || v == "trigger_music")
 335                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 336                         }
 337                 }
 338         }
 339         if(inWorldspawn)
 340         {
 341                 print(fn, " ended still in worldspawn, BUG\n");
 342                 return 0;
 343         }
 344         diameter = vlen(mapMaxs - mapMins);
 345
 346         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 347         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 348         {
 349                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 350                 // as the map is too symmetric for them.
 351         }
 352         else
 353         {
 354                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 355                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 356                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 357                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 358
 359                 if(spawnpoints >= 8  && diameter > 4096) {
 360                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 361                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 362                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 363                 }
 364                 if(                     diameter < 4096)
 365                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 366                 if(spawnpoints >= 12 && diameter > 5120)
 367                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 368         }
 369
 370         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 371         if(!spawnplaces)
 372         {
 373                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 374                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 375         }
 376
 377         dprint("-> diameter ",    ftos(diameter));
 378         dprint(";  spawnpoints ", ftos(spawnpoints));
 379         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 380
 381         fclose(fh);
 382
 383         return r;
 384 }
 385
 386 void _MapInfo_Map_Reset()
 387 {
 388         MapInfo_Map_title = "<TITLE>";
 389         MapInfo_Map_titlestring = "<TITLE>";
 390         MapInfo_Map_description = "<DESCRIPTION>";
 391         MapInfo_Map_author = "<AUTHOR>";
 392         MapInfo_Map_supportedGametypes = 0;
 393         MapInfo_Map_supportedFeatures = 0;
 394         MapInfo_Map_flags = 0;
 395         MapInfo_Map_clientstuff = "";
 396         MapInfo_Map_fog = "";
 397         MapInfo_Map_mins = '0 0 0';
 398         MapInfo_Map_maxs = '0 0 0';
 399 }
 400
 401 string _MapInfo_GetDefault(float t)
 402 {
 403         switch(t)
 404         {
 405                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 406                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 407                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 408                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 409                 case MAPINFO_TYPE_RUNEMATCH:       return "200 20 0";
 410                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 411                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 412                 case MAPINFO_TYPE_CA:              return "10 20 0";
 413                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 414                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 415                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 416                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 417                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 418                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 419                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 420                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 421                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 422                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 423                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 424                 default:                           return "";
 425         }
 426 }
 427
 428 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 429 {
 430         string sa;
 431         MapInfo_Map_supportedGametypes |= pThisType;
 432         if(!(pThisType & pWantedType))
 433                 return;
 434
 435         if(load_default)
 436                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 437
 438         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 439         {
 440                 cvar_set("fraglimit", "0");
 441         }
 442         else
 443         {
 444                 sa = car(s);
 445                 if(sa != "")
 446                         cvar_set("fraglimit", sa);
 447                 s = cdr(s);
 448         }
 449
 450         sa = car(s);
 451         if(sa != "")
 452                 cvar_set("timelimit", sa);
 453         s = cdr(s);
 454
 455         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 456         {
 457                 sa = car(s);
 458                 if(sa != "")
 459                         cvar_set("g_tdm_teams", sa);
 460                 s = cdr(s);
 461         }
 462
 463         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 464         {
 465                 sa = car(s);
 466                 if(sa != "")
 467                         cvar_set("g_keyhunt_teams", sa);
 468                 s = cdr(s);
 469         }
 470
 471         if(pWantedType == MAPINFO_TYPE_CTF)
 472         {
 473                 sa = car(s);
 474                 if(sa != "")
 475                         if(cvar("g_ctf_win_mode") < 2)
 476                                 cvar_set("fraglimit", sa);
 477                 s = cdr(s);
 478         }
 479
 480         /* keepaway wuz here
 481         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 482         {
 483                 sa = car(s);
 484                 if(sa != "")
 485                         cvar_set("fraglimit", sa);
 486                 s = cdr(s);
 487         }
 488         */
 489
 490         // rc = timelimit timelimit_qualification laps laps_teamplay
 491         if(pWantedType == MAPINFO_TYPE_RACE)
 492         {
 493                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 494                 cvar_set("g_race_qualifying_timelimit", sa);
 495                 s = cdr(s);
 496
 497                 sa = car(s);
 498                 if(sa != "")
 499                         if(cvar("g_race_teams") < 2)
 500                                 cvar_set("fraglimit", sa);
 501                 s = cdr(s);
 502
 503                 sa = car(s);
 504                 if(sa != "")
 505                         if(cvar("g_race_teams") >= 2)
 506                                 cvar_set("fraglimit", sa);
 507                 s = cdr(s);
 508         }
 509
 510         if(pWantedType == MAPINFO_TYPE_CTS)
 511         {
 512                 sa = car(s);
 513
 514                 // this is the skill of the map
 515                 // not parsed by anything yet
 516                 // for map databases
 517                 //if(sa != "")
 518                 //      cvar_set("fraglimit", sa);
 519
 520                 s = cdr(s);
 521         }
 522
 523         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 524         {
 525                 cvar_set("leadlimit", "0");
 526         }
 527         else
 528         {
 529                 sa = car(s);
 530                 if(sa != "")
 531                         cvar_set("leadlimit", sa);
 532                 s = cdr(s);
 533         }
 534 }
 535
 536 string _MapInfo_GetDefaultEx(float t)
 537 {
 538         switch(t)
 539         {
 540                 case MAPINFO_TYPE_DEATHMATCH:      return "timelimit=20 pointlimit=30 leadlimit=0";
 541                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "timelimit=20 pointlimit=50 teams=2 leadlimit=0";
 542                 case MAPINFO_TYPE_DOMINATION:      return "timelimit=20 pointlimit=200 teams=2 leadlimit=0";
 543                 case MAPINFO_TYPE_CTF:             return "timelimit=20 pointlimit=300 caplimit=10 leadlimit=0";
 544                 case MAPINFO_TYPE_RUNEMATCH:       return "timelimit=20 pointlimit=200 leadlimit=0";
 545                 case MAPINFO_TYPE_LMS:             return "timelimit=20 lives=9 leadlimit=0";
 546                 case MAPINFO_TYPE_ARENA:           return "timelimit=20 pointlimit=10 leadlimit=0";
 547                 case MAPINFO_TYPE_CA:              return "timelimit=20 pointlimit=10 leadlimit=0";
 548                 case MAPINFO_TYPE_KEYHUNT:         return "timelimit=20 pointlimit=1000 teams=3 leadlimit=0";
 549                 case MAPINFO_TYPE_ASSAULT:         return "timelimit=20";
 550                 case MAPINFO_TYPE_RACE:            return "timelimit=20 qualifying_timelimit=5 laplimit=7 teamlaplimit=15 leadlimit=0";
 551                 case MAPINFO_TYPE_ONSLAUGHT:       return "timelimit=20";
 552                 case MAPINFO_TYPE_NEXBALL:         return "timelimit=20 pointlimit=5 leadlimit=0";
 553                 case MAPINFO_TYPE_CTS:             return "timelimit=20 skill=-1";
 554                 case MAPINFO_TYPE_FREEZETAG:       return "timelimit=20 pointlimit=10 teams=2 leadlimit=0";
 555                 case MAPINFO_TYPE_KEEPAWAY:        return "timelimit=20 pointlimit=30";
 556                 default:                           return "";
 557         }
 558 }
 559
 560 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 561 {
 562         string sa, k, v;
 563         float p;
 564         string fraglimit_normal;
 565         string fraglimit_caps;
 566         string fraglimit_teams;
 567
 568         MapInfo_Map_supportedGametypes |= pThisType;
 569         if(!(pThisType & pWantedType))
 570                 return;
 571
 572         // reset all the cvars to their defaults
 573
 574         cvar_set("timelimit", cvar_defstring("timelimit"));
 575         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 576         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 577         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 578         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 579         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 580         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 581
 582         fraglimit_normal = string_null;
 583         fraglimit_caps = string_null;
 584         fraglimit_teams = string_null;
 585
 586         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 587         while(s != "")
 588         {
 589                 sa = car(s);
 590                 s = cdr(s);
 591
 592                 if(sa == "")
 593                         continue;
 594
 595                 p = strstrofs(sa, "=", 0);
 596                 if(p < 0)
 597                 {
 598                         k = "timelimit";
 599                         v = s;
 600                 }
 601                 else
 602                 {
 603                         k = substring(sa, 0, p);
 604                         v = substring(sa, p+1, -1);
 605                 }
 606
 607                 if(k == "timelimit")
 608                 {
 609                         cvar_set("timelimit", v);
 610                 }
 611                 else if(k == "leadlimit")
 612                 {
 613                         cvar_set("leadlimit", v);
 614                 }
 615                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit")
 616                 {
 617                         fraglimit_normal = v;
 618                 }
 619                 else if(k == "caplimit")
 620                 {
 621                         fraglimit_caps = v;
 622                 }
 623                 else if(k == "teampointlimit" || k == "teamlaplimit")
 624                 {
 625                         fraglimit_teams = v;
 626                 }
 627                 else if(k == "teams")
 628                 {
 629                         cvar_set("g_tdm_teams", v);
 630                         cvar_set("g_keyhunt_teams", v);
 631                         cvar_set("g_domination_default_teams", v);
 632                 }
 633                 else if(k == "qualifying_timelimit")
 634                 {
 635                         cvar_set("g_race_qualifying_timelimit", v);
 636                 }
 637                 else if(k == "skill")
 638                 {
 639                         // ignore
 640                 }
 641                 else
 642                 {
 643                         print("Invalid gametype key in mapinfo: ", k, "\n");
 644                 }
 645         }
 646
 647         if(pWantedType == MAPINFO_TYPE_CTF && cvar("g_ctf_win_mode") < 2)
 648         {
 649                 if(fraglimit_caps)
 650                         cvar_set("fraglimit", fraglimit_caps);
 651         }
 652         else if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 653         {
 654                 if(fraglimit_teams)
 655                         cvar_set("fraglimit", fraglimit_teams);
 656         }
 657         else
 658         {
 659                 if(fraglimit_normal)
 660                         cvar_set("fraglimit", fraglimit_normal);
 661         }
 662 }
 663
 664 float MapInfo_Type_FromString(string t)
 665 {
 666         entity e;
 667         if(t == "all")
 668                 return MAPINFO_TYPE_ALL;
 669         for(e = MapInfo_Type_first; e; e = e.enemy)
 670                 if(t == e.model2)
 671                         return e.weapons;
 672         return 0;
 673 }
 674
 675 string MapInfo_Type_ToString(float t)
 676 {
 677         entity e;
 678         if(t == MAPINFO_TYPE_ALL)
 679                 return "all";
 680         for(e = MapInfo_Type_first; e; e = e.enemy)
 681                 if(t == e.weapons)
 682                         return e.model2;
 683         return "";
 684 }
 685
 686 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 687 {
 688         string t;
 689         float fh, o;
 690         t = car(s); s = cdr(s);
 691
 692         // limited support of "" and comments
 693         //   remove trailing and leading " of t
 694         if(substring(t, 0, 1) == "\"")
 695         {
 696                 if(substring(t, -1, 1) == "\"")
 697                         t = substring(t, 1, -2);
 698         }
 699
 700         //   remove leading " of s
 701         if(substring(s, 0, 1) == "\"")
 702         {
 703                 s = substring(s, 1, -1);
 704         }
 705         //   remove trailing " of s, and all that follows (cvar description)
 706         o = strstrofs(s, "\"", 0);
 707         if(o >= 0)
 708                 s = substring(s, 0, o);
 709
 710         //   remove // comments
 711         o = strstrofs(s, "//", 0);
 712         if(o >= 0)
 713                 s = substring(s, 0, o);
 714
 715         //   remove trailing spaces
 716         while(substring(s, -1, 1) == " ")
 717                 s = substring(s, 0, -2);
 718
 719         if(t == "#include")
 720         {
 721                 if(recurse > 0)
 722                 {
 723                         fh = fopen(s, FILE_READ);
 724                         if(fh < 0)
 725                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 726                         else
 727                         {
 728                                 for(;;)
 729                                 {
 730                                         if not((s = fgets(fh)))
 731                                                 break;
 732
 733                                         // catch different sorts of comments
 734                                         if(s == "")                    // empty lines
 735                                                 continue;
 736                                         if(substring(s, 0, 1) == "#")  // UNIX style
 737                                                 continue;
 738                                         if(substring(s, 0, 2) == "//") // C++ style
 739                                                 continue;
 740                                         if(substring(s, 0, 1) == "_")  // q3map style
 741                                                 continue;
 742
 743                                         if(substring(s, 0, 4) == "set ")
 744                                                 s = substring(s, 4, -1);
 745                                         if(substring(s, 0, 5) == "seta ")
 746                                                 s = substring(s, 5, -1);
 747
 748                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 749                                 }
 750                                 fclose(fh);
 751                         }
 752                 }
 753                 else
 754                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 755         }
 756         else if(t == "")
 757                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 758         else if not(cvar_value_issafe(t))
 759                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 760         else if not (cvar_value_issafe(s))
 761                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 762         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 763                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 764         else if(matchacl(acl, t) <= 0)
 765                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 766         else
 767         {
 768                 if(type == 0) // server set
 769                 {
 770                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 771                         if(cvar("g_campaign"))
 772                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 773                         else
 774                                 cvar_settemp(t, s);
 775                 }
 776                 else
 777                 {
 778                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 779                         MapInfo_Map_clientstuff = strcat(
 780                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 781                                         );
 782                 }
 783         }
 784 }
 785
 786 float MapInfo_isRedundant(string fn, string t)
 787 {
 788         // normalize file name
 789         fn = strreplace("_", "-", fn);
 790
 791         // normalize visible title
 792         t = strreplace(": ", "-", t);
 793         t = strreplace(":", "-", t);
 794         t = strreplace(" ", "-", t);
 795         t = strreplace("_", "-", t);
 796         t = strreplace("'", "-", t);
 797
 798         if(!strcasecmp(fn, t))
 799                 return TRUE;
 800
 801         // we allow the visible title to have punctuation the file name does
 802         // not, but not vice versa
 803         t = strreplace("-", "", t);
 804
 805         if(!strcasecmp(fn, t))
 806                 return TRUE;
 807
 808         return FALSE;
 809 }
 810
 811 // load info about a map by name into the MapInfo_Map_* globals
 812 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 813 {
 814         string fn;
 815         string s, t;
 816         float fh;
 817         float r, f, n, i, p;
 818         string acl;
 819
 820         acl = MAPINFO_SETTEMP_ACL_USER;
 821
 822         if(strstrofs(pFilename, "/", 0) >= 0)
 823         {
 824                 print("Invalid character in map name, ignored\n");
 825                 return 0;
 826         }
 827
 828         if(pGametypeToSet == 0)
 829                 if(MapInfo_Cache_Retrieve(pFilename))
 830                         return 1;
 831
 832         r = 1;
 833
 834         MapInfo_Map_bspname = pFilename;
 835
 836         // default all generic fields so they have "good" values in case something fails
 837         fn = strcat("maps/", pFilename, ".mapinfo");
 838         fh = fopen(fn, FILE_READ);
 839         if(fh < 0)
 840         {
 841                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 842                 fh = fopen(fn, FILE_READ);
 843                 if(fh < 0)
 844                 {
 845                         if(!pAllowGenerate)
 846                                 return 0;
 847                         _MapInfo_Map_Reset();
 848                         r = _MapInfo_Generate(pFilename);
 849                         if(!r)
 850                                 return 0;
 851                         fh = fopen(fn, FILE_WRITE);
 852                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 853                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 854                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 855                         if(_MapInfo_Map_worldspawn_music != "")
 856                         {
 857                                 if(
 858                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 859                                         ||
 860                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 861                                 )
 862                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 863                                 else
 864                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 865                         }
 866                         else
 867                         {
 868                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 869                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 870                                 for(;;)
 871                                 {
 872                                         i = floor(random() * n);
 873                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 874                                                 break;
 875                                 }
 876                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 877                         }
 878                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 879                                 fputs(fh, "has weapons\n");
 880                         else
 881                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 882                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 883                                 fputs(fh, "has turrets\n");
 884                         else
 885                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 886                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 887                                 fputs(fh, "has weapons\n");
 888                         else
 889                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 890                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 891                                 fputs(fh, "frustrating\n");
 892
 893                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 894                                 if(MapInfo_Map_supportedGametypes & i)
 895                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 896
 897                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 898                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 899
 900                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 901                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 902                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 903                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 904                         fputs(fh, "// optional: hidden\n");
 905
 906                         fclose(fh);
 907                         r = 2;
 908                         // return r;
 909                         fh = fopen(fn, FILE_READ);
 910                         if(fh < 0)
 911                                 error("... but I just wrote it!");
 912                 }
 913
 914                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 915         }
 916
 917         _MapInfo_Map_Reset();
 918         for(;;)
 919         {
 920                 if not((s = fgets(fh)))
 921                         break;
 922
 923                 // catch different sorts of comments
 924                 if(s == "")                    // empty lines
 925                         continue;
 926                 if(substring(s, 0, 1) == "#")  // UNIX style
 927                         continue;
 928                 if(substring(s, 0, 2) == "//") // C++ style
 929                         continue;
 930                 if(substring(s, 0, 1) == "_")  // q3map style
 931                         continue;
 932
 933                 p = strstrofs(s, "//", 0);
 934                 if(p >= 0)
 935                         s = substring(s, 0, p);
 936
 937                 t = car(s); s = cdr(s);
 938                 if(t == "title")
 939                         MapInfo_Map_title = s;
 940                 else if(t == "description")
 941                         MapInfo_Map_description = s;
 942                 else if(t == "author")
 943                         MapInfo_Map_author = s;
 944                 else if(t == "has")
 945                 {
 946                         t = car(s); s = cdr(s);
 947                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 948                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 949                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 950                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 951                         else
 952                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 953                 }
 954                 else if(t == "hidden")
 955                 {
 956                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 957                 }
 958                 else if(t == "forbidden")
 959                 {
 960                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 961                 }
 962                 else if(t == "frustrating")
 963                 {
 964                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 965                 }
 966                 else if(t == "type")
 967                 {
 968                         t = car(s); s = cdr(s);
 969                         f = MapInfo_Type_FromString(t);
 970                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
 971                         if(f)
 972                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
 973                         else
 974                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 975                 }
 976                 else if(t == "gametype")
 977                 {
 978                         t = car(s); s = cdr(s);
 979                         f = MapInfo_Type_FromString(t);
 980                         if(f)
 981                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 982                         else
 983                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 984                 }
 985                 else if(t == "size")
 986                 {
 987                         float a, b, c, d, e;
 988                         t = car(s); s = cdr(s); a = stof(t);
 989                         t = car(s); s = cdr(s); b = stof(t);
 990                         t = car(s); s = cdr(s); c = stof(t);
 991                         t = car(s); s = cdr(s); d = stof(t);
 992                         t = car(s); s = cdr(s); e = stof(t);
 993                         if(s == "")
 994                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 995                         else
 996                         {
 997                                 t = car(s); s = cdr(s); f = stof(t);
 998                                 if(s != "")
 999                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1000                                 else
1001                                 {
1002                                         if(a >= d || b >= e || c >= f)
1003                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1004                                         else
1005                                         {
1006                                                 MapInfo_Map_mins_x = a;
1007                                                 MapInfo_Map_mins_y = b;
1008                                                 MapInfo_Map_mins_z = c;
1009                                                 MapInfo_Map_maxs_x = d;
1010                                                 MapInfo_Map_maxs_y = e;
1011                                                 MapInfo_Map_maxs_z = f;
1012                                         }
1013                                 }
1014                         }
1015                 }
1016                 else if(t == "settemp_for_type")
1017                 {
1018                         t = car(s); s = cdr(s);
1019                         if((f = MapInfo_Type_FromString(t)))
1020                         {
1021                                 if(f & pGametypeToSet)
1022                                 {
1023                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1024                                 }
1025                         }
1026                         else
1027                         {
1028                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1029                         }
1030                 }
1031                 else if(t == "clientsettemp_for_type")
1032                 {
1033                         t = car(s); s = cdr(s);
1034                         if((f = MapInfo_Type_FromString(t)))
1035                         {
1036                                 if(f & pGametypeToSet)
1037                                 {
1038                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1039                                 }
1040                         }
1041                         else
1042                         {
1043                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1044                         }
1045                 }
1046                 else if(t == "fog")
1047                 {
1048                         if not(cvar_value_issafe(t))
1049                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1050                         else
1051                                 MapInfo_Map_fog = s;
1052                 }
1053                 else if(t == "cdtrack")
1054                 {
1055                         if(pGametypeToSet)
1056                         {
1057                                 if not(cvar_value_issafe(t))
1058                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1059                                 else
1060                                         MapInfo_Map_clientstuff = strcat(
1061                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
1062                                         );
1063                         }
1064                 }
1065                 else
1066                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1067         }
1068         fclose(fh);
1069
1070         if(MapInfo_Map_title == "<TITLE>")
1071                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1072         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1073                 MapInfo_Map_titlestring = MapInfo_Map_title;
1074         else
1075                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1076
1077         MapInfo_Cache_Store();
1078         if(MapInfo_Map_supportedGametypes != 0)
1079                 return r;
1080         dprint("Map ", pFilename, " supports no game types, ignored\n");
1081         return 0;
1082 }
1083 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1084 {
1085         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1086
1087         if(cvar("g_tdm_on_dm_maps"))
1088         {
1089                 // if this is set, all DM maps support TDM too
1090                 if not(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH)
1091                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1092                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1093         }
1094
1095         if(pGametypeToSet)
1096         {
1097                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1098                 {
1099                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1100                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1101                         //return;
1102                 }
1103         }
1104
1105         return r;
1106 }
1107
1108 float MapInfo_FindName(string s)
1109 {
1110         // if there is exactly one map of prefix s, return it
1111         // if not, return the null string
1112         // note that DP sorts glob results... so I can use a binary search
1113         float l, r, m, cmp;
1114         l = 0;
1115         r = MapInfo_count;
1116         // invariants: r is behind s, l-1 is equal or before
1117         while(l != r)
1118         {
1119                 m = floor((l + r) / 2);
1120                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1121                 cmp = strcasecmp(MapInfo_FindName_match, s);
1122                 if(cmp == 0)
1123                         return m; // found and good
1124                 if(cmp < 0)
1125                         l = m + 1; // l-1 is before s
1126                 else
1127                         r = m; // behind s
1128         }
1129         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1130         MapInfo_FindName_firstResult = l;
1131         // r == l, so: l is behind s, l-1 is before
1132         // SO: if there is any, l is the one with the right prefix
1133         //     and l+1 may be one too
1134         if(l == MapInfo_count)
1135         {
1136                 MapInfo_FindName_match = string_null;
1137                 MapInfo_FindName_firstResult = -1;
1138                 return -1; // no MapInfo_FindName_match, behind last item
1139         }
1140         if(!startsWithNocase(MapInfo_FindName_match, s))
1141         {
1142                 MapInfo_FindName_match = string_null;
1143                 MapInfo_FindName_firstResult = -1;
1144                 return -1; // wrong prefix
1145         }
1146         if(l == MapInfo_count - 1)
1147                 return l; // last one, nothing can follow => unique
1148         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1149         {
1150                 MapInfo_FindName_match = string_null;
1151                 return -1; // ambigous MapInfo_FindName_match
1152         }
1153         return l;
1154 }
1155
1156 string MapInfo_FixName(string s)
1157 {
1158         MapInfo_FindName(s);
1159         return MapInfo_FindName_match;
1160 }
1161
1162 float MapInfo_CurrentFeatures()
1163 {
1164         float req;
1165         req = 0;
1166         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1167                 req |= MAPINFO_FEATURE_WEAPONS;
1168         return req;
1169 }
1170
1171 float MapInfo_CurrentGametype()
1172 {
1173         float prev, i;
1174         entity e;
1175         prev = cvar("gamecfg");
1176         for(e = MapInfo_Type_first; e; e = e.enemy)
1177                 if(cvar(e.mdl))
1178                         if(prev != e.weapons)
1179                                 return e.weapons;
1180         if(prev)
1181                 return prev;
1182         return MAPINFO_TYPE_DEATHMATCH;
1183 }
1184
1185 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1186 {
1187         if(!MapInfo_Get_ByName(s, 1, 0))
1188                 return 0;
1189         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1190                 return 0;
1191         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1192                 return 0;
1193         return 1;
1194 }
1195
1196 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1197 {
1198         float r;
1199         r = _MapInfo_CheckMap(s);
1200         MapInfo_ClearTemps();
1201         return r;
1202 }
1203
1204 string MapInfo_GetGameTypeCvar(float t)
1205 {
1206         entity e;
1207         for(e = MapInfo_Type_first; e; e = e.enemy)
1208                 if(e.weapons == t)
1209                         return e.mdl;
1210         return "";
1211 }
1212
1213 void MapInfo_SwitchGameType(float t)
1214 {
1215         entity e;
1216         for(e = MapInfo_Type_first; e; e = e.enemy)
1217                 cvar_set(e.mdl, (t == e.weapons) ? "1" : "0");
1218 }
1219
1220 void MapInfo_LoadMap(string s, float reinit)
1221 {
1222         MapInfo_Map_supportedGametypes = 0;
1223         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1224         //if(!MapInfo_CheckMap(s))
1225         //{
1226         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1227         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1228         //}
1229
1230         cvar_settemp_restore();
1231         if(reinit)
1232                 localcmd(strcat("\nmap ", s, "\n"));
1233         else
1234                 localcmd(strcat("\nchangelevel ", s, "\n"));
1235 }
1236
1237 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1238 {
1239         string out;
1240         float i;
1241
1242         // to make absolutely sure:
1243         MapInfo_Enumerate();
1244         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1245
1246         out = "";
1247         for(i = 0; i < MapInfo_count; ++i)
1248                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1249         return substring(out, 1, strlen(out) - 1);
1250 }
1251
1252 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1253 {
1254         string out;
1255         float i;
1256
1257         // to make absolutely sure:
1258         MapInfo_Enumerate();
1259         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1260
1261         out = "";
1262         for(i = 0; i < MapInfo_count; ++i)
1263                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1264
1265         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1266
1267         return substring(out, 1, strlen(out) - 1);
1268 }
1269
1270 void MapInfo_LoadMapSettings_SaveGameType(float t)
1271 {
1272         MapInfo_SwitchGameType(t);
1273         cvar_set("gamecfg", ftos(t));
1274         MapInfo_LoadedGametype = t;
1275 }
1276
1277 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1278 {
1279         float t;
1280
1281         t = MapInfo_CurrentGametype();
1282         MapInfo_LoadMapSettings_SaveGameType(t);
1283
1284         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1285         {
1286                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1287                 {
1288                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1289                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1290                         return; // do not call Get_ByName!
1291                 }
1292
1293                 if(MapInfo_Map_supportedGametypes == 0)
1294                 {
1295                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1296                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1297                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1298                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1299                         return; // do not call Get_ByName!
1300                 }
1301
1302                 t = 1;
1303                 while(!(MapInfo_Map_supportedGametypes & 1))
1304                 {
1305                         t *= 2;
1306                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1307                 }
1308
1309                 // t is now a supported mode!
1310                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1311                 MapInfo_LoadMapSettings_SaveGameType(t);
1312         }
1313         MapInfo_Get_ByName(s, 1, t);
1314 }
1315
1316 void MapInfo_ClearTemps()
1317 {
1318         MapInfo_Map_bspname = string_null;
1319         MapInfo_Map_title = string_null;
1320         MapInfo_Map_titlestring = string_null;
1321         MapInfo_Map_description = string_null;
1322         MapInfo_Map_author = string_null;
1323         MapInfo_Map_clientstuff = string_null;
1324         MapInfo_Map_supportedGametypes = 0;
1325         MapInfo_Map_supportedFeatures = 0;
1326 }
1327
1328 void MapInfo_Shutdown()
1329 {
1330         MapInfo_ClearTemps();
1331         MapInfo_Filter_Free();
1332         MapInfo_Cache_Destroy();
1333         if(_MapInfo_globopen)
1334         {
1335                 search_end(_MapInfo_globhandle);
1336                 _MapInfo_globhandle = -1;
1337                 _MapInfo_globopen = FALSE;
1338         }
1339 }
1340
1341 float MapInfo_ForbiddenFlags()
1342 {
1343         float f;
1344         f = MAPINFO_FLAG_FORBIDDEN;
1345
1346 #ifndef MENUQC
1347         if not(cvar("g_maplist_allow_hidden"))
1348 #endif
1349                 f |= MAPINFO_FLAG_HIDDEN;
1350
1351         if not(cvar("g_maplist_allow_frustrating"))
1352                 f |= MAPINFO_FLAG_FRUSTRATING;
1353
1354         return f;
1355 }
1356
1357 float MapInfo_RequiredFlags()
1358 {
1359         float f;
1360         f = 0;
1361
1362         if(cvar("g_maplist_allow_frustrating") > 1)
1363                 f |= MAPINFO_FLAG_FRUSTRATING;
1364
1365         return f;
1366 }