qcsrc/common/mutators/mutator/powerups/sv_powerups.qc

   1 #include "sv_powerups.qh"
   2
   3 MUTATOR_HOOKFUNCTION(powerups, W_PlayStrengthSound)
   4 {
   5         entity player = M_ARGV(0, entity);
   6
   7         if(StatusEffects_active(STATUSEFFECT_Strength, player)
   8                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
   9                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
  10                 {
  11                         sound(player, CH_TRIGGER, SND_STRENGTH_FIRE, VOL_BASE, ATTEN_NORM);
  12                         player.prevstrengthsound = time;
  13                 }
  14         player.prevstrengthsoundattempt = time;
  15 }
  16
  17 MUTATOR_HOOKFUNCTION(powerups, LogDeath_AppendItemCodes)
  18 {
  19         entity player = M_ARGV(0, entity);
  20
  21         if(StatusEffects_active(STATUSEFFECT_Strength, player))
  22                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "S");
  23
  24         if(StatusEffects_active(STATUSEFFECT_Shield, player))
  25                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "I");
  26
  27         // TODO: item codes for other powerups?
  28 }
  29
  30 MUTATOR_HOOKFUNCTION(powerups, Damage_Calculate)
  31 {
  32         entity attacker = M_ARGV(1, entity);
  33         entity targ = M_ARGV(2, entity);
  34
  35         // apply strength multiplier
  36         if(StatusEffects_active(STATUSEFFECT_Strength, attacker))
  37         {
  38                 if(targ == attacker)
  39                 {
  40                         M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_strength_selfdamage;
  41                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_strength_selfforce;
  42                 }
  43                 else
  44                 {
  45                         M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_strength_damage;
  46                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_strength_force;
  47                 }
  48         }
  49
  50         // apply shield multiplier
  51         if(StatusEffects_active(STATUSEFFECT_Shield, targ))
  52         {
  53                 M_ARGV(4, float) = M_ARGV(4, float) * autocvar_g_balance_powerup_invincible_takedamage;
  54                 if (targ != attacker)
  55                 {
  56                         M_ARGV(6, vector) = M_ARGV(6, vector) * autocvar_g_balance_powerup_invincible_takeforce;
  57                 }
  58         }
  59 }
  60
  61 MUTATOR_HOOKFUNCTION(powerups, CustomizeWaypoint)
  62 {
  63         entity wp = M_ARGV(0, entity);
  64         entity player = M_ARGV(1, entity);
  65
  66         entity e = WaypointSprite_getviewentity(player);
  67
  68         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
  69         // but only apply this to real players, not to spectators
  70         if(IS_CLIENT(wp.owner) && (e == player) && DIFF_TEAM(wp.owner, e) && StatusEffects_active(STATUSEFFECT_Invisibility, wp.owner))
  71                 return true;
  72 }
  73
  74 MUTATOR_HOOKFUNCTION(powerups, MonsterValidTarget)
  75 {
  76         entity targ = M_ARGV(1, entity);
  77         return StatusEffects_active(STATUSEFFECT_Invisibility, targ);
  78 }
  79
  80 void powerups_DropItem(entity this, StatusEffects effect)
  81 {
  82         entity item = Item_DefinitionFromInternalName(effect.netname);
  83         float timeleft = StatusEffects_gettime(effect, this);
  84         if((timeleft - time) <= 0 || !item)
  85                 return;
  86         entity e = spawn();
  87         // TODO: items cannot hold their "item field" yet, so we need to list all the powerups here!
  88         switch(item)
  89         {
  90                 case ITEM_Strength: e.strength_finished = timeleft; break;
  91                 case ITEM_Shield: e.invincible_finished = timeleft; break;
  92                 case ITEM_Invisibility: e.invisibility_finished = timeleft; break;
  93                 case ITEM_Speed: e.speed_finished = timeleft; break;
  94         }
  95         Item_InitializeLoot(e, item.m_canonical_spawnfunc, this.origin + '0 0 32', randomvec() * 175 + '0 0 175', min(timeleft - time, 10));
  96         Item_SetExpiring(e, true);
  97 }
  98
  99 MUTATOR_HOOKFUNCTION(powerups, PlayerDies)
 100 {
 101         if(!autocvar_g_powerups_dropondeath)
 102                 return;
 103
 104         entity frag_target = M_ARGV(2, entity);
 105
 106         FOREACH(StatusEffect, it.instanceOfPowerups,
 107         {
 108                 if(StatusEffects_active(it, frag_target))
 109                         powerups_DropItem(frag_target, it);
 110         });
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(powerups, PlayerPhysics_UpdateStats)
 114 {
 115         entity player = M_ARGV(0, entity);
 116         // these automatically reset, no need to worry
 117
 118         if(StatusEffects_active(STATUSEFFECT_Speed, player))
 119                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_balance_powerup_speed_highspeed;
 120 }
 121
 122 MUTATOR_HOOKFUNCTION(powerups, WeaponRateFactor)
 123 {
 124         entity player = M_ARGV(1, entity);
 125
 126         if(StatusEffects_active(STATUSEFFECT_Speed, player))
 127                 M_ARGV(0, float) *= autocvar_g_balance_powerup_speed_attackrate;
 128 }
 129
 130 MUTATOR_HOOKFUNCTION(powerups, BuildMutatorsPrettyString)
 131 {
 132         if(autocvar_g_powerups == 0)
 133                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", No powerups");
 134         if(autocvar_g_powerups > 0)
 135                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Powerups");
 136 }
 137
 138 MUTATOR_HOOKFUNCTION(powerups, BotShouldAttack)
 139 {
 140         entity targ = M_ARGV(1, entity);
 141
 142         if(StatusEffects_active(STATUSEFFECT_Invisibility, targ))
 143                 return true;
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(powerups, BuildMutatorsString)
 147 {
 148         if(autocvar_g_powerups == 0)
 149                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":no_powerups");
 150         if(autocvar_g_powerups > 0)
 151                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":powerups");
 152 }