qcsrc/common/monsters/monster/wyvern.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ WYVERN,
   4 /* function   */ m_wyvern,
   5 /* mins,maxs  */ '-20 -20 -58', '20 20 20',
   6 /* model      */ "wizard.mdl",
   7 /* netname    */ "wyvern",
   8 /* fullname   */ _("Wyvern")
   9 );
  10
  11 #else
  12 #ifdef SVQC
  13 float autocvar_g_monster_wyvern;
  14 float autocvar_g_monster_wyvern_health;
  15 float autocvar_g_monster_wyvern_speed_walk;
  16 float autocvar_g_monster_wyvern_speed_run;
  17 float autocvar_g_monster_wyvern_fireball_damage;
  18 float autocvar_g_monster_wyvern_fireball_force;
  19 float autocvar_g_monster_wyvern_fireball_radius;
  20 float autocvar_g_monster_wyvern_fireball_edgedamage;
  21 float autocvar_g_monster_wyvern_fireball_damagetime;
  22 float autocvar_g_monster_wyvern_fireball_speed;
  23
  24 const float wyvern_anim_hover   = 0;
  25 const float wyvern_anim_fly     = 1;
  26 const float wyvern_anim_magic   = 2;
  27 const float wyvern_anim_pain    = 3;
  28 const float wyvern_anim_death   = 4;
  29
  30 void wyvern_fireball_explode()
  31 {
  32         entity e;
  33         if(self)
  34         {
  35                 pointparticles(particleeffectnum("fireball_explode"), self.origin, '0 0 0', 1);
  36
  37                 RadiusDamage(self, self.realowner, autocvar_g_monster_wyvern_fireball_damage, autocvar_g_monster_wyvern_fireball_edgedamage, autocvar_g_monster_wyvern_fireball_force, world, autocvar_g_monster_wyvern_fireball_radius, self.projectiledeathtype, world);
  38
  39                 for(e = world; (e = findfloat(e, takedamage, DAMAGE_AIM)); ) if(vlen(e.origin - self.origin) <= autocvar_g_monster_wyvern_fireball_radius)
  40                         Fire_AddDamage(e, self, 5 * monster_skill, autocvar_g_monster_wyvern_fireball_damagetime, self.projectiledeathtype);
  41
  42                 remove(self);
  43         }
  44 }
  45
  46 void wyvern_fireball_touch()
  47 {
  48         PROJECTILE_TOUCH;
  49
  50         wyvern_fireball_explode();
  51 }
  52
  53 void wyvern_fireball()
  54 {
  55         entity missile = spawn();
  56         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
  57
  58         monster_makevectors(self.enemy);
  59
  60         missile.owner = missile.realowner = self;
  61         missile.solid = SOLID_TRIGGER;
  62         missile.movetype = MOVETYPE_FLYMISSILE;
  63         missile.projectiledeathtype = DEATH_MONSTER_WYVERN;
  64         setsize(missile, '-6 -6 -6', '6 6 6');
  65         setorigin(missile, self.origin + self.view_ofs + v_forward * 14);
  66         missile.flags = FL_PROJECTILE;
  67         missile.velocity = dir * autocvar_g_monster_wyvern_fireball_speed;
  68         missile.avelocity = '300 300 300';
  69         missile.nextthink = time + 5;
  70         missile.think = wyvern_fireball_explode;
  71         missile.enemy = self.enemy;
  72         missile.touch = wyvern_fireball_touch;
  73         CSQCProjectile(missile, TRUE, PROJECTILE_FIREMINE, TRUE);
  74 }
  75
  76 float wyvern_attack(float attack_type)
  77 {
  78         switch(attack_type)
  79         {
  80                 case MONSTER_ATTACK_MELEE:
  81                 case MONSTER_ATTACK_RANGED:
  82                 {
  83                         self.attack_finished_single = time + 1.2;
  84
  85                         wyvern_fireball();
  86
  87                         return TRUE;
  88                 }
  89         }
  90
  91         return FALSE;
  92 }
  93
  94 void spawnfunc_monster_wyvern()
  95 {
  96         if not(autocvar_g_monster_wyvern) { remove(self); return; }
  97
  98         self.classname = "monster_wyvern";
  99
 100         self.monster_spawnfunc = spawnfunc_monster_wyvern;
 101
 102         if(Monster_CheckAppearFlags(self))
 103                 return;
 104
 105         if not(monster_initialize(MON_WYVERN, TRUE, MONSTER_TYPE_FLY | MONSTER_SIZE_BROKEN)) { remove(self); return; }
 106 }
 107
 108 // compatibility with old spawns
 109 void spawnfunc_monster_wizard() { spawnfunc_monster_wyvern(); }
 110
 111 float m_wyvern(float req)
 112 {
 113         switch(req)
 114         {
 115                 case MR_THINK:
 116                 {
 117                         monster_move(autocvar_g_monster_wyvern_speed_run, autocvar_g_monster_wyvern_speed_walk, 300, wyvern_anim_fly, wyvern_anim_hover, wyvern_anim_hover);
 118                         return TRUE;
 119                 }
 120                 case MR_DEATH:
 121                 {
 122                         monsters_setframe(wyvern_anim_death);
 123                         self.velocity_x = -200 + 400 * random();
 124                         self.velocity_y = -200 + 400 * random();
 125                         self.velocity_z = 100 + 100 * random();
 126                         return TRUE;
 127                 }
 128                 case MR_SETUP:
 129                 {
 130                         if not(self.health) self.health = autocvar_g_monster_wyvern_health;
 131
 132                         self.monster_attackfunc = wyvern_attack;
 133                         monsters_setframe(wyvern_anim_hover);
 134
 135                         return TRUE;
 136                 }
 137                 case MR_INIT:
 138                 {
 139                         // nothing
 140                         return TRUE;
 141                 }
 142         }
 143
 144         return TRUE;
 145 }
 146
 147 #endif // SVQC
 148 #ifdef CSQC
 149 float m_wyvern(float req)
 150 {
 151         switch(req)
 152         {
 153                 case MR_DEATH:
 154                 {
 155                         // nothing
 156                         return TRUE;
 157                 }
 158                 case MR_INIT:
 159                 {
 160                         precache_model ("models/monsters/wizard.mdl");
 161                         return TRUE;
 162                 }
 163         }
 164
 165         return TRUE;
 166 }
 167
 168 #endif // CSQC
 169 #endif // REGISTER_MONSTER