qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(!s) // empty string is NOT valid here!
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(!s)
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         s = search_getfilename(_MapInfo_globhandle, i);
  93         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  94 }
  95
  96 void MapInfo_Enumerate()
  97 {
  98         if(_MapInfo_globopen)
  99                 search_end(_MapInfo_globhandle);
 100         MapInfo_Cache_Invalidate();
 101         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 102         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 103         _MapInfo_globopen = 1;
 104 }
 105
 106 // filter the info by game type mask (updates MapInfo_count)
 107 //
 108 float _MapInfo_filtered;
 109 float _MapInfo_filtered_allocated;
 110 float MapInfo_FilterList_Lookup(float i)
 111 {
 112         return stof(bufstr_get(_MapInfo_filtered, i));
 113 }
 114
 115 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 116 {
 117         string h;
 118         h = bufstr_get(_MapInfo_filtered, i);
 119         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 120         bufstr_set(_MapInfo_filtered, j, h);
 121 }
 122
 123 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 124 {
 125         string a, b;
 126         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 127         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 128         return strcasecmp(a, b);
 129 }
 130
 131 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 132 {
 133         float i, j;
 134         if not(_MapInfo_filtered_allocated)
 135         {
 136                 _MapInfo_filtered_allocated = 1;
 137                 _MapInfo_filtered = buf_create();
 138         }
 139         MapInfo_count = 0;
 140         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 141         {
 142                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 143                         if(pAbortOnGenerate)
 144                         {
 145                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 146                                 MapInfo_progress = i / _MapInfo_globcount;
 147                                 return 0;
 148                         }
 149                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 150                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 151                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 152                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 153                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 154         }
 155         MapInfo_count = j + 1;
 156         MapInfo_ClearTemps();
 157
 158         // sometimes the glob isn't sorted nicely, so fix it here...
 159         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 160
 161         return 1;
 162 }
 163
 164 void MapInfo_Filter_Free()
 165 {
 166         if(_MapInfo_filtered_allocated)
 167         {
 168                 buf_del(_MapInfo_filtered);
 169                 _MapInfo_filtered_allocated = 0;
 170         }
 171 }
 172
 173 // load info about the i-th map into the MapInfo_Map_* globals
 174 string MapInfo_BSPName_ByID(float i)
 175 {
 176         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 177 }
 178
 179 string unquote(string s)
 180 {
 181         float i, j, l;
 182         l = strlen(s);
 183         j = -1;
 184         for(i = 0; i < l; ++i)
 185         {
 186                 string ch;
 187                 ch = substring(s, i, 1);
 188                 if(ch != " ") if(ch != "\"")
 189                 {
 190                         for(j = strlen(s) - i - 1; j > 0; --j)
 191                         {
 192                                 ch = substring(s, i+j, 1);
 193                                 if(ch != " ") if(ch != "\"")
 194                                         return substring(s, i, j+1);
 195                         }
 196                         return substring(s, i, 1);
 197                 }
 198         }
 199         return "";
 200 }
 201
 202 float MapInfo_Get_ByID(float i)
 203 {
 204         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 205                 return 1;
 206         return 0;
 207 }
 208
 209 string _MapInfo_Map_worldspawn_music;
 210
 211 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 212 {
 213         string fn;
 214         float fh;
 215         string s, k, v;
 216         vector o;
 217         float i;
 218         float inWorldspawn;
 219         float r;
 220         float twoBaseModes;
 221         float diameter, spawnpoints;
 222         float spawnplaces;
 223
 224         vector mapMins, mapMaxs;
 225
 226         r = 1;
 227         fn = strcat("maps/", pFilename, ".ent");
 228         fh = fopen(fn, FILE_READ);
 229         if(fh < 0)
 230         {
 231                 r = 2;
 232                 fn = strcat("maps/", pFilename, ".bsp");
 233                 fh = fopen(fn, FILE_READ);
 234         }
 235         if(fh < 0)
 236                 return 0;
 237         print("Analyzing ", fn, " to generate initial mapinfo\n");
 238
 239         inWorldspawn = 2;
 240         MapInfo_Map_flags = 0;
 241         MapInfo_Map_supportedGametypes = 0;
 242         spawnpoints = 0;
 243         spawnplaces = 0;
 244         _MapInfo_Map_worldspawn_music = "";
 245
 246         for(;;)
 247         {
 248                 if not((s = fgets(fh)))
 249                         break;
 250                 if(inWorldspawn == 1)
 251                         if(startsWith(s, "}"))
 252                                 inWorldspawn = 0;
 253                 k = unquote(car(s));
 254                 v = unquote(cdr(s));
 255                 if(inWorldspawn)
 256                 {
 257                         if(k == "classname" && v == "worldspawn")
 258                                 inWorldspawn = 1;
 259                         else if(k == "author")
 260                                 MapInfo_Map_author = v;
 261                         else if(k == "_description")
 262                                 MapInfo_Map_description = v;
 263                         else if(k == "music")
 264                                 _MapInfo_Map_worldspawn_music = v;
 265                         else if(k == "noise")
 266                                 _MapInfo_Map_worldspawn_music = v;
 267                         else if(k == "message")
 268                         {
 269                                 i = strstrofs(v, " by ", 0);
 270                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 271                                 {
 272                                         MapInfo_Map_title = substring(v, 0, i);
 273                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 274                                 }
 275                                 else
 276                                         MapInfo_Map_title = v;
 277                         }
 278                 }
 279                 else
 280                 {
 281                         if(k == "origin")
 282                         {
 283                                 o = stov(strcat("'", v, "'"));
 284                                 mapMins_x = min(mapMins_x, o_x);
 285                                 mapMins_y = min(mapMins_y, o_y);
 286                                 mapMins_z = min(mapMins_z, o_z);
 287                                 mapMaxs_x = max(mapMaxs_x, o_x);
 288                                 mapMaxs_y = max(mapMaxs_y, o_y);
 289                                 mapMaxs_z = max(mapMaxs_z, o_z);
 290                         }
 291                         else if(k == "race_place")
 292                         {
 293                                 if(stof(v) > 0)
 294                                         spawnplaces = 1;
 295                         }
 296                         else if(k == "classname")
 297                         {
 298                                 if(v == "dom_controlpoint")
 299                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 300                                 else if(v == "item_flag_team2")
 301                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 302                                 else if(v == "team_CTF_blueflag")
 303                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 304                                 else if(v == "runematch_spawn_point")
 305                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 306                                 else if(v == "target_assault_roundend")
 307                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 308                                 else if(v == "onslaught_generator")
 309                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 310                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 312                                 else if(v == "info_player_team1")
 313                                         ++spawnpoints;
 314                                 else if(v == "info_player_team2")
 315                                         ++spawnpoints;
 316                                 else if(v == "info_player_start")
 317                                         ++spawnpoints;
 318                                 else if(v == "info_player_deathmatch")
 319                                         ++spawnpoints;
 320                                 else if(v == "trigger_race_checkpoint")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 322                                 else if(v == "target_startTimer")
 323                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 324                                 else if(v == "weapon_nex")
 325                                         { }
 326                                 else if(v == "weapon_railgun")
 327                                         { }
 328                                 else if(startsWith(v, "weapon_"))
 329                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 330                                 else if(startsWith(v, "turret_"))
 331                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 332                                 else if(startsWith(v, "vehicle_"))
 333                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 334                                 else if(v == "target_music" || v == "trigger_music")
 335                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 336                         }
 337                 }
 338         }
 339         if(inWorldspawn)
 340         {
 341                 print(fn, " ended still in worldspawn, BUG\n");
 342                 return 0;
 343         }
 344         diameter = vlen(mapMaxs - mapMins);
 345
 346         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 347         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 348         {
 349                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 350                 // as the map is too symmetric for them.
 351         }
 352         else
 353         {
 354                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 355                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 356                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 357                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 358
 359                 if(spawnpoints >= 8  && diameter > 4096) {
 360                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 361                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 362                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 363                 }
 364                 if(                     diameter < 4096)
 365                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 366                 if(spawnpoints >= 12 && diameter > 5120)
 367                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 368         }
 369
 370         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 371         if(!spawnplaces)
 372         {
 373                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 374                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 375         }
 376
 377         dprint("-> diameter ",    ftos(diameter));
 378         dprint(";  spawnpoints ", ftos(spawnpoints));
 379         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 380
 381         fclose(fh);
 382
 383         return r;
 384 }
 385
 386 void _MapInfo_Map_Reset()
 387 {
 388         MapInfo_Map_title = "<TITLE>";
 389         MapInfo_Map_titlestring = "<TITLE>";
 390         MapInfo_Map_description = "<DESCRIPTION>";
 391         MapInfo_Map_author = "<AUTHOR>";
 392         MapInfo_Map_supportedGametypes = 0;
 393         MapInfo_Map_supportedFeatures = 0;
 394         MapInfo_Map_flags = 0;
 395         MapInfo_Map_clientstuff = "";
 396         MapInfo_Map_fog = "";
 397         MapInfo_Map_mins = '0 0 0';
 398         MapInfo_Map_maxs = '0 0 0';
 399 }
 400
 401 string _MapInfo_GetDefault(float t)
 402 {
 403         switch(t)
 404         {
 405                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 406                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 407                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 408                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 409                 case MAPINFO_TYPE_RUNEMATCH:       return "200 20 0";
 410                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 411                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 412                 case MAPINFO_TYPE_CA:              return "10 20 0";
 413                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 414                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 415                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 416                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 417                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 418                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 419                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 420                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 421                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 422                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 423                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 424                 default:                           return "";
 425         }
 426 }
 427
 428 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 429 {
 430         string sa;
 431         MapInfo_Map_supportedGametypes |= pThisType;
 432         if(!(pThisType & pWantedType))
 433                 return;
 434
 435         if(load_default)
 436                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 437
 438         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 439         {
 440                 cvar_set("fraglimit", "0");
 441         }
 442         else
 443         {
 444                 sa = car(s);
 445                 if(sa != "")
 446                         cvar_set("fraglimit", sa);
 447                 s = cdr(s);
 448         }
 449
 450         sa = car(s);
 451         if(sa != "")
 452                 cvar_set("timelimit", sa);
 453         s = cdr(s);
 454
 455         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 456         {
 457                 sa = car(s);
 458                 if(sa != "")
 459                         cvar_set("g_tdm_teams", sa);
 460                 s = cdr(s);
 461         }
 462
 463         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 464         {
 465                 sa = car(s);
 466                 if(sa != "")
 467                         cvar_set("g_keyhunt_teams", sa);
 468                 s = cdr(s);
 469         }
 470
 471         if(pWantedType == MAPINFO_TYPE_CTF)
 472         {
 473                 sa = car(s);
 474                 if(sa != "")
 475                         if(cvar("g_ctf_win_mode") < 2)
 476                                 cvar_set("fraglimit", sa);
 477                 s = cdr(s);
 478         }
 479
 480         /* keepaway wuz here
 481         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 482         {
 483                 sa = car(s);
 484                 if(sa != "")
 485                         cvar_set("fraglimit", sa);
 486                 s = cdr(s);
 487         }
 488         */
 489
 490         // rc = timelimit timelimit_qualification laps laps_teamplay
 491         if(pWantedType == MAPINFO_TYPE_RACE)
 492         {
 493                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 494                 cvar_set("g_race_qualifying_timelimit", sa);
 495                 s = cdr(s);
 496
 497                 sa = car(s);
 498                 if(sa != "")
 499                         if(cvar("g_race_teams") < 2)
 500                                 cvar_set("fraglimit", sa);
 501                 s = cdr(s);
 502
 503                 sa = car(s);
 504                 if(sa != "")
 505                         if(cvar("g_race_teams") >= 2)
 506                                 cvar_set("fraglimit", sa);
 507                 s = cdr(s);
 508         }
 509
 510         if(pWantedType == MAPINFO_TYPE_CTS)
 511         {
 512                 sa = car(s);
 513
 514                 // this is the skill of the map
 515                 // not parsed by anything yet
 516                 // for map databases
 517                 //if(sa != "")
 518                 //      cvar_set("fraglimit", sa);
 519
 520                 s = cdr(s);
 521         }
 522
 523         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 524         {
 525                 cvar_set("leadlimit", "0");
 526         }
 527         else
 528         {
 529                 sa = car(s);
 530                 if(sa != "")
 531                         cvar_set("leadlimit", sa);
 532                 s = cdr(s);
 533         }
 534 }
 535
 536 string _MapInfo_GetDefaultEx(float t)
 537 {
 538         entity e;
 539         for(e = MapInfo_Type_first; e; e = e.enemy)
 540                 if(t == e.weapons)
 541                         return e.message;
 542         return "";
 543 }
 544
 545 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 546 {
 547         string sa, k, v;
 548         float p;
 549         string fraglimit_normal;
 550         string fraglimit_caps;
 551         string fraglimit_teams;
 552
 553         MapInfo_Map_supportedGametypes |= pThisType;
 554         if(!(pThisType & pWantedType))
 555                 return;
 556
 557         // reset all the cvars to their defaults
 558
 559         cvar_set("timelimit", cvar_defstring("timelimit"));
 560         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 561         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 562         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 563         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 564         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 565         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 566
 567         fraglimit_normal = string_null;
 568         fraglimit_caps = string_null;
 569         fraglimit_teams = string_null;
 570
 571         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 572         while(s != "")
 573         {
 574                 sa = car(s);
 575                 s = cdr(s);
 576
 577                 if(sa == "")
 578                         continue;
 579
 580                 p = strstrofs(sa, "=", 0);
 581                 if(p < 0)
 582                 {
 583                         k = "timelimit";
 584                         v = s;
 585                 }
 586                 else
 587                 {
 588                         k = substring(sa, 0, p);
 589                         v = substring(sa, p+1, -1);
 590                 }
 591
 592                 if(k == "timelimit")
 593                 {
 594                         cvar_set("timelimit", v);
 595                 }
 596                 else if(k == "leadlimit")
 597                 {
 598                         cvar_set("leadlimit", v);
 599                 }
 600                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit")
 601                 {
 602                         fraglimit_normal = v;
 603                 }
 604                 else if(k == "caplimit")
 605                 {
 606                         fraglimit_caps = v;
 607                 }
 608                 else if(k == "teampointlimit" || k == "teamlaplimit")
 609                 {
 610                         fraglimit_teams = v;
 611                 }
 612                 else if(k == "teams")
 613                 {
 614                         cvar_set("g_tdm_teams", v);
 615                         cvar_set("g_keyhunt_teams", v);
 616                         cvar_set("g_domination_default_teams", v);
 617                 }
 618                 else if(k == "qualifying_timelimit")
 619                 {
 620                         cvar_set("g_race_qualifying_timelimit", v);
 621                 }
 622                 else if(k == "skill")
 623                 {
 624                         // ignore
 625                 }
 626                 else
 627                 {
 628                         print("Invalid gametype key in mapinfo: ", k, "\n");
 629                 }
 630         }
 631
 632         if(pWantedType == MAPINFO_TYPE_CTF && cvar("g_ctf_win_mode") < 2)
 633         {
 634                 if(fraglimit_caps)
 635                         cvar_set("fraglimit", fraglimit_caps);
 636         }
 637         else if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 638         {
 639                 if(fraglimit_teams)
 640                         cvar_set("fraglimit", fraglimit_teams);
 641         }
 642         else
 643         {
 644                 if(fraglimit_normal)
 645                         cvar_set("fraglimit", fraglimit_normal);
 646         }
 647 }
 648
 649 float MapInfo_Type_FromString(string t)
 650 {
 651         entity e;
 652         if(t == "all")
 653                 return MAPINFO_TYPE_ALL;
 654         for(e = MapInfo_Type_first; e; e = e.enemy)
 655                 if(t == e.mdl)
 656                         return e.weapons;
 657         return 0;
 658 }
 659
 660 string MapInfo_Type_ToString(float t)
 661 {
 662         entity e;
 663         if(t == MAPINFO_TYPE_ALL)
 664                 return "all";
 665         for(e = MapInfo_Type_first; e; e = e.enemy)
 666                 if(t == e.weapons)
 667                         return e.mdl;
 668         return "";
 669 }
 670
 671 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 672 {
 673         string t;
 674         float fh, o;
 675         t = car(s); s = cdr(s);
 676
 677         // limited support of "" and comments
 678         //   remove trailing and leading " of t
 679         if(substring(t, 0, 1) == "\"")
 680         {
 681                 if(substring(t, -1, 1) == "\"")
 682                         t = substring(t, 1, -2);
 683         }
 684
 685         //   remove leading " of s
 686         if(substring(s, 0, 1) == "\"")
 687         {
 688                 s = substring(s, 1, -1);
 689         }
 690         //   remove trailing " of s, and all that follows (cvar description)
 691         o = strstrofs(s, "\"", 0);
 692         if(o >= 0)
 693                 s = substring(s, 0, o);
 694
 695         //   remove // comments
 696         o = strstrofs(s, "//", 0);
 697         if(o >= 0)
 698                 s = substring(s, 0, o);
 699
 700         //   remove trailing spaces
 701         while(substring(s, -1, 1) == " ")
 702                 s = substring(s, 0, -2);
 703
 704         if(t == "#include")
 705         {
 706                 if(recurse > 0)
 707                 {
 708                         fh = fopen(s, FILE_READ);
 709                         if(fh < 0)
 710                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 711                         else
 712                         {
 713                                 for(;;)
 714                                 {
 715                                         if not((s = fgets(fh)))
 716                                                 break;
 717
 718                                         // catch different sorts of comments
 719                                         if(s == "")                    // empty lines
 720                                                 continue;
 721                                         if(substring(s, 0, 1) == "#")  // UNIX style
 722                                                 continue;
 723                                         if(substring(s, 0, 2) == "//") // C++ style
 724                                                 continue;
 725                                         if(substring(s, 0, 1) == "_")  // q3map style
 726                                                 continue;
 727
 728                                         if(substring(s, 0, 4) == "set ")
 729                                                 s = substring(s, 4, -1);
 730                                         if(substring(s, 0, 5) == "seta ")
 731                                                 s = substring(s, 5, -1);
 732
 733                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 734                                 }
 735                                 fclose(fh);
 736                         }
 737                 }
 738                 else
 739                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 740         }
 741         else if(t == "")
 742                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 743         else if not(cvar_value_issafe(t))
 744                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 745         else if not (cvar_value_issafe(s))
 746                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 747         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 748                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 749         else if(matchacl(acl, t) <= 0)
 750                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 751         else
 752         {
 753                 if(type == 0) // server set
 754                 {
 755                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 756                         if(cvar("g_campaign"))
 757                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 758                         else
 759                                 cvar_settemp(t, s);
 760                 }
 761                 else
 762                 {
 763                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 764                         MapInfo_Map_clientstuff = strcat(
 765                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 766                                         );
 767                 }
 768         }
 769 }
 770
 771 float MapInfo_isRedundant(string fn, string t)
 772 {
 773         // normalize file name
 774         fn = strreplace("_", "-", fn);
 775
 776         // normalize visible title
 777         t = strreplace(": ", "-", t);
 778         t = strreplace(":", "-", t);
 779         t = strreplace(" ", "-", t);
 780         t = strreplace("_", "-", t);
 781         t = strreplace("'", "-", t);
 782
 783         if(!strcasecmp(fn, t))
 784                 return TRUE;
 785
 786         // we allow the visible title to have punctuation the file name does
 787         // not, but not vice versa
 788         t = strreplace("-", "", t);
 789
 790         if(!strcasecmp(fn, t))
 791                 return TRUE;
 792
 793         return FALSE;
 794 }
 795
 796 // load info about a map by name into the MapInfo_Map_* globals
 797 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 798 {
 799         string fn;
 800         string s, t;
 801         float fh;
 802         float r, f, n, i, p;
 803         string acl;
 804
 805         acl = MAPINFO_SETTEMP_ACL_USER;
 806
 807         if(strstrofs(pFilename, "/", 0) >= 0)
 808         {
 809                 print("Invalid character in map name, ignored\n");
 810                 return 0;
 811         }
 812
 813         if(pGametypeToSet == 0)
 814                 if(MapInfo_Cache_Retrieve(pFilename))
 815                         return 1;
 816
 817         r = 1;
 818
 819         MapInfo_Map_bspname = pFilename;
 820
 821         // default all generic fields so they have "good" values in case something fails
 822         fn = strcat("maps/", pFilename, ".mapinfo");
 823         fh = fopen(fn, FILE_READ);
 824         if(fh < 0)
 825         {
 826                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 827                 fh = fopen(fn, FILE_READ);
 828                 if(fh < 0)
 829                 {
 830                         if(!pAllowGenerate)
 831                                 return 0;
 832                         _MapInfo_Map_Reset();
 833                         r = _MapInfo_Generate(pFilename);
 834                         if(!r)
 835                                 return 0;
 836                         fh = fopen(fn, FILE_WRITE);
 837                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 838                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 839                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 840                         if(_MapInfo_Map_worldspawn_music != "")
 841                         {
 842                                 if(
 843                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 844                                         ||
 845                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 846                                 )
 847                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 848                                 else
 849                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 850                         }
 851                         else
 852                         {
 853                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 854                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 855                                 for(;;)
 856                                 {
 857                                         i = floor(random() * n);
 858                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 859                                                 break;
 860                                 }
 861                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 862                         }
 863                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 864                                 fputs(fh, "has weapons\n");
 865                         else
 866                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 867                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 868                                 fputs(fh, "has turrets\n");
 869                         else
 870                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 871                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 872                                 fputs(fh, "has weapons\n");
 873                         else
 874                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 875                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 876                                 fputs(fh, "frustrating\n");
 877
 878                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 879                                 if(MapInfo_Map_supportedGametypes & i)
 880                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 881
 882                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 883                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 884
 885                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 886                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 887                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 888                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 889                         fputs(fh, "// optional: hidden\n");
 890
 891                         fclose(fh);
 892                         r = 2;
 893                         // return r;
 894                         fh = fopen(fn, FILE_READ);
 895                         if(fh < 0)
 896                                 error("... but I just wrote it!");
 897                 }
 898
 899                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 900         }
 901
 902         _MapInfo_Map_Reset();
 903         for(;;)
 904         {
 905                 if not((s = fgets(fh)))
 906                         break;
 907
 908                 // catch different sorts of comments
 909                 if(s == "")                    // empty lines
 910                         continue;
 911                 if(substring(s, 0, 1) == "#")  // UNIX style
 912                         continue;
 913                 if(substring(s, 0, 2) == "//") // C++ style
 914                         continue;
 915                 if(substring(s, 0, 1) == "_")  // q3map style
 916                         continue;
 917
 918                 p = strstrofs(s, "//", 0);
 919                 if(p >= 0)
 920                         s = substring(s, 0, p);
 921
 922                 t = car(s); s = cdr(s);
 923                 if(t == "title")
 924                         MapInfo_Map_title = s;
 925                 else if(t == "description")
 926                         MapInfo_Map_description = s;
 927                 else if(t == "author")
 928                         MapInfo_Map_author = s;
 929                 else if(t == "has")
 930                 {
 931                         t = car(s); s = cdr(s);
 932                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 933                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 934                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 935                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 936                         else
 937                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 938                 }
 939                 else if(t == "hidden")
 940                 {
 941                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 942                 }
 943                 else if(t == "forbidden")
 944                 {
 945                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 946                 }
 947                 else if(t == "frustrating")
 948                 {
 949                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 950                 }
 951                 else if(t == "type")
 952                 {
 953                         t = car(s); s = cdr(s);
 954                         f = MapInfo_Type_FromString(t);
 955                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
 956                         if(f)
 957                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
 958                         else
 959                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 960                 }
 961                 else if(t == "gametype")
 962                 {
 963                         t = car(s); s = cdr(s);
 964                         f = MapInfo_Type_FromString(t);
 965                         if(f)
 966                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 967                         else
 968                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 969                 }
 970                 else if(t == "size")
 971                 {
 972                         float a, b, c, d, e;
 973                         t = car(s); s = cdr(s); a = stof(t);
 974                         t = car(s); s = cdr(s); b = stof(t);
 975                         t = car(s); s = cdr(s); c = stof(t);
 976                         t = car(s); s = cdr(s); d = stof(t);
 977                         t = car(s); s = cdr(s); e = stof(t);
 978                         if(s == "")
 979                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 980                         else
 981                         {
 982                                 t = car(s); s = cdr(s); f = stof(t);
 983                                 if(s != "")
 984                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 985                                 else
 986                                 {
 987                                         if(a >= d || b >= e || c >= f)
 988                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 989                                         else
 990                                         {
 991                                                 MapInfo_Map_mins_x = a;
 992                                                 MapInfo_Map_mins_y = b;
 993                                                 MapInfo_Map_mins_z = c;
 994                                                 MapInfo_Map_maxs_x = d;
 995                                                 MapInfo_Map_maxs_y = e;
 996                                                 MapInfo_Map_maxs_z = f;
 997                                         }
 998                                 }
 999                         }
1000                 }
1001                 else if(t == "settemp_for_type")
1002                 {
1003                         t = car(s); s = cdr(s);
1004                         if((f = MapInfo_Type_FromString(t)))
1005                         {
1006                                 if(f & pGametypeToSet)
1007                                 {
1008                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1009                                 }
1010                         }
1011                         else
1012                         {
1013                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1014                         }
1015                 }
1016                 else if(t == "clientsettemp_for_type")
1017                 {
1018                         t = car(s); s = cdr(s);
1019                         if((f = MapInfo_Type_FromString(t)))
1020                         {
1021                                 if(f & pGametypeToSet)
1022                                 {
1023                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1024                                 }
1025                         }
1026                         else
1027                         {
1028                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1029                         }
1030                 }
1031                 else if(t == "fog")
1032                 {
1033                         if not(cvar_value_issafe(t))
1034                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1035                         else
1036                                 MapInfo_Map_fog = s;
1037                 }
1038                 else if(t == "cdtrack")
1039                 {
1040                         if(pGametypeToSet)
1041                         {
1042                                 if not(cvar_value_issafe(t))
1043                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1044                                 else
1045                                         MapInfo_Map_clientstuff = strcat(
1046                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
1047                                         );
1048                         }
1049                 }
1050                 else
1051                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1052         }
1053         fclose(fh);
1054
1055         if(MapInfo_Map_title == "<TITLE>")
1056                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1057         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1058                 MapInfo_Map_titlestring = MapInfo_Map_title;
1059         else
1060                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1061
1062         MapInfo_Cache_Store();
1063         if(MapInfo_Map_supportedGametypes != 0)
1064                 return r;
1065         dprint("Map ", pFilename, " supports no game types, ignored\n");
1066         return 0;
1067 }
1068 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1069 {
1070         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1071
1072         if(cvar("g_tdm_on_dm_maps"))
1073         {
1074                 // if this is set, all DM maps support TDM too
1075                 if not(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH)
1076                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1077                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1078         }
1079
1080         if(pGametypeToSet)
1081         {
1082                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1083                 {
1084                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1085                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1086                         //return;
1087                 }
1088         }
1089
1090         return r;
1091 }
1092
1093 float MapInfo_FindName(string s)
1094 {
1095         // if there is exactly one map of prefix s, return it
1096         // if not, return the null string
1097         // note that DP sorts glob results... so I can use a binary search
1098         float l, r, m, cmp;
1099         l = 0;
1100         r = MapInfo_count;
1101         // invariants: r is behind s, l-1 is equal or before
1102         while(l != r)
1103         {
1104                 m = floor((l + r) / 2);
1105                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1106                 cmp = strcasecmp(MapInfo_FindName_match, s);
1107                 if(cmp == 0)
1108                         return m; // found and good
1109                 if(cmp < 0)
1110                         l = m + 1; // l-1 is before s
1111                 else
1112                         r = m; // behind s
1113         }
1114         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1115         MapInfo_FindName_firstResult = l;
1116         // r == l, so: l is behind s, l-1 is before
1117         // SO: if there is any, l is the one with the right prefix
1118         //     and l+1 may be one too
1119         if(l == MapInfo_count)
1120         {
1121                 MapInfo_FindName_match = string_null;
1122                 MapInfo_FindName_firstResult = -1;
1123                 return -1; // no MapInfo_FindName_match, behind last item
1124         }
1125         if(!startsWithNocase(MapInfo_FindName_match, s))
1126         {
1127                 MapInfo_FindName_match = string_null;
1128                 MapInfo_FindName_firstResult = -1;
1129                 return -1; // wrong prefix
1130         }
1131         if(l == MapInfo_count - 1)
1132                 return l; // last one, nothing can follow => unique
1133         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1134         {
1135                 MapInfo_FindName_match = string_null;
1136                 return -1; // ambigous MapInfo_FindName_match
1137         }
1138         return l;
1139 }
1140
1141 string MapInfo_FixName(string s)
1142 {
1143         MapInfo_FindName(s);
1144         return MapInfo_FindName_match;
1145 }
1146
1147 float MapInfo_CurrentFeatures()
1148 {
1149         float req;
1150         req = 0;
1151         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1152                 req |= MAPINFO_FEATURE_WEAPONS;
1153         return req;
1154 }
1155
1156 float MapInfo_CurrentGametype()
1157 {
1158         float prev;
1159         entity e;
1160         prev = cvar("gamecfg");
1161         for(e = MapInfo_Type_first; e; e = e.enemy)
1162                 if(cvar(e.netname))
1163                         if(prev != e.weapons)
1164                                 return e.weapons;
1165         if(prev)
1166                 return prev;
1167         return MAPINFO_TYPE_DEATHMATCH;
1168 }
1169
1170 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1171 {
1172         if(!MapInfo_Get_ByName(s, 1, 0))
1173                 return 0;
1174         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1175                 return 0;
1176         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1177                 return 0;
1178         return 1;
1179 }
1180
1181 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1182 {
1183         float r;
1184         r = _MapInfo_CheckMap(s);
1185         MapInfo_ClearTemps();
1186         return r;
1187 }
1188
1189 void MapInfo_SwitchGameType(float t)
1190 {
1191         entity e;
1192         for(e = MapInfo_Type_first; e; e = e.enemy)
1193                 cvar_set(e.netname, (t == e.weapons) ? "1" : "0");
1194 }
1195
1196 void MapInfo_LoadMap(string s, float reinit)
1197 {
1198         MapInfo_Map_supportedGametypes = 0;
1199         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1200         //if(!MapInfo_CheckMap(s))
1201         //{
1202         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1203         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1204         //}
1205
1206         cvar_settemp_restore();
1207         if(reinit)
1208                 localcmd(strcat("\nmap ", s, "\n"));
1209         else
1210                 localcmd(strcat("\nchangelevel ", s, "\n"));
1211 }
1212
1213 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1214 {
1215         string out;
1216         float i;
1217
1218         // to make absolutely sure:
1219         MapInfo_Enumerate();
1220         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1221
1222         out = "";
1223         for(i = 0; i < MapInfo_count; ++i)
1224                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1225         return substring(out, 1, strlen(out) - 1);
1226 }
1227
1228 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1229 {
1230         string out;
1231         float i;
1232
1233         // to make absolutely sure:
1234         MapInfo_Enumerate();
1235         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1236
1237         out = "";
1238         for(i = 0; i < MapInfo_count; ++i)
1239                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1240
1241         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1242
1243         return substring(out, 1, strlen(out) - 1);
1244 }
1245
1246 void MapInfo_LoadMapSettings_SaveGameType(float t)
1247 {
1248         MapInfo_SwitchGameType(t);
1249         cvar_set("gamecfg", ftos(t));
1250         MapInfo_LoadedGametype = t;
1251 }
1252
1253 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1254 {
1255         float t;
1256
1257         t = MapInfo_CurrentGametype();
1258         MapInfo_LoadMapSettings_SaveGameType(t);
1259
1260         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1261         {
1262                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1263                 {
1264                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1265                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1266                         return; // do not call Get_ByName!
1267                 }
1268
1269                 if(MapInfo_Map_supportedGametypes == 0)
1270                 {
1271                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1272                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1273                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1274                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1275                         return; // do not call Get_ByName!
1276                 }
1277
1278                 t = 1;
1279                 while(!(MapInfo_Map_supportedGametypes & 1))
1280                 {
1281                         t *= 2;
1282                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1283                 }
1284
1285                 // t is now a supported mode!
1286                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1287                 MapInfo_LoadMapSettings_SaveGameType(t);
1288         }
1289         MapInfo_Get_ByName(s, 1, t);
1290 }
1291
1292 void MapInfo_ClearTemps()
1293 {
1294         MapInfo_Map_bspname = string_null;
1295         MapInfo_Map_title = string_null;
1296         MapInfo_Map_titlestring = string_null;
1297         MapInfo_Map_description = string_null;
1298         MapInfo_Map_author = string_null;
1299         MapInfo_Map_clientstuff = string_null;
1300         MapInfo_Map_supportedGametypes = 0;
1301         MapInfo_Map_supportedFeatures = 0;
1302 }
1303
1304 void MapInfo_Shutdown()
1305 {
1306         MapInfo_ClearTemps();
1307         MapInfo_Filter_Free();
1308         MapInfo_Cache_Destroy();
1309         if(_MapInfo_globopen)
1310         {
1311                 search_end(_MapInfo_globhandle);
1312                 _MapInfo_globhandle = -1;
1313                 _MapInfo_globopen = FALSE;
1314         }
1315 }
1316
1317 float MapInfo_ForbiddenFlags()
1318 {
1319         float f;
1320         f = MAPINFO_FLAG_FORBIDDEN;
1321
1322 #ifndef MENUQC
1323         if not(cvar("g_maplist_allow_hidden"))
1324 #endif
1325                 f |= MAPINFO_FLAG_HIDDEN;
1326
1327         if not(cvar("g_maplist_allow_frustrating"))
1328                 f |= MAPINFO_FLAG_FRUSTRATING;
1329
1330         return f;
1331 }
1332
1333 float MapInfo_RequiredFlags()
1334 {
1335         float f;
1336         f = 0;
1337
1338         if(cvar("g_maplist_allow_frustrating") > 1)
1339                 f |= MAPINFO_FLAG_FRUSTRATING;
1340
1341         return f;
1342 }