qcsrc/common/mutators/mutator/dodging/sv_dodging.qc

   1 #include "sv_dodging.qh"
   2
   3 #define PHYS_DODGING                                            g_dodging
   4 #define PHYS_DODGING_DELAY                                      autocvar_sv_dodging_delay
   5 #define PHYS_DODGING_DISTANCE_THRESHOLD         autocvar_sv_dodging_wall_distance_threshold
   6 #define PHYS_DODGING_FROZEN_DOUBLETAP           autocvar_sv_dodging_frozen_doubletap
   7 #define PHYS_DODGING_HEIGHT_THRESHOLD           autocvar_sv_dodging_height_threshold
   8 #define PHYS_DODGING_HORIZ_SPEED                        autocvar_sv_dodging_horiz_speed
   9 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         autocvar_sv_dodging_horiz_speed_frozen
  10 #define PHYS_DODGING_RAMP_TIME                          autocvar_sv_dodging_ramp_time
  11 #define PHYS_DODGING_UP_SPEED                           autocvar_sv_dodging_up_speed
  12 #define PHYS_DODGING_WALL                                       autocvar_sv_dodging_wall_dodging
  13 #define PHYS_DODGING_AIR                                        autocvar_sv_dodging_air_dodging
  14 #define PHYS_DODGING_MAXSPEED                           autocvar_sv_dodging_maxspeed // TODO separate max air speed, fix frozen dodging
  15
  16 // we ran out of stats slots! TODO: re-enable this when prediction is available for dodging
  17 #if 0
  18 #define PHYS_DODGING                                            STAT(DODGING, this)
  19 #define PHYS_DODGING_DELAY                                      STAT(DODGING_DELAY, this)
  20 #define PHYS_DODGING_DISTANCE_THRESHOLD         STAT(DODGING_DISTANCE_THRESHOLD, this)
  21 #define PHYS_DODGING_FROZEN_DOUBLETAP           STAT(DODGING_FROZEN_DOUBLETAP, this)
  22 #define PHYS_DODGING_HEIGHT_THRESHOLD           STAT(DODGING_HEIGHT_THRESHOLD, this)
  23 #define PHYS_DODGING_HORIZ_SPEED                        STAT(DODGING_HORIZ_SPEED, this)
  24 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         STAT(DODGING_HORIZ_SPEED_FROZEN, this)
  25 #define PHYS_DODGING_RAMP_TIME                          STAT(DODGING_RAMP_TIME, this)
  26 #define PHYS_DODGING_UP_SPEED                           STAT(DODGING_UP_SPEED, this)
  27 #define PHYS_DODGING_WALL                                       STAT(DODGING_WALL, this)
  28 #define PHYS_DODGING_AIR                                        STAT(DODGING_AIR, this)
  29 #define PHYS_DODGING_MAXSPEED                           STAT(DODGING_MAXSPEED, this)
  30 #endif
  31
  32 #ifdef CSQC // FIXME this is an sv_ file, none of this will even be compiled
  33         #define PHYS_DODGING_FRAMETIME                          (1 / (frametime <= 0 ? 60 : frametime))
  34         #define PHYS_DODGING_TIMEOUT(s)                         STAT(DODGING_TIMEOUT)
  35         #define PHYS_DODGING_PRESSED_KEYS(s)            (s).pressedkeys
  36 #elif defined(SVQC)
  37         #define PHYS_DODGING_FRAMETIME                          sys_frametime
  38         #define PHYS_DODGING_TIMEOUT(s)                         CS(s).cvar_cl_dodging_timeout
  39         #define PHYS_DODGING_PRESSED_KEYS(s)            CS(s).pressedkeys
  40 #endif
  41
  42 #ifdef SVQC
  43
  44 bool autocvar_sv_dodging_sound;
  45
  46 #include <common/animdecide.qh>
  47 #include <common/physics/player.qh>
  48
  49 .float cvar_cl_dodging_timeout;
  50
  51 REGISTER_MUTATOR(dodging, cvar("g_dodging"))
  52 {
  53         // this just turns on the cvar.
  54         MUTATOR_ONADD
  55         {
  56                 g_dodging = cvar("g_dodging");
  57         }
  58
  59         // this just turns off the cvar.
  60         MUTATOR_ONROLLBACK_OR_REMOVE
  61         {
  62                 g_dodging = 0;
  63         }
  64
  65         return false;
  66 }
  67
  68 #elif defined(CSQC)
  69 REGISTER_MUTATOR(dodging, true);
  70 #endif
  71
  72 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  73 .float dodging_action;
  74
  75 // the jump part of the dodge cannot be ramped
  76 .float dodging_single_action;
  77
  78 // these are used to store the last key press time for each of the keys..
  79 .float last_FORWARD_KEY_time;
  80 .float last_BACKWARD_KEY_time;
  81 .float last_LEFT_KEY_time;
  82 .float last_RIGHT_KEY_time;
  83
  84 // these store the movement direction at the time of the dodge action happening.
  85 .vector dodging_direction;
  86
  87 // this indicates the last time a dodge was executed. used to check if another one is allowed
  88 // and to ramp up the dodge acceleration in the physics hook.
  89 .float last_dodging_time;
  90
  91 // This is the velocity gain to be added over the ramp time.
  92 // It will decrease from frame to frame during dodging_action = 1
  93 // until it's 0.
  94 //.float dodging_velocity_gain;
  95
  96 .float dodging_force_total;
  97 .float dodging_force_remaining;
  98
  99 #ifdef CSQC // TODO what is this? 1) CSQC in sv_ file never even gets compiled 2) pressedkeys is only defined on server so this would be always 0
 100 .int pressedkeys;
 101 #endif
 102
 103 #define X(dir) \
 104         tracebox(this.origin, this.mins, this.maxs, this.origin + threshold * dir, true, this); \
 105         if (trace_fraction < 1 && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)) \
 106                 return true;
 107
 108 // returns true if the player is close to a wall
 109 bool is_close_to_wall(entity this, float threshold)
 110 {
 111         X(v_right);
 112         X(-v_right);
 113         X(v_forward);
 114         X(-v_forward);
 115
 116         return false;
 117 }
 118
 119 bool is_close_to_ground(entity this, float threshold)
 120 {
 121         if (IS_ONGROUND(this)) return true;
 122         X(-v_up); // necessary for dodging down a slope using doubletap (using `+dodge` works anyway)
 123
 124         return false;
 125 }
 126
 127 #undef X
 128
 129 // TODO use real cvars
 130 /*float autocvar_velocity_min = 200;
 131 float autocvar_velocity_max = 700;
 132 float autocvar_force_min = 50;
 133 float autocvar_force_max = 350;*/
 134 float determine_speed(entity player) {
 135         float x = PHYS_FROZEN(player) ? PHYS_DODGING_HORIZ_SPEED_FROZEN : PHYS_DODGING_HORIZ_SPEED;
 136         x = x; // unused
 137         return x;
 138
 139         /*float horiz_vel = vlen(vec2(player.velocity));
 140         // force min and max are inverted - the faster you are the wekaer dodging becomes
 141         // TODO document cvars in cfg
 142         return map_bound_ranges(horiz_vel, autocvar_velocity_min, autocvar_velocity_max, autocvar_force_max, autocvar_force_min);*/
 143 }
 144
 145 bool PM_dodging_checkpressedkeys(entity this)
 146 {
 147         // first check if the last dodge is far enough back in time so we can dodge again
 148         if ((time - this.last_dodging_time) < PHYS_DODGING_DELAY)
 149                 return false;
 150
 151         bool frozen_dodging = (PHYS_FROZEN(this) && PHYS_DODGING_FROZEN(this));
 152         bool frozen_no_doubletap = (frozen_dodging && !PHYS_DODGING_FROZEN_DOUBLETAP);
 153
 154         float tap_direction_x = 0;
 155         float tap_direction_y = 0;
 156         bool dodge_detected = false;
 157         vector mymovement = PHYS_CS(this).movement;
 158
 159         #define X(COND,BTN,RESULT)                                                                                                                      \
 160         if (mymovement_##COND)                                                                                          \
 161                 /* is this a state change? */                                                                                                   \
 162                 if(!(PHYS_DODGING_PRESSED_KEYS(this) & KEY_##BTN) || frozen_no_doubletap) {             \
 163                         tap_direction_##RESULT;                                                                                                 \
 164                         if ((time - this.last_##BTN##_KEY_time) < PHYS_DODGING_TIMEOUT(this) || frozen_no_doubletap)    \
 165                                 dodge_detected = true;                                                                                          \
 166                         if(PHYS_INPUT_BUTTON_DODGE(this))                                                                               \
 167                                 dodge_detected = true;                                                                                          \
 168                         this.last_##BTN##_KEY_time = time;                                                                              \
 169                 }
 170         X(x < 0, BACKWARD,      x--);
 171         X(x > 0, FORWARD,       x++);
 172         X(y < 0, LEFT,          y--);
 173         X(y > 0, RIGHT,         y++);
 174         #undef X
 175
 176         if (!dodge_detected) return false;
 177
 178         makevectors(this.angles);
 179
 180         bool wall_dodge = false;
 181
 182         if(!PHYS_DODGING_AIR)
 183         if(!is_close_to_ground(this, PHYS_DODGING_HEIGHT_THRESHOLD))
 184         {
 185                 wall_dodge = (PHYS_DODGING_WALL && is_close_to_wall(this, PHYS_DODGING_DISTANCE_THRESHOLD));
 186                 if(!wall_dodge) // we're not on the ground, and wall dodging isn't allowed, end it!
 187                         return false;
 188         }
 189
 190         if(!wall_dodge && PHYS_DODGING_MAXSPEED && vdist(this.velocity, >, PHYS_DODGING_MAXSPEED))
 191                 return false;
 192
 193         this.last_dodging_time = time;
 194
 195         this.dodging_action = 1;
 196         this.dodging_single_action = 1;
 197
 198         //this.dodging_velocity_gain = PHYS_DODGING_HORIZ_SPEED;
 199         this.dodging_force_total = determine_speed(this);
 200         this.dodging_force_remaining = this.dodging_force_total;
 201
 202         this.dodging_direction.x = tap_direction_x;
 203         this.dodging_direction.y = tap_direction_y;
 204
 205         // normalize the dodging_direction vector.. (unlike UT99) XD
 206         float length = sqrt(this.dodging_direction.x ** 2 + this.dodging_direction.y ** 2);
 207
 208         this.dodging_direction_x = this.dodging_direction_x / length;
 209         this.dodging_direction_y = this.dodging_direction_y / length;
 210
 211         return true;
 212 }
 213
 214 void PM_dodging(entity this)
 215 {
 216         // can't use return value from PM_dodging_checkpressedkeys because they're called from different hooks
 217         if (!this.dodging_action) return;
 218
 219         // when swimming or dead, no dodging allowed..
 220         if (this.waterlevel >= WATERLEVEL_SWIMMING || IS_DEAD(this))
 221         {
 222                 this.dodging_action = 0;
 223                 this.dodging_direction_x = 0;
 224                 this.dodging_direction_y = 0;
 225                 return;
 226         }
 227
 228         // make sure v_up, v_right and v_forward are sane
 229         if(PHYS_DODGING_AIR)
 230                 makevectors(this.v_angle);
 231         else
 232                 makevectors(this.angles);
 233
 234         // fraction of the force to apply each frame
 235         // if we have e.g. 0.5 sec ramptime and a frametime of 0.25, then the ramp code
 236         // will be called ramp_time/frametime times = 2 times. so, we need to
 237         // add 0.5 * the total speed each frame until the dodge action is done..
 238         float common_factor = PHYS_DODGING_FRAMETIME / PHYS_DODGING_RAMP_TIME;
 239         common_factor /= 2; // FIXME this is WRONG but this function is called twice per frame!!!
 240
 241         // if ramp time is smaller than frametime we get problems ;D
 242         common_factor = min(common_factor, 1);
 243
 244         /*float horiz_speed = determine_speed(this); // TODO kill this
 245         //LOG_INFOF("velocity %f -> force %f\n", vlen(vec2(this.velocity)), horiz_speed);
 246         float new_velocity_gain = this.dodging_velocity_gain - (common_factor * horiz_speed);
 247         new_velocity_gain = max(0, new_velocity_gain);
 248
 249         float velocity_difference = this.dodging_velocity_gain - new_velocity_gain;*/
 250
 251         /*float velocity_increase = min(common_factor * this.dodging_force_total, this.dodging_force_remaining;
 252         this.dodging_force_remaining -= velocity_increase;*/
 253
 254         /*this.velocity += ((this.dodging_direction_y * velocity_difference) * v_right)
 255                                 + ((this.dodging_direction_x * velocity_difference) * v_forward);
 256
 257         this.dodging_velocity_gain = this.dodging_velocity_gain - velocity_difference;*/
 258
 259         float velocity_increase = common_factor * this.dodging_force_total;
 260         LOG_INFOF("time %f velocity_increase: %f\n", time, velocity_increase);
 261         this.velocity += this.dodging_direction_x * velocity_increase * v_forward
 262                        + this.dodging_direction_y * velocity_increase * v_right;
 263
 264         // the up part of the dodge is a single shot action
 265         if (this.dodging_single_action == 1)
 266         {
 267                 UNSET_ONGROUND(this);
 268
 269                 this.velocity += PHYS_DODGING_UP_SPEED * v_up;
 270
 271 #ifdef SVQC
 272                 if (autocvar_sv_dodging_sound)
 273                         PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 274
 275                 animdecide_setaction(this, ANIMACTION_JUMP, true);
 276 #endif
 277
 278                 this.dodging_single_action = 0;
 279         }
 280
 281         // are we done with the dodging ramp yet?
 282         if((time - this.last_dodging_time) > PHYS_DODGING_RAMP_TIME)
 283         {
 284                 // reset state so next dodge can be done correctly
 285                 this.dodging_action = 0;
 286                 this.dodging_direction.x = 0;
 287                 this.dodging_direction.y = 0;
 288         }
 289 }
 290
 291 #ifdef CSQC
 292 void PM_dodging_GetPressedKeys(entity this)
 293 {
 294         PM_dodging_checkpressedkeys(this);
 295
 296         int keys = this.pressedkeys;
 297         keys = BITSET(keys, KEY_FORWARD,        PHYS_CS(this).movement.x > 0);
 298         keys = BITSET(keys, KEY_BACKWARD,       PHYS_CS(this).movement.x < 0);
 299         keys = BITSET(keys, KEY_RIGHT,          PHYS_CS(this).movement.y > 0);
 300         keys = BITSET(keys, KEY_LEFT,           PHYS_CS(this).movement.y < 0);
 301
 302         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
 303         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
 304         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
 305         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
 306         this.pressedkeys = keys;
 307 }
 308 #endif
 309
 310 MUTATOR_HOOKFUNCTION(dodging, PlayerPhysics)
 311 {
 312         entity player = M_ARGV(0, entity);
 313         //LOG_INFOF("player %s, physics %f\n", player.netname, time);
 314
 315 #ifdef CSQC
 316         PM_dodging_GetPressedKeys(player);
 317 #endif
 318         PM_dodging(player);
 319 }
 320
 321 #ifdef SVQC
 322
 323 REPLICATE(cvar_cl_dodging_timeout, float, "cl_dodging_timeout");
 324
 325 MUTATOR_HOOKFUNCTION(dodging, GetPressedKeys)
 326 {
 327         entity player = M_ARGV(0, entity);
 328         //LOG_INFOF("player %s, keys %f\n", player.netname, time);
 329
 330         PM_dodging_checkpressedkeys(player);
 331 }
 332
 333 #endif