qcsrc/common/triggers/trigger/jumppads.qc

   1 #include "jumppads.qh"
   2 // TODO: split target_push and put it in the target folder
   3 #ifdef SVQC
   4 #include "jumppads.qh"
   5 #include <common/physics/movetypes/movetypes.qh>
   6
   7 void trigger_push_use(entity this, entity actor, entity trigger)
   8 {
   9         if(teamplay)
  10         {
  11                 this.team = actor.team;
  12                 this.SendFlags |= 2;
  13         }
  14 }
  15 #endif
  16
  17 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
  18 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
  19
  20 /*
  21         trigger_push_calculatevelocity
  22
  23         Arguments:
  24           org - origin of the object which is to be pushed
  25           tgt - target entity (can be either a point or a model entity; if it is
  26                 the latter, its midpoint is used)
  27           ht  - jump height, measured from the higher one of org and tgt's midpoint
  28           pushed_entity - object that is to be pushed
  29
  30         Returns: velocity for the jump
  31  */
  32 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht, entity pushed_entity)
  33 {
  34         float grav, sdist, zdist, vs, vz, jumpheight;
  35         vector sdir, torg;
  36
  37         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  38
  39         grav = PHYS_GRAVITY(NULL);
  40         if(pushed_entity && PHYS_ENTGRAVITY(pushed_entity))
  41                 grav *= PHYS_ENTGRAVITY(pushed_entity);
  42
  43         zdist = torg.z - org.z;
  44         sdist = vlen(torg - org - zdist * '0 0 1');
  45         sdir = normalize(torg - org - zdist * '0 0 1');
  46
  47         // how high do we need to push the player?
  48         jumpheight = fabs(ht);
  49         if(zdist > 0)
  50                 jumpheight = jumpheight + zdist;
  51
  52         /*
  53                 STOP.
  54
  55                 You will not understand the following equations anyway...
  56                 But here is what I did to get them.
  57
  58                 I used the functions
  59
  60                   s(t) = t * vs
  61                   z(t) = t * vz - 1/2 grav t^2
  62
  63                 and solved for:
  64
  65                   s(ti) = sdist
  66                   z(ti) = zdist
  67                   max(z, ti) = jumpheight
  68
  69                 From these three equations, you will find the three parameters vs, vz
  70                 and ti.
  71          */
  72
  73         // push him so high...
  74         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  75
  76         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  77         if(ht < 0)
  78                 if(zdist < 0)
  79                         vz = -vz;
  80
  81         vector solution;
  82         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  83         // ALWAYS solvable because jumpheight >= zdist
  84         if(!solution.z)
  85                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  86         if(zdist == 0)
  87                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  88
  89         float flighttime;
  90         if(zdist < 0)
  91         {
  92                 // down-jump
  93                 if(ht < 0)
  94                 {
  95                         // almost straight line type
  96                         // jump apex is before the jump
  97                         // we must take the larger one
  98                         flighttime = solution.y;
  99                 }
 100                 else
 101                 {
 102                         // regular jump
 103                         // jump apex is during the jump
 104                         // we must take the larger one too
 105                         flighttime = solution.y;
 106                 }
 107         }
 108         else
 109         {
 110                 // up-jump
 111                 if(ht < 0)
 112                 {
 113                         // almost straight line type
 114                         // jump apex is after the jump
 115                         // we must take the smaller one
 116                         flighttime = solution.x;
 117                 }
 118                 else
 119                 {
 120                         // regular jump
 121                         // jump apex is during the jump
 122                         // we must take the larger one
 123                         flighttime = solution.y;
 124                 }
 125         }
 126         vs = sdist / flighttime;
 127
 128         // finally calculate the velocity
 129         return sdir * vs + '0 0 1' * vz;
 130 }
 131
 132 bool jumppad_push(entity this, entity targ)
 133 {
 134         if (!isPushable(targ))
 135                 return false;
 136
 137         if(this.enemy)
 138         {
 139                 targ.velocity = trigger_push_calculatevelocity(targ.origin, this.enemy, this.height, targ);
 140         }
 141         else if(this.target && this.target != "")
 142         {
 143                 entity e;
 144                 RandomSelection_Init();
 145                 for(e = NULL; (e = find(e, targetname, this.target)); )
 146                 {
 147                         if(e.cnt)
 148                                 RandomSelection_AddEnt(e, e.cnt, 1);
 149                         else
 150                                 RandomSelection_AddEnt(e, 1, 1);
 151                 }
 152                 targ.velocity = trigger_push_calculatevelocity(targ.origin, RandomSelection_chosen_ent, this.height, targ);
 153         }
 154         else
 155         {
 156                 targ.velocity = this.movedir;
 157         }
 158
 159         UNSET_ONGROUND(targ);
 160
 161 #ifdef CSQC
 162         if (targ.flags & FL_PROJECTILE)
 163         {
 164                 targ.angles = vectoangles (targ.velocity);
 165                 switch(targ.move_movetype)
 166                 {
 167                         case MOVETYPE_FLY:
 168                                 set_movetype(targ, MOVETYPE_TOSS);
 169                                 targ.gravity = 1;
 170                                 break;
 171                         case MOVETYPE_BOUNCEMISSILE:
 172                                 set_movetype(targ, MOVETYPE_BOUNCE);
 173                                 targ.gravity = 1;
 174                                 break;
 175                 }
 176         }
 177 #endif
 178
 179 #ifdef SVQC
 180         if (IS_PLAYER(targ))
 181         {
 182                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 183                 targ.oldvelocity = targ.velocity;
 184
 185                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 186                 {
 187                         // flash when activated
 188                         Send_Effect(EFFECT_JUMPPAD, targ.origin, targ.velocity, 1);
 189                         _sound (targ, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 190                         this.pushltime = time + 0.2;
 191                 }
 192                 if(IS_REAL_CLIENT(targ) || IS_BOT_CLIENT(targ))
 193                 {
 194                         bool found = false;
 195                         for(int i = 0; i < targ.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 196                                 if(targ.(jumppadsused[i]) == this)
 197                                         found = true;
 198                         if(!found)
 199                         {
 200                                 targ.(jumppadsused[targ.jumppadcount % NUM_JUMPPADSUSED]) = this;
 201                                 targ.jumppadcount = targ.jumppadcount + 1;
 202                         }
 203
 204                         if(IS_REAL_CLIENT(targ))
 205                         {
 206                                 if(this.message)
 207                                         centerprint(targ, this.message);
 208                         }
 209                         else
 210                         {
 211                                 targ.lastteleporttime = time;
 212                                 targ.lastteleport_origin = targ.origin;
 213                         }
 214
 215                         if (!IS_DEAD(targ))
 216                                 animdecide_setaction(targ, ANIMACTION_JUMP, true);
 217                 }
 218                 else
 219                         targ.jumppadcount = true;
 220
 221                 // reset tracking of who pushed you into a hazard (for kill credit)
 222                 targ.pushltime = 0;
 223                 targ.istypefrag = 0;
 224         }
 225
 226         if(this.enemy.target)
 227                 SUB_UseTargets(this.enemy, targ, this);
 228
 229         if (targ.flags & FL_PROJECTILE)
 230         {
 231                 targ.angles = vectoangles (targ.velocity);
 232                 targ.com_phys_gravity_factor = 1;
 233                 switch(targ.move_movetype)
 234                 {
 235                         case MOVETYPE_FLY:
 236                                 set_movetype(targ, MOVETYPE_TOSS);
 237                                 targ.gravity = 1;
 238                                 break;
 239                         case MOVETYPE_BOUNCEMISSILE:
 240                                 set_movetype(targ, MOVETYPE_BOUNCE);
 241                                 targ.gravity = 1;
 242                                 break;
 243                 }
 244                 UpdateCSQCProjectile(targ);
 245         }
 246 #endif
 247
 248         return true;
 249 }
 250
 251 void trigger_push_touch(entity this, entity toucher)
 252 {
 253         if (this.active == ACTIVE_NOT)
 254                 return;
 255
 256         if(this.team)
 257                 if(((this.spawnflags & 4) == 0) == (DIFF_TEAM(this, toucher)))
 258                         return;
 259
 260         EXACTTRIGGER_TOUCH(this, toucher);
 261
 262         noref bool success = jumppad_push(this, toucher);
 263
 264 #ifdef SVQC
 265         if (success && (this.spawnflags & PUSH_ONCE))
 266         {
 267                 settouch(this, func_null);
 268                 setthink(this, SUB_Remove);
 269                 this.nextthink = time;
 270         }
 271 #endif
 272 }
 273
 274 #ifdef SVQC
 275 void trigger_push_link(entity this);
 276 void trigger_push_updatelink(entity this);
 277 bool trigger_push_testorigin(entity tracetest_ent, entity targ, entity jp, vector org)
 278 {
 279         setorigin(tracetest_ent, org);
 280         tracetoss(tracetest_ent, tracetest_ent);
 281         if(trace_startsolid)
 282                 return false;
 283
 284         if (!jp.height)
 285         {
 286                 // since tracetoss starting from jumppad's origin often fails when target
 287                 // is very close to real destination, start it directly from target's
 288                 // origin instead
 289                 vector ofs = '0 0 0';
 290                 if (vdist(vec2(tracetest_ent.velocity), <, autocvar_sv_maxspeed))
 291                         ofs = stepheightvec;
 292
 293                 tracetest_ent.velocity.z = 0;
 294                 setorigin(tracetest_ent, targ.origin + ofs);
 295                 tracetoss(tracetest_ent, tracetest_ent);
 296                 if (trace_startsolid && ofs.z)
 297                 {
 298                         setorigin(tracetest_ent, targ.origin + ofs / 2);
 299                         tracetoss(tracetest_ent, tracetest_ent);
 300                         if (trace_startsolid && ofs.z)
 301                         {
 302                                 setorigin(tracetest_ent, targ.origin);
 303                                 tracetoss(tracetest_ent, tracetest_ent);
 304                                 if (trace_startsolid)
 305                                         return false;
 306                         }
 307                 }
 308         }
 309         tracebox(trace_endpos, tracetest_ent.mins, tracetest_ent.maxs, trace_endpos - eZ * 1500, true, tracetest_ent);
 310         return true;
 311 }
 312 #endif
 313 void trigger_push_findtarget(entity this)
 314 {
 315         // first calculate a typical start point for the jump
 316         vector org = (this.absmin + this.absmax) * 0.5;
 317         org.z = this.absmax.z - PL_MIN_CONST.z - 10;
 318
 319         if (this.target)
 320         {
 321                 int n = 0;
 322 #ifdef SVQC
 323                 vector vel = '0 0 0';
 324 #endif
 325                 for(entity t = NULL; (t = find(t, targetname, this.target)); )
 326                 {
 327                         ++n;
 328 #ifdef SVQC
 329                         if(t.move_movetype != MOVETYPE_NONE)
 330                                 continue;
 331
 332                         entity e = spawn();
 333                         setsize(e, PL_MIN_CONST, PL_MAX_CONST);
 334                         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 335                         e.velocity = trigger_push_calculatevelocity(org, t, this.height, e);
 336                         vel = e.velocity;
 337                         vector best_target = '0 0 0';
 338                         vector best_org = '0 0 0';
 339                         vector best_vel = '0 0 0';
 340                         bool valid_best_target = false;
 341                         if (trigger_push_testorigin(e, t, this, org))
 342                         {
 343                                 best_target = trace_endpos;
 344                                 best_org = org;
 345                                 best_vel = e.velocity;
 346                                 valid_best_target = true;
 347                         }
 348
 349                         vector new_org;
 350                         vector dist = t.origin - org;
 351                         if (dist.x || dist.y) // if not perfectly vertical
 352                         {
 353                                 // test trajectory with different starting points, sometimes the trajectory
 354                                 // starting from the jumppad origin can't reach the real destination
 355                                 // and destination waypoint ends up near the jumppad itself
 356                                 vector flatdir = normalize(dist - eZ * dist.z);
 357                                 vector ofs = flatdir * 0.5 * min(fabs(this.absmax.x - this.absmin.x), fabs(this.absmax.y - this.absmin.y));
 358                                 new_org = org + ofs;
 359                                 e.velocity = trigger_push_calculatevelocity(new_org, t, this.height, e);
 360                                 vel = e.velocity;
 361                                 if (vdist(vec2(e.velocity), <, autocvar_sv_maxspeed))
 362                                         e.velocity = autocvar_sv_maxspeed * flatdir;
 363                                 if (trigger_push_testorigin(e, t, this, new_org) && (!valid_best_target || trace_endpos.z > best_target.z + 50))
 364                                 {
 365                                         best_target = trace_endpos;
 366                                         best_org = new_org;
 367                                         best_vel = vel;
 368                                         valid_best_target = true;
 369                                 }
 370                                 new_org = org - ofs;
 371                                 e.velocity = trigger_push_calculatevelocity(new_org, t, this.height, e);
 372                                 vel = e.velocity;
 373                                 if (vdist(vec2(e.velocity), <, autocvar_sv_maxspeed))
 374                                         e.velocity = autocvar_sv_maxspeed * flatdir;
 375                                 if (trigger_push_testorigin(e, t, this, new_org) && (!valid_best_target || trace_endpos.z > best_target.z + 50))
 376                                 {
 377                                         best_target = trace_endpos;
 378                                         best_org = new_org;
 379                                         best_vel = vel;
 380                                         valid_best_target = true;
 381                                 }
 382                         }
 383
 384                         if (valid_best_target)
 385                         {
 386                                 if (!(boxesoverlap(this.absmin, this.absmax + eZ * 50, best_target + PL_MIN_CONST, best_target + PL_MAX_CONST)))
 387                                 {
 388                                         float velxy = vlen(vec2(best_vel));
 389                                         float cost = vlen(vec2(t.origin - best_org)) / velxy;
 390                                         if(velxy < autocvar_sv_maxspeed)
 391                                                 velxy = autocvar_sv_maxspeed;
 392                                         cost += vlen(vec2(best_target - t.origin)) / velxy;
 393                                         waypoint_spawnforteleporter(this, best_target, cost, e);
 394                                 }
 395                         }
 396                         delete(e);
 397 #endif
 398                 }
 399
 400                 if(!n)
 401                 {
 402                         // no dest!
 403 #ifdef SVQC
 404                         objerror (this, "Jumppad with nonexistant target");
 405 #endif
 406                         return;
 407                 }
 408                 else if(n == 1)
 409                 {
 410                         // exactly one dest - bots love that
 411                         this.enemy = find(NULL, targetname, this.target);
 412                 }
 413                 else
 414                 {
 415                         // have to use random selection every single time
 416                         this.enemy = NULL;
 417                 }
 418         }
 419 #ifdef SVQC
 420         else
 421         {
 422                 entity e = spawn();
 423                 setsize(e, PL_MIN_CONST, PL_MAX_CONST);
 424                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 425                 setorigin(e, org);
 426                 e.velocity = this.movedir;
 427                 tracetoss(e, e);
 428                 if (!(boxesoverlap(this.absmin, this.absmax + eZ * 50, trace_endpos + PL_MIN_CONST, trace_endpos + PL_MAX_CONST)))
 429                         waypoint_spawnforteleporter(this, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity), e);
 430                 delete(e);
 431         }
 432
 433         defer(this, 0.1, trigger_push_updatelink);
 434 #endif
 435 }
 436
 437 #ifdef SVQC
 438 float trigger_push_send(entity this, entity to, float sf)
 439 {
 440         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 441
 442         WriteByte(MSG_ENTITY, this.team);
 443         WriteInt24_t(MSG_ENTITY, this.spawnflags);
 444         WriteByte(MSG_ENTITY, this.active);
 445         WriteCoord(MSG_ENTITY, this.height);
 446
 447         WriteCoord(MSG_ENTITY, this.movedir_x);
 448         WriteCoord(MSG_ENTITY, this.movedir_y);
 449         WriteCoord(MSG_ENTITY, this.movedir_z);
 450
 451         trigger_common_write(this, true);
 452
 453         return true;
 454 }
 455
 456 void trigger_push_updatelink(entity this)
 457 {
 458         this.SendFlags |= 1;
 459 }
 460
 461 void trigger_push_link(entity this)
 462 {
 463         trigger_link(this, trigger_push_send);
 464 }
 465
 466 /*
 467  * ENTITY PARAMETERS:
 468  *
 469  *   target:  target of jump
 470  *   height:  the absolute value is the height of the highest point of the jump
 471  *            trajectory above the higher one of the player and the target.
 472  *            the sign indicates whether the highest point is INSIDE (positive)
 473  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 474  *            positive values for targets mounted on the floor, and use negative
 475  *            values to target a point on the ceiling.
 476  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 477  */
 478 spawnfunc(trigger_push)
 479 {
 480         SetMovedir(this);
 481
 482         trigger_init(this);
 483
 484         this.active = ACTIVE_ACTIVE;
 485         this.use = trigger_push_use;
 486         settouch(this, trigger_push_touch);
 487
 488         // normal push setup
 489         if (!this.speed)
 490                 this.speed = 1000;
 491         this.movedir = this.movedir * this.speed * 10;
 492
 493         if (!this.noise)
 494                 this.noise = "misc/jumppad.wav";
 495         precache_sound (this.noise);
 496
 497         trigger_push_link(this); // link it now
 498
 499         // this must be called to spawn the teleport waypoints for bots
 500         InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
 501 }
 502
 503
 504 bool target_push_send(entity this, entity to, float sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 507
 508         WriteByte(MSG_ENTITY, this.cnt);
 509         WriteString(MSG_ENTITY, this.targetname);
 510         WriteCoord(MSG_ENTITY, this.origin_x);
 511         WriteCoord(MSG_ENTITY, this.origin_y);
 512         WriteCoord(MSG_ENTITY, this.origin_z);
 513
 514         WriteAngle(MSG_ENTITY, this.angles_x);
 515         WriteAngle(MSG_ENTITY, this.angles_y);
 516         WriteAngle(MSG_ENTITY, this.angles_z);
 517
 518         return true;
 519 }
 520
 521 void target_push_use(entity this, entity actor, entity trigger)
 522 {
 523         if(trigger.classname == "trigger_push" || trigger == this)
 524                 return; // WTF, why is this a thing
 525
 526         jumppad_push(this, actor);
 527 }
 528
 529 void target_push_link(entity this)
 530 {
 531         BITSET_ASSIGN(this.effects, EF_NODEPTHTEST);
 532         Net_LinkEntity(this, false, 0, target_push_send);
 533         //this.SendFlags |= 1; // update
 534 }
 535
 536 void target_push_init(entity this)
 537 {
 538         this.mangle = this.angles;
 539         setorigin(this, this.origin);
 540         target_push_link(this);
 541 }
 542
 543 void target_push_init2(entity this)
 544 {
 545         if(this.target && this.target != "") // we have an old style pusher!
 546         {
 547                 InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
 548                 this.use = target_push_use;
 549         }
 550
 551         target_push_init(this); // normal push target behaviour can be combined with a legacy pusher?
 552 }
 553
 554 spawnfunc(target_push) { target_push_init2(this); }
 555 spawnfunc(info_notnull) { target_push_init(this); }
 556 spawnfunc(target_position) { target_push_init(this); }
 557
 558 #elif defined(CSQC)
 559
 560 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
 561 {
 562         this.classname = "jumppad";
 563         int mytm = ReadByte(); if(mytm) { this.team = mytm - 1; }
 564         this.spawnflags = ReadInt24_t();
 565         this.active = ReadByte();
 566         this.height = ReadCoord();
 567
 568         this.movedir_x = ReadCoord();
 569         this.movedir_y = ReadCoord();
 570         this.movedir_z = ReadCoord();
 571
 572         trigger_common_read(this, true);
 573
 574         this.entremove = trigger_remove_generic;
 575         this.solid = SOLID_TRIGGER;
 576         settouch(this, trigger_push_touch);
 577         this.move_time = time;
 578         defer(this, 0.25, trigger_push_findtarget);
 579
 580         return true;
 581 }
 582
 583 void target_push_remove(entity this)
 584 {
 585         //if(this.classname)
 586                 //strunzone(this.classname);
 587         //this.classname = string_null;
 588
 589         if(this.targetname)
 590                 strunzone(this.targetname);
 591         this.targetname = string_null;
 592 }
 593
 594 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
 595 {
 596         this.classname = "push_target";
 597         this.cnt = ReadByte();
 598         this.targetname = strzone(ReadString());
 599         this.origin_x = ReadCoord();
 600         this.origin_y = ReadCoord();
 601         this.origin_z = ReadCoord();
 602
 603         this.angles_x = ReadAngle();
 604         this.angles_y = ReadAngle();
 605         this.angles_z = ReadAngle();
 606
 607         return = true;
 608
 609         setorigin(this, this.origin);
 610
 611         this.drawmask = MASK_NORMAL;
 612         this.entremove = target_push_remove;
 613 }
 614 #endif