qcsrc/common/physics.qc

   1 #include "physics.qh"
   2 #include "triggers/include.qh"
   3 #include "viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include "../server/miscfunctions.qh"
   8 #include "triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity pl, string option)
  17 {
  18         if(Physics_Valid(pl.cvar_cl_physics))
  19         {
  20                 string s = sprintf("g_physics_%s_%s", pl.cvar_cl_physics, option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return cvar(strcat("sv_", option));
  31 }
  32
  33 void Physics_AddStats()
  34 {
  35         // static view offset and hitbox vectors
  36         // networked for all you bandwidth pigs out there
  37         addstat(STAT_PL_VIEW_OFS1, AS_FLOAT, stat_pl_view_ofs_x);
  38         addstat(STAT_PL_VIEW_OFS2, AS_FLOAT, stat_pl_view_ofs_y);
  39         addstat(STAT_PL_VIEW_OFS3, AS_FLOAT, stat_pl_view_ofs_z);
  40         addstat(STAT_PL_CROUCH_VIEW_OFS1, AS_FLOAT, stat_pl_crouch_view_ofs_x);
  41         addstat(STAT_PL_CROUCH_VIEW_OFS2, AS_FLOAT, stat_pl_crouch_view_ofs_y);
  42         addstat(STAT_PL_CROUCH_VIEW_OFS3, AS_FLOAT, stat_pl_crouch_view_ofs_z);
  43
  44         addstat(STAT_PL_MIN1, AS_FLOAT, stat_pl_min_x);
  45         addstat(STAT_PL_MIN2, AS_FLOAT, stat_pl_min_y);
  46         addstat(STAT_PL_MIN3, AS_FLOAT, stat_pl_min_z);
  47         addstat(STAT_PL_MAX1, AS_FLOAT, stat_pl_max_x);
  48         addstat(STAT_PL_MAX2, AS_FLOAT, stat_pl_max_y);
  49         addstat(STAT_PL_MAX3, AS_FLOAT, stat_pl_max_z);
  50         addstat(STAT_PL_CROUCH_MIN1, AS_FLOAT, stat_pl_crouch_min_x);
  51         addstat(STAT_PL_CROUCH_MIN2, AS_FLOAT, stat_pl_crouch_min_y);
  52         addstat(STAT_PL_CROUCH_MIN3, AS_FLOAT, stat_pl_crouch_min_z);
  53         addstat(STAT_PL_CROUCH_MAX1, AS_FLOAT, stat_pl_crouch_max_x);
  54         addstat(STAT_PL_CROUCH_MAX2, AS_FLOAT, stat_pl_crouch_max_y);
  55         addstat(STAT_PL_CROUCH_MAX3, AS_FLOAT, stat_pl_crouch_max_z);
  56
  57         // g_movementspeed hack
  58         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
  59         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
  60         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
  61         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
  62         addstat(STAT_MOVEVARS_HIGHSPEED, AS_FLOAT, stat_movement_highspeed);
  63
  64         // jet pack
  65         addstat(STAT_JETPACK_ACCEL_SIDE, AS_FLOAT, stat_jetpack_accel_side);
  66         addstat(STAT_JETPACK_ACCEL_UP, AS_FLOAT, stat_jetpack_accel_up);
  67         addstat(STAT_JETPACK_ANTIGRAVITY, AS_FLOAT, stat_jetpack_antigravity);
  68         addstat(STAT_JETPACK_FUEL, AS_FLOAT, stat_jetpack_fuel);
  69         addstat(STAT_JETPACK_MAXSPEED_UP, AS_FLOAT, stat_jetpack_maxspeed_up);
  70         addstat(STAT_JETPACK_MAXSPEED_SIDE, AS_FLOAT, stat_jetpack_maxspeed_side);
  71
  72         // hack to fix track_canjump
  73         addstat(STAT_MOVEVARS_CL_TRACK_CANJUMP, AS_INT, cvar_cl_movement_track_canjump);
  74         addstat(STAT_MOVEVARS_TRACK_CANJUMP, AS_INT, stat_sv_track_canjump);
  75
  76         // double jump
  77         addstat(STAT_DOUBLEJUMP, AS_INT, stat_doublejump);
  78
  79         // jump speed caps
  80         addstat(STAT_MOVEVARS_JUMPSPEEDCAP_DISABLE_ONRAMPS, AS_INT, stat_jumpspeedcap_disable_onramps);
  81
  82         // hacks
  83         addstat(STAT_MOVEVARS_FRICTION_ONLAND, AS_FLOAT, stat_sv_friction_on_land);
  84         addstat(STAT_MOVEVARS_FRICTION_SLICK, AS_FLOAT, stat_sv_friction_slick);
  85         addstat(STAT_GAMEPLAYFIX_EASIERWATERJUMP, AS_INT, stat_gameplayfix_easierwaterjump);
  86
  87         // new properties
  88         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
  89         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
  90         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
  91         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
  92         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
  93         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
  94         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
  95         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
  96         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
  97         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
  98         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
  99         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 100         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 101         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 102         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 103         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 104         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 105         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 106         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 107
 108         addstat(STAT_GAMEPLAYFIX_UPVELOCITYCLEARSONGROUND, AS_INT, stat_gameplayfix_upvelocityclearsonground);
 109 }
 110
 111 void Physics_UpdateStats(float maxspd_mod)
 112 {SELFPARAM();
 113         // blah
 114         self.stat_pl_view_ofs = PL_VIEW_OFS;
 115         self.stat_pl_crouch_view_ofs = PL_CROUCH_VIEW_OFS;
 116
 117         self.stat_pl_min = PL_MIN;
 118         self.stat_pl_max = PL_MAX;
 119         self.stat_pl_crouch_min = PL_CROUCH_MIN;
 120         self.stat_pl_crouch_max = PL_CROUCH_MAX;
 121
 122
 123         self.stat_sv_airaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airaccel_qw"), maxspd_mod);
 124         if(Physics_ClientOption(self, "airstrafeaccel_qw"))
 125                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(Physics_ClientOption(self, "airstrafeaccel_qw"), maxspd_mod);
 126         else
 127                 self.stat_sv_airstrafeaccel_qw = 0;
 128         self.stat_sv_airspeedlimit_nonqw = Physics_ClientOption(self, "airspeedlimit_nonqw") * maxspd_mod;
 129         self.stat_sv_maxspeed = Physics_ClientOption(self, "maxspeed") * maxspd_mod; // also slow walking
 130         self.stat_movement_highspeed = PHYS_HIGHSPEED; // TODO: remove this!
 131
 132         self.stat_doublejump = PHYS_DOUBLEJUMP;
 133
 134         self.stat_jetpack_antigravity = PHYS_JETPACK_ANTIGRAVITY;
 135         self.stat_jetpack_accel_up = PHYS_JETPACK_ACCEL_UP;
 136         self.stat_jetpack_accel_side = PHYS_JETPACK_ACCEL_SIDE;
 137         self.stat_jetpack_maxspeed_side = PHYS_JETPACK_MAXSPEED_SIDE;
 138         self.stat_jetpack_maxspeed_up = PHYS_JETPACK_MAXSPEED_UP;
 139         self.stat_jetpack_fuel = PHYS_JETPACK_FUEL;
 140
 141         self.stat_jumpspeedcap_disable_onramps = PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS;
 142
 143         self.stat_sv_friction_on_land = PHYS_FRICTION_ONLAND;
 144         self.stat_sv_friction_slick = PHYS_FRICTION_SLICK;
 145
 146         self.stat_gameplayfix_easierwaterjump = GAMEPLAYFIX_EASIERWATERJUMP;
 147
 148
 149         // old stats
 150         // fix some new settings
 151         self.stat_sv_airaccel_qw_stretchfactor = Physics_ClientOption(self, "airaccel_qw_stretchfactor");
 152         self.stat_sv_maxairstrafespeed = Physics_ClientOption(self, "maxairstrafespeed");
 153         self.stat_sv_maxairspeed = Physics_ClientOption(self, "maxairspeed");
 154         self.stat_sv_airstrafeaccelerate = Physics_ClientOption(self, "airstrafeaccelerate");
 155         self.stat_sv_warsowbunny_turnaccel = Physics_ClientOption(self, "warsowbunny_turnaccel");
 156         self.stat_sv_airaccel_sideways_friction = Physics_ClientOption(self, "airaccel_sideways_friction");
 157         self.stat_sv_aircontrol = Physics_ClientOption(self, "aircontrol");
 158         self.stat_sv_aircontrol_power = Physics_ClientOption(self, "aircontrol_power");
 159         self.stat_sv_aircontrol_penalty = Physics_ClientOption(self, "aircontrol_penalty");
 160         self.stat_sv_warsowbunny_airforwardaccel = Physics_ClientOption(self, "warsowbunny_airforwardaccel");
 161         self.stat_sv_warsowbunny_topspeed = Physics_ClientOption(self, "warsowbunny_topspeed");
 162         self.stat_sv_warsowbunny_accel = Physics_ClientOption(self, "warsowbunny_accel");
 163         self.stat_sv_warsowbunny_backtosideratio = Physics_ClientOption(self, "warsowbunny_backtosideratio");
 164         self.stat_sv_friction = Physics_ClientOption(self, "friction");
 165         self.stat_sv_accelerate = Physics_ClientOption(self, "accelerate");
 166         self.stat_sv_stopspeed = Physics_ClientOption(self, "stopspeed");
 167         self.stat_sv_airaccelerate = Physics_ClientOption(self, "airaccelerate");
 168         self.stat_sv_airstopaccelerate = Physics_ClientOption(self, "airstopaccelerate");
 169         self.stat_sv_jumpvelocity = Physics_ClientOption(self, "jumpvelocity");
 170
 171         self.stat_sv_track_canjump = Physics_ClientOption(self, "track_canjump");
 172
 173         self.stat_gameplayfix_upvelocityclearsonground = UPWARD_VELOCITY_CLEARS_ONGROUND;
 174 }
 175 #endif
 176
 177 float IsMoveInDirection(vector mv, float ang) // key mix factor
 178 {
 179         if (mv_x == 0 && mv_y == 0)
 180                 return 0; // avoid division by zero
 181         ang -= RAD2DEG * atan2(mv_y, mv_x);
 182         ang = remainder(ang, 360) / 45;
 183         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
 184 }
 185
 186 float GeomLerp(float a, float lerp, float b)
 187 {
 188         return a == 0 ? (lerp < 1 ? 0 : b)
 189                 : b == 0 ? (lerp > 0 ? 0 : a)
 190                 : a * pow(fabs(b / a), lerp);
 191 }
 192
 193 noref float pmove_waterjumptime;
 194
 195 const float unstick_count = 27;
 196 vector unstick_offsets[unstick_count] =
 197 {
 198 // 1 no nudge (just return the original if this test passes)
 199         '0.000   0.000  0.000',
 200 // 6 simple nudges
 201         ' 0.000  0.000  0.125', '0.000  0.000 -0.125',
 202         '-0.125  0.000  0.000', '0.125  0.000  0.000',
 203         ' 0.000 -0.125  0.000', '0.000  0.125  0.000',
 204 // 4 diagonal flat nudges
 205         '-0.125 -0.125  0.000', '0.125 -0.125  0.000',
 206         '-0.125  0.125  0.000', '0.125  0.125  0.000',
 207 // 8 diagonal upward nudges
 208         '-0.125  0.000  0.125', '0.125  0.000  0.125',
 209         ' 0.000 -0.125  0.125', '0.000  0.125  0.125',
 210         '-0.125 -0.125  0.125', '0.125 -0.125  0.125',
 211         '-0.125  0.125  0.125', '0.125  0.125  0.125',
 212 // 8 diagonal downward nudges
 213         '-0.125  0.000 -0.125', '0.125  0.000 -0.125',
 214         ' 0.000 -0.125 -0.125', '0.000  0.125 -0.125',
 215         '-0.125 -0.125 -0.125', '0.125 -0.125 -0.125',
 216         '-0.125  0.125 -0.125', '0.125  0.125 -0.125',
 217 };
 218
 219 void PM_ClientMovement_Unstick()
 220 {SELFPARAM();
 221         float i;
 222         for (i = 0; i < unstick_count; i++)
 223         {
 224                 vector neworigin = unstick_offsets[i] + self.origin;
 225                 tracebox(neworigin, PL_CROUCH_MIN, PL_CROUCH_MAX, neworigin, MOVE_NORMAL, self);
 226                 if (!trace_startsolid)
 227                 {
 228                         setorigin(self, neworigin);
 229                         return;// true;
 230                 }
 231         }
 232 }
 233
 234 void PM_ClientMovement_UpdateStatus(bool ground)
 235 {SELFPARAM();
 236         // make sure player is not stuck
 237         PM_ClientMovement_Unstick();
 238
 239         // set crouched
 240         if (PHYS_INPUT_BUTTON_CROUCH(self))
 241         {
 242                 // wants to crouch, this always works..
 243                 if (!IS_DUCKED(self))
 244                         SET_DUCKED(self);
 245         }
 246         else
 247         {
 248                 // wants to stand, if currently crouching we need to check for a
 249                 // low ceiling first
 250                 if (IS_DUCKED(self))
 251                 {
 252                         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, MOVE_NORMAL, self);
 253                         if (!trace_startsolid)
 254                                 UNSET_DUCKED(self);
 255                 }
 256         }
 257
 258         // set onground
 259         vector origin1 = self.origin + '0 0 1';
 260         vector origin2 = self.origin - '0 0 1';
 261
 262         if(ground)
 263         {
 264                 tracebox(origin1, self.mins, self.maxs, origin2, MOVE_NORMAL, self);
 265                 if (trace_fraction < 1.0 && trace_plane_normal_z > 0.7)
 266                 {
 267                         SET_ONGROUND(self);
 268
 269                         // this code actually "predicts" an impact; so let's clip velocity first
 270                         float f = self.velocity * trace_plane_normal;
 271                         self.velocity -= f * trace_plane_normal;
 272                 }
 273                 else
 274                         UNSET_ONGROUND(self);
 275         }
 276
 277         // set watertype/waterlevel
 278         origin1 = self.origin;
 279         origin1_z += self.mins_z + 1;
 280         self.waterlevel = WATERLEVEL_NONE;
 281
 282         int thepoint = pointcontents(origin1);
 283
 284         self.watertype = (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME);
 285
 286         if(self.watertype)
 287         {
 288                 self.waterlevel = WATERLEVEL_WETFEET;
 289                 origin1_z = self.origin_z + (self.mins_z + self.maxs_z) * 0.5;
 290                 thepoint = pointcontents(origin1);
 291                 if(thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 292                 {
 293                         self.waterlevel = WATERLEVEL_SWIMMING;
 294                         origin1_z = self.origin_z + 22;
 295                         thepoint = pointcontents(origin1);
 296                         if(thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 297                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 298                 }
 299         }
 300
 301         if(IS_ONGROUND(self) || self.velocity_z <= 0 || pmove_waterjumptime <= 0)
 302                 pmove_waterjumptime = 0;
 303 }
 304
 305 void PM_ClientMovement_Move()
 306 {SELFPARAM();
 307 #ifdef CSQC
 308         int bump;
 309         float t;
 310         float f;
 311         vector neworigin;
 312         vector currentorigin2;
 313         vector neworigin2;
 314         vector primalvelocity;
 315
 316         vector trace1_endpos = '0 0 0';
 317         vector trace2_endpos = '0 0 0';
 318         vector trace3_endpos = '0 0 0';
 319         float trace1_fraction = 0;
 320         float trace2_fraction = 0;
 321         float trace3_fraction = 0;
 322         vector trace1_plane_normal = '0 0 0';
 323         vector trace2_plane_normal = '0 0 0';
 324         vector trace3_plane_normal = '0 0 0';
 325
 326
 327         PM_ClientMovement_UpdateStatus(false);
 328         primalvelocity = self.velocity;
 329         for(bump = 0, t = PHYS_INPUT_TIMELENGTH; bump < 8 && (self.velocity * self.velocity) > 0; bump++)
 330         {
 331                 neworigin = self.origin + t * self.velocity;
 332                 tracebox(self.origin, self.mins, self.maxs, neworigin, MOVE_NORMAL, self);
 333                 trace1_endpos = trace_endpos;
 334                 trace1_fraction = trace_fraction;
 335                 trace1_plane_normal = trace_plane_normal;
 336                 if(trace1_fraction < 1 && trace1_plane_normal_z == 0)
 337                 {
 338                         // may be a step or wall, try stepping up
 339                         // first move forward at a higher level
 340                         currentorigin2 = self.origin;
 341                         currentorigin2_z += PHYS_STEPHEIGHT;
 342                         neworigin2 = neworigin;
 343                         neworigin2_z += PHYS_STEPHEIGHT;
 344                         tracebox(currentorigin2, self.mins, self.maxs, neworigin2, MOVE_NORMAL, self);
 345                         trace2_endpos = trace_endpos;
 346                         trace2_fraction = trace_fraction;
 347                         trace2_plane_normal = trace_plane_normal;
 348                         if(!trace_startsolid)
 349                         {
 350                                 // then move down from there
 351                                 currentorigin2 = trace2_endpos;
 352                                 neworigin2 = trace2_endpos;
 353                                 neworigin2_z = self.origin_z;
 354                                 tracebox(currentorigin2, self.mins, self.maxs, neworigin2, MOVE_NORMAL, self);
 355                                 trace3_endpos = trace_endpos;
 356                                 trace3_fraction = trace_fraction;
 357                                 trace3_plane_normal = trace_plane_normal;
 358                                 // accept the new trace if it made some progress
 359                                 if(fabs(trace3_endpos_x - trace1_endpos_x) >= 0.03125 || fabs(trace3_endpos_y - trace1_endpos_y) >= 0.03125)
 360                                 {
 361                                         trace1_endpos = trace2_endpos;
 362                                         trace1_fraction = trace2_fraction;
 363                                         trace1_plane_normal = trace2_plane_normal;
 364                                         trace1_endpos = trace3_endpos;
 365                                 }
 366                         }
 367                 }
 368
 369                 // check if it moved at all
 370                 if(trace1_fraction >= 0.001)
 371                         setorigin(self, trace1_endpos);
 372
 373                 // check if it moved all the way
 374                 if(trace1_fraction == 1)
 375                         break;
 376
 377                 // this is only really needed for nogravityonground combined with gravityunaffectedbyticrate
 378                 // <LordHavoc> I'm pretty sure I commented it out solely because it seemed redundant
 379                 // this got commented out in a change that supposedly makes the code match QW better
 380                 // so if this is broken, maybe put it in an if(cls.protocol != PROTOCOL_QUAKEWORLD) block
 381                 if(trace1_plane_normal_z > 0.7)
 382                         SET_ONGROUND(self);
 383
 384                 t -= t * trace1_fraction;
 385
 386                 f = (self.velocity * trace1_plane_normal);
 387                 self.velocity = self.velocity + -f * trace1_plane_normal;
 388         }
 389         if(pmove_waterjumptime > 0)
 390                 self.velocity = primalvelocity;
 391 #endif
 392 }
 393
 394 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 395 {SELFPARAM();
 396         float k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 397         if (k <= 0)
 398                 return;
 399
 400         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(self), 1);
 401
 402         float zspeed = self.velocity_z;
 403         self.velocity_z = 0;
 404         float xyspeed = vlen(self.velocity);
 405         self.velocity = normalize(self.velocity);
 406
 407         float dot = self.velocity * wishdir;
 408
 409         if (dot > 0) // we can't change direction while slowing down
 410         {
 411                 k *= pow(dot, PHYS_AIRCONTROL_POWER) * PHYS_INPUT_TIMELENGTH;
 412                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY * sqrt(max(0, 1 - dot*dot)) * k/32);
 413                 k *= PHYS_AIRCONTROL;
 414                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 415         }
 416
 417         self.velocity = self.velocity * xyspeed;
 418         self.velocity_z = zspeed;
 419 }
 420
 421 float AdjustAirAccelQW(float accelqw, float factor)
 422 {
 423         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 424 }
 425
 426 // example config for alternate speed clamping:
 427 //   sv_airaccel_qw 0.8
 428 //   sv_airaccel_sideways_friction 0
 429 //   prvm_globalset server speedclamp_mode 1
 430 //     (or 2)
 431 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 432 {SELFPARAM();
 433         float speedclamp = stretchfactor > 0 ? stretchfactor
 434         : accelqw < 0 ? 1 // full clamping, no stretch
 435         : -1; // no clamping
 436
 437         accelqw = fabs(accelqw);
 438
 439         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 440                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 441
 442         float vel_straight = self.velocity * wishdir;
 443         float vel_z = self.velocity_z;
 444         vector vel_xy = vec2(self.velocity);
 445         vector vel_perpend = vel_xy - vel_straight * wishdir;
 446
 447         float step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
 448
 449         float vel_xy_current  = vlen(vel_xy);
 450         if (speedlimit)
 451                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 452         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 453         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 454         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 455         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 456
 457         if (sidefric < 0 && (vel_perpend*vel_perpend))
 458                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 459         {
 460                 float f = max(0, 1 + PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 461                 float fmin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 462                 // assume: fmin > 1
 463                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 464                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 465                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 466                 // obviously, this cannot be
 467                 if (fmin <= 0)
 468                         vel_perpend *= f;
 469                 else
 470                 {
 471                         fmin = sqrt(fmin);
 472                         vel_perpend *= max(fmin, f);
 473                 }
 474         }
 475         else
 476                 vel_perpend *= max(0, 1 - PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 477
 478         vel_xy = vel_straight * wishdir + vel_perpend;
 479
 480         if (speedclamp >= 0)
 481         {
 482                 float vel_xy_preclamp;
 483                 vel_xy_preclamp = vlen(vel_xy);
 484                 if (vel_xy_preclamp > 0) // prevent division by zero
 485                 {
 486                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 487                         if (vel_xy_current < vel_xy_preclamp)
 488                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 489                 }
 490         }
 491
 492         self.velocity = vel_xy + vel_z * '0 0 1';
 493 }
 494
 495 void PM_AirAccelerate(vector wishdir, float wishspeed)
 496 {SELFPARAM();
 497         if (wishspeed == 0)
 498                 return;
 499
 500         vector curvel = self.velocity;
 501         curvel_z = 0;
 502         float curspeed = vlen(curvel);
 503
 504         if (wishspeed > curspeed * 1.01)
 505                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL * PHYS_MAXSPEED(self) * PHYS_INPUT_TIMELENGTH);
 506         else
 507         {
 508                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED - PHYS_MAXSPEED(self)));
 509                 wishspeed = max(curspeed, PHYS_MAXSPEED(self)) + PHYS_WARSOWBUNNY_ACCEL * f * PHYS_MAXSPEED(self) * PHYS_INPUT_TIMELENGTH;
 510         }
 511         vector wishvel = wishdir * wishspeed;
 512         vector acceldir = wishvel - curvel;
 513         float addspeed = vlen(acceldir);
 514         acceldir = normalize(acceldir);
 515
 516         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL * PHYS_MAXSPEED(self) * PHYS_INPUT_TIMELENGTH);
 517
 518         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO < 1)
 519         {
 520                 vector curdir = normalize(curvel);
 521                 float dot = acceldir * curdir;
 522                 if (dot < 0)
 523                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO) * dot * curdir;
 524         }
 525
 526         self.velocity += accelspeed * acceldir;
 527 }
 528
 529
 530 /*
 531 =============
 532 PlayerJump
 533
 534 When you press the jump key
 535 returns true if handled
 536 =============
 537 */
 538 bool PlayerJump ()
 539 {SELFPARAM();
 540         if (PHYS_FROZEN(self))
 541                 return true; // no jumping in freezetag when frozen
 542
 543 #ifdef SVQC
 544         if (self.player_blocked)
 545                 return true; // no jumping while blocked
 546 #endif
 547
 548         bool doublejump = false;
 549         float mjumpheight = PHYS_JUMPVELOCITY;
 550 #ifdef CSQC
 551         player_multijump = doublejump;
 552         player_jumpheight = mjumpheight;
 553 #endif
 554
 555         if (MUTATOR_CALLHOOK(PlayerJump, doublejump, mjumpheight)
 556 #ifdef CSQC
 557                 || PM_multijump_checkjump()
 558 #endif
 559                 ) { return true; }
 560
 561         doublejump = player_multijump;
 562         mjumpheight = player_jumpheight;
 563
 564         if (PHYS_DOUBLEJUMP)
 565         {
 566                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 567                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
 568                 {
 569                         doublejump = true;
 570
 571                         // we MUST clip velocity here!
 572                         float f;
 573                         f = self.velocity * trace_plane_normal;
 574                         if (f < 0)
 575                                 self.velocity -= f * trace_plane_normal;
 576                 }
 577         }
 578
 579         if (self.waterlevel >= WATERLEVEL_SWIMMING)
 580         {
 581                 self.velocity_z = PHYS_MAXSPEED(self) * 0.7;
 582                 return true;
 583         }
 584
 585         if (!doublejump)
 586                 if (!IS_ONGROUND(self))
 587                         return IS_JUMP_HELD(self);
 588
 589         bool track_jump = PHYS_CL_TRACK_CANJUMP(self);
 590         if(PHYS_TRACK_CANJUMP(self))
 591                 track_jump = true;
 592
 593         if (track_jump)
 594                 if (IS_JUMP_HELD(self))
 595                         return true;
 596
 597         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 598         // velocity bounds.  Final velocity is bound between (jumpheight *
 599         // min + jumpheight) and (jumpheight * max + jumpheight);
 600
 601         if(PHYS_JUMPSPEEDCAP_MIN != "")
 602         {
 603                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 604
 605                 if (self.velocity_z < minjumpspeed)
 606                         mjumpheight += minjumpspeed - self.velocity_z;
 607         }
 608
 609         if(PHYS_JUMPSPEEDCAP_MAX != "")
 610         {
 611                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 612                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 613
 614                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS))
 615                 {
 616                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 617
 618                         if (self.velocity_z > maxjumpspeed)
 619                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 620                 }
 621         }
 622
 623         if (!WAS_ONGROUND(self))
 624         {
 625 #ifdef SVQC
 626                 if(autocvar_speedmeter)
 627                         LOG_TRACE(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 628 #endif
 629                 if(self.lastground < time - 0.3)
 630                 {
 631                         self.velocity_x *= (1 - PHYS_FRICTION_ONLAND);
 632                         self.velocity_y *= (1 - PHYS_FRICTION_ONLAND);
 633                 }
 634 #ifdef SVQC
 635                 if(self.jumppadcount > 1)
 636                         LOG_TRACE(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 637                 self.jumppadcount = 0;
 638 #endif
 639         }
 640
 641         self.velocity_z += mjumpheight;
 642
 643         UNSET_ONGROUND(self);
 644         SET_JUMP_HELD(self);
 645
 646 #ifdef SVQC
 647
 648         self.oldvelocity_z = self.velocity_z;
 649
 650         animdecide_setaction(self, ANIMACTION_JUMP, true);
 651
 652         if (autocvar_g_jump_grunt)
 653                 PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 654 #endif
 655         return true;
 656 }
 657
 658 void CheckWaterJump()
 659 {SELFPARAM();
 660 // check for a jump-out-of-water
 661         makevectors(self.v_angle);
 662         vector start = self.origin;
 663         start_z += 8;
 664         v_forward_z = 0;
 665         normalize(v_forward);
 666         vector end = start + v_forward*24;
 667         traceline (start, end, true, self);
 668         if (trace_fraction < 1)
 669         {       // solid at waist
 670                 start_z = start_z + self.maxs_z - 8;
 671                 end = start + v_forward*24;
 672                 self.movedir = trace_plane_normal * -50;
 673                 traceline(start, end, true, self);
 674                 if (trace_fraction == 1)
 675                 {       // open at eye level
 676                         self.velocity_z = 225;
 677                         self.flags |= FL_WATERJUMP;
 678                         SET_JUMP_HELD(self);
 679 #ifdef SVQC
 680                         self.teleport_time = time + 2;  // safety net
 681 #elif defined(CSQC)
 682                         pmove_waterjumptime = time + 2;
 683 #endif
 684                 }
 685         }
 686 }
 687
 688
 689 #ifdef SVQC
 690         #define JETPACK_JUMP(s) s.cvar_cl_jetpack_jump
 691 #elif defined(CSQC)
 692         float autocvar_cl_jetpack_jump;
 693         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 694 #endif
 695 .float jetpack_stopped;
 696 // Hack: shouldn't need to know about this
 697 .float multijump_count;
 698 void CheckPlayerJump()
 699 {SELFPARAM();
 700 #ifdef SVQC
 701         float was_flying = ITEMS_STAT(self) & IT_USING_JETPACK;
 702 #endif
 703         if (JETPACK_JUMP(self) < 2)
 704                 ITEMS_STAT(self) &= ~IT_USING_JETPACK;
 705
 706         if(PHYS_INPUT_BUTTON_JUMP(self) || PHYS_INPUT_BUTTON_JETPACK(self))
 707         {
 708                 float air_jump = !PlayerJump() || self.multijump_count > 0; // PlayerJump() has important side effects
 709                 float activate = JETPACK_JUMP(self) && air_jump && PHYS_INPUT_BUTTON_JUMP(self) || PHYS_INPUT_BUTTON_JETPACK(self);
 710                 float has_fuel = !PHYS_JETPACK_FUEL || PHYS_AMMO_FUEL(self) || ITEMS_STAT(self) & IT_UNLIMITED_WEAPON_AMMO;
 711
 712                 if (!(ITEMS_STAT(self) & ITEM_Jetpack.m_itemid)) { }
 713                 else if (self.jetpack_stopped) { }
 714                 else if (!has_fuel)
 715                 {
 716 #ifdef SVQC
 717                         if (was_flying) // TODO: ran out of fuel message
 718                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
 719                         else if (activate)
 720                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_JETPACK_NOFUEL);
 721 #endif
 722                         self.jetpack_stopped = true;
 723                         ITEMS_STAT(self) &= ~IT_USING_JETPACK;
 724                 }
 725                 else if (activate && !PHYS_FROZEN(self))
 726                         ITEMS_STAT(self) |= IT_USING_JETPACK;
 727         }
 728         else
 729         {
 730                 self.jetpack_stopped = false;
 731                 ITEMS_STAT(self) &= ~IT_USING_JETPACK;
 732         }
 733         if (!PHYS_INPUT_BUTTON_JUMP(self))
 734                 UNSET_JUMP_HELD(self);
 735
 736         if (self.waterlevel == WATERLEVEL_SWIMMING)
 737                 CheckWaterJump();
 738 }
 739
 740 float racecar_angle(float forward, float down)
 741 {
 742         if (forward < 0)
 743         {
 744                 forward = -forward;
 745                 down = -down;
 746         }
 747
 748         float ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 749
 750         float angle_mult = forward / (800 + forward);
 751
 752         if (ret > 180)
 753                 return ret * angle_mult + 360 * (1 - angle_mult);
 754         else
 755                 return ret * angle_mult;
 756 }
 757
 758 void RaceCarPhysics()
 759 {SELFPARAM();
 760 #ifdef SVQC
 761         // using this move type for "big rigs"
 762         // the engine does not push the entity!
 763
 764         vector rigvel;
 765
 766         vector angles_save = self.angles;
 767         float accel = bound(-1, self.movement.x / PHYS_MAXSPEED(self), 1);
 768         float steer = bound(-1, self.movement.y / PHYS_MAXSPEED(self), 1);
 769
 770         if (g_bugrigs_reverse_speeding)
 771         {
 772                 if (accel < 0)
 773                 {
 774                         // back accel is DIGITAL
 775                         // to prevent speedhack
 776                         if (accel < -0.5)
 777                                 accel = -1;
 778                         else
 779                                 accel = 0;
 780                 }
 781         }
 782
 783         self.angles_x = 0;
 784         self.angles_z = 0;
 785         makevectors(self.angles); // new forward direction!
 786
 787         if (IS_ONGROUND(self) || g_bugrigs_air_steering)
 788         {
 789                 float myspeed = self.velocity * v_forward;
 790                 float upspeed = self.velocity * v_up;
 791
 792                 // responsiveness factor for steering and acceleration
 793                 float f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 794                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 795
 796                 float steerfactor;
 797                 if (myspeed < 0 && g_bugrigs_reverse_spinning)
 798                         steerfactor = -myspeed * g_bugrigs_steer;
 799                 else
 800                         steerfactor = -myspeed * f * g_bugrigs_steer;
 801
 802                 float accelfactor;
 803                 if (myspeed < 0 && g_bugrigs_reverse_speeding)
 804                         accelfactor = g_bugrigs_accel;
 805                 else
 806                         accelfactor = f * g_bugrigs_accel;
 807                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 808
 809                 if (accel < 0)
 810                 {
 811                         if (myspeed > 0)
 812                         {
 813                                 myspeed = max(0, myspeed - PHYS_INPUT_TIMELENGTH * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 814                         }
 815                         else
 816                         {
 817                                 if (!g_bugrigs_reverse_speeding)
 818                                         myspeed = min(0, myspeed + PHYS_INPUT_TIMELENGTH * g_bugrigs_friction_floor);
 819                         }
 820                 }
 821                 else
 822                 {
 823                         if (myspeed >= 0)
 824                         {
 825                                 myspeed = max(0, myspeed - PHYS_INPUT_TIMELENGTH * g_bugrigs_friction_floor);
 826                         }
 827                         else
 828                         {
 829                                 if (g_bugrigs_reverse_stopping)
 830                                         myspeed = 0;
 831                                 else
 832                                         myspeed = min(0, myspeed + PHYS_INPUT_TIMELENGTH * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 833                         }
 834                 }
 835                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 836                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 837
 838                 self.angles_y += steer * PHYS_INPUT_TIMELENGTH * steerfactor; // apply steering
 839                 makevectors(self.angles); // new forward direction!
 840
 841                 myspeed += accel * accelfactor * PHYS_INPUT_TIMELENGTH;
 842
 843                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 844         }
 845         else
 846         {
 847                 float myspeed = vlen(self.velocity);
 848
 849                 // responsiveness factor for steering and acceleration
 850                 float f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 851                 float steerfactor = -myspeed * f;
 852                 self.angles_y += steer * PHYS_INPUT_TIMELENGTH * steerfactor; // apply steering
 853
 854                 rigvel = self.velocity;
 855                 makevectors(self.angles); // new forward direction!
 856         }
 857
 858         rigvel *= max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * PHYS_INPUT_TIMELENGTH);
 859         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 860         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 861         //MAXIMA: solve(total_acceleration(v) = 0, v);
 862
 863         if (g_bugrigs_planar_movement)
 864         {
 865                 vector rigvel_xy, neworigin, up;
 866                 float mt;
 867
 868                 rigvel_z -= PHYS_INPUT_TIMELENGTH * PHYS_GRAVITY; // 4x gravity plays better
 869                 rigvel_xy = vec2(rigvel);
 870
 871                 if (g_bugrigs_planar_movement_car_jumping)
 872                         mt = MOVE_NORMAL;
 873                 else
 874                         mt = MOVE_NOMONSTERS;
 875
 876                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 877                 up = trace_endpos - self.origin;
 878
 879                 // BUG RIGS: align the move to the surface instead of doing collision testing
 880                 // can we move?
 881                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * PHYS_INPUT_TIMELENGTH, mt, self);
 882
 883                 // align to surface
 884                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * PHYS_INPUT_TIMELENGTH, mt, self);
 885
 886                 if (trace_fraction < 0.5)
 887                 {
 888                         trace_fraction = 1;
 889                         neworigin = self.origin;
 890                 }
 891                 else
 892                         neworigin = trace_endpos;
 893
 894                 if (trace_fraction < 1)
 895                 {
 896                         // now set angles_x so that the car points parallel to the surface
 897                         self.angles = vectoangles(
 898                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 899                                         +
 900                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 901                                         +
 902                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 903                                         );
 904                         SET_ONGROUND(self);
 905                 }
 906                 else
 907                 {
 908                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 909                         UNSET_ONGROUND(self);
 910                 }
 911
 912                 self.velocity = (neworigin - self.origin) * (1.0 / PHYS_INPUT_TIMELENGTH);
 913                 self.movetype = MOVETYPE_NOCLIP;
 914         }
 915         else
 916         {
 917                 rigvel_z -= PHYS_INPUT_TIMELENGTH * PHYS_GRAVITY; // 4x gravity plays better
 918                 self.velocity = rigvel;
 919                 self.movetype = MOVETYPE_FLY;
 920         }
 921
 922         trace_fraction = 1;
 923         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 924         if (trace_fraction != 1)
 925         {
 926                 self.angles = vectoangles2(
 927                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 928                                 +
 929                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 930                                 +
 931                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 932                                 trace_plane_normal
 933                                 );
 934         }
 935         else
 936         {
 937                 vector vel_local;
 938
 939                 vel_local_x = v_forward * self.velocity;
 940                 vel_local_y = v_right * self.velocity;
 941                 vel_local_z = v_up * self.velocity;
 942
 943                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 944                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 945         }
 946
 947         // smooth the angles
 948         vector vf1, vu1, smoothangles;
 949         makevectors(self.angles);
 950         float f = bound(0, PHYS_INPUT_TIMELENGTH * g_bugrigs_angle_smoothing, 1);
 951         if (f == 0)
 952                 f = 1;
 953         vf1 = v_forward * f;
 954         vu1 = v_up * f;
 955         makevectors(angles_save);
 956         vf1 = vf1 + v_forward * (1 - f);
 957         vu1 = vu1 + v_up * (1 - f);
 958         smoothangles = vectoangles2(vf1, vu1);
 959         self.angles_x = -smoothangles_x;
 960         self.angles_z =  smoothangles_z;
 961 #endif
 962 }
 963
 964 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 965 .float specialcommand_pos;
 966 void SpecialCommand()
 967 {
 968 #ifdef SVQC
 969 #ifdef TETRIS
 970         TetrisImpulse();
 971 #else
 972         if (!CheatImpulse(99))
 973                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 974 #endif
 975 #endif
 976 }
 977
 978 float PM_check_specialcommand(float buttons)
 979 {SELFPARAM();
 980 #ifdef SVQC
 981         string c;
 982         if (!buttons)
 983                 c = "x";
 984         else if (buttons == 1)
 985                 c = "1";
 986         else if (buttons == 2)
 987                 c = " ";
 988         else if (buttons == 128)
 989                 c = "s";
 990         else if (buttons == 256)
 991                 c = "w";
 992         else if (buttons == 512)
 993                 c = "a";
 994         else if (buttons == 1024)
 995                 c = "d";
 996         else
 997                 c = "?";
 998
 999         if (c == substring(specialcommand, self.specialcommand_pos, 1))
1000         {
1001                 self.specialcommand_pos += 1;
1002                 if (self.specialcommand_pos >= strlen(specialcommand))
1003                 {
1004                         self.specialcommand_pos = 0;
1005                         SpecialCommand();
1006                         return true;
1007                 }
1008         }
1009         else if (self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
1010                 self.specialcommand_pos = 0;
1011 #endif
1012         return false;
1013 }
1014
1015 void PM_check_nickspam()
1016 {SELFPARAM();
1017 #ifdef SVQC
1018         if (time >= self.nickspamtime)
1019                 return;
1020         if (self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
1021         {
1022                 // slight annoyance for nick change scripts
1023                 self.movement = -1 * self.movement;
1024                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
1025
1026                 if (self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
1027                 {
1028                         self.v_angle_x = random() * 360;
1029                         self.v_angle_y = random() * 360;
1030                         // at least I'm not forcing retardedview by also assigning to angles_z
1031                         self.fixangle = true;
1032                 }
1033         }
1034 #endif
1035 }
1036
1037 void PM_check_punch()
1038 {SELFPARAM();
1039 #ifdef SVQC
1040         if (self.punchangle != '0 0 0')
1041         {
1042                 float f = vlen(self.punchangle) - 10 * PHYS_INPUT_TIMELENGTH;
1043                 if (f > 0)
1044                         self.punchangle = normalize(self.punchangle) * f;
1045                 else
1046                         self.punchangle = '0 0 0';
1047         }
1048
1049         if (self.punchvector != '0 0 0')
1050         {
1051                 float f = vlen(self.punchvector) - 30 * PHYS_INPUT_TIMELENGTH;
1052                 if (f > 0)
1053                         self.punchvector = normalize(self.punchvector) * f;
1054                 else
1055                         self.punchvector = '0 0 0';
1056         }
1057 #endif
1058 }
1059
1060 void PM_check_spider()
1061 {SELFPARAM();
1062 #ifdef SVQC
1063         if (time >= self.spider_slowness)
1064                 return;
1065         PHYS_MAXSPEED(self) *= 0.5; // half speed while slow from spider
1066         PHYS_MAXAIRSPEED(self) *= 0.5;
1067         PHYS_AIRSPEEDLIMIT_NONQW(self) *= 0.5;
1068         PHYS_AIRSTRAFEACCELERATE(self) *= 0.5;
1069 #endif
1070 }
1071
1072 // predict frozen movement, as frozen players CAN move in some cases
1073 void PM_check_frozen()
1074 {SELFPARAM();
1075         if (!PHYS_FROZEN(self))
1076                 return;
1077         if (PHYS_DODGING_FROZEN
1078 #ifdef SVQC
1079         && IS_REAL_CLIENT(self)
1080 #endif
1081         )
1082         {
1083                 self.movement_x = bound(-5, self.movement.x, 5);
1084                 self.movement_y = bound(-5, self.movement.y, 5);
1085                 self.movement_z = bound(-5, self.movement.z, 5);
1086         }
1087         else
1088                 self.movement = '0 0 0';
1089
1090         vector midpoint = ((self.absmin + self.absmax) * 0.5);
1091         if (pointcontents(midpoint) == CONTENT_WATER)
1092         {
1093                 self.velocity = self.velocity * 0.5;
1094
1095                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
1096                         self.velocity_z = 200;
1097         }
1098 }
1099
1100 void PM_check_hitground()
1101 {SELFPARAM();
1102 #ifdef SVQC
1103         if (!IS_PLAYER(this)) return; // no fall sounds for observers thank you very much
1104         if (!IS_ONGROUND(this)) return;
1105         if (!this.wasFlying) return;
1106     this.wasFlying = false;
1107     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
1108     if (time < this.ladder_time) return;
1109     if (this.hook) return;
1110     this.nextstep = time + 0.3 + random() * 0.1;
1111     trace_dphitq3surfaceflags = 0;
1112     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
1113     if ((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)) return;
1114     entity fall = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS) ? GS_FALL_METAL : GS_FALL;
1115     GlobalSound(fall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
1116 #endif
1117 }
1118
1119 void PM_check_blocked()
1120 {SELFPARAM();
1121 #ifdef SVQC
1122         if (!self.player_blocked)
1123                 return;
1124         self.movement = '0 0 0';
1125         self.disableclientprediction = 1;
1126 #endif
1127 }
1128
1129 void PM_check_vortex()
1130 {SELFPARAM();
1131 #ifdef SVQC
1132         // WEAPONTODO
1133         float xyspeed = vlen(vec2(self.velocity));
1134         if (self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && xyspeed > WEP_CVAR(vortex, charge_minspeed))
1135         {
1136                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1137                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
1138                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
1139                 // add the extra charge
1140                 self.vortex_charge = min(1, self.vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
1141         }
1142 #endif
1143 }
1144
1145 void PM_fly(float maxspd_mod)
1146 {SELFPARAM();
1147         // noclipping or flying
1148         UNSET_ONGROUND(self);
1149
1150         self.velocity = self.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION);
1151         makevectors(self.v_angle);
1152         //wishvel = v_forward * self.movement.x + v_right * self.movement.y + v_up * self.movement.z;
1153         vector wishvel = v_forward * self.movement.x
1154                                         + v_right * self.movement.y
1155                                         + '0 0 1' * self.movement.z;
1156         // acceleration
1157         vector wishdir = normalize(wishvel);
1158         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(self) * maxspd_mod);
1159 #ifdef SVQC
1160         if (time >= self.teleport_time)
1161 #endif
1162                 PM_Accelerate(wishdir, wishspeed, wishspeed, PHYS_ACCELERATE * maxspd_mod, 1, 0, 0, 0);
1163         PM_ClientMovement_Move();
1164 }
1165
1166 void PM_swim(float maxspd_mod)
1167 {SELFPARAM();
1168         // swimming
1169         UNSET_ONGROUND(self);
1170
1171         float jump = PHYS_INPUT_BUTTON_JUMP(self);
1172         // water jump only in certain situations
1173         // this mimics quakeworld code
1174         if (jump && self.waterlevel == WATERLEVEL_SWIMMING && self.velocity_z >= -180)
1175         {
1176                 vector yawangles = '0 1 0' * self.v_angle.y;
1177                 makevectors(yawangles);
1178                 vector forward = v_forward;
1179                 vector spot = self.origin + 24 * forward;
1180                 spot_z += 8;
1181                 traceline(spot, spot, MOVE_NOMONSTERS, self);
1182                 if (trace_startsolid)
1183                 {
1184                         spot_z += 24;
1185                         traceline(spot, spot, MOVE_NOMONSTERS, self);
1186                         if (!trace_startsolid)
1187                         {
1188                                 self.velocity = forward * 50;
1189                                 self.velocity_z = 310;
1190                                 pmove_waterjumptime = 2;
1191                                 UNSET_ONGROUND(self);
1192                                 SET_JUMP_HELD(self);
1193                         }
1194                 }
1195         }
1196         makevectors(self.v_angle);
1197         //wishvel = v_forward * self.movement.x + v_right * self.movement.y + v_up * self.movement.z;
1198         vector wishvel = v_forward * self.movement.x
1199                                         + v_right * self.movement.y
1200                                         + '0 0 1' * self.movement.z;
1201         if (wishvel == '0 0 0')
1202                 wishvel = '0 0 -60'; // drift towards bottom
1203
1204         vector wishdir = normalize(wishvel);
1205         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(self) * maxspd_mod) * 0.7;
1206
1207         if (IS_DUCKED(self))
1208         wishspeed *= 0.5;
1209
1210 //      if (pmove_waterjumptime <= 0) // TODO: use
1211     {
1212                 // water friction
1213                 float f = 1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION;
1214                 f = min(max(0, f), 1);
1215                 self.velocity *= f;
1216
1217                 f = wishspeed - self.velocity * wishdir;
1218                 if (f > 0)
1219                 {
1220                         float accelspeed = min(PHYS_ACCELERATE * PHYS_INPUT_TIMELENGTH * wishspeed, f);
1221                         self.velocity += accelspeed * wishdir;
1222                 }
1223
1224                 // holding jump button swims upward slowly
1225                 if (jump)
1226                 {
1227 #if 0
1228                         if (self.watertype & CONTENT_LAVA)
1229                                 self.velocity_z =  50;
1230                         else if (self.watertype & CONTENT_SLIME)
1231                                 self.velocity_z =  80;
1232                         else
1233                         {
1234                                 if (IS_NEXUIZ_DERIVED(gamemode))
1235 #endif
1236                                         self.velocity_z = 200;
1237 #if 0
1238                                 else
1239                                         self.velocity_z = 100;
1240                         }
1241 #endif
1242                 }
1243         }
1244         // water acceleration
1245         PM_Accelerate(wishdir, wishspeed, wishspeed, PHYS_ACCELERATE * maxspd_mod, 1, 0, 0, 0);
1246         PM_ClientMovement_Move();
1247 }
1248
1249 void PM_ladder(float maxspd_mod)
1250 {SELFPARAM();
1251         // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1252         UNSET_ONGROUND(self);
1253
1254         float g;
1255         g = PHYS_GRAVITY * PHYS_INPUT_TIMELENGTH;
1256         if (PHYS_ENTGRAVITY(self))
1257                 g *= PHYS_ENTGRAVITY(self);
1258         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1259         {
1260                 g *= 0.5;
1261                 self.velocity_z += g;
1262         }
1263
1264         self.velocity = self.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION);
1265         makevectors(self.v_angle);
1266         //wishvel = v_forward * self.movement.x + v_right * self.movement.y + v_up * self.movement.z;
1267         vector wishvel = v_forward * self.movement_x
1268                                         + v_right * self.movement_y
1269                                         + '0 0 1' * self.movement_z;
1270         self.velocity_z += g;
1271         if (self.ladder_entity.classname == "func_water")
1272         {
1273                 float f = vlen(wishvel);
1274                 if (f > self.ladder_entity.speed)
1275                         wishvel *= (self.ladder_entity.speed / f);
1276
1277                 self.watertype = self.ladder_entity.skin;
1278                 f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1279                 if ((self.origin_z + self.view_ofs_z) < f)
1280                         self.waterlevel = WATERLEVEL_SUBMERGED;
1281                 else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1282                         self.waterlevel = WATERLEVEL_SWIMMING;
1283                 else if ((self.origin_z + self.mins_z + 1) < f)
1284                         self.waterlevel = WATERLEVEL_WETFEET;
1285                 else
1286                 {
1287                         self.waterlevel = WATERLEVEL_NONE;
1288                         self.watertype = CONTENT_EMPTY;
1289                 }
1290         }
1291         // acceleration
1292         vector wishdir = normalize(wishvel);
1293         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(self) * maxspd_mod);
1294 #ifdef SVQC
1295         if (time >= self.teleport_time)
1296 #endif
1297                 // water acceleration
1298                 PM_Accelerate(wishdir, wishspeed, wishspeed, PHYS_ACCELERATE*maxspd_mod, 1, 0, 0, 0);
1299         PM_ClientMovement_Move();
1300 }
1301
1302 void PM_jetpack(float maxspd_mod)
1303 {SELFPARAM();
1304         //makevectors(self.v_angle.y * '0 1 0');
1305         makevectors(self.v_angle);
1306         vector wishvel = v_forward * self.movement_x
1307                                         + v_right * self.movement_y;
1308         // add remaining speed as Z component
1309         float maxairspd = PHYS_MAXAIRSPEED(self) * max(1, maxspd_mod);
1310         // fix speedhacks :P
1311         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
1312         // add the unused velocity as up component
1313         wishvel_z = 0;
1314
1315         // if (self.BUTTON_JUMP)
1316                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1317
1318         // it is now normalized, so...
1319         float a_side = PHYS_JETPACK_ACCEL_SIDE;
1320         float a_up = PHYS_JETPACK_ACCEL_UP;
1321         float a_add = PHYS_JETPACK_ANTIGRAVITY * PHYS_GRAVITY;
1322
1323         wishvel_x *= a_side;
1324         wishvel_y *= a_side;
1325         wishvel_z *= a_up;
1326         wishvel_z += a_add;
1327
1328         float best = 0;
1329         //////////////////////////////////////////////////////////////////////////////////////
1330         // finding the maximum over all vectors of above form
1331         // with wishvel having an absolute value of 1
1332         //////////////////////////////////////////////////////////////////////////////////////
1333         // we're finding the maximum over
1334         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1335         // for z in the range from -1 to 1
1336         //////////////////////////////////////////////////////////////////////////////////////
1337         // maximum is EITHER attained at the single extreme point:
1338         float a_diff = a_side * a_side - a_up * a_up;
1339         float f;
1340         if (a_diff != 0)
1341         {
1342                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1343                 if (f > -1 && f < 1) // can it be attained?
1344                 {
1345                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1346                         //print("middle\n");
1347                 }
1348         }
1349         // OR attained at z = 1:
1350         f = (a_up + a_add) * (a_up + a_add);
1351         if (f > best)
1352         {
1353                 best = f;
1354                 //print("top\n");
1355         }
1356         // OR attained at z = -1:
1357         f = (a_up - a_add) * (a_up - a_add);
1358         if (f > best)
1359         {
1360                 best = f;
1361                 //print("bottom\n");
1362         }
1363         best = sqrt(best);
1364         //////////////////////////////////////////////////////////////////////////////////////
1365
1366         //print("best possible acceleration: ", ftos(best), "\n");
1367
1368         float fxy, fz;
1369         fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE, 1);
1370         if (wishvel_z - PHYS_GRAVITY > 0)
1371                 fz = bound(0, 1 - self.velocity_z / PHYS_JETPACK_MAXSPEED_UP, 1);
1372         else
1373                 fz = bound(0, 1 + self.velocity_z / PHYS_JETPACK_MAXSPEED_UP, 1);
1374
1375         float fvel;
1376         fvel = vlen(wishvel);
1377         wishvel_x *= fxy;
1378         wishvel_y *= fxy;
1379         wishvel_z = (wishvel_z - PHYS_GRAVITY) * fz + PHYS_GRAVITY;
1380
1381         fvel = min(1, vlen(wishvel) / best);
1382         if (PHYS_JETPACK_FUEL && !(ITEMS_STAT(self) & IT_UNLIMITED_WEAPON_AMMO))
1383                 f = min(1, PHYS_AMMO_FUEL(self) / (PHYS_JETPACK_FUEL * PHYS_INPUT_TIMELENGTH * fvel));
1384         else
1385                 f = 1;
1386
1387         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1388
1389         if (f > 0 && wishvel != '0 0 0')
1390         {
1391                 self.velocity = self.velocity + wishvel * f * PHYS_INPUT_TIMELENGTH;
1392                 UNSET_ONGROUND(self);
1393
1394 #ifdef SVQC
1395                 if (!(ITEMS_STAT(self) & IT_UNLIMITED_WEAPON_AMMO))
1396                         self.ammo_fuel -= PHYS_JETPACK_FUEL * PHYS_INPUT_TIMELENGTH * fvel * f;
1397
1398                 ITEMS_STAT(self) |= IT_USING_JETPACK;
1399
1400                 // jetpack also inhibits health regeneration, but only for 1 second
1401                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1402 #endif
1403         }
1404
1405 #ifdef CSQC
1406         float g = PHYS_GRAVITY * PHYS_ENTGRAVITY(self) * PHYS_INPUT_TIMELENGTH;
1407         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1408                 self.velocity_z -= g * 0.5;
1409         else
1410                 self.velocity_z -= g;
1411         PM_ClientMovement_Move();
1412         if (!IS_ONGROUND(self) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1413                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1414                         self.velocity_z -= g * 0.5;
1415 #endif
1416 }
1417
1418 void PM_walk(float buttons_prev, float maxspd_mod)
1419 {SELFPARAM();
1420         if (!WAS_ONGROUND(self))
1421         {
1422 #ifdef SVQC
1423                 if (autocvar_speedmeter)
1424                         LOG_TRACE(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1425 #endif
1426                 if (self.lastground < time - 0.3)
1427                         self.velocity *= (1 - PHYS_FRICTION_ONLAND);
1428 #ifdef SVQC
1429                 if (self.jumppadcount > 1)
1430                         LOG_TRACE(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1431                 self.jumppadcount = 0;
1432 #endif
1433         }
1434
1435         // walking
1436         makevectors(self.v_angle.y * '0 1 0');
1437         vector wishvel = v_forward * self.movement.x
1438                                         + v_right * self.movement.y;
1439         // acceleration
1440         vector wishdir = normalize(wishvel);
1441         float wishspeed = vlen(wishvel);
1442
1443         wishspeed = min(wishspeed, PHYS_MAXSPEED(self) * maxspd_mod);
1444         if (IS_DUCKED(self))
1445                 wishspeed *= 0.5;
1446
1447         // apply edge friction
1448         float f = vlen(vec2(self.velocity));
1449         if (f > 0)
1450         {
1451                 float realfriction;
1452                 trace_dphitq3surfaceflags = 0;
1453                 tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
1454                 // TODO: apply edge friction
1455                 // apply ground friction
1456                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
1457                         realfriction = PHYS_FRICTION_SLICK;
1458                 else
1459                         realfriction = PHYS_FRICTION;
1460
1461                 f = 1 - PHYS_INPUT_TIMELENGTH * realfriction * ((f < PHYS_STOPSPEED) ? (PHYS_STOPSPEED / f) : 1);
1462                 f = max(0, f);
1463                 self.velocity *= f;
1464                 /*
1465                    Mathematical analysis time!
1466
1467                    Our goal is to invert this mess.
1468
1469                    For the two cases we get:
1470                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * (PHYS_STOPSPEED / v0) * PHYS_FRICTION)
1471                           = v0 - PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED * PHYS_FRICTION
1472                         v0 = v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED * PHYS_FRICTION
1473                    and
1474                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION)
1475                         v0 = v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION)
1476
1477                    These cases would be chosen ONLY if:
1478                         v0 < PHYS_STOPSPEED
1479                         v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED * PHYS_FRICTION < PHYS_STOPSPEED
1480                         v < PHYS_STOPSPEED * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION)
1481                    and, respectively:
1482                         v0 >= PHYS_STOPSPEED
1483                         v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION) >= PHYS_STOPSPEED
1484                         v >= PHYS_STOPSPEED * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION)
1485                  */
1486         }
1487         float addspeed = wishspeed - self.velocity * wishdir;
1488         if (addspeed > 0)
1489         {
1490                 float accelspeed = min(PHYS_ACCELERATE * PHYS_INPUT_TIMELENGTH * wishspeed, addspeed);
1491                 self.velocity += accelspeed * wishdir;
1492         }
1493         float g = PHYS_GRAVITY * PHYS_ENTGRAVITY(self) * PHYS_INPUT_TIMELENGTH;
1494         if (!(GAMEPLAYFIX_NOGRAVITYONGROUND))
1495                 self.velocity_z -= g * (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1);
1496         if (self.velocity * self.velocity)
1497                 PM_ClientMovement_Move();
1498         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1499                 if (!IS_ONGROUND(self) || !GAMEPLAYFIX_NOGRAVITYONGROUND)
1500                         self.velocity_z -= g * 0.5;
1501 }
1502
1503 void PM_air(float buttons_prev, float maxspd_mod)
1504 {SELFPARAM();
1505         makevectors(self.v_angle.y * '0 1 0');
1506         vector wishvel = v_forward * self.movement.x
1507                                         + v_right * self.movement.y;
1508         // acceleration
1509         vector wishdir = normalize(wishvel);
1510         float wishspeed = vlen(wishvel);
1511
1512 #ifdef SVQC
1513         if (time >= self.teleport_time)
1514 #else
1515         if (pmove_waterjumptime <= 0)
1516 #endif
1517         {
1518                 float maxairspd = PHYS_MAXAIRSPEED(self) * min(maxspd_mod, 1);
1519
1520                 // apply air speed limit
1521                 float airaccelqw = PHYS_AIRACCEL_QW(self);
1522                 float wishspeed0 = wishspeed;
1523                 wishspeed = min(wishspeed, maxairspd);
1524                 if (IS_DUCKED(self))
1525                         wishspeed *= 0.5;
1526                 float airaccel = PHYS_AIRACCELERATE * min(maxspd_mod, 1);
1527
1528                 float accelerating = (self.velocity * wishdir > 0);
1529                 float wishspeed2 = wishspeed;
1530
1531                 // CPM: air control
1532                 if (PHYS_AIRSTOPACCELERATE)
1533                 {
1534                         vector curdir = normalize(vec2(self.velocity));
1535                         airaccel += (PHYS_AIRSTOPACCELERATE*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1536                 }
1537                 // note that for straight forward jumping:
1538                 // step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
1539                 // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1540                 // -->
1541                 // dv/dt = accel * maxspeed (when slow)
1542                 // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1543                 // log dv/dt = logaccel + logmaxspeed (when slow)
1544                 // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1545                 float strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1546                 if (PHYS_MAXAIRSTRAFESPEED)
1547                         wishspeed = min(wishspeed, GeomLerp(PHYS_MAXAIRSPEED(self)*maxspd_mod, strafity, PHYS_MAXAIRSTRAFESPEED*maxspd_mod));
1548                 if (PHYS_AIRSTRAFEACCELERATE(self))
1549                         airaccel = GeomLerp(airaccel, strafity, PHYS_AIRSTRAFEACCELERATE(self)*maxspd_mod);
1550                 if (PHYS_AIRSTRAFEACCEL_QW(self))
1551                         airaccelqw =
1552                 (((strafity > 0.5 ? PHYS_AIRSTRAFEACCEL_QW(self) : PHYS_AIRACCEL_QW(self)) >= 0) ? +1 : -1)
1553                 *
1554                 (1 - GeomLerp(1 - fabs(PHYS_AIRACCEL_QW(self)), strafity, 1 - fabs(PHYS_AIRSTRAFEACCEL_QW(self))));
1555                 // !CPM
1556
1557                 if (PHYS_WARSOWBUNNY_TURNACCEL && accelerating && self.movement.y == 0 && self.movement.x != 0)
1558                         PM_AirAccelerate(wishdir, wishspeed2);
1559                 else
1560                         PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, PHYS_AIRACCEL_QW_STRETCHFACTOR(self), PHYS_AIRACCEL_SIDEWAYS_FRICTION / maxairspd, PHYS_AIRSPEEDLIMIT_NONQW(self));
1561
1562                 if (PHYS_AIRCONTROL)
1563                         CPM_PM_Aircontrol(wishdir, wishspeed2);
1564         }
1565         float g = PHYS_GRAVITY * PHYS_ENTGRAVITY(self) * PHYS_INPUT_TIMELENGTH;
1566         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1567                 self.velocity_z -= g * 0.5;
1568         else
1569                 self.velocity_z -= g;
1570         PM_ClientMovement_Move();
1571         if (!IS_ONGROUND(self) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1572                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1573                         self.velocity_z -= g * 0.5;
1574 }
1575
1576 // used for calculating airshots
1577 bool IsFlying(entity a)
1578 {
1579         if(IS_ONGROUND(a))
1580                 return false;
1581         if(a.waterlevel >= WATERLEVEL_SWIMMING)
1582                 return false;
1583         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
1584         if(trace_fraction < 1)
1585                 return false;
1586         return true;
1587 }
1588
1589 void PM_Main()
1590 {SELFPARAM();
1591         int buttons = PHYS_INPUT_BUTTON_MASK(self);
1592 #ifdef CSQC
1593         self.items = getstati(STAT_ITEMS, 0, 24);
1594
1595         self.movement = PHYS_INPUT_MOVEVALUES(self);
1596
1597         vector oldv_angle = self.v_angle;
1598         vector oldangles = self.angles; // we need to save these, as they're abused by other code
1599         self.v_angle = PHYS_INPUT_ANGLES(self);
1600         self.angles = PHYS_WORLD_ANGLES(self);
1601
1602         self.team = myteam + 1; // is this correct?
1603         if (!(PHYS_INPUT_BUTTON_JUMP(self))) // !jump
1604                 UNSET_JUMP_HELD(self); // canjump = true
1605         pmove_waterjumptime -= PHYS_INPUT_TIMELENGTH;
1606
1607         PM_ClientMovement_UpdateStatus(true);
1608 #endif
1609
1610
1611 #ifdef SVQC
1612         WarpZone_PlayerPhysics_FixVAngle();
1613 #endif
1614         float maxspeed_mod = 1;
1615         maxspeed_mod *= PHYS_HIGHSPEED;
1616
1617 #ifdef SVQC
1618         Physics_UpdateStats(maxspeed_mod);
1619
1620         if (self.PlayerPhysplug)
1621                 if (self.PlayerPhysplug())
1622                         return;
1623 #endif
1624
1625 #ifdef SVQC
1626         anticheat_physics();
1627 #endif
1628
1629         if (PM_check_specialcommand(buttons))
1630                 return;
1631 #ifdef SVQC
1632         if (sv_maxidle > 0)
1633         {
1634                 if (buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
1635                         self.parm_idlesince = time;
1636         }
1637 #endif
1638         int buttons_prev = self.buttons_old;
1639         self.buttons_old = buttons;
1640         self.movement_old = self.movement;
1641         self.v_angle_old = self.v_angle;
1642
1643         PM_check_nickspam();
1644
1645         PM_check_punch();
1646 #ifdef SVQC
1647         if (IS_BOT_CLIENT(self))
1648         {
1649                 if (playerdemo_read())
1650                         return;
1651                 bot_think();
1652         }
1653
1654         if (IS_PLAYER(self))
1655 #endif
1656         {
1657                 bool not_allowed_to_move = false;
1658 #ifdef SVQC
1659                 if (time < game_starttime)
1660                         not_allowed_to_move = true;
1661 #endif
1662
1663                 if (not_allowed_to_move)
1664                 {
1665                         self.velocity = '0 0 0';
1666                         self.movetype = MOVETYPE_NONE;
1667 #ifdef SVQC
1668                         self.disableclientprediction = 2;
1669 #endif
1670                 }
1671 #ifdef SVQC
1672                 else if (self.disableclientprediction == 2)
1673                 {
1674                         if (self.movetype == MOVETYPE_NONE)
1675                                 self.movetype = MOVETYPE_WALK;
1676                         self.disableclientprediction = 0;
1677                 }
1678 #endif
1679         }
1680
1681 #ifdef SVQC
1682         if (self.movetype == MOVETYPE_NONE)
1683                 return;
1684
1685         // when we get here, disableclientprediction cannot be 2
1686         self.disableclientprediction = 0;
1687 #endif
1688
1689         viewloc_PlayerPhysics();
1690
1691         PM_check_spider();
1692
1693         PM_check_frozen();
1694
1695         PM_check_blocked();
1696
1697         maxspeed_mod = 1;
1698
1699         if (self.in_swamp)
1700                 maxspeed_mod *= self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
1701
1702         // conveyors: first fix velocity
1703         if (self.conveyor.state)
1704                 self.velocity -= self.conveyor.movedir;
1705
1706 #ifdef SVQC
1707         MUTATOR_CALLHOOK(PlayerPhysics);
1708 #endif
1709 #ifdef CSQC
1710         PM_multijump();
1711 #endif
1712
1713 //      float forcedodge = 1;
1714 //      if(forcedodge) {
1715 //#ifdef CSQC
1716 //              PM_dodging_checkpressedkeys();
1717 //#endif
1718 //              PM_dodging();
1719 //              PM_ClientMovement_Move();
1720 //              return;
1721 //      }
1722
1723 #ifdef SVQC
1724         if (!IS_PLAYER(self))
1725         {
1726                 maxspeed_mod = autocvar_sv_spectator_speed_multiplier;
1727                 if (!self.spectatorspeed)
1728                         self.spectatorspeed = maxspeed_mod;
1729                 if (self.impulse && self.impulse <= 19 || (self.impulse >= 200 && self.impulse <= 209) || (self.impulse >= 220 && self.impulse <= 229))
1730                 {
1731                         if (self.lastclassname != "player")
1732                         {
1733                                 if (self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209))
1734                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
1735                                 else if (self.impulse == 11)
1736                                         self.spectatorspeed = maxspeed_mod;
1737                                 else if (self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229))
1738                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
1739                                 else if (self.impulse >= 1 && self.impulse <= 9)
1740                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
1741                         } // otherwise just clear
1742                         self.impulse = 0;
1743                 }
1744                 maxspeed_mod = self.spectatorspeed;
1745         }
1746
1747         float spd = max(PHYS_MAXSPEED(self), PHYS_MAXAIRSPEED(self)) * maxspeed_mod;
1748         if(self.speed != spd)
1749         {
1750                 self.speed = spd;
1751                 string temps = ftos(spd);
1752                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
1753                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
1754                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
1755                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
1756         }
1757
1758         if(self.stat_jumpspeedcap_min != PHYS_JUMPSPEEDCAP_MIN)
1759         {
1760                 self.stat_jumpspeedcap_min = PHYS_JUMPSPEEDCAP_MIN;
1761                 stuffcmd(self, strcat("cl_jumpspeedcap_min ", PHYS_JUMPSPEEDCAP_MIN, "\n"));
1762         }
1763         if(self.stat_jumpspeedcap_max != PHYS_JUMPSPEEDCAP_MAX)
1764         {
1765                 self.stat_jumpspeedcap_min = PHYS_JUMPSPEEDCAP_MAX;
1766                 stuffcmd(self, strcat("cl_jumpspeedcap_max ", PHYS_JUMPSPEEDCAP_MAX, "\n"));
1767         }
1768 #endif
1769
1770         if(PHYS_DEAD(self))
1771         {
1772                 // handle water here
1773                 vector midpoint = ((self.absmin + self.absmax) * 0.5);
1774                 if(pointcontents(midpoint) == CONTENT_WATER)
1775                 {
1776                         self.velocity = self.velocity * 0.5;
1777
1778                         // do we want this?
1779                         //if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
1780                                 //{ self.velocity_z = 70; }
1781                 }
1782                 goto end;
1783         }
1784
1785 #ifdef SVQC
1786         if (!self.fixangle && !g_bugrigs)
1787                 self.angles = '0 1 0' * self.v_angle.y;
1788 #endif
1789
1790         PM_check_hitground();
1791
1792         if(IsFlying(self))
1793                 self.wasFlying = 1;
1794
1795         if (IS_PLAYER(self))
1796                 CheckPlayerJump();
1797
1798         if (self.flags & FL_WATERJUMP)
1799         {
1800                 self.velocity_x = self.movedir_x;
1801                 self.velocity_y = self.movedir_y;
1802                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
1803                 {
1804                         self.flags &= ~FL_WATERJUMP;
1805                         self.teleport_time = 0;
1806                 }
1807         }
1808
1809 #ifdef SVQC
1810         else if (g_bugrigs && IS_PLAYER(self))
1811                 RaceCarPhysics();
1812 #endif
1813
1814         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY || self.movetype == MOVETYPE_FLY_WORLDONLY || (BUFFS_STAT(self) & BUFF_FLIGHT.m_itemid))
1815                 PM_fly(maxspeed_mod);
1816
1817         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
1818                 PM_swim(maxspeed_mod);
1819
1820         else if (time < self.ladder_time)
1821                 PM_ladder(maxspeed_mod);
1822
1823         else if (ITEMS_STAT(self) & IT_USING_JETPACK)
1824                 PM_jetpack(maxspeed_mod);
1825
1826         else if (IS_ONGROUND(self))
1827                 PM_walk(buttons_prev, maxspeed_mod);
1828
1829         else
1830                 PM_air(buttons_prev, maxspeed_mod);
1831
1832         PM_check_vortex();
1833
1834 :end
1835         if (IS_ONGROUND(self))
1836                 self.lastground = time;
1837
1838         // conveyors: then break velocity again
1839         if(self.conveyor.state)
1840                 self.velocity += self.conveyor.movedir;
1841
1842         self.lastflags = self.flags;
1843
1844         self.lastclassname = self.classname;
1845
1846 #ifdef CSQC
1847         self.v_angle = oldv_angle;
1848         self.angles = oldangles;
1849 #endif
1850 }
1851
1852 #ifdef SVQC
1853 void SV_PlayerPhysics()
1854 #elif defined(CSQC)
1855 void CSQC_ClientMovement_PlayerMove_Frame()
1856 #endif
1857 {SELFPARAM();
1858         PM_Main();
1859
1860 #ifdef CSQC
1861         self.pmove_flags =
1862                         ((self.flags & FL_DUCKED) ? PMF_DUCKED : 0) |
1863                         (!(self.flags & FL_JUMPRELEASED) ? 0 : PMF_JUMP_HELD) |
1864                         ((self.flags & FL_ONGROUND) ? PMF_ONGROUND : 0);
1865 #endif
1866 }