qcsrc/common/monsters/monster/shambler.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SHAMBLER,
   4 /* function   */ m_shambler,
   5 /* spawnflags */ MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   7 /* model      */ "shambler.mdl",
   8 /* netname    */ "shambler",
   9 /* fullname   */ _("Shambler")
  10 );
  11
  12 #define SHAMBLER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_smash_damage) \
  15         MON_ADD_CVAR(monster, attack_claw_damage) \
  16         MON_ADD_CVAR(monster, attack_lightning_damage) \
  17         MON_ADD_CVAR(monster, attack_lightning_force) \
  18         MON_ADD_CVAR(monster, attack_lightning_radius) \
  19         MON_ADD_CVAR(monster, attack_lightning_radius_zap) \
  20         MON_ADD_CVAR(monster, attack_lightning_speed) \
  21         MON_ADD_CVAR(monster, attack_lightning_speed_up) \
  22         MON_ADD_CVAR(monster, speed_stop) \
  23         MON_ADD_CVAR(monster, speed_run) \
  24         MON_ADD_CVAR(monster, speed_walk)
  25
  26 #ifdef SVQC
  27 SHAMBLER_SETTINGS(shambler)
  28 #endif // SVQC
  29 #else
  30 #ifdef SVQC
  31 const float shambler_anim_stand         = 0;
  32 const float shambler_anim_walk          = 1;
  33 const float shambler_anim_run           = 2;
  34 const float shambler_anim_smash         = 3;
  35 const float shambler_anim_swingr        = 4;
  36 const float shambler_anim_swingl        = 5;
  37 const float shambler_anim_magic         = 6;
  38 const float shambler_anim_pain          = 7;
  39 const float shambler_anim_death         = 8;
  40
  41 .float shambler_lastattack; // delay attacks separately
  42
  43 void shambler_smash()
  44 {
  45         makevectors(self.angles);
  46         pointparticles(particleeffectnum("explosion_medium"), (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs_z), '0 0 0', 1);
  47         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
  48
  49         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * 500, MOVE_NORMAL, self);
  50
  51         if(trace_ent.takedamage)
  52                 Damage(trace_ent, self, self, MON_CVAR(shambler, attack_smash_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  53 }
  54
  55 void shambler_swing()
  56 {
  57         float r = (random() < 0.5);
  58         monster_melee(self.enemy, MON_CVAR(shambler, attack_claw_damage), ((r) ? shambler_anim_swingr : shambler_anim_swingl), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, TRUE);
  59         if(r)
  60         {
  61                 defer(0.5, shambler_swing);
  62                 self.attack_finished_single += 0.5;
  63         }
  64 }
  65
  66 void shambler_lightning_explode()
  67 {
  68         entity head;
  69
  70         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
  71         pointparticles(particleeffectnum("electro_impact"), '0 0 0', '0 0 0', 1);
  72
  73         self.event_damage = func_null;
  74         self.takedamage = DAMAGE_NO;
  75         self.movetype = MOVETYPE_NONE;
  76         self.velocity = '0 0 0';
  77
  78         if(self.movetype == MOVETYPE_NONE)
  79                 self.velocity = self.oldvelocity;
  80
  81         RadiusDamage (self, self.realowner, MON_CVAR(shambler, attack_lightning_damage), MON_CVAR(shambler, attack_lightning_damage), MON_CVAR(shambler, attack_lightning_radius), world, MON_CVAR(shambler, attack_lightning_force), self.projectiledeathtype, other);
  82
  83         for(head = findradius(self.origin, MON_CVAR(shambler, attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner) if(head.takedamage)
  84         {
  85                 te_csqc_lightningarc(self.origin, head.origin);
  86                 Damage(head, self, self.realowner, MON_CVAR(shambler, attack_lightning_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
  87         }
  88
  89         self.think = SUB_Remove;
  90         self.nextthink = time + 0.2;
  91 }
  92
  93 void shambler_lightning_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  94 {
  95         if (self.health <= 0)
  96                 return;
  97
  98         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  99                 return; // g_projectiles_damage says to halt
 100
 101         self.health = self.health - damage;
 102
 103         if (self.health <= 0)
 104                 W_PrepareExplosionByDamage(attacker, self.use);
 105 }
 106
 107 void shambler_lightning_touch()
 108 {
 109         PROJECTILE_TOUCH;
 110
 111         self.use ();
 112 }
 113
 114 void shambler_lightning_think()
 115 {
 116         self.nextthink = time;
 117         if (time > self.cnt)
 118         {
 119                 other = world;
 120                 shambler_lightning_explode();
 121                 return;
 122         }
 123 }
 124
 125 void shambler_lightning()
 126 {
 127         entity gren;
 128
 129         monster_makevectors(self.enemy);
 130
 131         gren = spawn ();
 132         gren.owner = gren.realowner = self;
 133         gren.classname = "grenade";
 134         gren.bot_dodge = TRUE;
 135         gren.bot_dodgerating = MON_CVAR(shambler, attack_lightning_damage);
 136         gren.movetype = MOVETYPE_BOUNCE;
 137         PROJECTILE_MAKETRIGGER(gren);
 138         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 139         setorigin(gren, CENTER_OR_VIEWOFS(self));
 140         setsize(gren, '-8 -8 -8', '8 8 8');
 141         gren.scale = 2.5;
 142
 143         gren.cnt = time + 5;
 144         gren.nextthink = time;
 145         gren.think = shambler_lightning_think;
 146         gren.use = shambler_lightning_explode;
 147         gren.touch = shambler_lightning_touch;
 148
 149         gren.takedamage = DAMAGE_YES;
 150         gren.health = 50;
 151         gren.damageforcescale = 0;
 152         gren.event_damage = shambler_lightning_damage;
 153         gren.damagedbycontents = TRUE;
 154         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 155         W_SetupProjectileVelocityEx(gren, v_forward, v_up, MON_CVAR(shambler, attack_lightning_speed), MON_CVAR(shambler, attack_lightning_speed_up), 0, 0, FALSE);
 156
 157         gren.angles = vectoangles (gren.velocity);
 158         gren.flags = FL_PROJECTILE;
 159
 160         CSQCProjectile(gren, TRUE, PROJECTILE_SHAMBLER_LIGHTNING, TRUE);
 161 }
 162
 163 float shambler_attack(float attack_type)
 164 {
 165         switch(attack_type)
 166         {
 167                 case MONSTER_ATTACK_MELEE:
 168                 {
 169                         shambler_swing();
 170                         return TRUE;
 171                 }
 172                 case MONSTER_ATTACK_RANGED:
 173                 {
 174                         if(time >= self.shambler_lastattack) // shambler doesn't attack much
 175                         if(random() <= 0.5 && vlen(self.enemy.origin - self.origin) <= 500)
 176                         {
 177                                 self.frame = shambler_anim_smash;
 178                                 defer(0.7, shambler_smash);
 179                                 self.attack_finished_single = time + 1.1;
 180                                 self.shambler_lastattack = time + 3;
 181                                 return TRUE;
 182                         }
 183                         else if(random() <= 0.1) // small chance, don't want this spammed
 184                         {
 185                                 self.frame = shambler_anim_magic;
 186                                 self.attack_finished_single = time + 1.1;
 187                                 self.shambler_lastattack = time + 3;
 188                                 defer(0.6, shambler_lightning);
 189                                 return TRUE;
 190                         }
 191
 192                         return FALSE;
 193                 }
 194         }
 195
 196         return FALSE;
 197 }
 198
 199 void spawnfunc_monster_shambler()
 200 {
 201         self.classname = "monster_shambler";
 202
 203         self.monster_spawnfunc = spawnfunc_monster_shambler;
 204
 205         if(Monster_CheckAppearFlags(self))
 206                 return;
 207
 208         if not(monster_initialize(MON_SHAMBLER, FALSE)) { remove(self); return; }
 209 }
 210
 211 float m_shambler(float req)
 212 {
 213         switch(req)
 214         {
 215                 case MR_THINK:
 216                 {
 217                         monster_move(MON_CVAR(shambler, speed_run), MON_CVAR(shambler, speed_walk), MON_CVAR(shambler, speed_stop), shambler_anim_run, shambler_anim_walk, shambler_anim_stand);
 218                         return TRUE;
 219                 }
 220                 case MR_DEATH:
 221                 {
 222                         self.frame = shambler_anim_death;
 223                         return TRUE;
 224                 }
 225                 case MR_SETUP:
 226                 {
 227                         if not(self.health) self.health = MON_CVAR(shambler, health);
 228                         if not(self.attack_range) self.attack_range = 150;
 229
 230                         self.monster_loot = spawnfunc_item_health_mega;
 231                         self.monster_attackfunc = shambler_attack;
 232                         self.frame = shambler_anim_stand;
 233                         self.weapon = WEP_NEX;
 234
 235                         return TRUE;
 236                 }
 237                 case MR_PRECACHE:
 238                 {
 239                         precache_model ("models/monsters/shambler.mdl");
 240                         return TRUE;
 241                 }
 242                 case MR_CONFIG:
 243                 {
 244                         MON_CONFIG_SETTINGS(SHAMBLER_SETTINGS(shambler))
 245                         return TRUE;
 246                 }
 247         }
 248
 249         return TRUE;
 250 }
 251
 252 #endif // SVQC
 253 #ifdef CSQC
 254 float m_shambler(float req)
 255 {
 256         switch(req)
 257         {
 258                 case MR_PRECACHE:
 259                 {
 260                         precache_model ("models/monsters/shambler.mdl");
 261                         return TRUE;
 262                 }
 263         }
 264
 265         return TRUE;
 266 }
 267
 268 #endif // CSQC
 269 #endif // REGISTER_MONSTER