qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: December, 2012
   4 // ================================================
   5
   6 // ======================
   7 //  Supporting Functions
   8 // ======================
   9
  10 // team code replace
  11 string TCR(string input, string teamcolor, string teamtext) // TODO: MOVE TO UTIL.QC
  12 {
  13         input = strreplace("^TC", teamcolor, input);
  14         input = strreplace("^TT", teamtext, input);
  15         return input;
  16 }
  17
  18 // color code replace, place inside of sprintf and parse the string
  19 string CCR(string input) // TODO: MOVE TO UTIL.QC
  20 {
  21         // Default colors listed in comments
  22
  23         // foreground/normal colors
  24         input = strreplace("^F1", "^2", input); // Green  // primary priority (important names, etc)
  25         input = strreplace("^F2", "^3", input); // Yellow // secondary priority (items, locations, numbers, etc)
  26         input = strreplace("^F3", "^4", input); // Blue   // tertiary priority or relatively inconsequential text
  27         input = strreplace("^F4", "^1", input); // Red    // notice/attention grabbing texting
  28
  29         // "kill" colors
  30         input = strreplace("^K1", "^1", input); // Red    // "bad" or "dangerous" text (death messages against you, kill notifications, etc)
  31         input = strreplace("^K2", "^3", input); // Yellow // similar to above, but less important... OR, a highlight out of above message type
  32         input = strreplace("^K3", "^4", input); // Blue   // "good" or "beneficial" text (you fragging someone, etc)
  33
  34         // background colors
  35         input = strreplace("^BG", "^7", input); // White // neutral/unimportant text
  36         input = strreplace("^N", "^7", input);  // White // "none"-- reset to white...
  37         return input;
  38 }
  39
  40 #ifndef MENUQC
  41 // select between the normal or the gentle message string based on client (or server) settings
  42 string normal_or_gentle(string normal, string gentle)
  43 {
  44         #ifdef CSQC
  45         if(autocvar_cl_gentle || autocvar_cl_gentle_messages)
  46         #else
  47         if(autocvar_sv_gentle)
  48         #endif
  49                 return ((gentle != "") ? gentle : normal);
  50         else
  51                 return normal;
  52 }
  53
  54 float notif_checkstring(string input)
  55 {
  56         if not(input == "") { return TRUE; }
  57         else { return FALSE; }
  58 }
  59
  60 // get the actual name of a notification and return it as a string
  61 string Get_Field_Value(float field, float net_type, float net_name)
  62 {
  63         string output = "";
  64
  65         #define GET_FIELD_VALUE_OUTPUT(field,name,strnum,flnum) \
  66                 switch(field) { \
  67                         case F_NAME: { output = VAR_TO_TEXT(name); break; } \
  68                         case F_STRNUM: { output = ftos(strnum); break; } \
  69                         case F_FLNUM: { output = ftos(flnum); break; } }
  70
  71         switch(net_type)
  72         {
  73                 case MSG_INFO:
  74                 {
  75                         #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) \
  76                                 { NOTIF_MATCH(name, net_name) { GET_FIELD_VALUE_OUTPUT(field,name,strnum,flnum) } }
  77                         MSG_INFO_NOTIFICATIONS
  78                         #undef MSG_INFO_NOTIF
  79                         break;
  80                 }
  81                 case MSG_CENTER:
  82                 {
  83                         #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) \
  84                                 { NOTIF_MATCH(name, net_name) { GET_FIELD_VALUE_OUTPUT(field,name,strnum,flnum) } }
  85                         MSG_CENTER_NOTIFICATIONS
  86                         #undef MSG_CENTER_NOTIF
  87                         break;
  88                 }
  89                 case MSG_WEAPON:
  90                 {
  91                         #define MSG_WEAPON_NOTIF(name,infoname,centername) \
  92                                 { NOTIF_MATCH(name, net_name) { GET_FIELD_VALUE_OUTPUT(field,name, \
  93                                 max(stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername))), \
  94                                 max(stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)))) } }
  95                         MSG_WEAPON_NOTIFICATIONS
  96                         #undef MSG_WEAPON_NOTIF
  97                         break;
  98                 }
  99                 case MSG_DEATH:
 100                 {
 101                         #define MSG_DEATH_NOTIF(name,infoname,centername) \
 102                                 { NOTIF_MATCH(name, net_name) { GET_FIELD_VALUE_OUTPUT(field,name, \
 103                                 max(stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername))), \
 104                                 max(stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)))) } }
 105                         MSG_DEATH_NOTIFICATIONS
 106                         #undef MSG_DEATH_NOTIF
 107                         break;
 108                 }
 109         }
 110
 111         #undef GET_FIELD_VALUE_OUTPUT
 112         return output;
 113 }
 114 #endif // ifndef MENUQC
 115
 116
 117 // ===============================
 118 //  Frontend Notification Pushing
 119 // ===============================
 120
 121 void Dump_Notifications(float fh, float alsoprint)
 122 {
 123         float MSG_INFO_NOTIFS = 0, MSG_CENTER_NOTIFS = 0, MSG_WEAPON_NOTIFS = 0, MSG_DEATH_NOTIFS = 0;
 124         string notif_msg;
 125
 126         #define NOTIF_WRITE(type,name,text) notif_msg = sprintf("seta %s 1 // %s - %s\n", name, type, strreplace("\n", "\\n", text)); fputs(fh, notif_msg); if(alsoprint) { print(strreplace("^", "^^", notif_msg)); }
 127         #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) { ++MSG_INFO_NOTIFS; NOTIF_WRITE("MSG_INFO", VAR_TO_TEXT(name), normal) }
 128         #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) { ++MSG_CENTER_NOTIFS; NOTIF_WRITE("MSG_CENTER", VAR_TO_TEXT(name), normal) }
 129         #define MSG_WEAPON_NOTIF(name,infoname,centername) { ++MSG_WEAPON_NOTIFS; NOTIF_WRITE("MSG_WEAPON", VAR_TO_TEXT(name),sprintf("infoname: %s, centername: %s", VAR_TO_TEXT(infoname), VAR_TO_TEXT(centername))) }
 130         #define MSG_DEATH_NOTIF(name,infoname,centername) { ++MSG_DEATH_NOTIFS; NOTIF_WRITE("MSG_DEATH", VAR_TO_TEXT(name), sprintf("infoname: %s, centername: %s", VAR_TO_TEXT(infoname), VAR_TO_TEXT(centername))) }
 131         MSG_INFO_NOTIFICATIONS
 132         MSG_CENTER_NOTIFICATIONS
 133         MSG_WEAPON_NOTIFICATIONS
 134         MSG_DEATH_NOTIFICATIONS
 135         #undef NOTIF_WRITE
 136         #undef MSG_INFO_NOTIF
 137         #undef MSG_CENTER_NOTIF
 138         #undef MSG_WEAPON_NOTIF
 139         #undef MSG_DEATH_NOTIF
 140
 141         print(sprintf("Notification counts: MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n", MSG_INFO_NOTIFS, MSG_CENTER_NOTIFS, MSG_WEAPON_NOTIFS, MSG_DEATH_NOTIFS));
 142         return;
 143 }
 144
 145 #ifndef MENUQC
 146 #ifdef CSQC
 147 void HUD_Notify_Push(string icon, string attacker, string victim)
 148 {
 149         if(icon != "")
 150         {
 151                 --kn_index;
 152                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
 153                 killnotify_times[kn_index] = time;
 154
 155                 // icon
 156                 if(killnotify_icon[kn_index]) { strunzone(killnotify_icon[kn_index]); }
 157                 killnotify_icon[kn_index] = strzone(icon);
 158
 159                 // attacker
 160                 if(killnotify_attackers[kn_index]) { strunzone(killnotify_attackers[kn_index]); }
 161                 killnotify_attackers[kn_index] = strzone(attacker);
 162
 163                 // victim
 164                 if(killnotify_victims[kn_index]) { strunzone(killnotify_victims[kn_index]); }
 165                 killnotify_victims[kn_index] = strzone(victim);
 166         }
 167 }
 168 #endif // ifdef CSQC
 169
 170 void Local_Notification(float net_type, float net_name, ...count)
 171 {
 172         float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 173         float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 174
 175         string s1 = ((0 < stringcount) ? ...(0, string) : NO_STR_ARG);
 176         string s2 = ((1 < stringcount) ? ...(1, string) : NO_STR_ARG);
 177         string s3 = ((2 < stringcount) ? ...(2, string) : NO_STR_ARG);
 178         string s4 = ((3 < stringcount) ? ...(3, string) : NO_STR_ARG);
 179         float f1 = ((stringcount < count) ? ...(stringcount, float) : NO_FL_ARG);
 180         float f2 = (((stringcount + 1) < count) ? ...((stringcount + 1), float) : NO_FL_ARG);
 181         float f3 = (((stringcount + 2) < count) ? ...((stringcount + 2), float) : NO_FL_ARG);
 182         float f4 = (((stringcount + 3) < count) ? ...((stringcount + 3), float) : NO_FL_ARG);
 183
 184         dprint("Local_Notification(", ftos(net_type), ", ", Get_Field_Value(F_NAME, net_type, net_name), strcat(", ", s1, ", ", s2, ", ", s3, ", ", s4, ", "), strcat(ftos(f1), strcat(", ", ftos(f2), ", ", ftos(f3), ", ", ftos(f4), ");\n")));
 185         dprint("  ^--: stringcount: ", ftos(stringcount), ", floatcount: ", ftos(floatcount), ".\n");
 186
 187         if((stringcount + floatcount) > count) { backtrace(strcat("Not enough arguments for Local_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), ")"), " > count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 188         else if((stringcount + floatcount) < count) { backtrace(strcat("Too many arguments for Local_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), ")"), " < count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 189
 190         switch(net_type)
 191         {
 192                 case MSG_INFO:
 193                 {
 194                         #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) \
 195                                 { NOTIF_MATCH(name, net_name) CHECK_AUTOCVAR(name) \
 196                                 { \
 197                                         if(notif_checkstring(normal)) { print(sprintf(CCR(normal_or_gentle(normal, gentle)), args)); } \
 198                                         #ifdef CSQC \
 199                                                 if(notif_checkstring(icon)) { HUD_Notify_Push(icon, hudargs); } \
 200                                         #endif \
 201                                 } }
 202                         MSG_INFO_NOTIFICATIONS
 203                         #undef MSG_INFO_NOTIF
 204                         break;
 205                 }
 206                 #ifdef CSQC
 207                 case MSG_CENTER:
 208                 {
 209                         #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) \
 210                                 { NOTIF_MATCH(name, net_name) CHECK_AUTOCVAR(name) \
 211                                 { \
 212                                         if(notif_checkstring(normal)) { centerprint_generic(HANDLE_CPID(cpid), sprintf(CCR(normal_or_gentle(normal, gentle)), args), durcnt); } \
 213                                 } }
 214                         MSG_CENTER_NOTIFICATIONS
 215                         #undef MSG_CENTER_NOTIF
 216                         break;
 217                 }
 218                 #endif
 219                 case MSG_WEAPON:
 220                 {
 221                         #define MSG_WEAPON_NOTIF(name,infoname,centername) \
 222                                 { NOTIF_MATCH(name, net_name) CHECK_AUTOCVAR(name) \
 223                                 { \
 224                                         #if infoname != NO_MSG \
 225                                                 Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 226                                                         stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), \
 227                                                         stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), \
 228                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 229                                         #endif \
 230                                         #ifdef CSQC \
 231                                                 #if centername != NO_MSG \
 232                                                         Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 233                                                                 stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername)), \
 234                                                                 stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)), \
 235                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 236                                                 #endif \
 237                                         #endif \
 238                                 } }
 239                         MSG_WEAPON_NOTIFICATIONS
 240                         #undef MSG_WEAPON_NOTIF
 241                         break;
 242                 }
 243                 case MSG_DEATH:
 244                 {
 245                         #define MSG_DEATH_NOTIF(name,infoname,centername) \
 246                                 { NOTIF_MATCH(name, net_name) CHECK_AUTOCVAR(name) \
 247                                 { \
 248                                         #if infoname != NO_MSG \
 249                                                 Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 250                                                         stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), \
 251                                                         stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), \
 252                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 253                                         #endif \
 254                                         #ifdef CSQC \
 255                                                 #if centername != NO_MSG \
 256                                                         Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 257                                                                 stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername)), \
 258                                                                 stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)), \
 259                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 260                                                 #endif \
 261                                         #endif \
 262                                 } }
 263                         MSG_DEATH_NOTIFICATIONS
 264                         #undef MSG_DEATH_NOTIF
 265                         break;
 266                 }
 267         }
 268 }
 269
 270 void Local_Notification_Without_VarArgs(float net_type, float net_name, float stringcount, float floatcount, string s1, string s2, string s3, string s4, float f1, float f2, float f3, float f4)
 271 {
 272         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Local_Notification(net_type, net_name, args); return; }
 273         EIGHT_VARS_TO_VARARGS_VARLIST
 274         #undef VARITEM
 275
 276         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 277 }
 278
 279
 280 // =========================
 281 //  Notification Networking
 282 // =========================
 283
 284 #ifdef CSQC
 285 void Read_Notification(float is_new)
 286 {
 287         float net_type = ReadByte();
 288         float net_name = ReadShort();
 289
 290         float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 291         float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 292
 293         string s1 = ((stringcount >= 1) ? ReadString() : NO_STR_ARG);
 294         string s2 = ((stringcount >= 2) ? ReadString() : NO_STR_ARG);
 295         string s3 = ((stringcount >= 3) ? ReadString() : NO_STR_ARG);
 296         string s4 = ((stringcount == 4) ? ReadString() : NO_STR_ARG);
 297         float f1 = ((floatcount >= 1) ? ReadLong() : NO_FL_ARG);
 298         float f2 = ((floatcount >= 2) ? ReadLong() : NO_FL_ARG);
 299         float f3 = ((floatcount >= 3) ? ReadLong() : NO_FL_ARG);
 300         float f4 = ((floatcount == 4) ? ReadLong() : NO_FL_ARG);
 301
 302         if(is_new) { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount, s1, s2, s3, s4, f1, f2, f3, f4); }
 303         else { print("received old notification? net_name = ", ftos(net_name), ".\n"); }
 304 }
 305 #endif
 306
 307 #ifdef SVQC
 308 void Notification_Remove()
 309 {
 310         float i;
 311         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 312         remove(self);
 313 }
 314
 315 float Write_Notification(entity client, float sf)
 316 {
 317         float i, send = FALSE;
 318
 319         switch(self.nent_broadcast)
 320         {
 321                 case NOTIF_ONE: { if((client == self.nent_client) || (client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 322                 case NOTIF_ONE_ONLY: { if(client == self.nent_client) { send = TRUE; } break; }
 323                 case NOTIF_TEAM: { if((client.team == self.nent_client.team) || (client.classname == STR_SPECTATOR && client.enemy.team == self.nent_client.team)) { send = TRUE; } break; }
 324                 case NOTIF_TEAM_EXCEPT: { if(((client != self.nent_client) && (client.team == self.nent_client.team) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client))) { send = TRUE; } break; }
 325                 case NOTIF_ANY: { send = TRUE; break; }
 326                 case NOTIF_ANY_EXCEPT: { if((client != self.nent_client) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 327                 default: { send = FALSE; break; }
 328         }
 329
 330         if(send)
 331         {
 332                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 333                 WriteByte(MSG_ENTITY, self.nent_net_type);
 334                 WriteShort(MSG_ENTITY, self.nent_net_name);
 335                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 336                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 337         }
 338
 339         return send;
 340 }
 341
 342 void Send_Notification(float broadcast, entity client, float net_type, float net_name, ...count)
 343 {
 344         if(broadcast && net_type && net_name)
 345         {
 346                 float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 347                 float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 348                 float i;
 349
 350                 dprint("Send_Notification(", ftos(broadcast), ", ", ftos(net_type), ", ", Get_Field_Value(F_NAME, net_type, net_name), strcat(", ", ftos(count), ");\n"));
 351                 dprint("  ^--: stringcount: ", ftos(stringcount), ", floatcount: ", ftos(floatcount), ".\n");
 352
 353                 if((stringcount + floatcount) > count) { backtrace(strcat("Not enough arguments for Send_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), "),"), " > count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 354                 else if((stringcount + floatcount) < count) { backtrace(strcat("Too many arguments for Send_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), "),"), " < count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 355
 356                 entity notif = spawn();
 357                 notif.nent_broadcast = broadcast;
 358                 notif.nent_client = client;
 359                 notif.nent_net_type = net_type;
 360                 notif.nent_net_name = net_name;
 361                 notif.nent_stringcount = stringcount;
 362                 notif.nent_floatcount = floatcount;
 363                 for(i = 0; i < stringcount; ++i) { notif.nent_strings[i] = strzone(...(i, string)); }
 364                 for(i = 0; i < floatcount; ++i) { notif.nent_floats[i] = ...((stringcount + i), float); }
 365
 366                 notif.think = Notification_Remove;
 367                 notif.nextthink = (time + 0.5);
 368
 369                 Net_LinkEntity(notif, FALSE, 0, Write_Notification);
 370
 371                 if(!server_is_local)
 372                 {
 373                         Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount, IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3), IFFL(0), IFFL(1), IFFL(2), IFFL(3));
 374                 }
 375         }
 376         else { backtrace("Incorrect usage of Send_Notification!\n"); }
 377 }
 378
 379 void Send_Notification_Without_VarArgs(float broadcast, entity client, float net_type, float net_name, float stringcount, float floatcount, string s1, string s2, string s3, string s4, float f1, float f2, float f3, float f4)
 380 {
 381         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 382         EIGHT_VARS_TO_VARARGS_VARLIST
 383         #undef VARITEM
 384
 385         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 386 }
 387
 388 void Send_Notification_Legacy_Wrapper(float broadcast, entity client, float net_type, float net_name, string s1, string s2, float f1, float f2, float f3)
 389 {
 390         float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 391         float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 392         Send_Notification_Without_VarArgs(broadcast, client, net_type, net_name, stringcount, floatcount, s1, s2, NO_STR_ARG, NO_STR_ARG, f1, f2, f3, NO_FL_ARG);
 393 }
 394
 395
 396 // =============================
 397 //  LEGACY NOTIFICATION SYSTEMS
 398 // =============================
 399
 400 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 401 {
 402         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 403         {
 404                 msg_entity = e;
 405                 WRITESPECTATABLE_MSG_ONE({
 406                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 407                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 408                         WriteByte(MSG_ONE, id);
 409                         WriteString(MSG_ONE, s);
 410                         if (id != 0 && s != "")
 411                         {
 412                                 WriteByte(MSG_ONE, duration);
 413                                 WriteByte(MSG_ONE, countdown_num);
 414                         }
 415                 });
 416         }
 417 }
 418 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
 419 {
 420         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
 421 }
 422 #endif // ifdef SVQC
 423 #endif // ifndef MENUQC