qcsrc/common/mutators/mutator/dodging/sv_dodging.qc

   1 #include "sv_dodging.qh"
   2
   3 #define PHYS_DODGING                                            g_dodging
   4 #define PHYS_DODGING_DELAY                                      autocvar_sv_dodging_delay
   5 #define PHYS_DODGING_DISTANCE_THRESHOLD         autocvar_sv_dodging_wall_distance_threshold
   6 #define PHYS_DODGING_FROZEN_NODOUBLETAP         autocvar_sv_dodging_frozen_doubletap
   7 #define PHYS_DODGING_HEIGHT_THRESHOLD           autocvar_sv_dodging_height_threshold
   8 #define PHYS_DODGING_HORIZ_SPEED                        autocvar_sv_dodging_horiz_speed
   9 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         autocvar_sv_dodging_horiz_speed_frozen
  10 #define PHYS_DODGING_RAMP_TIME                          autocvar_sv_dodging_ramp_time
  11 #define PHYS_DODGING_UP_SPEED                           autocvar_sv_dodging_up_speed
  12 #define PHYS_DODGING_WALL                                       autocvar_sv_dodging_wall_dodging
  13 #define PHYS_DODGING_AIR                                        autocvar_sv_dodging_air_dodging
  14 #define PHYS_DODGING_MAXSPEED                           autocvar_sv_dodging_maxspeed
  15
  16 // we ran out of stats slots! TODO: re-enable this when prediction is available for dodging
  17 #if 0
  18 #define PHYS_DODGING                                            STAT(DODGING, this)
  19 #define PHYS_DODGING_DELAY                                      STAT(DODGING_DELAY, this)
  20 #define PHYS_DODGING_DISTANCE_THRESHOLD         STAT(DODGING_DISTANCE_THRESHOLD, this)
  21 #define PHYS_DODGING_FROZEN_NODOUBLETAP         STAT(DODGING_FROZEN_NO_DOUBLETAP, this)
  22 #define PHYS_DODGING_HEIGHT_THRESHOLD           STAT(DODGING_HEIGHT_THRESHOLD, this)
  23 #define PHYS_DODGING_HORIZ_SPEED                        STAT(DODGING_HORIZ_SPEED, this)
  24 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         STAT(DODGING_HORIZ_SPEED_FROZEN, this)
  25 #define PHYS_DODGING_RAMP_TIME                          STAT(DODGING_RAMP_TIME, this)
  26 #define PHYS_DODGING_UP_SPEED                           STAT(DODGING_UP_SPEED, this)
  27 #define PHYS_DODGING_WALL                                       STAT(DODGING_WALL, this)
  28 #define PHYS_DODGING_AIR                                        STAT(DODGING_AIR, this)
  29 #define PHYS_DODGING_MAXSPEED                           STAT(DODGING_MAXSPEED, this)
  30 #endif
  31
  32 #ifdef CSQC
  33         #define PHYS_DODGING_FRAMETIME                          (1 / (frametime <= 0 ? 60 : frametime))
  34         #define PHYS_DODGING_TIMEOUT(s)                         STAT(DODGING_TIMEOUT)
  35         #define PHYS_DODGING_PRESSED_KEYS(s)            (s).pressedkeys
  36 #elif defined(SVQC)
  37         #define PHYS_DODGING_FRAMETIME                          sys_frametime
  38         #define PHYS_DODGING_TIMEOUT(s)                         s.cvar_cl_dodging_timeout
  39         #define PHYS_DODGING_PRESSED_KEYS(s)            CS(s).pressedkeys
  40 #endif
  41
  42 #ifdef SVQC
  43
  44 bool autocvar_sv_dodging_sound;
  45
  46 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  47 .float dodging_action;
  48
  49 // the jump part of the dodge cannot be ramped
  50 .float dodging_single_action;
  51
  52 #include <common/animdecide.qh>
  53 #include <common/physics/player.qh>
  54
  55 .float cvar_cl_dodging_timeout = _STAT(DODGING_TIMEOUT);
  56
  57 REGISTER_MUTATOR(dodging, cvar("g_dodging"))
  58 {
  59         // this just turns on the cvar.
  60         MUTATOR_ONADD
  61         {
  62                 g_dodging = cvar("g_dodging");
  63         }
  64
  65         // this just turns off the cvar.
  66         MUTATOR_ONROLLBACK_OR_REMOVE
  67         {
  68                 g_dodging = 0;
  69         }
  70
  71         return false;
  72 }
  73
  74 #elif defined(CSQC)
  75 REGISTER_MUTATOR(dodging, true);
  76 #endif
  77
  78 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  79 .float dodging_action;
  80
  81 // the jump part of the dodge cannot be ramped
  82 .float dodging_single_action;
  83
  84
  85 // these are used to store the last key press time for each of the keys..
  86 .float last_FORWARD_KEY_time;
  87 .float last_BACKWARD_KEY_time;
  88 .float last_LEFT_KEY_time;
  89 .float last_RIGHT_KEY_time;
  90
  91 // these store the movement direction at the time of the dodge action happening.
  92 .vector dodging_direction;
  93
  94 // this indicates the last time a dodge was executed. used to check if another one is allowed
  95 // and to ramp up the dodge acceleration in the physics hook.
  96 .float last_dodging_time;
  97
  98 // This is the velocity gain to be added over the ramp time.
  99 // It will decrease from frame to frame during dodging_action = 1
 100 // until it's 0.
 101 .float dodging_velocity_gain;
 102
 103 #ifdef CSQC
 104 .int pressedkeys;
 105 #endif
 106
 107 // returns 1 if the player is close to a wall
 108 bool check_close_to_wall(entity this, float threshold)
 109 {
 110         if (PHYS_DODGING_WALL == 0) { return false; }
 111
 112 #define X(OFFSET) \
 113         tracebox(this.origin, this.mins, this.maxs, this.origin + OFFSET, true, this); \
 114         if(trace_fraction < 1 && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY) && vdist(this.origin - trace_endpos, <, threshold)) \
 115                 return true;
 116         X(1000*v_right);
 117         X(-1000*v_right);
 118         X(1000*v_forward);
 119         X(-1000*v_forward);
 120 #undef X
 121
 122         return false;
 123 }
 124
 125 bool check_close_to_ground(entity this, float threshold)
 126 {
 127         return IS_ONGROUND(this) ? true : false;
 128 }
 129
 130 bool PM_dodging_checkpressedkeys(entity this)
 131 {
 132         if(!PHYS_DODGING)
 133                 return false;
 134
 135         bool frozen_dodging = (PHYS_FROZEN(this) && PHYS_DODGING_FROZEN(this));
 136         bool frozen_no_doubletap = (frozen_dodging && !PHYS_DODGING_FROZEN_NODOUBLETAP);
 137
 138         // first check if the last dodge is far enough back in time so we can dodge again
 139         if ((time - this.last_dodging_time) < PHYS_DODGING_DELAY)
 140                 return false;
 141
 142         makevectors(this.angles);
 143
 144         bool wall_dodge = false;
 145
 146         if(!PHYS_DODGING_AIR)
 147         if(!check_close_to_ground(this, PHYS_DODGING_HEIGHT_THRESHOLD))
 148         {
 149                 wall_dodge = check_close_to_wall(this, PHYS_DODGING_DISTANCE_THRESHOLD);
 150                 if(!wall_dodge) // we're not on the ground, and wall dodging isn't allowed, end it!
 151                         return true;
 152         }
 153
 154         if(!wall_dodge && PHYS_DODGING_MAXSPEED && vdist(this.velocity, >, PHYS_DODGING_MAXSPEED))
 155                 return false;
 156
 157         float tap_direction_x = 0;
 158         float tap_direction_y = 0;
 159         bool dodge_detected = false;
 160
 161         #define X(COND,BTN,RESULT)                                                                                                                      \
 162         if (this.movement_##COND)                                                                                               \
 163                 /* is this a state change? */                                                                                                   \
 164                 if(!(PHYS_DODGING_PRESSED_KEYS(this) & KEY_##BTN) || frozen_no_doubletap) {             \
 165                                 tap_direction_##RESULT;                                                                                                 \
 166                                 if ((time - this.last_##BTN##_KEY_time) < PHYS_DODGING_TIMEOUT(this) || frozen_no_doubletap)    \
 167                                         dodge_detected = true;                                                                                          \
 168                                 if(PHYS_INPUT_BUTTON_DODGE(this))                                                                               \
 169                                         dodge_detected = true;                                                                                          \
 170                                 this.last_##BTN##_KEY_time = time;                                                                              \
 171                 }
 172         X(x < 0, BACKWARD,      x--);
 173         X(x > 0, FORWARD,       x++);
 174         X(y < 0, LEFT,          y--);
 175         X(y > 0, RIGHT,         y++);
 176         #undef X
 177
 178         if (dodge_detected)
 179         {
 180                 this.last_dodging_time = time;
 181
 182                 this.dodging_action = 1;
 183                 this.dodging_single_action = 1;
 184
 185                 this.dodging_velocity_gain = PHYS_DODGING_HORIZ_SPEED;
 186
 187                 this.dodging_direction_x = tap_direction_x;
 188                 this.dodging_direction_y = tap_direction_y;
 189
 190                 // normalize the dodging_direction vector.. (unlike UT99) XD
 191                 float length = this.dodging_direction_x * this.dodging_direction_x
 192                                         + this.dodging_direction_y * this.dodging_direction_y;
 193                 length = sqrt(length);
 194
 195                 this.dodging_direction_x = this.dodging_direction_x * 1.0 / length;
 196                 this.dodging_direction_y = this.dodging_direction_y * 1.0 / length;
 197                 return true;
 198         }
 199         return false;
 200 }
 201
 202 void PM_dodging(entity this)
 203 {
 204         if (!PHYS_DODGING)
 205                 return;
 206
 207         // when swimming or dead, no dodging allowed..
 208         if (this.waterlevel >= WATERLEVEL_SWIMMING || IS_DEAD(this))
 209         {
 210                 this.dodging_action = 0;
 211                 this.dodging_direction_x = 0;
 212                 this.dodging_direction_y = 0;
 213                 return;
 214         }
 215
 216         // make sure v_up, v_right and v_forward are sane
 217         if(PHYS_DODGING_AIR)
 218                 makevectors(this.v_angle);
 219         else
 220                 makevectors(this.angles);
 221
 222         // if we have e.g. 0.5 sec ramptime and a frametime of 0.25, then the ramp code
 223         // will be called ramp_time/frametime times = 2 times. so, we need to
 224         // add 0.5 * the total speed each frame until the dodge action is done..
 225         float common_factor = PHYS_DODGING_FRAMETIME / PHYS_DODGING_RAMP_TIME;
 226
 227         // if ramp time is smaller than frametime we get problems ;D
 228         common_factor = min(common_factor, 1);
 229
 230         float horiz_speed = PHYS_FROZEN(this) ? PHYS_DODGING_HORIZ_SPEED_FROZEN : PHYS_DODGING_HORIZ_SPEED;
 231         float new_velocity_gain = this.dodging_velocity_gain - (common_factor * horiz_speed);
 232         new_velocity_gain = max(0, new_velocity_gain);
 233
 234         float velocity_difference = this.dodging_velocity_gain - new_velocity_gain;
 235
 236         // ramp up dodging speed by adding some velocity each frame.. TODO: do it! :D
 237         if (this.dodging_action == 1)
 238         {
 239                 //disable jump key during dodge accel phase
 240                 if(this.movement_z > 0) { this.movement_z = 0; }
 241
 242                 this.velocity += ((this.dodging_direction_y * velocity_difference) * v_right)
 243                                         + ((this.dodging_direction_x * velocity_difference) * v_forward);
 244
 245                 this.dodging_velocity_gain = this.dodging_velocity_gain - velocity_difference;
 246         }
 247
 248         // the up part of the dodge is a single shot action
 249         if (this.dodging_single_action == 1)
 250         {
 251                 UNSET_ONGROUND(this);
 252
 253                 this.velocity += PHYS_DODGING_UP_SPEED * v_up;
 254
 255 #ifdef SVQC
 256                 if (autocvar_sv_dodging_sound)
 257                         PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 258
 259                 animdecide_setaction(this, ANIMACTION_JUMP, true);
 260 #endif
 261
 262                 this.dodging_single_action = 0;
 263         }
 264
 265         // are we done with the dodging ramp yet?
 266         if((this.dodging_action == 1) && ((time - this.last_dodging_time) > PHYS_DODGING_RAMP_TIME))
 267         {
 268                 // reset state so next dodge can be done correctly
 269                 this.dodging_action = 0;
 270                 this.dodging_direction_x = 0;
 271                 this.dodging_direction_y = 0;
 272         }
 273 }
 274
 275 void PM_dodging_GetPressedKeys(entity this)
 276 {
 277 #ifdef CSQC
 278         if(!PHYS_DODGING) { return; }
 279
 280         PM_dodging_checkpressedkeys(this);
 281
 282         int keys = this.pressedkeys;
 283         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
 284         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
 285         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
 286         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
 287
 288         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
 289         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
 290         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
 291         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
 292         this.pressedkeys = keys;
 293 #endif
 294 }
 295
 296 MUTATOR_HOOKFUNCTION(dodging, PlayerPhysics)
 297 {
 298     entity player = M_ARGV(0, entity);
 299
 300         // print("dodging_PlayerPhysics\n");
 301         PM_dodging_GetPressedKeys(player);
 302         PM_dodging(player);
 303 }
 304
 305 #ifdef SVQC
 306
 307 REPLICATE(cvar_cl_dodging_timeout, float, "cl_dodging_timeout");
 308
 309 MUTATOR_HOOKFUNCTION(dodging, GetPressedKeys)
 310 {
 311         entity player = M_ARGV(0, entity);
 312
 313         PM_dodging_checkpressedkeys(player);
 314 }
 315
 316 #endif