qcsrc/common/minigames/minigame/bd.qc

   1 REGISTER_MINIGAME(bd, "Bulldozer");
   2
   3 const int BD_TURN_MOVE  = 0x0100; // player must move the bulldozer
   4 const int BD_TURN_WIN   = 0x0200; // victory
   5 const int BD_TURN_LOSS  = 0x0400; // they did it?!
   6 const int BD_TURN_EDIT  = 0x0800; // editing mode
   7 const int BD_TURN_TYPE  = 0x0f00; // turn type mask
   8
   9 const int BD_SF_PLAYERMOVES = MINIG_SF_CUSTOM;
  10
  11 // 240 tiles...
  12 const int BD_LET_CNT = 20;
  13 const int BD_NUM_CNT = 20;
  14
  15 const int BD_TILE_SIZE = 20;
  16
  17 const int BD_TEAMS = 1;
  18
  19 .vector bd_dir;
  20
  21 .int bd_moves;
  22
  23 .string bd_levelname;
  24 .string bd_nextlevel;
  25
  26 #ifdef SVQC
  27 .bool bd_canedit;
  28 #endif
  29
  30 .int bd_tiletype;
  31 const int BD_TILE_DOZER = 1;
  32 const int BD_TILE_TARGET = 2;
  33 const int BD_TILE_BOULDER = 3;
  34 const int BD_TILE_BRICK1 = 4;
  35 const int BD_TILE_BRICK2 = 5;
  36 const int BD_TILE_BRICK3 = 6;
  37 const int BD_TILE_BRICK4 = 7;
  38 const int BD_TILE_BRICK5 = 8;
  39 const int BD_TILE_BRICK6 = 9;
  40 const int BD_TILE_BRICK7 = 10;
  41 const int BD_TILE_BRICK8 = 11;
  42 const int BD_TILE_LAST = 11;
  43
  44 string autocvar_sv_minigames_bulldozer_startlevel = "level1";
  45
  46 // find same game piece given its tile name
  47 entity bd_find_piece(entity minig, string tile, bool check_target)
  48 {
  49         entity e = world;
  50         while ( ( e = findentity(e,owner,minig) ) )
  51                 if ( e.classname == "minigame_board_piece" && e.netname == tile && ((check_target) ? e.bd_tiletype == BD_TILE_TARGET : e.bd_tiletype != BD_TILE_TARGET) )
  52                         return e;
  53         return world;
  54 }
  55
  56 // check if the tile name is valid (15x15 grid)
  57 bool bd_valid_tile(string tile)
  58 {
  59         if ( !tile )
  60                 return false;
  61         int number = minigame_tile_number(tile);
  62         int letter = minigame_tile_letter(tile);
  63         return 0 <= number && number < BD_NUM_CNT && 0 <= letter && letter < BD_LET_CNT;
  64 }
  65
  66 entity bd_find_dozer(entity minig)
  67 {
  68         entity e = world;
  69         while ( ( e = findentity(e,owner,minig) ) )
  70                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
  71                         return e;
  72         return world;
  73 }
  74
  75 void bd_check_winner(entity minig)
  76 {
  77         int total = 0, valid = 0;
  78         entity e = world;
  79         while ( ( e = findentity(e,owner,minig) ) )
  80                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
  81                 {
  82                         ++total;
  83                         if(bd_find_piece(minig, e.netname, false).bd_tiletype == BD_TILE_BOULDER)
  84                                 ++valid;
  85                 }
  86
  87         if(valid >= total)
  88         {
  89                 minig.minigame_flags = BD_TURN_WIN;
  90                 minigame_server_sendflags(minig,MINIG_SF_UPDATE);
  91         }
  92 }
  93
  94 bool bd_canfill(int ttype)
  95 {
  96         switch(ttype)
  97         {
  98                 case BD_TILE_BRICK8:
  99                 case BD_TILE_BRICK7:
 100                 case BD_TILE_BRICK6:
 101                 case BD_TILE_BRICK5:
 102                 case BD_TILE_BRICK4:
 103                 case BD_TILE_BRICK3:
 104                 case BD_TILE_BRICK2:
 105                 case BD_TILE_BRICK1: return true;
 106         }
 107
 108         return false;
 109 }
 110
 111 bool bd_move_dozer(entity minigame, entity dozer)
 112 {
 113         if(!dozer.bd_dir_x && !dozer.bd_dir_y)
 114                 return false; // nope!
 115
 116         int myx = minigame_tile_letter(dozer.netname);
 117         int myy = minigame_tile_number(dozer.netname);
 118
 119         myx += dozer.bd_dir_x;
 120         myy += dozer.bd_dir_y;
 121
 122         string newpos = minigame_tile_buildname(myx, myy);
 123         entity hit = bd_find_piece(minigame, newpos, false);
 124
 125         if(!bd_valid_tile(newpos))
 126                 return false;
 127
 128         if(hit)
 129         switch(hit.bd_tiletype)
 130         {
 131                 case BD_TILE_DOZER: // wtf, but let's do this incase
 132                 case BD_TILE_BRICK8:
 133                 case BD_TILE_BRICK7:
 134                 case BD_TILE_BRICK6:
 135                 case BD_TILE_BRICK5:
 136                 case BD_TILE_BRICK4:
 137                 case BD_TILE_BRICK3:
 138                 case BD_TILE_BRICK2:
 139                 case BD_TILE_BRICK1: return false;
 140                 case BD_TILE_BOULDER:
 141                 {
 142                         string testpos;
 143                         int tx = minigame_tile_letter(hit.netname);
 144                         int ty = minigame_tile_number(hit.netname);
 145
 146                         tx += dozer.bd_dir_x;
 147                         ty += dozer.bd_dir_y;
 148
 149                         testpos = minigame_tile_buildname(tx, ty);
 150                         entity testhit = bd_find_piece(minigame, testpos, false);
 151
 152                         if(!bd_valid_tile(testpos) || testhit)
 153                                 return false;
 154
 155                         if(hit.netname) { strunzone(hit.netname); }
 156                         hit.netname = strzone(testpos);
 157                         minigame_server_sendflags(hit,MINIG_SF_UPDATE);
 158                         break;
 159                 }
 160         }
 161
 162         if(dozer.netname) { strunzone(dozer.netname); }
 163         dozer.netname = strzone(newpos);
 164
 165         return true;
 166 }
 167
 168 // make a move
 169 void bd_move(entity minigame, entity player, string dir)
 170 {
 171         if ( minigame.minigame_flags & BD_TURN_MOVE )
 172         if ( dir )
 173         {
 174                 //if ( bd_valid_tile(pos) )
 175                 //if ( bd_find_piece(minigame, pos, false) )
 176                 {
 177                         entity dozer = bd_find_dozer(minigame);
 178                         if(!dozer)
 179                         {
 180                                 LOG_INFO("Dozer wasn't found!\n");
 181                                 return; // should not happen... TODO: end match?
 182                         }
 183
 184                         int dxs = 0, dys = 0;
 185                         string thedir = strtolower(dir);
 186                         if(thedir == "up" || thedir == "u") { dxs = 0; dys = 1; }
 187                         if(thedir == "down" || thedir == "dn" || thedir == "d") { dxs = 0; dys = -1; }
 188                         if(thedir == "left" || thedir == "lt" || thedir == "l") { dxs = -1; dys = 0; }
 189                         if(thedir == "right" || thedir == "rt" || thedir == "r") { dxs = 1; dys = 0; }
 190
 191                         int dx = bound(-1, dxs, 1);
 192                         int dy = bound(-1, dys, 1);
 193
 194                         dozer.bd_dir_x = dx;
 195                         dozer.bd_dir_y = dy;
 196                         dozer.bd_dir_z = 0;
 197
 198                         if(bd_move_dozer(minigame, dozer))
 199                                 player.bd_moves++;
 200
 201                         bd_check_winner(minigame);
 202
 203                         minigame_server_sendflags(dozer,MINIG_SF_UPDATE); // update anyway
 204                         minigame_server_sendflags(player,BD_SF_PLAYERMOVES);
 205                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 206                 }
 207         }
 208 }
 209
 210 // editor
 211 void bd_editor_place(entity minigame, entity player, string pos, int thetile, string thedir)
 212 {
 213         if ( minigame.minigame_flags & BD_TURN_EDIT )
 214         if ( pos && thetile )
 215         {
 216                 if ( bd_valid_tile(pos) )
 217                 {
 218                         entity found_piece = bd_find_piece(minigame, pos, false);
 219                         entity targ = bd_find_piece(minigame, pos, true);
 220
 221                         if(found_piece.bd_tiletype == BD_TILE_DOZER && thedir != "")
 222                         {
 223                                 int dxs = 0, dys = 0;
 224                                 string newdir = strtolower(thedir);
 225                                 if(newdir == "up" || newdir == "u") { dxs = 0; dys = 1; }
 226                                 if(newdir == "down" || newdir == "dn" || newdir == "d") { dxs = 0; dys = -1; }
 227                                 if(newdir == "left" || newdir == "lt" || newdir == "l") { dxs = -1; dys = 0; }
 228                                 if(newdir == "right" || newdir == "rt" || newdir == "r") { dxs = 1; dys = 0; }
 229
 230                                 int dx = bound(-1, dxs, 1);
 231                                 int dy = bound(-1, dys, 1);
 232
 233                                 found_piece.bd_dir_x = dx;
 234                                 found_piece.bd_dir_y = dy;
 235                                 found_piece.bd_dir_z = 0;
 236                                 minigame_server_sendflags(found_piece,MINIG_SF_UPDATE); // update anyway
 237                                 return;
 238                         }
 239
 240                         entity dozer = bd_find_dozer(minigame);
 241                         if(dozer && thetile == BD_TILE_DOZER && pos != dozer.netname)
 242                                 return; // nice try
 243
 244                         if(found_piece || (targ && thetile != BD_TILE_BOULDER))
 245                         {
 246                                 entity piece = bd_find_piece(minigame, pos, false);
 247                                 if(!piece) piece = bd_find_piece(minigame, pos, true);
 248                                 if(!piece)
 249                                         return; // how?!
 250
 251                                 if(piece.netname) { strunzone(piece.netname); }
 252                                 remove(piece);
 253                                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 254                                 return;
 255                         }
 256
 257                         entity piece = msle_spawn(minigame,"minigame_board_piece");
 258                         piece.team = 1;
 259                         piece.netname = strzone(pos);
 260                         piece.bd_tiletype = thetile;
 261                         piece.bd_dir = '0 -1 0';
 262                         minigame_server_sendflags(piece,MINIG_SF_UPDATE);
 263
 264                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 265                 }
 266         }
 267 }
 268
 269 void bd_do_move(entity minigame, entity player, string dir, string thetile, string thedir)
 270 {
 271         if(minigame.minigame_flags & BD_TURN_MOVE)
 272                 bd_move(minigame, player, dir);
 273
 274         if(minigame.minigame_flags & BD_TURN_EDIT)
 275                 bd_editor_place(minigame, player, dir, stof(thetile), thedir);
 276 }
 277
 278 void bd_fill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 279 {
 280         string pos = minigame_tile_buildname(letter,number);
 281         if(!bd_valid_tile(pos))
 282                 return;
 283         if(bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true))
 284                 return;
 285
 286         bd_editor_place(minigame, player, pos, thetype, "");
 287
 288         bd_fill_recurse(minigame, player, thetype, letter - 1, number);
 289         bd_fill_recurse(minigame, player, thetype, letter + 1, number);
 290         bd_fill_recurse(minigame, player, thetype, letter, number - 1);
 291         bd_fill_recurse(minigame, player, thetype, letter, number + 1);
 292 }
 293
 294 void bd_unfill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 295 {
 296         string pos = minigame_tile_buildname(letter,number);
 297         if(!bd_valid_tile(pos))
 298                 return;
 299
 300         entity targ = bd_find_piece(minigame, pos, true);
 301         entity piece = bd_find_piece(minigame, pos, false);
 302
 303         if(targ && thetype == targ.bd_tiletype)
 304         {
 305                 if(targ.netname) { strunzone(targ.netname); }
 306                 remove(targ);
 307         }
 308         else if(piece && thetype == piece.bd_tiletype)
 309         {
 310                 if(piece.netname) { strunzone(piece.netname); }
 311                 remove(piece);
 312         }
 313         else return;
 314
 315         bd_unfill_recurse(minigame, player, thetype, letter - 1, number);
 316         bd_unfill_recurse(minigame, player, thetype, letter + 1, number);
 317         bd_unfill_recurse(minigame, player, thetype, letter, number - 1);
 318         bd_unfill_recurse(minigame, player, thetype, letter, number + 1);
 319 }
 320
 321 void bd_do_fill(entity minigame, entity player, string dir, string thetile)
 322 {
 323         if(minigame.minigame_flags & BD_TURN_EDIT)
 324         {
 325                 int thetype = stof(thetile);
 326
 327                 entity targ = bd_find_piece(minigame, dir, true);
 328                 entity piece = bd_find_piece(minigame, dir, false);
 329
 330                 if(!bd_canfill(thetype) || (piece || targ))
 331                 {
 332                         int killtype = 0;
 333
 334                         if(targ) { killtype = targ.bd_tiletype; }
 335                         if(piece) { killtype = piece.bd_tiletype; }
 336
 337                         if(killtype)
 338                         {
 339                                 int letter = minigame_tile_letter(dir);
 340                                 int number = minigame_tile_number(dir);
 341                                 bd_unfill_recurse(minigame, player, killtype, letter, number);
 342                         }
 343
 344                         return;
 345                 }
 346
 347                 int letter = minigame_tile_letter(dir);
 348                 int number = minigame_tile_number(dir);
 349
 350                 bd_fill_recurse(minigame, player, thetype, letter, number);
 351         }
 352 }
 353
 354 void bd_reset_moves(entity minigame)
 355 {
 356         entity e;
 357 #ifdef SVQC
 358         for(e = minigame.minigame_players; e; e = e.list_next)
 359 #elif defined(CSQC)
 360         e = world;
 361         while( (e = findentity(e,owner,minigame)) )
 362                 if ( e.classname == "minigame_player" )
 363 #endif
 364                 {
 365                         e.bd_moves = 0;
 366                         minigame_server_sendflags(e,BD_SF_PLAYERMOVES);
 367                 }
 368 }
 369
 370 void bd_load_level(entity minigame);
 371 void bd_setup_pieces(entity minigame)
 372 {
 373         entity e = world;
 374         while( (e = findentity(e, owner, minigame)) )
 375                 if(e.classname == "minigame_board_piece")
 376                 {
 377                         if(e.netname) { strunzone(e.netname); }
 378                         remove(e);
 379                 }
 380
 381         bd_load_level(minigame);
 382 }
 383
 384 void bd_do_next_match(entity minigame, entity player)
 385 {
 386         minigame.minigame_flags = BD_TURN_MOVE;
 387         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 388
 389         if(minigame.bd_nextlevel && minigame.bd_nextlevel != "")
 390         {
 391                 if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 392                 minigame.bd_levelname = strzone(minigame.bd_nextlevel);
 393         }
 394
 395         bd_setup_pieces(minigame);
 396
 397         bd_reset_moves(minigame);
 398 }
 399
 400 void bd_set_next_match(entity minigame, string next)
 401 {
 402         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 403         minigame.bd_nextlevel = strzone(next);
 404 }
 405
 406 void bd_next_match(entity minigame, entity player, string next)
 407 {
 408         if(minigame.minigame_flags & BD_TURN_WIN)
 409                 bd_do_next_match(minigame, player);
 410         if(minigame.minigame_flags & BD_TURN_EDIT)
 411                 bd_set_next_match(minigame, next);
 412 }
 413
 414 // request a new match
 415 void bd_restart_match(entity minigame, entity player)
 416 {
 417         minigame.minigame_flags = BD_TURN_MOVE;
 418         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 419
 420         bd_setup_pieces(minigame);
 421
 422         bd_reset_moves(minigame);
 423 }
 424
 425 void bd_activate_editor(entity minigame, entity player)
 426 {
 427 #ifdef SVQC
 428         if(!player.minigame_players.bd_canedit)
 429         {
 430                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 431                 return;
 432         }
 433 #endif
 434
 435         minigame.minigame_flags = BD_TURN_EDIT;
 436         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 437
 438         bd_reset_moves(minigame);
 439
 440         bd_setup_pieces(minigame);
 441 }
 442
 443 string bd_save_piece(entity minigame, entity e)
 444 {
 445         string bd_string = "";
 446
 447         bd_string = strcat(bd_string, "\"", e.netname, "\" ");
 448         bd_string = strcat(bd_string, ftos(e.bd_tiletype), " ");
 449         bd_string = strcat(bd_string, sprintf("\"%.9v\"", e.bd_dir));
 450
 451         return bd_string;
 452 }
 453
 454 void bd_set_nextlevel(entity minigame, string s)
 455 {
 456         tokenize_console(s);
 457
 458         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 459         minigame.bd_nextlevel = strzone(argv(2));
 460 }
 461
 462 entity bd_load_piece(entity minigame, string s)
 463 {
 464         // separate pieces between the ; symbols
 465         string bd_string = s;
 466
 467         tokenize_console(bd_string);
 468
 469         entity e = msle_spawn(minigame,"minigame_board_piece");
 470         e.team = 1;
 471         e.bd_dir = '0 -1 0';
 472
 473         int argv_num = 0;
 474         e.netname = strzone(argv(argv_num)); ++argv_num;
 475         e.bd_tiletype = stof(argv(argv_num)); ++argv_num;
 476         e.bd_dir = stov(argv(argv_num)); ++argv_num;
 477
 478         minigame_server_sendflags(e,MINIG_SF_ALL);
 479
 480         return e;
 481 }
 482
 483 bool bd_save_level(entity minigame)
 484 {
 485         if(minigame.bd_levelname && minigame.bd_levelname != "")
 486         {
 487                 int target_count = 0, boulder_count = 0;
 488                 entity piece = world;
 489                 while((piece = findentity(piece,owner,minigame)))
 490                 if(piece.classname == "minigame_board_piece")
 491                         if(piece.bd_tiletype == BD_TILE_BOULDER)
 492                                 ++boulder_count;
 493                         else if(piece.bd_tiletype == BD_TILE_TARGET)
 494                                 ++target_count;
 495
 496                 if(boulder_count != target_count)
 497                 {
 498                         LOG_INFO("Not enough targets or boulders, fix your level!\n");
 499                         return false;
 500                 }
 501
 502                 // saves all objects to the database file
 503                 string file_name;
 504                 float file_get;
 505
 506                 file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 507                 file_get = fopen(file_name, FILE_WRITE);
 508                 fputs(file_get, strcat("// bulldozer storage \"", minigame.bd_levelname, "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S"), "\n"));
 509
 510                 if(minigame.bd_nextlevel && minigame.bd_nextlevel != "" && fexists(strcat("minigames/bulldozer/storage_", minigame.bd_nextlevel, ".txt")))
 511                         fputs(file_get, strcat("nextlevel = \"", minigame.bd_nextlevel, "\"\n"));
 512
 513                 entity e = world;
 514                 while ( ( e = findentity(e,owner,minigame) ) )
 515                 if ( e.classname == "minigame_board_piece" )
 516                 {
 517                         // use a line of text for each object, listing all properties
 518                         fputs(file_get, strcat(bd_save_piece(minigame, e), "\n"));
 519                 }
 520                 fclose(file_get);
 521
 522                 return true;
 523         }
 524
 525         return false;
 526 }
 527
 528 void bd_load_level(entity minigame)
 529 {
 530         // loads all items from the database file
 531         string file_read, file_name;
 532         float file_get;
 533
 534         file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 535         file_get = fopen(file_name, FILE_READ);
 536         if(file_get < 0)
 537         {
 538                 LOG_INFO("^3BULLDOZER: ^7could not find storage file ^3", file_name, "^7, no items were loaded\n");
 539         }
 540         else
 541         {
 542                 for(;;)
 543                 {
 544                         file_read = fgets(file_get);
 545                         if(file_read == "")
 546                                 break;
 547                         if(substring(file_read, 0, 2) == "//")
 548                                 continue;
 549                         if(substring(file_read, 0, 1) == "#")
 550                                 continue;
 551                         if(substring(file_read, 0, 9) == "nextlevel")
 552                         {
 553                                 bd_set_nextlevel(minigame, file_read);
 554                                 continue;
 555                         }
 556
 557                         entity e;
 558                         e = bd_load_piece(minigame, file_read);
 559                 }
 560         }
 561         fclose(file_get);
 562 }
 563
 564 void bd_close_editor(entity minigame)
 565 {
 566         entity dozer = bd_find_dozer(minigame);
 567         if(!dozer)
 568         {
 569                 LOG_INFO("You need to place a bulldozer on the level to save it!\n");
 570                 return;
 571         }
 572
 573         if(bd_save_level(minigame))
 574         {
 575                 minigame.minigame_flags = BD_TURN_MOVE;
 576                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 577         }
 578         else
 579         {
 580                 LOG_INFO("You need to set the level name!\n");
 581                 return;
 582         }
 583 }
 584
 585 #ifdef SVQC
 586
 587 // required function, handle server side events
 588 int bd_server_event(entity minigame, string event, ...)
 589 {
 590         switch(event)
 591         {
 592                 case "start":
 593                 {
 594                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 595                         minigame.bd_levelname = strzone(autocvar_sv_minigames_bulldozer_startlevel);
 596                         bd_setup_pieces(minigame);
 597                         minigame.minigame_flags = BD_TURN_MOVE;
 598
 599                         return true;
 600                 }
 601                 case "end":
 602                 {
 603                         entity e = world;
 604                         while( (e = findentity(e, owner, minigame)) )
 605                         if(e.classname == "minigame_board_piece")
 606                         {
 607                                 if(e.netname) { strunzone(e.netname); }
 608                                 remove(e);
 609                         }
 610
 611                         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 612                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 613                         return false;
 614                 }
 615                 case "join":
 616                 {
 617                         int pl_num = minigame_count_players(minigame);
 618
 619                         if(pl_num >= BD_TEAMS) { return false; }
 620
 621                         return 1;
 622                 }
 623                 case "cmd":
 624                 {
 625                         switch(argv(0))
 626                         {
 627                                 case "move":
 628                                         bd_do_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null), ((...(1,int)) >= 4 ? argv(3) : string_null));
 629                                         return true;
 630                                 case "next":
 631                                         bd_next_match(minigame,...(0,entity), ((...(1,int) >= 2 ? argv(1) : string_null)));
 632                                         return true;
 633                                 case "restart":
 634                                         bd_restart_match(minigame,...(0,entity));
 635                                         return true;
 636                                 case "edit":
 637                                         bd_activate_editor(minigame,...(0,entity));
 638                                         return true;
 639                                 case "save":
 640                                         bd_close_editor(minigame);
 641                                         return true;
 642                                 case "fill":
 643                                         bd_do_fill(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 644                                         return true;
 645                         }
 646
 647                         return false;
 648                 }
 649                 case "network_send":
 650                 {
 651                         entity sent = ...(0,entity);
 652                         int sf = ...(1,int);
 653                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 654                         {
 655                                 int letter = minigame_tile_letter(sent.netname);
 656                                 int number = minigame_tile_number(sent.netname);
 657
 658                                 WriteByte(MSG_ENTITY,letter);
 659                                 WriteByte(MSG_ENTITY,number);
 660
 661                                 WriteByte(MSG_ENTITY,sent.bd_tiletype);
 662
 663                                 int dx = sent.bd_dir_x;
 664                                 int dy = sent.bd_dir_y;
 665                                 if(dx == -1) dx = 2;
 666                                 if(dy == -1) dy = 2;
 667                                 WriteByte(MSG_ENTITY,dx);
 668                                 WriteByte(MSG_ENTITY,dy);
 669                         }
 670                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
 671                                 WriteShort(MSG_ENTITY,sent.bd_moves);
 672                         return false;
 673                 }
 674         }
 675
 676         return false;
 677 }
 678
 679
 680 #elif defined(CSQC)
 681
 682 int bd_curr_tile;
 683 string bd_curr_pos;
 684
 685 vector bd_boardpos; // HUD board position
 686 vector bd_boardsize;// HUD board size
 687
 688 string bd_get_tile_pic(int tileid)
 689 {
 690         switch(tileid)
 691         {
 692                 case BD_TILE_BOULDER: return "bd/boulder";
 693                 case BD_TILE_BRICK1: return "bd/brick1";
 694                 case BD_TILE_BRICK2: return "bd/brick2";
 695                 case BD_TILE_BRICK3: return "bd/brick3";
 696                 case BD_TILE_BRICK4: return "bd/brick4";
 697                 case BD_TILE_BRICK5: return "bd/brick5";
 698                 case BD_TILE_BRICK6: return "bd/brick6";
 699                 case BD_TILE_BRICK7: return "bd/brick7";
 700                 case BD_TILE_BRICK8: return "bd/brick8";
 701                 case BD_TILE_TARGET: return "bd/target";
 702                 case BD_TILE_DOZER: return "bd/dozer";
 703         }
 704
 705         return string_null;
 706 }
 707
 708 // Required function, draw the game board
 709 void bd_hud_board(vector pos, vector mySize)
 710 {
 711         minigame_hud_fitsqare(pos, mySize);
 712         bd_boardpos = pos;
 713         bd_boardsize = mySize;
 714
 715         minigame_hud_simpleboard(pos,mySize,minigame_texture("bd/board"));
 716
 717         vector tile_size = minigame_hud_denormalize_size('1 1 0' / BD_TILE_SIZE,pos,mySize);
 718         vector tile_pos;
 719
 720         entity e;
 721         FOREACH_MINIGAME_ENTITY(e)
 722         {
 723                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 724                 {
 725                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 726                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 727
 728                         string thepiece = bd_get_tile_pic(e.bd_tiletype);
 729
 730                         minigame_drawpic_centered( tile_pos,
 731                                         minigame_texture(thepiece),
 732                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 733                 }
 734
 735                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 736                 {
 737                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 738                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 739
 740                         minigame_drawpic_centered( tile_pos,
 741                                         minigame_texture("bd/target"),
 742                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 743                 }
 744
 745                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype == BD_TILE_DOZER )
 746                 {
 747                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 748                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 749
 750                         vector thedir = e.bd_dir;
 751                         float theang = 0;
 752
 753                         if(thedir_y == -1) { theang = M_PI; }
 754                         if(thedir_x == 1) { theang = M_PI/2; }
 755                         if(thedir_x == -1) { theang = M_PI*3/2; }
 756
 757                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 758                                                 tile_size, tile_size/2, '1 1 1',
 759                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 760                 }
 761         }
 762
 763         FOREACH_MINIGAME_ENTITY(e)
 764         {
 765                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
 766                 {
 767                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 768                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 769
 770                         minigame_drawpic_centered( tile_pos,
 771                                         minigame_texture("bd/target"),
 772                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 773                 }
 774         }
 775
 776         FOREACH_MINIGAME_ENTITY(e)
 777         {
 778                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 779                 {
 780                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 781                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 782
 783                         vector thedir = e.bd_dir;
 784                         float theang = 0;
 785
 786                         if(thedir_y == -1) { theang = M_PI; }
 787                         if(thedir_x == 1) { theang = M_PI/2; }
 788                         if(thedir_x == -1) { theang = M_PI*3/2; }
 789
 790                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 791                                                 tile_size, tile_size/2, '1 1 1',
 792                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 793                 }
 794         }
 795
 796         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 797         if(bd_valid_tile(bd_curr_pos))
 798         {
 799                 entity piece = bd_find_piece(active_minigame, bd_curr_pos, false);
 800                 entity targ = bd_find_piece(active_minigame, bd_curr_pos, true);
 801                 string thepiece = ((piece || (targ && bd_curr_tile != BD_TILE_BOULDER)) ? "bd/delete" : bd_get_tile_pic(bd_curr_tile));
 802
 803                 tile_pos = minigame_tile_pos(bd_curr_pos,BD_LET_CNT,BD_NUM_CNT);
 804                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 805                 if(bd_curr_tile == BD_TILE_DOZER)
 806                 {
 807                         drawrotpic(tile_pos, M_PI, minigame_texture("bd/dozer"),
 808                                                 tile_size, tile_size/2, '1 1 1',
 809                                                 panel_fg_alpha/2, DRAWFLAG_NORMAL );
 810                 }
 811                 else
 812                 {
 813                         minigame_drawpic_centered( tile_pos,
 814                                         minigame_texture(thepiece),
 815                                         tile_size, '1 1 1', panel_fg_alpha/2, DRAWFLAG_NORMAL );
 816                 }
 817         }
 818
 819         if ( (active_minigame.minigame_flags & BD_TURN_LOSS) || (active_minigame.minigame_flags & BD_TURN_WIN) )
 820         {
 821                 vector winfs = hud_fontsize*2;
 822                 string victory_text = "Game over!";
 823
 824                 if(active_minigame.minigame_flags & BD_TURN_WIN)
 825                         victory_text = "Well done! Click 'Next Level' to continue";
 826
 827                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 828                 vector win_sz;
 829                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 830                         sprintf("%s", victory_text),
 831                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 832
 833                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 834
 835                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 836                         sprintf("%s", victory_text),
 837                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 838         }
 839 }
 840
 841
 842 // Required function, draw the game status panel
 843 void bd_hud_status(vector pos, vector mySize)
 844 {
 845         HUD_Panel_DrawBg(1);
 846         vector ts;
 847         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 848                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 849
 850         pos_y += ts_y;
 851         mySize_y -= ts_y;
 852
 853         vector player_fontsize = hud_fontsize * 1.75;
 854         ts_y = ( mySize_y - 2*player_fontsize_y ) / BD_TEAMS;
 855         ts_x = mySize_x;
 856         vector mypos;
 857         vector tile_size = '48 48 0';
 858
 859         mypos = pos;
 860         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 861         mypos_y += player_fontsize_y;
 862         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 863
 864         entity e;
 865         FOREACH_MINIGAME_ENTITY(e)
 866         {
 867                 if ( e.classname == "minigame_player" )
 868                 {
 869                         mypos = pos;
 870                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 871                                 GetPlayerName(e.minigame_playerslot-1),
 872                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 873
 874                         mypos_y += player_fontsize_y;
 875                         string thepiece = "bd/dozer";
 876                         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 877                                 thepiece = bd_get_tile_pic(bd_curr_tile);
 878                         drawpic( mypos,
 879                                         minigame_texture(thepiece),
 880                                         tile_size * 0.7, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 881
 882                         mypos_x += tile_size_x;
 883
 884                         drawstring(mypos,ftos(e.bd_moves),tile_size,
 885                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 886                 }
 887         }
 888 }
 889
 890 // Turn a set of flags into a help message
 891 string bd_turn_to_string(int turnflags)
 892 {
 893         if ( turnflags & BD_TURN_LOSS )
 894                 return _("Better luck next time!");
 895
 896         if ( turnflags & BD_TURN_WIN )
 897                 if(random() > 0.5)
 898                         return _("Tubular! Press \"Next Level\" to continue!");
 899                 else
 900                         return _("Wicked! Press \"Next Level\" to continue!");
 901
 902         if( turnflags & BD_TURN_EDIT )
 903                 return _("Press the space bar to change your currently selected tile");
 904
 905         if ( turnflags & BD_TURN_MOVE )
 906                 return _("Push the boulders onto the targets");
 907
 908         return "";
 909 }
 910
 911 // Make the correct move
 912 void bd_make_move(entity minigame, string dir)
 913 {
 914         if ( minigame.minigame_flags == BD_TURN_MOVE )
 915         {
 916                 minigame_cmd("move ", dir);
 917         }
 918 }
 919
 920 void bd_editor_make_move(entity minigame, string dir)
 921 {
 922         if ( minigame.minigame_flags == BD_TURN_EDIT )
 923         {
 924                 minigame_cmd("move ", bd_curr_pos, " ", ftos(bd_curr_tile), " ", dir);
 925         }
 926 }
 927
 928 void bd_editor_fill(entity minigame)
 929 {
 930         if ( minigame.minigame_flags == BD_TURN_EDIT )
 931         {
 932                 minigame_cmd("fill ", bd_curr_pos, " ", ftos(bd_curr_tile));
 933         }
 934 }
 935
 936 void bd_set_curr_pos(string s)
 937 {
 938         if ( bd_curr_pos )
 939                 strunzone(bd_curr_pos);
 940         if ( s )
 941                 s = strzone(s);
 942         bd_curr_pos = s;
 943 }
 944
 945 bool bd_normal_move(entity minigame, int themove)
 946 {
 947         switch ( themove )
 948         {
 949                 case K_RIGHTARROW:
 950                 case K_KP_RIGHTARROW:
 951                         bd_make_move(minigame, "r");
 952                         return true;
 953                 case K_LEFTARROW:
 954                 case K_KP_LEFTARROW:
 955                         bd_make_move(minigame, "l");
 956                         return true;
 957                 case K_UPARROW:
 958                 case K_KP_UPARROW:
 959                         bd_make_move(minigame, "u");
 960                         return true;
 961                 case K_DOWNARROW:
 962                 case K_KP_DOWNARROW:
 963                         bd_make_move(minigame, "d");
 964                         return true;
 965         }
 966
 967         return false;
 968 }
 969
 970 bool bd_change_dozer_angle(entity minigame)
 971 {
 972         entity dozer = bd_find_piece(minigame, bd_curr_pos, false);
 973         if(!dozer || dozer.bd_tiletype != BD_TILE_DOZER)
 974                 return false;
 975
 976         string thedir = "";
 977         vector dir = dozer.bd_dir;
 978         if(dir.x == 0 && dir.y == 0) { thedir = "r"; }
 979
 980         if(dir.x == 0 && dir.y == 1) { thedir = "r"; }
 981         if(dir.x == 0 && dir.y ==-1) { thedir = "l"; }
 982         if(dir.x ==-1 && dir.y == 0) { thedir = "u"; }
 983         if(dir.x == 1 && dir.y == 0) { thedir = "d"; }
 984
 985         bd_editor_make_move(minigame, thedir);
 986         return true;
 987 }
 988
 989 bool bd_editor_move(entity minigame, int themove)
 990 {
 991         switch ( themove )
 992         {
 993                 case K_RIGHTARROW:
 994                 case K_KP_RIGHTARROW:
 995                         if ( ! bd_curr_pos )
 996                                 bd_set_curr_pos("a3");
 997                         else
 998                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,1,0,BD_NUM_CNT,BD_LET_CNT));
 999                         return true;
1000                 case K_LEFTARROW:
1001                 case K_KP_LEFTARROW:
1002                         if ( ! bd_curr_pos )
1003                                 bd_set_curr_pos("c3");
1004                         else
1005                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,-1,0,BD_NUM_CNT,BD_LET_CNT));
1006                         return true;
1007                 case K_UPARROW:
1008                 case K_KP_UPARROW:
1009                         if ( ! bd_curr_pos )
1010                                 bd_set_curr_pos("a1");
1011                         else
1012                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,1,BD_NUM_CNT,BD_LET_CNT));
1013                         return true;
1014                 case K_DOWNARROW:
1015                 case K_KP_DOWNARROW:
1016                         if ( ! bd_curr_pos )
1017                                 bd_set_curr_pos("a3");
1018                         else
1019                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,-1,BD_NUM_CNT,BD_LET_CNT));
1020                         return true;
1021                 case K_ENTER:
1022                 case K_KP_ENTER:
1023                         bd_editor_make_move(minigame, "");
1024                         return true;
1025                 case K_SPACE:
1026                         if(bd_change_dozer_angle(minigame))
1027                                 return true;
1028                         bd_curr_tile += 1;
1029                         if(bd_curr_tile > BD_TILE_LAST)
1030                                 bd_curr_tile = 1;
1031                         return true;
1032         }
1033
1034         return false;
1035 }
1036
1037 // Required function, handle client events
1038 int bd_client_event(entity minigame, string event, ...)
1039 {
1040         switch(event)
1041         {
1042                 case "activate":
1043                 {
1044                         minigame.message = bd_turn_to_string(minigame.minigame_flags);
1045                         bd_set_curr_pos("");
1046                         bd_curr_tile = BD_TILE_BRICK1;
1047                         return false;
1048                 }
1049                 case "key_pressed":
1050                 {
1051                         if(minigame.minigame_flags & BD_TURN_MOVE)
1052                         {
1053                                 if(bd_normal_move(minigame, ...(0,int)))
1054                                         return true;
1055                         }
1056
1057                         if(minigame.minigame_flags & BD_TURN_EDIT)
1058                         {
1059                                 if(bd_editor_move(minigame, ...(0,int)))
1060                                         return true;
1061                         }
1062
1063                         return false;
1064                 }
1065                 case "mouse_pressed":
1066                 {
1067                         if(minigame.minigame_flags & BD_TURN_EDIT)
1068                         {
1069                                 if(...(0,int) == K_MOUSE1)
1070                                 {
1071                                         bd_editor_make_move(minigame, "");
1072                                         return true;
1073                                 }
1074
1075                                 if(...(0,int) == K_MOUSE2)
1076                                 {
1077                                         bd_editor_fill(minigame);
1078                                         return true;
1079                                 }
1080                         }
1081
1082                         return false;
1083                 }
1084                 case "mouse_moved":
1085                 {
1086                         if(minigame.minigame_flags & BD_TURN_EDIT)
1087                         {
1088                                 vector mouse_pos = minigame_hud_normalize(mousepos,bd_boardpos,bd_boardsize);
1089                                 bd_set_curr_pos(minigame_tile_name(mouse_pos,BD_LET_CNT,BD_NUM_CNT));
1090                                 if ( ! bd_valid_tile(bd_curr_pos) )
1091                                         bd_set_curr_pos("");
1092                         }
1093                         return true;
1094                 }
1095                 case "network_receive":
1096                 {
1097                         entity sent = ...(0,entity);
1098                         int sf = ...(1,int);
1099                         if ( sent.classname == "minigame" )
1100                         {
1101                                 if ( sf & MINIG_SF_UPDATE )
1102                                 {
1103                                         sent.message = bd_turn_to_string(sent.minigame_flags);
1104                                         //if ( sent.minigame_flags & minigame_self.team )
1105                                                 minigame_prompt();
1106                                 }
1107                         }
1108                         else if(sent.classname == "minigame_board_piece")
1109                         {
1110                                 if(sf & MINIG_SF_UPDATE)
1111                                 {
1112                                         int letter = ReadByte();
1113                                         int number = ReadByte();
1114                                         if(sent.netname) { strunzone(sent.netname); }
1115                                         sent.netname = strzone(minigame_tile_buildname(letter, number));
1116
1117                                         sent.bd_tiletype = ReadByte();
1118
1119                                         int dx = ReadByte();
1120                                         int dy = ReadByte();
1121
1122                                         if(dx == 2) dx = -1;
1123                                         if(dy == 2) dy = -1;
1124
1125                                         sent.bd_dir_x = dx;
1126                                         sent.bd_dir_y = dy;
1127                                         sent.bd_dir_z = 0;
1128                                 }
1129                         }
1130                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
1131                                 sent.bd_moves = ReadShort(); // make this a byte when possible
1132
1133                         return false;
1134                 }
1135                 case "menu_show":
1136                 {
1137                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Next Level"),"next");
1138                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Restart"),"restart");
1139                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Editor"),"edit");
1140                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Save"),"save");
1141                         return false;
1142                 }
1143                 case "menu_click":
1144                 {
1145                         if(...(0,string) == "next")
1146                                 minigame_cmd("next");
1147                         if(...(0,string) == "restart")
1148                                 minigame_cmd("restart");
1149                         if(...(0,string) == "edit")
1150                                 minigame_cmd("edit");
1151                         if(...(0,string) == "save")
1152                                 minigame_cmd("save");
1153                         return false;
1154                 }
1155         }
1156
1157         return false;
1158 }
1159
1160 #endif