qcsrc/common/mutators/mutator/damagetext.qc

   1 REGISTER_MUTATOR(damagetext, true);
   2
   3 #ifdef CSQC
   4 string autocvar_cl_damagetext_format = "-%3$d";
   5 vector autocvar_cl_damagetext_color = '1 1 0';
   6 float autocvar_cl_damagetext_size = 8;
   7 float autocvar_cl_damagetext_alpha_start = 1;
   8 float autocvar_cl_damagetext_alpha_lifetime = 3;
   9 vector autocvar_cl_damagetext_velocity = '0 0 20';
  10 vector autocvar_cl_damagetext_offset = '0 -40 0';
  11 float autocvar_cl_damagetext_accumulate_range = 30;
  12
  13 CLASS(DamageText, Object)
  14     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  15     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  16     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  17     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  18     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  19     ATTRIB(DamageText, m_group, int, 0)
  20     ATTRIB(DamageText, m_damage, int, 0)
  21     ATTRIB(DamageText, m_armordamage, int, 0)
  22     ATTRIB(DamageText, time_prev, float, time)
  23
  24     void DamageText_draw() {
  25         entity this = self;
  26         float dt = time - this.time_prev;
  27         this.time_prev = time;
  28         setorigin(this, this.origin + dt * this.velocity);
  29         this.alpha -= dt * this.fade_rate;
  30         if (this.alpha < 0) remove(this);
  31         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  32         if (pos.z >= 0 && this.m_size > 0) {
  33             pos.z = 0;
  34             string s = sprintf(autocvar_cl_damagetext_format, this.m_damage, this.m_armordamage, this.m_damage + this.m_armordamage);
  35             drawcolorcodedstring2(pos, s, this.m_size * '1 1 0', this.m_color, this.alpha, DRAWFLAG_NORMAL);
  36         }
  37     }
  38     ATTRIB(DamageText, draw2d, void(), DamageText_draw)
  39
  40     void DamageText_update(DamageText this, vector _origin, int _health, int _armor) {
  41         this.m_damage = _health;
  42         this.m_armordamage = _armor;
  43         setorigin(this, _origin);
  44         this.alpha = 1;
  45     }
  46
  47     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor) {
  48         CONSTRUCT(DamageText);
  49         this.m_group = _group;
  50         DamageText_update(this, _origin, _health, _armor);
  51         return this;
  52     }
  53 ENDCLASS(DamageText)
  54 #endif
  55
  56 #ifdef SVQC
  57 int autocvar_sv_damagetext = 2;
  58 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  59 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  60 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  61 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  62 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  63     if (SV_DAMAGETEXT_DISABLED()) return;
  64     const entity attacker = mutator_argv_entity_0;
  65     const entity hit = mutator_argv_entity_1; if (hit == attacker) return;
  66     const int health = mutator_argv_int_0;
  67     const int armor = mutator_argv_int_1;
  68     const vector location = hit.origin;
  69     entity e;
  70     FOR_EACH_REALCLIENT(e) if (
  71         (SV_DAMAGETEXT_ALL()) ||
  72         (SV_DAMAGETEXT_PLAYERS() && e == attacker) ||
  73         (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(e) && e.enemy == attacker) ||
  74         (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(e))
  75     ) {
  76         msg_entity = e;
  77         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  78         WriteMutator(MSG_ONE, damagetext);
  79         WriteShort(MSG_ONE, health);
  80         WriteShort(MSG_ONE, armor);
  81         WriteEntity(MSG_ONE, hit);
  82         WriteCoord(MSG_ONE, location.x);
  83         WriteCoord(MSG_ONE, location.y);
  84         WriteCoord(MSG_ONE, location.z);
  85     }
  86 }
  87 #endif
  88
  89 #ifdef CSQC
  90 bool autocvar_cl_damagetext = false;
  91 MUTATOR_HOOKFUNCTION(damagetext, CSQC_Parse_TempEntity) {
  92     if (MUTATOR_RETURNVALUE) return false;
  93     if (!ReadMutatorEquals(mutator_argv_int_0, damagetext)) return false;
  94     int health = ReadShort();
  95     int armor = ReadShort();
  96     int group = ReadShort();
  97     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
  98     if (autocvar_cl_damagetext) {
  99         if (autocvar_cl_damagetext_accumulate_range) {
 100             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 101                 if (e.instanceOfDamageText && e.m_group == group) {
 102                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor);
 103                     return true;
 104                 }
 105             }
 106         }
 107         NEW(DamageText, group, location, health, armor);
 108     }
 109     return true;
 110 }
 111 #endif