qcsrc/common/triggers/trigger/secret.qc

   1 #include "secret.qh"
   2 #if defined(CSQC)
   3 #elif defined(MENUQC)
   4 #elif defined(SVQC)
   5     #include <common/util.qh>
   6     #include <server/defs.qh>
   7 #endif
   8
   9 #ifdef SVQC
  10
  11 void secrets_setstatus(entity this)
  12 {
  13         this.stat_secrets_total = secrets_total;
  14         this.stat_secrets_found = secrets_found;
  15 }
  16
  17 /**
  18  * A secret has been found (maybe :P)
  19  */
  20 void trigger_secret_touch(entity this, entity toucher)
  21 {
  22         // only a player can trigger this
  23         if (!IS_PLAYER(toucher))
  24                 return;
  25
  26         // update secrets found counter
  27         secrets_found += 1;
  28         //print("Secret found: ", ftos(secret_counter.cnt), "/");
  29         //print(ftos(secret_counter.count), "\n");
  30
  31         // centerprint message (multi_touch() doesn't always call centerprint())
  32         centerprint(toucher, this.message);
  33         this.message = "";
  34
  35         // handle normal trigger features
  36         multi_touch(this, toucher);
  37         // we can't just delete(this) here, because this is a touch function
  38         // called while C code is looping through area links...
  39         //delete(this);
  40 }
  41
  42 /*QUAKED trigger_secret (.5 .5 .5) ?
  43 Variable sized secret trigger. Can be targeted at one or more entities.
  44 Basically, it's a trigger_once (with restrictions, see notes) that additionally updates the number of secrets found.
  45 -------- KEYS --------
  46 sounds: 1 to play misc/secret.wav, 2 to play misc/talk.wav, 3 to play misc/trigger1.wav (default: 1)
  47 noise: path to sound file, if you want to play something else
  48 target: trigger all entities with this targetname when triggered
  49 message: print this message to the player who activated the trigger instead of the standard 'You found a secret!'
  50 killtarget: remove all entities with this targetname when triggered
  51 -------- NOTES --------
  52 You should create a common/trigger textured brush covering the entrance to a secret room/area.
  53 Trigger secret can only be trigger by a player's touch and can not be a target itself.
  54 */
  55 spawnfunc(trigger_secret)
  56 {
  57         // FIXME: should it be disabled in most modes?
  58
  59         // update secrets count
  60         secrets_total += 1;
  61
  62         // add default message
  63         if (this.message == "")
  64                 this.message = "You found a secret!";
  65
  66         // set default sound
  67         if (this.noise == "")
  68         if (!this.sounds)
  69                 this.sounds = 1; // misc/secret.wav
  70
  71         // this entity can't be a target itself!!!!
  72         this.targetname = "";
  73
  74         // you can't just shoot a room to find it, can you?
  75         this.health = 0;
  76
  77         // a secret can not be delayed
  78         this.delay = 0;
  79
  80         // convert this trigger to trigger_once
  81         //this.classname = "trigger_once";
  82         spawnfunc_trigger_once(this);
  83
  84         // take over the touch() function, so we can mark secret as found
  85         settouch(this, trigger_secret_touch);
  86         // ignore triggering;
  87         this.use = func_null;
  88 }
  89 #endif