qcsrc/common/monsters/monster/mage.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ MAGE,
   4 /* function   */ m_mage,
   5 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-36 -36 -24', '36 36 50',
   7 /* model      */ "mage.dpm",
   8 /* netname    */ "mage",
   9 /* fullname   */ _("Mage")
  10 );
  11
  12 #define MAGE_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_spike_damage) \
  15         MON_ADD_CVAR(monster, attack_spike_radius) \
  16         MON_ADD_CVAR(monster, attack_spike_delay) \
  17         MON_ADD_CVAR(monster, attack_spike_accel) \
  18         MON_ADD_CVAR(monster, attack_spike_decel) \
  19         MON_ADD_CVAR(monster, attack_spike_turnrate) \
  20         MON_ADD_CVAR(monster, attack_spike_speed_max) \
  21         MON_ADD_CVAR(monster, attack_spike_smart) \
  22         MON_ADD_CVAR(monster, attack_spike_smart_trace_min) \
  23         MON_ADD_CVAR(monster, attack_spike_smart_trace_max) \
  24         MON_ADD_CVAR(monster, attack_spike_smart_mindist) \
  25         MON_ADD_CVAR(monster, attack_melee_damage) \
  26         MON_ADD_CVAR(monster, attack_melee_delay) \
  27         MON_ADD_CVAR(monster, attack_grenade_damage) \
  28         MON_ADD_CVAR(monster, attack_grenade_edgedamage) \
  29         MON_ADD_CVAR(monster, attack_grenade_force) \
  30         MON_ADD_CVAR(monster, attack_grenade_radius) \
  31         MON_ADD_CVAR(monster, attack_grenade_lifetime) \
  32         MON_ADD_CVAR(monster, attack_grenade_chance) \
  33         MON_ADD_CVAR(monster, attack_grenade_speed) \
  34         MON_ADD_CVAR(monster, attack_grenade_speed_up) \
  35         MON_ADD_CVAR(monster, heal_self) \
  36         MON_ADD_CVAR(monster, heal_allies) \
  37         MON_ADD_CVAR(monster, heal_minhealth) \
  38         MON_ADD_CVAR(monster, heal_range) \
  39         MON_ADD_CVAR(monster, heal_delay) \
  40         MON_ADD_CVAR(monster, shield_time) \
  41         MON_ADD_CVAR(monster, shield_delay) \
  42         MON_ADD_CVAR(monster, shield_blockpercent) \
  43         MON_ADD_CVAR(monster, speed_stop) \
  44         MON_ADD_CVAR(monster, speed_run) \
  45         MON_ADD_CVAR(monster, speed_walk)
  46
  47 #ifdef SVQC
  48 MAGE_SETTINGS(mage)
  49 #endif // SVQC
  50 #else
  51 #ifdef SVQC
  52 const float mage_anim_idle              = 0;
  53 const float mage_anim_walk              = 1;
  54 const float mage_anim_attack    = 2;
  55 const float mage_anim_pain              = 3;
  56 const float mage_anim_death     = 4;
  57 const float mage_anim_run               = 5;
  58
  59 void() mage_heal;
  60 void() mage_shield;
  61
  62 float friend_needshelp(entity e)
  63 {
  64         if(e == world)
  65                 return FALSE;
  66         if(e.health <= 0)
  67                 return FALSE;
  68         if(vlen(e.origin - self.origin) > MON_CVAR(mage, heal_range))
  69                 return FALSE;
  70         if(DIFF_TEAM(e, self) && e != self.monster_owner)
  71                 return FALSE;
  72         if(e.frozen)
  73                 return FALSE;
  74         if(!IS_PLAYER(e))
  75                 return (e.health < e.max_health);
  76         if(e.items & IT_INVINCIBLE)
  77                 return FALSE;
  78
  79         switch(self.skin)
  80         {
  81                 case 0: return (e.health < autocvar_g_balance_health_regenstable);
  82                 case 1: return ((e.ammo_cells && e.ammo_cells < g_pickup_cells_max) || (e.ammo_rockets && e.ammo_rockets < g_pickup_rockets_max) || (e.ammo_nails && e.ammo_nails < g_pickup_nails_max) || (e.ammo_shells && e.ammo_shells < g_pickup_shells_max));
  83                 case 2: return (e.armorvalue < autocvar_g_balance_armor_regenstable);
  84                 case 3: return (e.health > 0);
  85         }
  86
  87         return FALSE;
  88 }
  89
  90 void mageattack_melee()
  91 {
  92         monster_melee(self.enemy, MON_CVAR(mage, attack_melee_damage), mage_anim_attack, self.attack_range, MON_CVAR(mage, attack_melee_delay) - 0.2, DEATH_MONSTER_MAGE, TRUE);
  93 }
  94
  95 void mage_grenade_explode()
  96 {
  97         pointparticles(particleeffectnum("explosion_small"), self.origin, '0 0 0', 1);
  98
  99         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTEN_NORM);
 100         RadiusDamage (self, self.realowner, MON_CVAR(mage, attack_grenade_damage), MON_CVAR(mage, attack_grenade_edgedamage), MON_CVAR(mage, attack_grenade_radius), world, MON_CVAR(mage, attack_grenade_force), DEATH_MONSTER_MAGE, other);
 101         remove(self);
 102 }
 103
 104 void mage_grenade_touch()
 105 {
 106         if(IS_PLAYER(other))
 107         {
 108                 PROJECTILE_TOUCH;
 109                 mage_grenade_explode();
 110                 return;
 111         }
 112 }
 113
 114 void mage_throw_itemgrenade()
 115 {
 116         makevectors(self.angles);
 117
 118         entity gren = spawn ();
 119         gren.owner = gren.realowner = self;
 120         gren.classname = "grenade";
 121         gren.bot_dodge = FALSE;
 122         gren.movetype = MOVETYPE_BOUNCE;
 123         gren.solid = SOLID_TRIGGER;
 124         gren.projectiledeathtype = DEATH_MONSTER_MAGE;
 125         setorigin(gren, CENTER_OR_VIEWOFS(self));
 126         setsize(gren, '-64 -64 -64', '64 64 64');
 127
 128         gren.nextthink = time + MON_CVAR(mage, attack_grenade_lifetime);
 129         gren.think = mage_grenade_explode;
 130         gren.use = mage_grenade_explode;
 131         gren.touch = mage_grenade_touch;
 132
 133         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 134         W_SetupProjectileVelocityEx(gren, v_forward, v_up, MON_CVAR(mage, attack_grenade_speed), MON_CVAR(mage, attack_grenade_speed_up), 0, 0, FALSE);
 135
 136         gren.flags = FL_PROJECTILE;
 137
 138         setmodel(gren, "models/items/g_h50.md3");
 139
 140         self.attack_finished_single = time + 1.5;
 141 }
 142
 143 void mage_spike_explode()
 144 {
 145         self.event_damage = func_null;
 146
 147         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTEN_NORM);
 148
 149         pointparticles(particleeffectnum("explosion_small"), self.origin, '0 0 0', 1);
 150         RadiusDamage (self, self.realowner, MON_CVAR(mage, attack_spike_damage), MON_CVAR(mage, attack_spike_damage) * 0.5, MON_CVAR(mage, attack_spike_radius), world, 0, DEATH_MONSTER_MAGE, other);
 151
 152         remove (self);
 153 }
 154
 155 void mage_spike_touch()
 156 {
 157         PROJECTILE_TOUCH;
 158
 159         mage_spike_explode();
 160 }
 161
 162 // copied from W_Seeker_Think
 163 void mage_spike_think()
 164 {
 165         entity e;
 166         vector desireddir, olddir, newdir, eorg;
 167         float turnrate;
 168         float dist;
 169         float spd;
 170
 171         if (time > self.ltime || self.enemy.health <= 0 || self.owner.health <= 0)
 172         {
 173                 self.projectiledeathtype |= HITTYPE_SPLASH;
 174                 mage_spike_explode();
 175         }
 176
 177         spd = vlen(self.velocity);
 178         spd = bound(
 179                 spd - MON_CVAR(mage, attack_spike_decel) * frametime,
 180                 MON_CVAR(mage, attack_spike_speed_max),
 181                 spd + MON_CVAR(mage, attack_spike_accel) * frametime
 182         );
 183
 184         if (self.enemy != world)
 185                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 186                         self.enemy = world;
 187
 188         if (self.enemy != world)
 189         {
 190                 e               = self.enemy;
 191                 eorg            = 0.5 * (e.absmin + e.absmax);
 192                 turnrate        = MON_CVAR(mage, attack_spike_turnrate); // how fast to turn
 193                 desireddir      = normalize(eorg - self.origin);
 194                 olddir          = normalize(self.velocity); // get my current direction
 195                 dist            = vlen(eorg - self.origin);
 196
 197                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 198                 if (MON_CVAR(mage, attack_spike_smart) && (dist > MON_CVAR(mage, attack_spike_smart_mindist)))
 199                 {
 200                         // Is it a better idea (shorter distance) to trace to the target itself?
 201                         if ( vlen(self.origin + olddir * self.wait) < dist)
 202                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 203                         else
 204                                 traceline(self.origin, eorg, FALSE, self);
 205
 206                         // Setup adaptive tracelength
 207                         self.wait = bound(MON_CVAR(mage, attack_spike_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = MON_CVAR(mage, attack_spike_smart_trace_max));
 208
 209                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 210                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 211                 }
 212
 213                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 214                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 215         }
 216         else
 217                 dist = 0;
 218
 219         ///////////////
 220
 221         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 222         self.nextthink = time;// + 0.05; // csqc projectiles
 223         UpdateCSQCProjectile(self);
 224 }
 225
 226 void mage_spike()
 227 {
 228         entity missile;
 229         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
 230
 231         makevectors(self.angles);
 232
 233         missile = spawn ();
 234         missile.owner = missile.realowner = self;
 235         missile.think = mage_spike_think;
 236         missile.ltime = time + 7;
 237         missile.nextthink = time;
 238         missile.solid = SOLID_BBOX;
 239         missile.movetype = MOVETYPE_FLYMISSILE;
 240         missile.flags = FL_PROJECTILE;
 241         setorigin(missile, self.origin + v_forward * 14 + '0 0 30' + v_right * -14);
 242         setsize (missile, '0 0 0', '0 0 0');
 243         missile.velocity = dir * 400;
 244         missile.avelocity = '300 300 300';
 245         missile.enemy = self.enemy;
 246         missile.touch = mage_spike_touch;
 247
 248         CSQCProjectile(missile, TRUE, PROJECTILE_MAGE_SPIKE, TRUE);
 249 }
 250
 251 void mage_heal()
 252 {
 253         entity head;
 254         float washealed = FALSE;
 255
 256         for(head = world; (head = findfloat(head, monster_attack, TRUE)); ) if(friend_needshelp(head))
 257         {
 258                 washealed = TRUE;
 259                 string fx = "";
 260                 if(IS_PLAYER(head))
 261                 {
 262                         switch(self.skin)
 263                         {
 264                                 case 0:
 265                                         if(head.health < autocvar_g_balance_health_regenstable) head.health = bound(0, head.health + MON_CVAR(mage, heal_allies), autocvar_g_balance_health_regenstable);
 266                                         fx = "healing_fx";
 267                                         break;
 268                                 case 1:
 269                                         if(head.ammo_cells) head.ammo_cells = bound(head.ammo_cells, head.ammo_cells + 1, g_pickup_cells_max);
 270                                         if(head.ammo_rockets) head.ammo_rockets = bound(head.ammo_rockets, head.ammo_rockets + 1, g_pickup_rockets_max);
 271                                         if(head.ammo_shells) head.ammo_shells = bound(head.ammo_shells, head.ammo_shells + 2, g_pickup_shells_max);
 272                                         if(head.ammo_nails) head.ammo_nails = bound(head.ammo_nails, head.ammo_nails + 5, g_pickup_nails_max);
 273                                         fx = "ammoregen_fx";
 274                                         break;
 275                                 case 2:
 276                                         if(head.armorvalue < autocvar_g_balance_armor_regenstable)
 277                                         {
 278                                                 head.armorvalue = bound(0, head.armorvalue + MON_CVAR(mage, heal_allies), autocvar_g_balance_armor_regenstable);
 279                                                 fx = "armorrepair_fx";
 280                                         }
 281                                         break;
 282                                 case 3:
 283                                         head.health = bound(0, head.health - ((head == self)  ? MON_CVAR(mage, heal_self) : MON_CVAR(mage, heal_allies)), autocvar_g_balance_health_regenstable);
 284                                         fx = "rage";
 285                                         break;
 286                         }
 287
 288                         pointparticles(particleeffectnum(fx), head.origin, '0 0 0', 1);
 289                 }
 290                 else
 291                 {
 292                         pointparticles(particleeffectnum("healing_fx"), head.origin, '0 0 0', 1);
 293                         head.health = bound(0, head.health + MON_CVAR(mage, heal_allies), head.max_health);
 294                 }
 295         }
 296
 297         if(washealed)
 298         {
 299                 self.frame = mage_anim_attack;
 300                 self.attack_finished_single = time + MON_CVAR(mage, heal_delay);
 301         }
 302 }
 303
 304 void mage_shield_think()
 305 {
 306         self.nextthink = time;
 307
 308         if(time >= self.ltime || self.owner.health <= 0)
 309         {
 310                 self.owner.armorvalue = 0;
 311                 self.owner.m_armor_blockpercent = autocvar_g_monsters_armor_blockpercent;
 312                 remove(self);
 313                 return;
 314         }
 315 }
 316
 317 void mage_shield()
 318 {
 319         if(self.weaponentity)
 320                 return; // already have a shield
 321
 322         entity shield = spawn();
 323
 324         shield.owner = self;
 325         shield.team = self.team;
 326         shield.ltime = time + MON_CVAR(mage, shield_time);
 327         shield.classname = "shield";
 328         shield.effects = EF_ADDITIVE;
 329         shield.movetype = MOVETYPE_NOCLIP;
 330         shield.solid = SOLID_TRIGGER;
 331         shield.avelocity = '7 0 11';
 332         shield.scale = self.scale * 0.6;
 333         shield.think = mage_shield_think;
 334         shield.nextthink = time;
 335
 336         setattachment(shield, self, "");
 337         setmodel(shield, "models/ctf/shield.md3");
 338         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 339
 340         self.lastshielded = time + MON_CVAR(mage, shield_delay);
 341
 342         self.frame = mage_anim_attack;
 343         self.attack_finished_single = time + 1;
 344
 345         self.m_armor_blockpercent = MON_CVAR(mage, shield_blockpercent);
 346         self.armorvalue = self.health;
 347 }
 348
 349 float mage_attack(float attack_type)
 350 {
 351         switch(attack_type)
 352         {
 353                 case MONSTER_ATTACK_MELEE:
 354                 {
 355                         self.frame = mage_anim_attack;
 356                         self.attack_finished_single = time + MON_CVAR(mage, attack_melee_delay);
 357                         defer(0.2, mageattack_melee);
 358
 359                         return TRUE;
 360                 }
 361                 case MONSTER_ATTACK_RANGED:
 362                 {
 363                         if(random() < MON_CVAR(mage, attack_grenade_chance) / 100)
 364                         {
 365                                 mage_throw_itemgrenade();
 366                                 return TRUE;
 367                         }
 368
 369                         self.frame = mage_anim_attack;
 370                         self.attack_finished_single = time + MON_CVAR(mage, attack_spike_delay);
 371                         defer(0.2, mage_spike);
 372
 373                         return TRUE;
 374                 }
 375         }
 376
 377         return FALSE;
 378 }
 379
 380 void spawnfunc_monster_mage()
 381 {
 382         self.classname = "monster_mage";
 383
 384         self.monster_spawnfunc = spawnfunc_monster_mage;
 385
 386         if(Monster_CheckAppearFlags(self))
 387                 return;
 388
 389         if not(monster_initialize(MON_MAGE, FALSE)) { remove(self); return; }
 390 }
 391
 392 // compatibility with old spawns
 393 void spawnfunc_monster_shalrath() { spawnfunc_monster_mage(); }
 394
 395 float m_mage(float req)
 396 {
 397         switch(req)
 398         {
 399                 case MR_THINK:
 400                 {
 401                         entity head;
 402                         float need_help = FALSE;
 403
 404                         FOR_EACH_PLAYER(head)
 405                         if(friend_needshelp(head))
 406                         {
 407                                 need_help = TRUE;
 408                                 break; // found 1 player near us who is low on health
 409                         }
 410                         if(!need_help)
 411                         FOR_EACH_MONSTER(head)
 412                         if(head != self)
 413                         if(friend_needshelp(head))
 414                         {
 415                                 need_help = TRUE;
 416                                 break; // found 1 player near us who is low on health
 417                         }
 418
 419                         if(self.health < MON_CVAR(mage, heal_minhealth) || need_help)
 420                         if(time >= self.attack_finished_single)
 421                         if(random() < 0.5)
 422                                 mage_heal();
 423
 424                         if(self.enemy)
 425                         if(self.health < self.max_health)
 426                         if(time >= self.lastshielded)
 427                         if(random() < 0.5)
 428                                 mage_shield();
 429
 430                         monster_move(MON_CVAR(mage, speed_run), MON_CVAR(mage, speed_walk), MON_CVAR(mage, speed_stop), mage_anim_walk, mage_anim_run, mage_anim_idle);
 431                         return TRUE;
 432                 }
 433                 case MR_DEATH:
 434                 {
 435                         self.frame = mage_anim_death;
 436                         return TRUE;
 437                 }
 438                 case MR_SETUP:
 439                 {
 440                         if not(self.health) self.health = MON_CVAR(mage, health);
 441
 442                         self.monster_loot = spawnfunc_item_health_large;
 443                         self.monster_attackfunc = mage_attack;
 444                         self.frame = mage_anim_walk;
 445
 446                         return TRUE;
 447                 }
 448                 case MR_PRECACHE:
 449                 {
 450                         precache_model ("models/monsters/mage.dpm");
 451                         precache_model ("models/items/g_h50.md3");
 452                         precache_model ("models/ctf/shield.md3");
 453                         precache_sound ("weapons/grenade_impact.wav");
 454                         return TRUE;
 455                 }
 456                 case MR_CONFIG:
 457                 {
 458                         MON_CONFIG_SETTINGS(MAGE_SETTINGS(mage))
 459                         return TRUE;
 460                 }
 461         }
 462
 463         return TRUE;
 464 }
 465
 466 #endif // SVQC
 467 #ifdef CSQC
 468 float m_mage(float req)
 469 {
 470         switch(req)
 471         {
 472                 case MR_PRECACHE:
 473                 {
 474                         precache_model ("models/monsters/mage.dpm");
 475                         return TRUE;
 476                 }
 477         }
 478
 479         return TRUE;
 480 }
 481
 482 #endif // CSQC
 483 #endif // REGISTER_MONSTER