qcsrc/common/monsters/monster/shambler.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SHAMBLER,
   4 /* function   */ m_shambler,
   5 /* spawnflags */ MONSTER_SIZE_BROKEN,
   6 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   7 /* model      */ "shambler.mdl",
   8 /* netname    */ "shambler",
   9 /* fullname   */ _("Shambler")
  10 );
  11
  12 #else
  13 #ifdef SVQC
  14 float autocvar_g_monster_shambler;
  15 float autocvar_g_monster_shambler_health;
  16 float autocvar_g_monster_shambler_damage;
  17 float autocvar_g_monster_shambler_attack_lightning_damage;
  18 float autocvar_g_monster_shambler_attack_claw_damage;
  19 float autocvar_g_monster_shambler_speed_walk;
  20 float autocvar_g_monster_shambler_speed_run;
  21
  22 const float shambler_anim_stand         = 0;
  23 const float shambler_anim_walk          = 1;
  24 const float shambler_anim_run           = 2;
  25 const float shambler_anim_smash         = 3;
  26 const float shambler_anim_swingr        = 4;
  27 const float shambler_anim_swingl        = 5;
  28 const float shambler_anim_magic         = 6;
  29 const float shambler_anim_pain          = 7;
  30 const float shambler_anim_death         = 8;
  31
  32 void shambler_smash()
  33 {
  34         monster_melee(self.enemy, autocvar_g_monster_shambler_damage, 0.3, DEATH_MONSTER_SHAMBLER_SMASH, TRUE);
  35 }
  36
  37 void shambler_delayedsmash()
  38 {
  39         monsters_setframe(shambler_anim_smash);
  40         defer(0.7, shambler_smash);
  41         self.attack_finished_single = time + 1.1;
  42 }
  43
  44 void shambler_swing()
  45 {
  46         float r = (random() < 0.5);
  47         monsters_setframe((r) ? shambler_anim_swingr : shambler_anim_swingl);
  48         monster_melee(self.enemy, autocvar_g_monster_shambler_attack_claw_damage, 0.3, DEATH_MONSTER_SHAMBLER_CLAW, TRUE);
  49         self.attack_finished_single = time + 0.8;
  50         if(r)
  51                 defer(0.5, shambler_swing);
  52 }
  53
  54 void CastLightning()
  55 {
  56         local vector org, dir;
  57         //vector v = '0 0 0';
  58
  59         self.effects |= EF_MUZZLEFLASH;
  60
  61         org = self.origin + '0 0 40';
  62
  63         dir = self.enemy.origin + '0 0 16' - org;
  64         dir = normalize (dir);
  65
  66         traceline (org, self.origin + dir * 1000, TRUE, self);
  67
  68         FireRailgunBullet (org, org + dir * 1000, autocvar_g_monster_shambler_attack_lightning_damage * monster_skill, 0, 0, 0, 0, 0, DEATH_MONSTER_SHAMBLER_ZAP);
  69
  70         // teamcolor / hit beam effect
  71         //v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  72         //WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), org, v);
  73
  74         te_csqc_lightningarc(org, trace_endpos);
  75 }
  76
  77 float shambler_attack(float attack_type)
  78 {
  79         switch(attack_type)
  80         {
  81                 case MONSTER_ATTACK_MELEE:
  82                 {
  83                         float chance = random();
  84
  85                         if(chance > 0.6)
  86                                 shambler_delayedsmash();
  87                         else
  88                                 shambler_swing();
  89
  90                         return TRUE;
  91                 }
  92                 case MONSTER_ATTACK_RANGED:
  93                 {
  94                         monsters_setframe(shambler_anim_magic);
  95                         self.attack_finished_single = time + 1.1;
  96                         defer(0.6, CastLightning);
  97
  98                         return TRUE;
  99                 }
 100         }
 101
 102         return FALSE;
 103 }
 104
 105 void spawnfunc_monster_shambler()
 106 {
 107         if not(autocvar_g_monster_shambler) { remove(self); return; }
 108
 109         self.classname = "monster_shambler";
 110
 111         self.monster_spawnfunc = spawnfunc_monster_shambler;
 112
 113         if(Monster_CheckAppearFlags(self))
 114                 return;
 115
 116         if not(monster_initialize(MON_SHAMBLER, FALSE)) { remove(self); return; }
 117 }
 118
 119 float m_shambler(float req)
 120 {
 121         switch(req)
 122         {
 123                 case MR_THINK:
 124                 {
 125                         monster_move(autocvar_g_monster_shambler_speed_run, autocvar_g_monster_shambler_speed_walk, 300, shambler_anim_run, shambler_anim_walk, shambler_anim_stand);
 126                         return TRUE;
 127                 }
 128                 case MR_DEATH:
 129                 {
 130                         monsters_setframe(shambler_anim_death);
 131                         return TRUE;
 132                 }
 133                 case MR_SETUP:
 134                 {
 135                         if not(self.health) self.health = autocvar_g_monster_shambler_health;
 136
 137                         self.monster_attackfunc = shambler_attack;
 138                         monsters_setframe(shambler_anim_stand);
 139                         self.weapon = WEP_NEX;
 140
 141                         return TRUE;
 142                 }
 143                 case MR_INIT:
 144                 {
 145                         // nothing
 146                         return TRUE;
 147                 }
 148         }
 149
 150         return TRUE;
 151 }
 152
 153 #endif // SVQC
 154 #ifdef CSQC
 155 float m_shambler(float req)
 156 {
 157         switch(req)
 158         {
 159                 case MR_DEATH:
 160                 {
 161                         // nothing
 162                         return TRUE;
 163                 }
 164                 case MR_INIT:
 165                 {
 166                         precache_model ("models/monsters/shambler.mdl");
 167                         return TRUE;
 168                 }
 169         }
 170
 171         return TRUE;
 172 }
 173
 174 #endif // CSQC
 175 #endif // REGISTER_MONSTER