qcsrc/common/mutators/mutator/dodging/sv_dodging.qc

   1 #include "sv_dodging.qh"
   2
   3 #define PHYS_DODGING                                            g_dodging
   4 #define PHYS_DODGING_DELAY                                      autocvar_sv_dodging_delay
   5 #define PHYS_DODGING_DISTANCE_THRESHOLD         autocvar_sv_dodging_wall_distance_threshold
   6 #define PHYS_DODGING_FROZEN_NODOUBLETAP         autocvar_sv_dodging_frozen_doubletap
   7 #define PHYS_DODGING_HEIGHT_THRESHOLD           autocvar_sv_dodging_height_threshold
   8 #define PHYS_DODGING_HORIZ_SPEED                        autocvar_sv_dodging_horiz_speed
   9 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         autocvar_sv_dodging_horiz_speed_frozen
  10 #define PHYS_DODGING_RAMP_TIME                          autocvar_sv_dodging_ramp_time
  11 #define PHYS_DODGING_UP_SPEED                           autocvar_sv_dodging_up_speed
  12 #define PHYS_DODGING_WALL                                       autocvar_sv_dodging_wall_dodging
  13 #define PHYS_DODGING_AIR                                        autocvar_sv_dodging_air_dodging
  14 #define PHYS_DODGING_MAXSPEED                           autocvar_sv_dodging_maxspeed
  15
  16 // we ran out of stats slots! TODO: re-enable this when prediction is available for dodging
  17 #if 0
  18 #define PHYS_DODGING                                            STAT(DODGING, this)
  19 #define PHYS_DODGING_DELAY                                      STAT(DODGING_DELAY, this)
  20 #define PHYS_DODGING_DISTANCE_THRESHOLD         STAT(DODGING_DISTANCE_THRESHOLD, this)
  21 #define PHYS_DODGING_FROZEN_NODOUBLETAP         STAT(DODGING_FROZEN_NO_DOUBLETAP, this)
  22 #define PHYS_DODGING_HEIGHT_THRESHOLD           STAT(DODGING_HEIGHT_THRESHOLD, this)
  23 #define PHYS_DODGING_HORIZ_SPEED                        STAT(DODGING_HORIZ_SPEED, this)
  24 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         STAT(DODGING_HORIZ_SPEED_FROZEN, this)
  25 #define PHYS_DODGING_RAMP_TIME                          STAT(DODGING_RAMP_TIME, this)
  26 #define PHYS_DODGING_UP_SPEED                           STAT(DODGING_UP_SPEED, this)
  27 #define PHYS_DODGING_WALL                                       STAT(DODGING_WALL, this)
  28 #define PHYS_DODGING_AIR                                        STAT(DODGING_AIR, this)
  29 #define PHYS_DODGING_MAXSPEED                           STAT(DODGING_MAXSPEED, this)
  30 #endif
  31
  32 #ifdef CSQC
  33         #define PHYS_DODGING_FRAMETIME                          (1 / (frametime <= 0 ? 60 : frametime))
  34         #define PHYS_DODGING_TIMEOUT(s)                         STAT(DODGING_TIMEOUT)
  35         #define PHYS_DODGING_PRESSED_KEYS(s)            (s).pressedkeys
  36 #elif defined(SVQC)
  37         #define PHYS_DODGING_FRAMETIME                          sys_frametime
  38         #define PHYS_DODGING_TIMEOUT(s)                         CS(s).cvar_cl_dodging_timeout
  39         #define PHYS_DODGING_PRESSED_KEYS(s)            CS(s).pressedkeys
  40 #endif
  41
  42 #ifdef SVQC
  43
  44 bool autocvar_sv_dodging_sound;
  45
  46 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  47 .float dodging_action;
  48
  49 // the jump part of the dodge cannot be ramped
  50 .float dodging_single_action;
  51
  52 #include <common/animdecide.qh>
  53 #include <common/physics/player.qh>
  54
  55 .float cvar_cl_dodging_timeout;
  56
  57 REGISTER_MUTATOR(dodging, cvar("g_dodging"))
  58 {
  59         // this just turns on the cvar.
  60         MUTATOR_ONADD
  61         {
  62                 g_dodging = cvar("g_dodging");
  63         }
  64
  65         // this just turns off the cvar.
  66         MUTATOR_ONROLLBACK_OR_REMOVE
  67         {
  68                 g_dodging = 0;
  69         }
  70
  71         return false;
  72 }
  73
  74 #elif defined(CSQC)
  75 REGISTER_MUTATOR(dodging, true);
  76 #endif
  77
  78 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  79 .float dodging_action;
  80
  81 // the jump part of the dodge cannot be ramped
  82 .float dodging_single_action;
  83
  84
  85 // these are used to store the last key press time for each of the keys..
  86 .float last_FORWARD_KEY_time;
  87 .float last_BACKWARD_KEY_time;
  88 .float last_LEFT_KEY_time;
  89 .float last_RIGHT_KEY_time;
  90
  91 // these store the movement direction at the time of the dodge action happening.
  92 .vector dodging_direction;
  93
  94 // this indicates the last time a dodge was executed. used to check if another one is allowed
  95 // and to ramp up the dodge acceleration in the physics hook.
  96 .float last_dodging_time;
  97
  98 // This is the velocity gain to be added over the ramp time.
  99 // It will decrease from frame to frame during dodging_action = 1
 100 // until it's 0.
 101 .float dodging_velocity_gain;
 102
 103 #ifdef CSQC
 104 .int pressedkeys;
 105 #endif
 106
 107 // returns true if the player is close to a wall
 108 bool check_close_to_wall(entity this, float threshold)
 109 {
 110         if (PHYS_DODGING_WALL == 0) { return false; }
 111
 112 #define X(dir) \
 113         tracebox(this.origin, this.mins, this.maxs, this.origin + threshold * dir, true, this); \
 114         if (trace_fraction < 1 && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)) \
 115                 return true;
 116
 117         X(v_right);
 118         X(-v_right);
 119         X(v_forward);
 120         X(-v_forward);
 121 #undef X
 122
 123         return false;
 124 }
 125
 126 bool check_close_to_ground(entity this, float threshold)
 127 {
 128         return IS_ONGROUND(this) ? true : false;
 129 }
 130
 131 bool PM_dodging_checkpressedkeys(entity this)
 132 {
 133         if(!PHYS_DODGING)
 134                 return false;
 135
 136         bool frozen_dodging = (PHYS_FROZEN(this) && PHYS_DODGING_FROZEN(this));
 137         bool frozen_no_doubletap = (frozen_dodging && !PHYS_DODGING_FROZEN_NODOUBLETAP);
 138
 139         // first check if the last dodge is far enough back in time so we can dodge again
 140         if ((time - this.last_dodging_time) < PHYS_DODGING_DELAY)
 141                 return false;
 142
 143         makevectors(this.angles);
 144
 145         bool wall_dodge = false;
 146
 147         if(!PHYS_DODGING_AIR)
 148         if(!check_close_to_ground(this, PHYS_DODGING_HEIGHT_THRESHOLD))
 149         {
 150                 wall_dodge = check_close_to_wall(this, PHYS_DODGING_DISTANCE_THRESHOLD);
 151                 if(!wall_dodge) // we're not on the ground, and wall dodging isn't allowed, end it!
 152                         return true;
 153         }
 154
 155         if(!wall_dodge && PHYS_DODGING_MAXSPEED && vdist(this.velocity, >, PHYS_DODGING_MAXSPEED))
 156                 return false;
 157
 158         float tap_direction_x = 0;
 159         float tap_direction_y = 0;
 160         bool dodge_detected = false;
 161         vector mymovement = PHYS_CS(this).movement;
 162
 163         #define X(COND,BTN,RESULT)                                                                                                                      \
 164         if (mymovement_##COND)                                                                                          \
 165                 /* is this a state change? */                                                                                                   \
 166                 if(!(PHYS_DODGING_PRESSED_KEYS(this) & KEY_##BTN) || frozen_no_doubletap) {             \
 167                                 tap_direction_##RESULT;                                                                                                 \
 168                                 if ((time - this.last_##BTN##_KEY_time) < PHYS_DODGING_TIMEOUT(this) || frozen_no_doubletap)    \
 169                                         dodge_detected = true;                                                                                          \
 170                                 if(PHYS_INPUT_BUTTON_DODGE(this))                                                                               \
 171                                         dodge_detected = true;                                                                                          \
 172                                 this.last_##BTN##_KEY_time = time;                                                                              \
 173                 }
 174         X(x < 0, BACKWARD,      x--);
 175         X(x > 0, FORWARD,       x++);
 176         X(y < 0, LEFT,          y--);
 177         X(y > 0, RIGHT,         y++);
 178         #undef X
 179
 180         if (dodge_detected)
 181         {
 182                 this.last_dodging_time = time;
 183
 184                 this.dodging_action = 1;
 185                 this.dodging_single_action = 1;
 186
 187                 this.dodging_velocity_gain = PHYS_DODGING_HORIZ_SPEED;
 188
 189                 this.dodging_direction_x = tap_direction_x;
 190                 this.dodging_direction_y = tap_direction_y;
 191
 192                 // normalize the dodging_direction vector.. (unlike UT99) XD
 193                 float length = this.dodging_direction_x * this.dodging_direction_x
 194                                         + this.dodging_direction_y * this.dodging_direction_y;
 195                 length = sqrt(length);
 196
 197                 this.dodging_direction_x = this.dodging_direction_x * 1.0 / length;
 198                 this.dodging_direction_y = this.dodging_direction_y * 1.0 / length;
 199                 return true;
 200         }
 201         return false;
 202 }
 203
 204 void PM_dodging(entity this)
 205 {
 206         if (!PHYS_DODGING)
 207                 return;
 208
 209         // when swimming or dead, no dodging allowed..
 210         if (this.waterlevel >= WATERLEVEL_SWIMMING || IS_DEAD(this))
 211         {
 212                 this.dodging_action = 0;
 213                 this.dodging_direction_x = 0;
 214                 this.dodging_direction_y = 0;
 215                 return;
 216         }
 217
 218         // make sure v_up, v_right and v_forward are sane
 219         if(PHYS_DODGING_AIR)
 220                 makevectors(this.v_angle);
 221         else
 222                 makevectors(this.angles);
 223
 224         // if we have e.g. 0.5 sec ramptime and a frametime of 0.25, then the ramp code
 225         // will be called ramp_time/frametime times = 2 times. so, we need to
 226         // add 0.5 * the total speed each frame until the dodge action is done..
 227         float common_factor = PHYS_DODGING_FRAMETIME / PHYS_DODGING_RAMP_TIME;
 228
 229         // if ramp time is smaller than frametime we get problems ;D
 230         common_factor = min(common_factor, 1);
 231
 232         float horiz_speed = PHYS_FROZEN(this) ? PHYS_DODGING_HORIZ_SPEED_FROZEN : PHYS_DODGING_HORIZ_SPEED;
 233         float new_velocity_gain = this.dodging_velocity_gain - (common_factor * horiz_speed);
 234         new_velocity_gain = max(0, new_velocity_gain);
 235
 236         float velocity_difference = this.dodging_velocity_gain - new_velocity_gain;
 237
 238         // ramp up dodging speed by adding some velocity each frame.. TODO: do it! :D
 239         if (this.dodging_action == 1)
 240         {
 241                 //disable jump key during dodge accel phase
 242                 if(PHYS_CS(this).movement.z > 0) { PHYS_CS(this).movement_z = 0; }
 243
 244                 this.velocity += ((this.dodging_direction_y * velocity_difference) * v_right)
 245                                         + ((this.dodging_direction_x * velocity_difference) * v_forward);
 246
 247                 this.dodging_velocity_gain = this.dodging_velocity_gain - velocity_difference;
 248         }
 249
 250         // the up part of the dodge is a single shot action
 251         if (this.dodging_single_action == 1)
 252         {
 253                 UNSET_ONGROUND(this);
 254
 255                 this.velocity += PHYS_DODGING_UP_SPEED * v_up;
 256
 257 #ifdef SVQC
 258                 if (autocvar_sv_dodging_sound)
 259                         PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 260
 261                 animdecide_setaction(this, ANIMACTION_JUMP, true);
 262 #endif
 263
 264                 this.dodging_single_action = 0;
 265         }
 266
 267         // are we done with the dodging ramp yet?
 268         if((this.dodging_action == 1) && ((time - this.last_dodging_time) > PHYS_DODGING_RAMP_TIME))
 269         {
 270                 // reset state so next dodge can be done correctly
 271                 this.dodging_action = 0;
 272                 this.dodging_direction_x = 0;
 273                 this.dodging_direction_y = 0;
 274         }
 275 }
 276
 277 void PM_dodging_GetPressedKeys(entity this)
 278 {
 279 #ifdef CSQC
 280         if(!PHYS_DODGING) { return; }
 281
 282         PM_dodging_checkpressedkeys(this);
 283
 284         int keys = this.pressedkeys;
 285         keys = BITSET(keys, KEY_FORWARD,        PHYS_CS(this).movement.x > 0);
 286         keys = BITSET(keys, KEY_BACKWARD,       PHYS_CS(this).movement.x < 0);
 287         keys = BITSET(keys, KEY_RIGHT,          PHYS_CS(this).movement.y > 0);
 288         keys = BITSET(keys, KEY_LEFT,           PHYS_CS(this).movement.y < 0);
 289
 290         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
 291         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
 292         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
 293         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
 294         this.pressedkeys = keys;
 295 #endif
 296 }
 297
 298 MUTATOR_HOOKFUNCTION(dodging, PlayerPhysics)
 299 {
 300     entity player = M_ARGV(0, entity);
 301
 302         // print("dodging_PlayerPhysics\n");
 303         PM_dodging_GetPressedKeys(player);
 304         PM_dodging(player);
 305 }
 306
 307 #ifdef SVQC
 308
 309 REPLICATE(cvar_cl_dodging_timeout, float, "cl_dodging_timeout");
 310
 311 MUTATOR_HOOKFUNCTION(dodging, PlayerPreThink)
 312 {
 313         entity player = M_ARGV(0, entity);
 314
 315         STAT(DODGING_TIMEOUT, player) = CS(player).cvar_cl_dodging_timeout;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(dodging, GetPressedKeys)
 319 {
 320         entity player = M_ARGV(0, entity);
 321
 322         PM_dodging_checkpressedkeys(player);
 323 }
 324
 325 #endif