qcsrc/common/minigames/minigame/snake.qc

   1 const float SNAKE_TURN_MOVE  = 0x0100; // the snake is moving, player must control it
   2 const float SNAKE_TURN_LOSS  = 0x0200; // they did it?!
   3 const float SNAKE_TURN_WAIT  = 0x0400; // the snake is waiting for the player to make their first move and begin the game
   4 const float SNAKE_TURN_TYPE  = 0x0f00; // turn type mask
   5
   6 const int SNAKE_SF_PLAYERSCORE = MINIG_SF_CUSTOM;
   7
   8 const int SNAKE_LET_CNT = 15;
   9 const int SNAKE_NUM_CNT = 15;
  10
  11 const int SNAKE_TILE_SIZE = 15;
  12
  13 bool autocvar_sv_minigames_snake_wrap = false;
  14 float autocvar_sv_minigames_snake_delay_initial = 0.7;
  15 float autocvar_sv_minigames_snake_delay_multiplier = 50;
  16 float autocvar_sv_minigames_snake_delay_min = 0.1;
  17
  18 .int snake_score;
  19 .entity snake_head;
  20
  21 .float snake_delay;
  22 .float snake_nextmove;
  23 .vector snake_dir;
  24
  25 // find same game piece given its tile name
  26 entity snake_find_piece(entity minig, string tile)
  27 {
  28         entity e = world;
  29         while ( ( e = findentity(e,owner,minig) ) )
  30                 if ( e.classname == "minigame_board_piece" && e.netname == tile )
  31                         return e;
  32         return world;
  33 }
  34
  35 // find same game piece given its cnt
  36 entity snake_find_cnt(entity minig, int tile)
  37 {
  38         entity e = world;
  39         while ( ( e = findentity(e,owner,minig) ) )
  40                 if ( e.classname == "minigame_board_piece" && e.cnt == tile )
  41                         return e;
  42         return world;
  43 }
  44
  45 // check if the tile name is valid (15x15 grid)
  46 bool snake_valid_tile(string tile)
  47 {
  48         if ( !tile )
  49                 return false;
  50         int number = minigame_tile_number(tile);
  51         int letter = minigame_tile_letter(tile);
  52         return 0 <= number && number < SNAKE_NUM_CNT && 0 <= letter && letter < SNAKE_LET_CNT;
  53 }
  54
  55 void snake_new_mouse(entity minigame)
  56 {
  57         RandomSelection_Init();
  58         int i, j;
  59         for(i = 0; i < SNAKE_LET_CNT; ++i)
  60         for(j = 0; j < SNAKE_NUM_CNT; ++j)
  61         {
  62                 string pos = minigame_tile_buildname(i, j);
  63                 if(!snake_find_piece(minigame, pos))
  64                         RandomSelection_Add(world, 0, pos, 1, 1);
  65         }
  66
  67         entity piece = msle_spawn(minigame,"minigame_board_piece");
  68         piece.team = 1;
  69         piece.netname = strzone(RandomSelection_chosen_string);
  70         minigame_server_sendflags(piece,MINIG_SF_ALL);
  71
  72         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
  73 }
  74
  75 void snake_setup_pieces(entity minigame)
  76 {
  77         int targnum = bound(1, floor(random() * SNAKE_NUM_CNT), SNAKE_NUM_CNT - 1);
  78         int targlet = bound(1, floor(random() * SNAKE_LET_CNT), SNAKE_LET_CNT - 1);
  79
  80         entity piece = msle_spawn(minigame,"minigame_board_piece");
  81         piece.team = 1; // init default team?
  82         piece.netname = strzone(minigame_tile_buildname(targlet,targnum));
  83         piece.cnt = 1;
  84         minigame_server_sendflags(piece,MINIG_SF_ALL);
  85
  86         minigame.snake_head = piece;
  87
  88         snake_new_mouse(minigame);
  89
  90         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
  91 }
  92
  93 void snake_add_score(entity minigame, int thescore)
  94 {
  95 #ifdef SVQC
  96         if(!minigame)
  97                 return;
  98         if(minigame.minigame_players)
  99         {
 100                 minigame.minigame_players.snake_score += thescore;
 101                 minigame.minigame_players.SendFlags |= SNAKE_SF_PLAYERSCORE;
 102         }
 103 #endif
 104 }
 105
 106 void snake_move_body(entity minigame, bool ate_mouse)
 107 {
 108         entity tail = world;
 109         string tailpos = string_null;
 110         vector taildir = '0 0 0';
 111
 112         int i, pieces = 0;
 113         for(i = (SNAKE_NUM_CNT * SNAKE_LET_CNT); i >= 2; --i)
 114         {
 115                 entity piece = snake_find_cnt(minigame, i);
 116                 entity nextpiece = snake_find_cnt(minigame, i - 1);
 117                 if(!piece)
 118                         continue;
 119
 120                 pieces++;
 121
 122                 if(!tail)
 123                 {
 124                         tail = piece;
 125                         tailpos = piece.netname;
 126                         taildir = piece.snake_dir;
 127                 }
 128
 129                 if(piece.netname) { strunzone(piece.netname); }
 130                 piece.netname = strzone(nextpiece.netname);
 131                 piece.snake_dir = nextpiece.snake_dir;
 132                 minigame_server_sendflags(piece, MINIG_SF_ALL);
 133         }
 134
 135         // just a head
 136         if(!pieces)
 137         {
 138                 tail = minigame.snake_head;
 139                 tailpos = minigame.snake_head.netname;
 140                 taildir = minigame.snake_head.snake_dir;
 141         }
 142
 143         if(tail && ate_mouse)
 144         {
 145                 int newcnt = tail.cnt + 1;
 146                 minigame.snake_delay = max(autocvar_sv_minigames_snake_delay_min, autocvar_sv_minigames_snake_delay_initial - (newcnt / autocvar_sv_minigames_snake_delay_multiplier));
 147                 snake_add_score(minigame, 1);
 148
 149                 entity piece = msle_spawn(minigame,"minigame_board_piece");
 150                 piece.cnt = newcnt;
 151                 piece.team = 1;
 152                 piece.snake_dir = taildir;
 153                 piece.netname = strzone(tailpos);
 154                 minigame_server_sendflags(piece,MINIG_SF_ALL);
 155
 156                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 157         }
 158 }
 159
 160 void snake_move_head(entity minigame)
 161 {
 162         entity head = minigame.snake_head;
 163         string newpos;
 164
 165         if(autocvar_sv_minigames_snake_wrap)
 166                 newpos = minigame_relative_tile(head.netname, minigame.snake_dir_x, minigame.snake_dir_y, SNAKE_NUM_CNT, SNAKE_LET_CNT);
 167         else
 168         {
 169                 int myx = minigame_tile_letter(head.netname);
 170                 int myy = minigame_tile_number(head.netname);
 171
 172                 myx += minigame.snake_dir_x;
 173                 myy += minigame.snake_dir_y;
 174
 175                 newpos = minigame_tile_buildname(myx, myy);
 176         }
 177
 178         if(!snake_valid_tile(newpos) || (snake_find_piece(minigame, newpos)).cnt)
 179         {
 180                 minigame.minigame_flags = SNAKE_TURN_LOSS;
 181                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 182                 return;
 183         }
 184
 185         bool ate_mouse = false;
 186         entity piece = snake_find_piece(minigame, newpos);
 187         if(piece && !piece.cnt)
 188                 ate_mouse = true;
 189
 190         // move the body first, then set the new head position?
 191         snake_move_body(minigame, ate_mouse);
 192
 193         if(ate_mouse)
 194         {
 195                 if(piece.netname) { strunzone(piece.netname); }
 196                 remove(piece);
 197
 198                 snake_new_mouse(minigame);
 199         }
 200
 201         if(head.netname) { strunzone(head.netname); }
 202         head.netname = strzone(newpos);
 203         minigame_server_sendflags(head,MINIG_SF_ALL);
 204 }
 205
 206 // make a move
 207 void snake_move(entity minigame, entity player, string dxs, string dys )
 208 {
 209         if ( (minigame.minigame_flags & SNAKE_TURN_MOVE) || (minigame.minigame_flags & SNAKE_TURN_WAIT) )
 210         if ( dxs || dys )
 211         {
 212                 //if ( snake_valid_tile(pos) )
 213                 //if ( snake_find_piece(minigame, pos) )
 214                 {
 215                         int dx = ((dxs) ? bound(-1, stof(dxs), 1) : 0);
 216                         int dy = ((dys) ? bound(-1, stof(dys), 1) : 0);
 217
 218                         int myl = minigame_tile_letter(minigame.snake_head.netname);
 219                         int myn = minigame_tile_number(minigame.snake_head.netname);
 220
 221                         entity head = snake_find_piece(minigame, minigame_tile_buildname(myl + dx, myn + dy));
 222                         if(head && head.cnt == 2)
 223                                 return; // nope!
 224
 225                         if(minigame.minigame_flags & SNAKE_TURN_WAIT)
 226                                 minigame.snake_nextmove = time;
 227                         minigame.minigame_flags = SNAKE_TURN_MOVE;
 228                         minigame.snake_dir_x = dx;
 229                         minigame.snake_dir_y = dy;
 230                         minigame.snake_dir_z = 0;
 231                         minigame.snake_head.snake_dir = minigame.snake_dir;
 232                         minigame_server_sendflags(minigame.snake_head,MINIG_SF_UPDATE);
 233                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 234                 }
 235         }
 236 }
 237
 238 #ifdef SVQC
 239
 240
 241 // required function, handle server side events
 242 int snake_server_event(entity minigame, string event, ...)
 243 {
 244         switch(event)
 245         {
 246                 case "start":
 247                 {
 248                         snake_setup_pieces(minigame);
 249                         minigame.snake_delay = autocvar_sv_minigames_snake_delay_initial;
 250                         minigame.minigame_flags = SNAKE_TURN_WAIT;
 251                         return true;
 252                 }
 253                 case "end":
 254                 {
 255                         entity e = world;
 256                         while( (e = findentity(e, owner, minigame)) )
 257                         if(e.classname == "minigame_board_piece")
 258                         {
 259                                 if(e.netname) { strunzone(e.netname); }
 260                                 remove(e);
 261                         }
 262                         minigame.snake_head = world;
 263                         return false;
 264                 }
 265                 case "join":
 266                 {
 267                         int pl_num = minigame_count_players(minigame);
 268
 269                         // Don't allow more than 1 player
 270                         // not sure if this should be a multiplayer game (might get crazy)
 271                         if(pl_num >= 1) { return false; }
 272
 273                         // Team 1 by default
 274                         return 1;
 275                 }
 276                 case "frame":
 277                 {
 278                         if(minigame.minigame_flags & SNAKE_TURN_MOVE)
 279                         if(time >= minigame.snake_nextmove)
 280                         {
 281                                 snake_move_head(minigame);
 282                                 minigame.snake_nextmove = time + minigame.snake_delay;
 283                         }
 284                         return false;
 285                 }
 286                 case "cmd":
 287                 {
 288                         switch(argv(0))
 289                         {
 290                                 case "move":
 291                                         snake_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) == 3 ? argv(2) : string_null));
 292                                         return true;
 293                         }
 294
 295                         return false;
 296                 }
 297                 case "network_send":
 298                 {
 299                         entity sent = ...(0,entity);
 300                         int sf = ...(1,int);
 301                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 302                         {
 303                                 WriteByte(MSG_ENTITY,sent.cnt);
 304                                 WriteCoord(MSG_ENTITY,sent.snake_dir_x);
 305                                 WriteCoord(MSG_ENTITY,sent.snake_dir_y);
 306                         }
 307                         else if ( sent.classname == "minigame_player" && (sf & SNAKE_SF_PLAYERSCORE ) )
 308                         {
 309                                 WriteLong(MSG_ENTITY,sent.snake_score);
 310                         }
 311                         return false;
 312                 }
 313         }
 314
 315         return false;
 316 }
 317
 318
 319 #elif defined(CSQC)
 320
 321 vector snake_boardpos; // HUD board position
 322 vector snake_boardsize;// HUD board size
 323
 324 // Required function, draw the game board
 325 void snake_hud_board(vector pos, vector mySize)
 326 {
 327         minigame_hud_fitsqare(pos, mySize);
 328         snake_boardpos = pos;
 329         snake_boardsize = mySize;
 330
 331         minigame_hud_simpleboard(pos,mySize,minigame_texture("snake/board"));
 332
 333         vector tile_size = minigame_hud_denormalize_size('1 1 0' / SNAKE_TILE_SIZE,pos,mySize);
 334         vector tile_pos;
 335
 336         entity tail = world;
 337         int i;
 338         for(i = (SNAKE_NUM_CNT * SNAKE_LET_CNT); i >= 2; --i)
 339         {
 340                 entity piece = snake_find_cnt(active_minigame, i);
 341                 if(piece)
 342                 {
 343                         tail = piece;
 344                         break;
 345                 }
 346         }
 347
 348         entity e;
 349         FOREACH_MINIGAME_ENTITY(e)
 350         {
 351                 if ( e.classname == "minigame_board_piece" )
 352                 {
 353                         tile_pos = minigame_tile_pos(e.netname,SNAKE_NUM_CNT,SNAKE_LET_CNT);
 354                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 355                         string thepiece = "snake/mouse";
 356                         if(e.cnt)
 357                                 thepiece = "snake/body";
 358                         if(tail && e.cnt == tail.cnt)
 359                                 thepiece = "snake/tail";
 360                         if(e.cnt == 1)
 361                         {
 362                                 int dx = minigame_tile_letter(e.netname) + e.snake_dir_x * 2;
 363                                 int dy = minigame_tile_number(e.netname) + e.snake_dir_y * 2;
 364                                 entity mouse = snake_find_piece(active_minigame, minigame_tile_buildname(dx, dy));
 365                                 thepiece = "snake/head";
 366                                 if(mouse && !mouse.cnt)
 367                                 {
 368                                         float myang = 0;
 369                                         int myx = minigame_tile_letter(e.netname);
 370                                         int myy = minigame_tile_number(e.netname);
 371                                         if(myx - 2 == dx)
 372                                                 myang = M_PI*3/2;
 373                                         if(myx + 2 == dx)
 374                                                 myang = M_PI/2;
 375                                         if(myy - 2 == dy)
 376                                                 myang = M_PI;
 377
 378                                         int newx = minigame_tile_letter(e.netname) + e.snake_dir_x;
 379                                         int newy = minigame_tile_number(e.netname) + e.snake_dir_y;
 380                                         string newpos = minigame_tile_buildname(newx, newy);
 381
 382                                         vector my_pos = minigame_tile_pos(newpos,SNAKE_NUM_CNT,SNAKE_LET_CNT);
 383                                         my_pos = minigame_hud_denormalize(my_pos,pos,mySize);
 384
 385                                         drawrotpic(my_pos, myang, minigame_texture("snake/tongue"),
 386                                                         tile_size, tile_size/2, '1 1 1',
 387                                                         panel_fg_alpha, DRAWFLAG_NORMAL );
 388                                 }
 389                         }
 390
 391                         if(e.cnt == 1 || e.cnt == tail.cnt)
 392                         {
 393                                 vector thedir = e.snake_dir;
 394                                 float theang = 0;
 395                                 if(e.cnt == tail.cnt)
 396                                 {
 397                                         int thex = minigame_tile_letter(e.netname);
 398                                         int they = minigame_tile_number(e.netname);
 399                                         entity t = snake_find_cnt(active_minigame, e.cnt - 1);
 400                                         int tx = minigame_tile_letter(t.netname);
 401                                         int ty = minigame_tile_number(t.netname);
 402
 403                                         if(thex - 1 == tx)
 404                                         {
 405                                                 thedir_y = 0;
 406                                                 thedir_x = -1;
 407                                         }
 408                                         if(they + 1 == ty)
 409                                         {
 410                                                 thedir_x = 0;
 411                                                 thedir_y = 1;
 412                                         }
 413                                         if(they - 1 == ty)
 414                                         {
 415                                                 thedir_x = 0;
 416                                                 thedir_y = -1;
 417                                         }
 418                                 }
 419
 420                                 if(thedir_y == -1)
 421                                         theang = M_PI;
 422                                 if(thedir_x == 1)
 423                                         theang = M_PI/2;
 424                                 if(thedir_x == -1)
 425                                         theang = M_PI*3/2;
 426
 427                                 drawrotpic(tile_pos, theang, minigame_texture(thepiece),
 428                                                         tile_size, tile_size/2, '1 1 1',
 429                                                         panel_fg_alpha, DRAWFLAG_NORMAL );
 430                         }
 431                         else
 432                         {
 433                                 minigame_drawpic_centered( tile_pos,
 434                                                 minigame_texture(thepiece),
 435                                                 tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 436                         }
 437                 }
 438         }
 439
 440         if ( active_minigame.minigame_flags & SNAKE_TURN_LOSS )
 441         {
 442                 int scores = 0;
 443                 FOREACH_MINIGAME_ENTITY(e)
 444                         if(e.classname == "minigame_player")
 445                                 scores = e.snake_score;
 446
 447                 vector winfs = hud_fontsize*2;
 448                 string scores_text;
 449                 scores_text = strcat("Score: ", ftos(scores));
 450
 451                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 452                 vector win_sz;
 453                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 454                         sprintf("Game over! %s", scores_text),
 455                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 456
 457                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 458
 459                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 460                         sprintf("Game over! %s", scores_text),
 461                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 462         }
 463 }
 464
 465
 466 // Required function, draw the game status panel
 467 void snake_hud_status(vector pos, vector mySize)
 468 {
 469         HUD_Panel_DrawBg(1);
 470         vector ts;
 471         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 472                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 473
 474         pos_y += ts_y;
 475         mySize_y -= ts_y;
 476
 477         vector player_fontsize = hud_fontsize * 1.75;
 478         ts_y = ( mySize_y - 2*player_fontsize_y ) / 2;
 479         ts_x = mySize_x;
 480         vector mypos;
 481         vector tile_size = '48 48 0';
 482
 483         mypos = pos;
 484         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 485         mypos_y += player_fontsize_y;
 486         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 487
 488         entity e;
 489         FOREACH_MINIGAME_ENTITY(e)
 490         {
 491                 if ( e.classname == "minigame_player" )
 492                 {
 493                         mypos = pos;
 494                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 495                                 GetPlayerName(e.minigame_playerslot-1),
 496                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 497
 498                         mypos_y += player_fontsize_y;
 499                         //drawpic( mypos,
 500                         //              minigame_texture("snake/piece"),
 501                         //              tile_size, '1 0 0', panel_fg_alpha, DRAWFLAG_NORMAL );
 502
 503                         //mypos_x += tile_size_x;
 504
 505                         drawstring(mypos,ftos(e.snake_score),tile_size,
 506                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 507                 }
 508         }
 509 }
 510
 511 // Turn a set of flags into a help message
 512 string snake_turn_to_string(int turnflags)
 513 {
 514         if ( turnflags & SNAKE_TURN_LOSS )
 515                 return _("Game over!");
 516
 517         if ( turnflags & SNAKE_TURN_WAIT )
 518                 return _("Press an arrow key to begin the game");
 519
 520         if ( turnflags & SNAKE_TURN_MOVE )
 521                 return _("Avoid the walls and the snake's body, collect the mice!");
 522
 523         return "";
 524 }
 525
 526 // Make the correct move
 527 void snake_set_direction(entity minigame, int dx, int dy)
 528 {
 529         //if ( minigame.minigame_flags == SNAKE_TURN_MOVE )
 530         //{
 531                 minigame_cmd("move ",ftos(dx), " ", ftos(dy));
 532         //}
 533 }
 534
 535 // Required function, handle client events
 536 int snake_client_event(entity minigame, string event, ...)
 537 {
 538         switch(event)
 539         {
 540                 case "activate":
 541                 {
 542                         minigame.message = snake_turn_to_string(minigame.minigame_flags);
 543                         return false;
 544                 }
 545                 case "key_pressed":
 546                 {
 547                         //if((minigame.minigame_flags & SNAKE_TURN_TEAM) == minigame_self.team)
 548                         {
 549                                 switch ( ...(0,int) )
 550                                 {
 551                                         case K_RIGHTARROW:
 552                                         case K_KP_RIGHTARROW:
 553                                                 snake_set_direction(minigame, 1, 0);
 554                                                 return true;
 555                                         case K_LEFTARROW:
 556                                         case K_KP_LEFTARROW:
 557                                                 snake_set_direction(minigame, -1, 0);
 558                                                 return true;
 559                                         case K_UPARROW:
 560                                         case K_KP_UPARROW:
 561                                                 snake_set_direction(minigame, 0, 1);
 562                                                 return true;
 563                                         case K_DOWNARROW:
 564                                         case K_KP_DOWNARROW:
 565                                                 snake_set_direction(minigame, 0, -1);
 566                                                 return true;
 567                                 }
 568                         }
 569
 570                         return false;
 571                 }
 572                 case "network_receive":
 573                 {
 574                         entity sent = ...(0,entity);
 575                         int sf = ...(1,int);
 576                         if ( sent.classname == "minigame" )
 577                         {
 578                                 if ( sf & MINIG_SF_UPDATE )
 579                                 {
 580                                         sent.message = snake_turn_to_string(sent.minigame_flags);
 581                                         //if ( sent.minigame_flags & minigame_self.team )
 582                                                 minigame_prompt();
 583                                 }
 584                         }
 585                         else if(sent.classname == "minigame_board_piece")
 586                         {
 587                                 if(sf & MINIG_SF_UPDATE)
 588                                 {
 589                                         sent.cnt = ReadByte();
 590                                         sent.snake_dir_x = ReadCoord();
 591                                         sent.snake_dir_y = ReadCoord();
 592                                         sent.snake_dir_z = 0;
 593                                         if(sent.cnt == 1)
 594                                                 minigame.snake_head = sent; // hax
 595                                 }
 596                         }
 597                         else if ( sent.classname == "minigame_player" && (sf & SNAKE_SF_PLAYERSCORE ) )
 598                         {
 599                                 sent.snake_score = ReadLong();
 600                         }
 601
 602                         return false;
 603                 }
 604         }
 605
 606         return false;
 607 }
 608
 609 #endif