qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 string unescape(string in)
  43 {
  44         local float i, len;
  45         local string str, s;
  46
  47         // but it doesn't seem to be necessary in my tests at least
  48         in = strzone(in);
  49
  50         len = strlen(in);
  51         str = "";
  52         for(i = 0; i < len; ++i)
  53         {
  54                 s = substring(in, i, 1);
  55                 if(s == "\\")
  56                 {
  57                         s = substring(in, i+1, 1);
  58                         if(s == "n")
  59                                 str = strcat(str, "\n");
  60                         else if(s == "\\")
  61                                 str = strcat(str, "\\");
  62                         else
  63                                 str = strcat(str, substring(in, i, 2));
  64                         ++i;
  65                 } else
  66                         str = strcat(str, s);
  67         }
  68
  69         strunzone(in);
  70         return str;
  71 }
  72
  73 void wordwrap_cb(string s, float l, void(string) callback)
  74 {
  75         local string c;
  76         local float lleft, i, j, wlen;
  77
  78         s = strzone(s);
  79         lleft = l;
  80         for (i = 0;i < strlen(s);++i)
  81         {
  82                 if (substring(s, i, 2) == "\\n")
  83                 {
  84                         callback("\n");
  85                         lleft = l;
  86                         ++i;
  87                 }
  88                 else if (substring(s, i, 1) == "\n")
  89                 {
  90                         callback("\n");
  91                         lleft = l;
  92                 }
  93                 else if (substring(s, i, 1) == " ")
  94                 {
  95                         if (lleft > 0)
  96                         {
  97                                 callback(" ");
  98                                 lleft = lleft - 1;
  99                         }
 100                 }
 101                 else
 102                 {
 103                         for (j = i+1;j < strlen(s);++j)
 104                                 //    ^^ this skips over the first character of a word, which
 105                                 //       is ALWAYS part of the word
 106                                 //       this is safe since if i+1 == strlen(s), i will become
 107                                 //       strlen(s)-1 at the end of this block and the function
 108                                 //       will terminate. A space can't be the first character we
 109                                 //       read here, and neither can a \n be the start, since these
 110                                 //       two cases have been handled above.
 111                         {
 112                                 c = substring(s, j, 1);
 113                                 if (c == " ")
 114                                         break;
 115                                 if (c == "\\")
 116                                         break;
 117                                 if (c == "\n")
 118                                         break;
 119                                 // we need to keep this tempstring alive even if substring is
 120                                 // called repeatedly, so call strcat even though we're not
 121                                 // doing anything
 122                                 callback("");
 123                         }
 124                         wlen = j - i;
 125                         if (lleft < wlen)
 126                         {
 127                                 callback("\n");
 128                                 lleft = l;
 129                         }
 130                         callback(substring(s, i, wlen));
 131                         lleft = lleft - wlen;
 132                         i = j - 1;
 133                 }
 134         }
 135         strunzone(s);
 136 }
 137
 138 float dist_point_line(vector p, vector l0, vector ldir)
 139 {
 140         ldir = normalize(ldir);
 141
 142         // remove the component in line direction
 143         p = p - (p * ldir) * ldir;
 144
 145         // vlen of the remaining vector
 146         return vlen(p);
 147 }
 148
 149 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 150 {
 151         entity e;
 152         e = start;
 153         funcPre(pass, e);
 154         while(e.downleft)
 155         {
 156                 e = e.downleft;
 157                 funcPre(pass, e);
 158         }
 159         funcPost(pass, e);
 160         while(e != start)
 161         {
 162                 if(e.right)
 163                 {
 164                         e = e.right;
 165                         funcPre(pass, e);
 166                         while(e.downleft)
 167                         {
 168                                 e = e.downleft;
 169                                 funcPre(pass, e);
 170                         }
 171                 }
 172                 else
 173                         e = e.up;
 174                 funcPost(pass, e);
 175         }
 176 }
 177
 178 float median(float a, float b, float c)
 179 {
 180         if(a < c)
 181                 return bound(a, b, c);
 182         return bound(c, b, a);
 183 }
 184
 185 // converts a number to a string with the indicated number of decimals
 186 // works for up to 10 decimals!
 187 string ftos_decimals(float number, float decimals)
 188 {
 189         // we have sprintf...
 190         return sprintf("%.*f", decimals, number);
 191 }
 192
 193 float time;
 194 vector colormapPaletteColor(float c, float isPants)
 195 {
 196         switch(c)
 197         {
 198                 case  0: return '0.800000 0.800000 0.800000';
 199                 case  1: return '0.600000 0.400000 0.000000';
 200                 case  2: return '0.000000 1.000000 0.501961';
 201                 case  3: return '0.000000 1.000000 0.000000';
 202                 case  4: return '1.000000 0.000000 0.000000';
 203                 case  5: return '0.000000 0.658824 1.000000';
 204                 case  6: return '0.000000 1.000000 1.000000';
 205                 case  7: return '0.501961 1.000000 0.000000';
 206                 case  8: return '0.501961 0.000000 1.000000';
 207                 case  9: return '1.000000 0.000000 1.000000';
 208                 case 10: return '1.000000 0.000000 0.501961';
 209                 case 11: return '0.600000 0.600000 0.600000';
 210                 case 12: return '1.000000 1.000000 0.000000';
 211                 case 13: return '0.000000 0.313725 1.000000';
 212                 case 14: return '1.000000 0.501961 0.000000';
 213                 case 15:
 214                         if(isPants)
 215                                 return
 216                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 217                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 218                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 219                         else
 220                                 return
 221                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 222                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 223                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 224                 default: return '0.000 0.000 0.000';
 225         }
 226 }
 227
 228 // unzone the string, and return it as tempstring. Safe to be called on string_null
 229 string fstrunzone(string s)
 230 {
 231         string sc;
 232         if not(s)
 233                 return s;
 234         sc = strcat(s, "");
 235         strunzone(s);
 236         return sc;
 237 }
 238
 239 float fexists(string f)
 240 {
 241     float fh;
 242     fh = fopen(f, FILE_READ);
 243     if (fh < 0)
 244         return FALSE;
 245     fclose(fh);
 246     return TRUE;
 247 }
 248
 249 // Databases (hash tables)
 250 #define DB_BUCKETS 8192
 251 void db_save(float db, string pFilename)
 252 {
 253         float fh, i, n;
 254         fh = fopen(pFilename, FILE_WRITE);
 255         if(fh < 0)
 256         {
 257                 print(strcat("^1Can't write DB to ", pFilename));
 258                 return;
 259         }
 260         n = buf_getsize(db);
 261         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 262         for(i = 0; i < n; ++i)
 263                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 264         fclose(fh);
 265 }
 266
 267 float db_create()
 268 {
 269         return buf_create();
 270 }
 271
 272 float db_load(string pFilename)
 273 {
 274         float db, fh, i, j, n;
 275         string l;
 276         db = buf_create();
 277         if(db < 0)
 278                 return -1;
 279         fh = fopen(pFilename, FILE_READ);
 280         if(fh < 0)
 281                 return db;
 282         l = fgets(fh);
 283         if(stof(l) == DB_BUCKETS)
 284         {
 285                 i = 0;
 286                 while((l = fgets(fh)))
 287                 {
 288                         if(l != "")
 289                                 bufstr_set(db, i, l);
 290                         ++i;
 291                 }
 292         }
 293         else
 294         {
 295                 // different count of buckets, or a dump?
 296                 // need to reorganize the database then (SLOW)
 297                 //
 298                 // note: we also parse the first line (l) in case the DB file is
 299                 // missing the bucket count
 300                 do
 301                 {
 302                         n = tokenizebyseparator(l, "\\");
 303                         for(j = 2; j < n; j += 2)
 304                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 305                 }
 306                 while((l = fgets(fh)));
 307         }
 308         fclose(fh);
 309         return db;
 310 }
 311
 312 void db_dump(float db, string pFilename)
 313 {
 314         float fh, i, j, n, m;
 315         fh = fopen(pFilename, FILE_WRITE);
 316         if(fh < 0)
 317                 error(strcat("Can't dump DB to ", pFilename));
 318         n = buf_getsize(db);
 319         fputs(fh, "0\n");
 320         for(i = 0; i < n; ++i)
 321         {
 322                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 323                 for(j = 2; j < m; j += 2)
 324                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 325         }
 326         fclose(fh);
 327 }
 328
 329 void db_close(float db)
 330 {
 331         buf_del(db);
 332 }
 333
 334 string db_get(float db, string pKey)
 335 {
 336         float h;
 337         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 338         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 339 }
 340
 341 void db_put(float db, string pKey, string pValue)
 342 {
 343         float h;
 344         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 345         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 346 }
 347
 348 void db_test()
 349 {
 350         float db, i;
 351         print("LOAD...\n");
 352         db = db_load("foo.db");
 353         print("LOADED. FILL...\n");
 354         for(i = 0; i < DB_BUCKETS; ++i)
 355                 db_put(db, ftos(random()), "X");
 356         print("FILLED. SAVE...\n");
 357         db_save(db, "foo.db");
 358         print("SAVED. CLOSE...\n");
 359         db_close(db);
 360         print("CLOSED.\n");
 361 }
 362
 363 // Multiline text file buffers
 364 float buf_load(string pFilename)
 365 {
 366         float buf, fh, i;
 367         string l;
 368         buf = buf_create();
 369         if(buf < 0)
 370                 return -1;
 371         fh = fopen(pFilename, FILE_READ);
 372         if(fh < 0)
 373         {
 374                 buf_del(buf);
 375                 return -1;
 376         }
 377         i = 0;
 378         while((l = fgets(fh)))
 379         {
 380                 bufstr_set(buf, i, l);
 381                 ++i;
 382         }
 383         fclose(fh);
 384         return buf;
 385 }
 386
 387 void buf_save(float buf, string pFilename)
 388 {
 389         float fh, i, n;
 390         fh = fopen(pFilename, FILE_WRITE);
 391         if(fh < 0)
 392                 error(strcat("Can't write buf to ", pFilename));
 393         n = buf_getsize(buf);
 394         for(i = 0; i < n; ++i)
 395                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 396         fclose(fh);
 397 }
 398
 399 string GametypeNameFromType(float g)
 400 {
 401         if      (g == GAME_DEATHMATCH) return "dm";
 402         else if (g == GAME_TEAM_DEATHMATCH) return "tdm";
 403         else if (g == GAME_DOMINATION) return "dom";
 404         else if (g == GAME_CTF) return "ctf";
 405         else if (g == GAME_RUNEMATCH) return "rune";
 406         else if (g == GAME_LMS) return "lms";
 407         else if (g == GAME_ARENA) return "arena";
 408         else if (g == GAME_CA) return "ca";
 409         else if (g == GAME_KEYHUNT) return "kh";
 410         else if (g == GAME_ONSLAUGHT) return "ons";
 411         else if (g == GAME_ASSAULT) return "as";
 412         else if (g == GAME_RACE) return "rc";
 413         else if (g == GAME_NEXBALL) return "nexball";
 414         else if (g == GAME_CTS) return "cts";
 415         else if (g == GAME_FREEZETAG) return "freezetag";
 416         else if (g == GAME_KEEPAWAY) return "ka";
 417         return "dm";
 418 }
 419
 420 string mmsss(float tenths)
 421 {
 422         float minutes;
 423         string s;
 424         tenths = floor(tenths + 0.5);
 425         minutes = floor(tenths / 600);
 426         tenths -= minutes * 600;
 427         s = ftos(1000 + tenths);
 428         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 429 }
 430
 431 string mmssss(float hundredths)
 432 {
 433         float minutes;
 434         string s;
 435         hundredths = floor(hundredths + 0.5);
 436         minutes = floor(hundredths / 6000);
 437         hundredths -= minutes * 6000;
 438         s = ftos(10000 + hundredths);
 439         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
 440 }
 441
 442 string ScoreString(float pFlags, float pValue)
 443 {
 444         string valstr;
 445         float l;
 446
 447         pValue = floor(pValue + 0.5); // round
 448
 449         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 450                 valstr = "";
 451         else if(pFlags & SFL_RANK)
 452         {
 453                 valstr = ftos(pValue);
 454                 l = strlen(valstr);
 455                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 456                         valstr = strcat(valstr, "th");
 457                 else if(substring(valstr, l - 1, 1) == "1")
 458                         valstr = strcat(valstr, "st");
 459                 else if(substring(valstr, l - 1, 1) == "2")
 460                         valstr = strcat(valstr, "nd");
 461                 else if(substring(valstr, l - 1, 1) == "3")
 462                         valstr = strcat(valstr, "rd");
 463                 else
 464                         valstr = strcat(valstr, "th");
 465         }
 466         else if(pFlags & SFL_TIME)
 467                 valstr = TIME_ENCODED_TOSTRING(pValue);
 468         else
 469                 valstr = ftos(pValue);
 470
 471         return valstr;
 472 }
 473
 474 vector cross(vector a, vector b)
 475 {
 476         return
 477                 '1 0 0' * (a_y * b_z - a_z * b_y)
 478         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 479         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 480 }
 481
 482 // compressed vector format:
 483 // like MD3, just even shorter
 484 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 485 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 486 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 487 //     length = 2^(length_encoded/8) / 8
 488 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 489 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 490 // the special value 0 indicates the zero vector
 491
 492 float lengthLogTable[128];
 493
 494 float invertLengthLog(float x)
 495 {
 496         float l, r, m, lerr, rerr;
 497
 498         if(x >= lengthLogTable[127])
 499                 return 127;
 500         if(x <= lengthLogTable[0])
 501                 return 0;
 502
 503         l = 0;
 504         r = 127;
 505
 506         while(r - l > 1)
 507         {
 508                 m = floor((l + r) / 2);
 509                 if(lengthLogTable[m] < x)
 510                         l = m;
 511                 else
 512                         r = m;
 513         }
 514
 515         // now: r is >=, l is <
 516         lerr = (x - lengthLogTable[l]);
 517         rerr = (lengthLogTable[r] - x);
 518         if(lerr < rerr)
 519                 return l;
 520         return r;
 521 }
 522
 523 vector decompressShortVector(float data)
 524 {
 525         vector out;
 526         float pitch, yaw, len;
 527         if(data == 0)
 528                 return '0 0 0';
 529         pitch = (data & 0xF000) / 0x1000;
 530         yaw =   (data & 0x0F80) / 0x80;
 531         len =   (data & 0x007F);
 532
 533         //print("\ndecompress: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 534
 535         if(pitch == 0)
 536         {
 537                 out_x = 0;
 538                 out_y = 0;
 539                 if(yaw == 31)
 540                         out_z = -1;
 541                 else
 542                         out_z = +1;
 543         }
 544         else
 545         {
 546                 yaw   = .19634954084936207740 * yaw;
 547                 pitch = .19634954084936207740 * pitch - 1.57079632679489661922;
 548                 out_x = cos(yaw) *  cos(pitch);
 549                 out_y = sin(yaw) *  cos(pitch);
 550                 out_z =            -sin(pitch);
 551         }
 552
 553         //print("decompressed: ", vtos(out), "\n");
 554
 555         return out * lengthLogTable[len];
 556 }
 557
 558 float compressShortVector(vector vec)
 559 {
 560         vector ang;
 561         float pitch, yaw, len;
 562         if(vlen(vec) == 0)
 563                 return 0;
 564         //print("compress: ", vtos(vec), "\n");
 565         ang = vectoangles(vec);
 566         ang_x = -ang_x;
 567         if(ang_x < -90)
 568                 ang_x += 360;
 569         if(ang_x < -90 && ang_x > +90)
 570                 error("BOGUS vectoangles");
 571         //print("angles: ", vtos(ang), "\n");
 572
 573         pitch = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 574         if(pitch == 0)
 575         {
 576                 if(vec_z < 0)
 577                         yaw = 31;
 578                 else
 579                         yaw = 30;
 580         }
 581         else
 582                 yaw = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 583         len = invertLengthLog(vlen(vec));
 584
 585         //print("compressed: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 586
 587         return (pitch * 0x1000) + (yaw * 0x80) + len;
 588 }
 589
 590 void compressShortVector_init()
 591 {
 592         float l, f, i;
 593         l = 1;
 594         f = pow(2, 1/8);
 595         for(i = 0; i < 128; ++i)
 596         {
 597                 lengthLogTable[i] = l;
 598                 l *= f;
 599         }
 600
 601         if(cvar("developer"))
 602         {
 603                 print("Verifying vector compression table...\n");
 604                 for(i = 0x0F00; i < 0xFFFF; ++i)
 605                         if(i != compressShortVector(decompressShortVector(i)))
 606                         {
 607                                 print("BROKEN vector compression: ", ftos(i));
 608                                 print(" -> ", vtos(decompressShortVector(i)));
 609                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 610                                 print("\n");
 611                                 error("b0rk");
 612                         }
 613                 print("Done.\n");
 614         }
 615 }
 616
 617 #ifndef MENUQC
 618 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 619 {
 620         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 621         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 622         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 624         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 625         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 626         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 627         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 628         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 629         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 630         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 631         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 632         return 1;
 633 }
 634 #endif
 635
 636 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 637 {
 638         string neworder;
 639         float i, n, w;
 640
 641         n = tokenize_console(order);
 642         neworder = "";
 643         for(i = 0; i < n; ++i)
 644         {
 645                 w = stof(argv(i));
 646                 if(w == floor(w))
 647                 {
 648                         if(w >= from && w <= to)
 649                                 neworder = strcat(neworder, ftos(w), " ");
 650                         else
 651                         {
 652                                 w -= subtract;
 653                                 if(w >= from && w <= to)
 654                                         neworder = strcat(neworder, ftos(w), " ");
 655                         }
 656                 }
 657         }
 658
 659         if(complete)
 660         {
 661                 n = tokenize_console(neworder);
 662                 for(w = to; w >= from; --w)
 663                 {
 664                         for(i = 0; i < n; ++i)
 665                                 if(stof(argv(i)) == w)
 666                                         break;
 667                         if(i == n) // not found
 668                                 neworder = strcat(neworder, ftos(w), " ");
 669                 }
 670         }
 671
 672         return substring(neworder, 0, strlen(neworder) - 1);
 673 }
 674
 675 string mapPriorityList(string order, string(string) mapfunc)
 676 {
 677         string neworder;
 678         float i, n;
 679
 680         n = tokenize_console(order);
 681         neworder = "";
 682         for(i = 0; i < n; ++i)
 683                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 684
 685         return substring(neworder, 0, strlen(neworder) - 1);
 686 }
 687
 688 string swapInPriorityList(string order, float i, float j)
 689 {
 690         string s;
 691         float w, n;
 692
 693         n = tokenize_console(order);
 694
 695         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 696         {
 697                 s = "";
 698                 for(w = 0; w < n; ++w)
 699                 {
 700                         if(w == i)
 701                                 s = strcat(s, argv(j), " ");
 702                         else if(w == j)
 703                                 s = strcat(s, argv(i), " ");
 704                         else
 705                                 s = strcat(s, argv(w), " ");
 706                 }
 707                 return substring(s, 0, strlen(s) - 1);
 708         }
 709
 710         return order;
 711 }
 712
 713 float cvar_value_issafe(string s)
 714 {
 715         if(strstrofs(s, "\"", 0) >= 0)
 716                 return 0;
 717         if(strstrofs(s, "\\", 0) >= 0)
 718                 return 0;
 719         if(strstrofs(s, ";", 0) >= 0)
 720                 return 0;
 721         if(strstrofs(s, "$", 0) >= 0)
 722                 return 0;
 723         if(strstrofs(s, "\r", 0) >= 0)
 724                 return 0;
 725         if(strstrofs(s, "\n", 0) >= 0)
 726                 return 0;
 727         return 1;
 728 }
 729
 730 #ifndef MENUQC
 731 void get_mi_min_max(float mode)
 732 {
 733         vector mi, ma;
 734
 735         if(mi_shortname)
 736                 strunzone(mi_shortname);
 737         mi_shortname = mapname;
 738         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 739                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 740         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 741                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 742         mi_shortname = strzone(mi_shortname);
 743
 744 #ifdef CSQC
 745         mi = world.mins;
 746         ma = world.maxs;
 747 #else
 748         mi = world.absmin;
 749         ma = world.absmax;
 750 #endif
 751
 752         mi_min = mi;
 753         mi_max = ma;
 754         MapInfo_Get_ByName(mi_shortname, 0, 0);
 755         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 756         {
 757                 mi_min = MapInfo_Map_mins;
 758                 mi_max = MapInfo_Map_maxs;
 759         }
 760         else
 761         {
 762                 // not specified
 763                 if(mode)
 764                 {
 765                         // be clever
 766                         tracebox('1 0 0' * mi_x,
 767                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 768                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 769                                          '1 0 0' * ma_x,
 770                                          MOVE_WORLDONLY,
 771                                          world);
 772                         if(!trace_startsolid)
 773                                 mi_min_x = trace_endpos_x;
 774
 775                         tracebox('0 1 0' * mi_y,
 776                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 777                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 778                                          '0 1 0' * ma_y,
 779                                          MOVE_WORLDONLY,
 780                                          world);
 781                         if(!trace_startsolid)
 782                                 mi_min_y = trace_endpos_y;
 783
 784                         tracebox('0 0 1' * mi_z,
 785                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 786                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 787                                          '0 0 1' * ma_z,
 788                                          MOVE_WORLDONLY,
 789                                          world);
 790                         if(!trace_startsolid)
 791                                 mi_min_z = trace_endpos_z;
 792
 793                         tracebox('1 0 0' * ma_x,
 794                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 795                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 796                                          '1 0 0' * mi_x,
 797                                          MOVE_WORLDONLY,
 798                                          world);
 799                         if(!trace_startsolid)
 800                                 mi_max_x = trace_endpos_x;
 801
 802                         tracebox('0 1 0' * ma_y,
 803                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 804                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 805                                          '0 1 0' * mi_y,
 806                                          MOVE_WORLDONLY,
 807                                          world);
 808                         if(!trace_startsolid)
 809                                 mi_max_y = trace_endpos_y;
 810
 811                         tracebox('0 0 1' * ma_z,
 812                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 813                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 814                                          '0 0 1' * mi_z,
 815                                          MOVE_WORLDONLY,
 816                                          world);
 817                         if(!trace_startsolid)
 818                                 mi_max_z = trace_endpos_z;
 819                 }
 820         }
 821 }
 822
 823 void get_mi_min_max_texcoords(float mode)
 824 {
 825         vector extend;
 826
 827         get_mi_min_max(mode);
 828
 829         mi_picmin = mi_min;
 830         mi_picmax = mi_max;
 831
 832         // extend mi_picmax to get a square aspect ratio
 833         // center the map in that area
 834         extend = mi_picmax - mi_picmin;
 835         if(extend_y > extend_x)
 836         {
 837                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 838                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 839         }
 840         else
 841         {
 842                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 843                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 844         }
 845
 846         // add another some percent
 847         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 848         mi_picmin -= extend;
 849         mi_picmax += extend;
 850
 851         // calculate the texcoords
 852         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 853         // first the two corners of the origin
 854         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 855         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 856         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 857         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 858         // then the other corners
 859         mi_pictexcoord1_x = mi_pictexcoord0_x;
 860         mi_pictexcoord1_y = mi_pictexcoord2_y;
 861         mi_pictexcoord3_x = mi_pictexcoord2_x;
 862         mi_pictexcoord3_y = mi_pictexcoord0_y;
 863 }
 864 #endif
 865
 866 #ifdef CSQC
 867 void cvar_settemp(string pKey, string pValue)
 868 {
 869         error("cvar_settemp called from CSQC - use cvar_clientsettemp instead!");
 870 }
 871 void cvar_settemp_restore()
 872 {
 873         error("cvar_settemp_restore called from CSQC - use cvar_clientsettemp instead!");
 874 }
 875 #else
 876 void cvar_settemp(string pKey, string pValue)
 877 {
 878         float i;
 879         string settemp_var;
 880         if(cvar_string(pKey) == pValue)
 881                 return;
 882         i = cvar("settemp_idx");
 883         cvar_set("settemp_idx", ftos(i+1));
 884         settemp_var = strcat("_settemp_x", ftos(i));
 885 #ifdef MENUQC
 886         registercvar(settemp_var, "", 0);
 887 #else
 888         registercvar(settemp_var, "");
 889 #endif
 890         cvar_set("settemp_list", strcat("1 ", pKey, " ", settemp_var, " ", cvar_string("settemp_list")));
 891         cvar_set(settemp_var, cvar_string(pKey));
 892         cvar_set(pKey, pValue);
 893 }
 894
 895 void cvar_settemp_restore()
 896 {
 897         // undo what cvar_settemp did
 898         float n, i;
 899         n = tokenize_console(cvar_string("settemp_list"));
 900         for(i = 0; i < n - 3; i += 3)
 901                 cvar_set(argv(i + 1), cvar_string(argv(i + 2)));
 902         cvar_set("settemp_list", "0");
 903 }
 904 #endif
 905
 906 float almost_equals(float a, float b)
 907 {
 908         float eps;
 909         eps = (max(a, -a) + max(b, -b)) * 0.001;
 910         if(a - b < eps && b - a < eps)
 911                 return TRUE;
 912         return FALSE;
 913 }
 914
 915 float almost_in_bounds(float a, float b, float c)
 916 {
 917         float eps;
 918         eps = (max(a, -a) + max(c, -c)) * 0.001;
 919         return b == median(a - eps, b, c + eps);
 920 }
 921
 922 float power2of(float e)
 923 {
 924         return pow(2, e);
 925 }
 926 float log2of(float x)
 927 {
 928         // NOTE: generated code
 929         if(x > 2048)
 930                 if(x > 131072)
 931                         if(x > 1048576)
 932                                 if(x > 4194304)
 933                                         return 23;
 934                                 else
 935                                         if(x > 2097152)
 936                                                 return 22;
 937                                         else
 938                                                 return 21;
 939                         else
 940                                 if(x > 524288)
 941                                         return 20;
 942                                 else
 943                                         if(x > 262144)
 944                                                 return 19;
 945                                         else
 946                                                 return 18;
 947                 else
 948                         if(x > 16384)
 949                                 if(x > 65536)
 950                                         return 17;
 951                                 else
 952                                         if(x > 32768)
 953                                                 return 16;
 954                                         else
 955                                                 return 15;
 956                         else
 957                                 if(x > 8192)
 958                                         return 14;
 959                                 else
 960                                         if(x > 4096)
 961                                                 return 13;
 962                                         else
 963                                                 return 12;
 964         else
 965                 if(x > 32)
 966                         if(x > 256)
 967                                 if(x > 1024)
 968                                         return 11;
 969                                 else
 970                                         if(x > 512)
 971                                                 return 10;
 972                                         else
 973                                                 return 9;
 974                         else
 975                                 if(x > 128)
 976                                         return 8;
 977                                 else
 978                                         if(x > 64)
 979                                                 return 7;
 980                                         else
 981                                                 return 6;
 982                 else
 983                         if(x > 4)
 984                                 if(x > 16)
 985                                         return 5;
 986                                 else
 987                                         if(x > 8)
 988                                                 return 4;
 989                                         else
 990                                                 return 3;
 991                         else
 992                                 if(x > 2)
 993                                         return 2;
 994                                 else
 995                                         if(x > 1)
 996                                                 return 1;
 997                                         else
 998                                                 return 0;
 999 }
1000
1001 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
1002 {
1003         if(mi == ma)
1004                 return 0;
1005         else if(ma == rgb_x)
1006         {
1007                 if(rgb_y >= rgb_z)
1008                         return (rgb_y - rgb_z) / (ma - mi);
1009                 else
1010                         return (rgb_y - rgb_z) / (ma - mi) + 6;
1011         }
1012         else if(ma == rgb_y)
1013                 return (rgb_z - rgb_x) / (ma - mi) + 2;
1014         else // if(ma == rgb_z)
1015                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1016 }
1017
1018 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1019 {
1020         vector rgb;
1021
1022         hue -= 6 * floor(hue / 6);
1023
1024         //else if(ma == rgb_x)
1025         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1026         if(hue <= 1)
1027         {
1028                 rgb_x = ma;
1029                 rgb_y = hue * (ma - mi) + mi;
1030                 rgb_z = mi;
1031         }
1032         //else if(ma == rgb_y)
1033         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1034         else if(hue <= 2)
1035         {
1036                 rgb_x = (2 - hue) * (ma - mi) + mi;
1037                 rgb_y = ma;
1038                 rgb_z = mi;
1039         }
1040         else if(hue <= 3)
1041         {
1042                 rgb_x = mi;
1043                 rgb_y = ma;
1044                 rgb_z = (hue - 2) * (ma - mi) + mi;
1045         }
1046         //else // if(ma == rgb_z)
1047         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1048         else if(hue <= 4)
1049         {
1050                 rgb_x = mi;
1051                 rgb_y = (4 - hue) * (ma - mi) + mi;
1052                 rgb_z = ma;
1053         }
1054         else if(hue <= 5)
1055         {
1056                 rgb_x = (hue - 4) * (ma - mi) + mi;
1057                 rgb_y = mi;
1058                 rgb_z = ma;
1059         }
1060         //else if(ma == rgb_x)
1061         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1062         else // if(hue <= 6)
1063         {
1064                 rgb_x = ma;
1065                 rgb_y = mi;
1066                 rgb_z = (6 - hue) * (ma - mi) + mi;
1067         }
1068
1069         return rgb;
1070 }
1071
1072 vector rgb_to_hsv(vector rgb)
1073 {
1074         float mi, ma;
1075         vector hsv;
1076
1077         mi = min3(rgb_x, rgb_y, rgb_z);
1078         ma = max3(rgb_x, rgb_y, rgb_z);
1079
1080         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1081         hsv_z = ma;
1082
1083         if(ma == 0)
1084                 hsv_y = 0;
1085         else
1086                 hsv_y = 1 - mi/ma;
1087
1088         return hsv;
1089 }
1090
1091 vector hsv_to_rgb(vector hsv)
1092 {
1093         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1094 }
1095
1096 vector rgb_to_hsl(vector rgb)
1097 {
1098         float mi, ma;
1099         vector hsl;
1100
1101         mi = min3(rgb_x, rgb_y, rgb_z);
1102         ma = max3(rgb_x, rgb_y, rgb_z);
1103
1104         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1105
1106         hsl_z = 0.5 * (mi + ma);
1107         if(mi == ma)
1108                 hsl_y = 0;
1109         else if(hsl_z <= 0.5)
1110                 hsl_y = (ma - mi) / (2*hsl_z);
1111         else // if(hsl_z > 0.5)
1112                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1113
1114         return hsl;
1115 }
1116
1117 vector hsl_to_rgb(vector hsl)
1118 {
1119         float mi, ma, maminusmi;
1120
1121         if(hsl_z <= 0.5)
1122                 maminusmi = hsl_y * 2 * hsl_z;
1123         else
1124                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1125
1126         // hsl_z     = 0.5 * mi + 0.5 * ma
1127         // maminusmi =     - mi +       ma
1128         mi = hsl_z - 0.5 * maminusmi;
1129         ma = hsl_z + 0.5 * maminusmi;
1130
1131         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1132 }
1133
1134 string rgb_to_hexcolor(vector rgb)
1135 {
1136         return
1137                 strcat(
1138                         "^x",
1139                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1140                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1141                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1142                 );
1143 }
1144
1145 // requires that m2>m1 in all coordinates, and that m4>m3
1146 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
1147
1148 // requires the same, but is a stronger condition
1149 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
1150
1151 #ifndef MENUQC
1152 #endif
1153
1154 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
1155 {
1156         float ICanHasKallerz;
1157
1158         // detect color codes support in the width function
1159         ICanHasKallerz = (w("^7", theSize) == 0);
1160
1161         // STOP.
1162         // The following function is SLOW.
1163         // For your safety and for the protection of those around you...
1164         // DO NOT CALL THIS AT HOME.
1165         // No really, don't.
1166         if(w(theText, theSize) <= maxWidth)
1167                 return strlen(theText); // yeah!
1168
1169         // binary search for right place to cut string
1170         float ch;
1171         float left, right, middle; // this always works
1172         left = 0;
1173         right = strlen(theText); // this always fails
1174         do
1175         {
1176                 middle = floor((left + right) / 2);
1177                 if(w(substring(theText, 0, middle), theSize) <= maxWidth)
1178                         left = middle;
1179                 else
1180                         right = middle;
1181         }
1182         while(left < right - 1);
1183
1184         if(ICanHasKallerz)
1185         {
1186                 // NOTE: when color codes are involved, this binary search is,
1187                 // mathematically, BROKEN. However, it is obviously guaranteed to
1188                 // terminate, as the range still halves each time - but nevertheless, it is
1189                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1190                 // range, and "right" is outside).
1191
1192                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1193                 // and decrease left on the basis of the chars detected of the truncated tag
1194                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1195                 // (sometimes too much but with a correct result)
1196                 // it fixes also ^[0-9]
1197                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1198                         left-=1;
1199
1200                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1201                         left-=2;
1202                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1203                         {
1204                                 ch = str2chr(theText, left-1);
1205                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1206                                         left-=3;
1207                         }
1208                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1209                         {
1210                                 ch = str2chr(theText, left-2);
1211                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1212                                 {
1213                                         ch = str2chr(theText, left-1);
1214                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1215                                                 left-=4;
1216                                 }
1217                         }
1218         }
1219
1220         return left;
1221 }
1222
1223 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
1224 {
1225         float ICanHasKallerz;
1226
1227         // detect color codes support in the width function
1228         ICanHasKallerz = (w("^7") == 0);
1229
1230         // STOP.
1231         // The following function is SLOW.
1232         // For your safety and for the protection of those around you...
1233         // DO NOT CALL THIS AT HOME.
1234         // No really, don't.
1235         if(w(theText) <= maxWidth)
1236                 return strlen(theText); // yeah!
1237
1238         // binary search for right place to cut string
1239         float ch;
1240         float left, right, middle; // this always works
1241         left = 0;
1242         right = strlen(theText); // this always fails
1243         do
1244         {
1245                 middle = floor((left + right) / 2);
1246                 if(w(substring(theText, 0, middle)) <= maxWidth)
1247                         left = middle;
1248                 else
1249                         right = middle;
1250         }
1251         while(left < right - 1);
1252
1253         if(ICanHasKallerz)
1254         {
1255                 // NOTE: when color codes are involved, this binary search is,
1256                 // mathematically, BROKEN. However, it is obviously guaranteed to
1257                 // terminate, as the range still halves each time - but nevertheless, it is
1258                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1259                 // range, and "right" is outside).
1260
1261                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1262                 // and decrease left on the basis of the chars detected of the truncated tag
1263                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1264                 // (sometimes too much but with a correct result)
1265                 // it fixes also ^[0-9]
1266                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1267                         left-=1;
1268
1269                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1270                         left-=2;
1271                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1272                         {
1273                                 ch = str2chr(theText, left-1);
1274                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1275                                         left-=3;
1276                         }
1277                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1278                         {
1279                                 ch = str2chr(theText, left-2);
1280                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1281                                 {
1282                                         ch = str2chr(theText, left-1);
1283                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1284                                                 left-=4;
1285                                 }
1286                         }
1287         }
1288
1289         return left;
1290 }
1291
1292 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1293 {
1294         float cantake;
1295         float take;
1296         string s;
1297
1298         s = getWrappedLine_remaining;
1299
1300         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
1301         if(cantake > 0 && cantake < strlen(s))
1302         {
1303                 take = cantake - 1;
1304                 while(take > 0 && substring(s, take, 1) != " ")
1305                         --take;
1306                 if(take == 0)
1307                 {
1308                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1309                         if(getWrappedLine_remaining == "")
1310                                 getWrappedLine_remaining = string_null;
1311                         return substring(s, 0, cantake);
1312                 }
1313                 else
1314                 {
1315                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1316                         if(getWrappedLine_remaining == "")
1317                                 getWrappedLine_remaining = string_null;
1318                         return substring(s, 0, take);
1319                 }
1320         }
1321         else
1322         {
1323                 getWrappedLine_remaining = string_null;
1324                 return s;
1325         }
1326 }
1327
1328 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
1329 {
1330         float cantake;
1331         float take;
1332         string s;
1333
1334         s = getWrappedLine_remaining;
1335
1336         cantake = textLengthUpToLength(s, w, tw);
1337         if(cantake > 0 && cantake < strlen(s))
1338         {
1339                 take = cantake - 1;
1340                 while(take > 0 && substring(s, take, 1) != " ")
1341                         --take;
1342                 if(take == 0)
1343                 {
1344                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1345                         if(getWrappedLine_remaining == "")
1346                                 getWrappedLine_remaining = string_null;
1347                         return substring(s, 0, cantake);
1348                 }
1349                 else
1350                 {
1351                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1352                         if(getWrappedLine_remaining == "")
1353                                 getWrappedLine_remaining = string_null;
1354                         return substring(s, 0, take);
1355                 }
1356         }
1357         else
1358         {
1359                 getWrappedLine_remaining = string_null;
1360                 return s;
1361         }
1362 }
1363
1364 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1365 {
1366         if(tw(theText, theFontSize) <= maxWidth)
1367                 return theText;
1368         else
1369                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
1370 }
1371
1372 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
1373 {
1374         if(tw(theText) <= maxWidth)
1375                 return theText;
1376         else
1377                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
1378 }
1379
1380 float isGametypeInFilter(float gt, float tp, float ts, string pattern)
1381 {
1382         string subpattern, subpattern2, subpattern3, subpattern4;
1383         subpattern = strcat(",", GametypeNameFromType(gt), ",");
1384         if(tp)
1385                 subpattern2 = ",teams,";
1386         else
1387                 subpattern2 = ",noteams,";
1388         if(ts)
1389                 subpattern3 = ",teamspawns,";
1390         else
1391                 subpattern3 = ",noteamspawns,";
1392         if(gt == GAME_RACE || gt == GAME_CTS)
1393                 subpattern4 = ",race,";
1394         else
1395                 subpattern4 = string_null;
1396
1397         if(substring(pattern, 0, 1) == "-")
1398         {
1399                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1400                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1401                         return 0;
1402                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1403                         return 0;
1404                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
1405                         return 0;
1406                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
1407                         return 0;
1408         }
1409         else
1410         {
1411                 if(substring(pattern, 0, 1) == "+")
1412                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1413                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1414                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1415                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
1416                 if((!subpattern4) || strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
1417                         return 0;
1418         }
1419         return 1;
1420 }
1421
1422 void shuffle(float n, swapfunc_t swap, entity pass)
1423 {
1424         float i, j;
1425         for(i = 1; i < n; ++i)
1426         {
1427                 // swap i-th item at a random position from 0 to i
1428                 // proof for even distribution:
1429                 //   n = 1: obvious
1430                 //   n -> n+1:
1431                 //     item n+1 gets at any position with chance 1/(n+1)
1432                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1433                 //     to be on place n+1, their chance will be 1/(n+1)
1434                 //     1/n * n/(n+1) = 1/(n+1)
1435                 //     q.e.d.
1436                 j = floor(random() * (i + 1));
1437                 if(j != i)
1438                         swap(j, i, pass);
1439         }
1440 }
1441
1442 string substring_range(string s, float b, float e)
1443 {
1444         return substring(s, b, e - b);
1445 }
1446
1447 string swapwords(string str, float i, float j)
1448 {
1449         float n;
1450         string s1, s2, s3, s4, s5;
1451         float si, ei, sj, ej, s0, en;
1452         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1453         si = argv_start_index(i);
1454         sj = argv_start_index(j);
1455         ei = argv_end_index(i);
1456         ej = argv_end_index(j);
1457         s0 = argv_start_index(0);
1458         en = argv_end_index(n-1);
1459         s1 = substring_range(str, s0, si);
1460         s2 = substring_range(str, si, ei);
1461         s3 = substring_range(str, ei, sj);
1462         s4 = substring_range(str, sj, ej);
1463         s5 = substring_range(str, ej, en);
1464         return strcat(s1, s4, s3, s2, s5);
1465 }
1466
1467 string _shufflewords_str;
1468 void _shufflewords_swapfunc(float i, float j, entity pass)
1469 {
1470         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1471 }
1472 string shufflewords(string str)
1473 {
1474         float n;
1475         _shufflewords_str = str;
1476         n = tokenizebyseparator(str, " ");
1477         shuffle(n, _shufflewords_swapfunc, world);
1478         str = _shufflewords_str;
1479         _shufflewords_str = string_null;
1480         return str;
1481 }
1482
1483 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1484 {
1485         vector v;
1486         float D;
1487         v = '0 0 0';
1488         if(a == 0)
1489         {
1490                 if(b != 0)
1491                 {
1492                         v_x = v_y = -c / b;
1493                         v_z = 1;
1494                 }
1495                 else
1496                 {
1497                         if(c == 0)
1498                         {
1499                                 // actually, every number solves the equation!
1500                                 v_z = 1;
1501                         }
1502                 }
1503         }
1504         else
1505         {
1506                 D = b*b - 4*a*c;
1507                 if(D >= 0)
1508                 {
1509                         D = sqrt(D);
1510                         if(a > 0) // put the smaller solution first
1511                         {
1512                                 v_x = ((-b)-D) / (2*a);
1513                                 v_y = ((-b)+D) / (2*a);
1514                         }
1515                         else
1516                         {
1517                                 v_x = (-b+D) / (2*a);
1518                                 v_y = (-b-D) / (2*a);
1519                         }
1520                         v_z = 1;
1521                 }
1522                 else
1523                 {
1524                         // complex solutions!
1525                         D = sqrt(-D);
1526                         v_x = -b / (2*a);
1527                         if(a > 0)
1528                                 v_y =  D / (2*a);
1529                         else
1530                                 v_y = -D / (2*a);
1531                         v_z = 0;
1532                 }
1533         }
1534         return v;
1535 }
1536
1537 void check_unacceptable_compiler_bugs()
1538 {
1539         if(cvar("_allow_unacceptable_compiler_bugs"))
1540                 return;
1541         tokenize_console("foo bar");
1542         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1543                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1544 }
1545
1546 float compressShotOrigin(vector v)
1547 {
1548         float x, y, z;
1549         x = rint(v_x * 2);
1550         y = rint(v_y * 4) + 128;
1551         z = rint(v_z * 4) + 128;
1552         if(x > 255 || x < 0)
1553         {
1554                 print("shot origin ", vtos(v), " x out of bounds\n");
1555                 x = bound(0, x, 255);
1556         }
1557         if(y > 255 || y < 0)
1558         {
1559                 print("shot origin ", vtos(v), " y out of bounds\n");
1560                 y = bound(0, y, 255);
1561         }
1562         if(z > 255 || z < 0)
1563         {
1564                 print("shot origin ", vtos(v), " z out of bounds\n");
1565                 z = bound(0, z, 255);
1566         }
1567         return x * 0x10000 + y * 0x100 + z;
1568 }
1569 vector decompressShotOrigin(float f)
1570 {
1571         vector v;
1572         v_x = ((f & 0xFF0000) / 0x10000) / 2;
1573         v_y = ((f & 0xFF00) / 0x100 - 128) / 4;
1574         v_z = ((f & 0xFF) - 128) / 4;
1575         return v;
1576 }
1577
1578 void heapsort(float n, swapfunc_t swap, comparefunc_t cmp, entity pass)
1579 {
1580         float start, end, root, child;
1581
1582         // heapify
1583         start = floor((n - 2) / 2);
1584         while(start >= 0)
1585         {
1586                 // siftdown(start, count-1);
1587                 root = start;
1588                 while(root * 2 + 1 <= n-1)
1589                 {
1590                         child = root * 2 + 1;
1591                         if(child < n-1)
1592                                 if(cmp(child, child+1, pass) < 0)
1593                                         ++child;
1594                         if(cmp(root, child, pass) < 0)
1595                         {
1596                                 swap(root, child, pass);
1597                                 root = child;
1598                         }
1599                         else
1600                                 break;
1601                 }
1602                 // end of siftdown
1603                 --start;
1604         }
1605
1606         // extract
1607         end = n - 1;
1608         while(end > 0)
1609         {
1610                 swap(0, end, pass);
1611                 --end;
1612                 // siftdown(0, end);
1613                 root = 0;
1614                 while(root * 2 + 1 <= end)
1615                 {
1616                         child = root * 2 + 1;
1617                         if(child < end && cmp(child, child+1, pass) < 0)
1618                                 ++child;
1619                         if(cmp(root, child, pass) < 0)
1620                         {
1621                                 swap(root, child, pass);
1622                                 root = child;
1623                         }
1624                         else
1625                                 break;
1626                 }
1627                 // end of siftdown
1628         }
1629 }
1630
1631 void RandomSelection_Init()
1632 {
1633         RandomSelection_totalweight = 0;
1634         RandomSelection_chosen_ent = world;
1635         RandomSelection_chosen_float = 0;
1636         RandomSelection_chosen_string = string_null;
1637         RandomSelection_best_priority = -1;
1638 }
1639 void RandomSelection_Add(entity e, float f, string s, float weight, float priority)
1640 {
1641         if(priority > RandomSelection_best_priority)
1642         {
1643                 RandomSelection_best_priority = priority;
1644                 RandomSelection_chosen_ent = e;
1645                 RandomSelection_chosen_float = f;
1646                 RandomSelection_chosen_string = s;
1647                 RandomSelection_totalweight = weight;
1648         }
1649         else if(priority == RandomSelection_best_priority)
1650         {
1651                 RandomSelection_totalweight += weight;
1652                 if(random() * RandomSelection_totalweight <= weight)
1653                 {
1654                         RandomSelection_chosen_ent = e;
1655                         RandomSelection_chosen_float = f;
1656                         RandomSelection_chosen_string = s;
1657                 }
1658         }
1659 }
1660
1661 vector healtharmor_maxdamage(float h, float a, float armorblock)
1662 {
1663         // NOTE: we'll always choose the SMALLER value...
1664         float healthdamage, armordamage, armorideal;
1665         vector v;
1666         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1667         armordamage = a + (h - 1); // damage we can take if we could use more armor
1668         armorideal = healthdamage * armorblock;
1669         v_y = armorideal;
1670         if(armordamage < healthdamage)
1671         {
1672                 v_x = armordamage;
1673                 v_z = 1;
1674         }
1675         else
1676         {
1677                 v_x = healthdamage;
1678                 v_z = 0;
1679         }
1680         return v;
1681 }
1682
1683 vector healtharmor_applydamage(float a, float armorblock, float damage)
1684 {
1685         vector v;
1686         v_y = bound(0, damage * armorblock, a); // save
1687         v_x = bound(0, damage - v_y, damage); // take
1688         v_z = 0;
1689         return v;
1690 }
1691
1692 string getcurrentmod()
1693 {
1694         float n;
1695         string m;
1696         m = cvar_string("fs_gamedir");
1697         n = tokenize_console(m);
1698         if(n == 0)
1699                 return "data";
1700         else
1701                 return argv(n - 1);
1702 }
1703
1704 #ifndef MENUQC
1705 #ifdef CSQC
1706 float ReadInt24_t()
1707 {
1708         float v;
1709         v = ReadShort() * 256; // note: this is signed
1710         v += ReadByte(); // note: this is unsigned
1711         return v;
1712 }
1713 #else
1714 void WriteInt24_t(float dest, float val)
1715 {
1716         float v;
1717         WriteShort(dest, (v = floor(val / 256)));
1718         WriteByte(dest, val - v * 256); // 0..255
1719 }
1720 #endif
1721 #endif
1722
1723 float float2range11(float f)
1724 {
1725         // continuous function mapping all reals into -1..1
1726         return f / (fabs(f) + 1);
1727 }
1728
1729 float float2range01(float f)
1730 {
1731         // continuous function mapping all reals into 0..1
1732         return 0.5 + 0.5 * float2range11(f);
1733 }
1734
1735 // from the GNU Scientific Library
1736 float gsl_ran_gaussian_lastvalue;
1737 float gsl_ran_gaussian_lastvalue_set;
1738 float gsl_ran_gaussian(float sigma)
1739 {
1740         float a, b;
1741         if(gsl_ran_gaussian_lastvalue_set)
1742         {
1743                 gsl_ran_gaussian_lastvalue_set = 0;
1744                 return sigma * gsl_ran_gaussian_lastvalue;
1745         }
1746         else
1747         {
1748                 a = random() * 2 * M_PI;
1749                 b = sqrt(-2 * log(random()));
1750                 gsl_ran_gaussian_lastvalue = cos(a) * b;
1751                 gsl_ran_gaussian_lastvalue_set = 1;
1752                 return sigma * sin(a) * b;
1753         }
1754 }
1755
1756 string car(string s)
1757 {
1758         float o;
1759         o = strstrofs(s, " ", 0);
1760         if(o < 0)
1761                 return s;
1762         return substring(s, 0, o);
1763 }
1764 string cdr(string s)
1765 {
1766         float o;
1767         o = strstrofs(s, " ", 0);
1768         if(o < 0)
1769                 return string_null;
1770         return substring(s, o + 1, strlen(s) - (o + 1));
1771 }
1772 float matchacl(string acl, string str)
1773 {
1774         string t, s;
1775         float r, d;
1776         r = 0;
1777         while(acl)
1778         {
1779                 t = car(acl); acl = cdr(acl);
1780                 d = 1;
1781                 if(substring(t, 0, 1) == "-")
1782                 {
1783                         d = -1;
1784                         t = substring(t, 1, strlen(t) - 1);
1785                 }
1786                 else if(substring(t, 0, 1) == "+")
1787                         t = substring(t, 1, strlen(t) - 1);
1788                 if(substring(t, -1, 1) == "*")
1789                 {
1790                         t = substring(t, 0, strlen(t) - 1);
1791                         s = substring(s, 0, strlen(t));
1792                 }
1793                 else
1794                         s = str;
1795
1796                 if(s == t)
1797                 {
1798                         r = d;
1799                 }
1800         }
1801         return r;
1802 }
1803 float startsWith(string haystack, string needle)
1804 {
1805         return substring(haystack, 0, strlen(needle)) == needle;
1806 }
1807 float startsWithNocase(string haystack, string needle)
1808 {
1809         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
1810 }
1811
1812 string get_model_datafilename(string m, float sk, string fil)
1813 {
1814         if(m)
1815                 m = strcat(m, "_");
1816         else
1817                 m = "models/player/*_";
1818         if(sk >= 0)
1819                 m = strcat(m, ftos(sk));
1820         else
1821                 m = strcat(m, "*");
1822         return strcat(m, ".", fil);
1823 }
1824
1825 float get_model_parameters(string m, float sk)
1826 {
1827         string fn, s, c;
1828         float fh;
1829
1830         get_model_parameters_modelname = string_null;
1831         get_model_parameters_modelskin = -1;
1832         get_model_parameters_name = string_null;
1833         get_model_parameters_species = -1;
1834         get_model_parameters_sex = string_null;
1835         get_model_parameters_weight = -1;
1836         get_model_parameters_age = -1;
1837         get_model_parameters_desc = string_null;
1838
1839         if not(m)
1840                 return 1;
1841         if(sk < 0)
1842         {
1843                 if(substring(m, -4, -1) != ".txt")
1844                         return 0;
1845                 if(substring(m, -6, 1) != "_")
1846                         return 0;
1847                 sk = stof(substring(m, -5, 1));
1848                 m = substring(m, 0, -7);
1849         }
1850
1851         fn = get_model_datafilename(m, sk, "txt");
1852         fh = fopen(fn, FILE_READ);
1853         if(fh < 0)
1854         {
1855                 sk = 0;
1856                 fn = get_model_datafilename(m, sk, "txt");
1857                 fh = fopen(fn, FILE_READ);
1858                 if(fh < 0)
1859                         return 0;
1860         }
1861
1862         get_model_parameters_modelname = m;
1863         get_model_parameters_modelskin = sk;
1864         while((s = fgets(fh)))
1865         {
1866                 if(s == "")
1867                         break; // next lines will be description
1868                 c = car(s);
1869                 s = cdr(s);
1870                 if(c == "name")
1871                         get_model_parameters_name = s;
1872                 if(c == "species")
1873                         switch(s)
1874                         {
1875                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1876                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1877                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1878                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1879                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1880                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1881                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1882                         }
1883                 if(c == "sex")
1884                         get_model_parameters_sex = s;
1885                 if(c == "weight")
1886                         get_model_parameters_weight = stof(s);
1887                 if(c == "age")
1888                         get_model_parameters_age = stof(s);
1889         }
1890
1891         while((s = fgets(fh)))
1892         {
1893                 if(get_model_parameters_desc)
1894                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1895                 if(s != "")
1896                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1897         }
1898
1899         fclose(fh);
1900
1901         return 1;
1902 }
1903
1904 vector vec2(vector v)
1905 {
1906         v_z = 0;
1907         return v;
1908 }
1909
1910 #ifndef MENUQC
1911 vector NearestPointOnBox(entity box, vector org)
1912 {
1913         vector m1, m2, nearest;
1914
1915         m1 = box.mins + box.origin;
1916         m2 = box.maxs + box.origin;
1917
1918         nearest_x = bound(m1_x, org_x, m2_x);
1919         nearest_y = bound(m1_y, org_y, m2_y);
1920         nearest_z = bound(m1_z, org_z, m2_z);
1921
1922         return nearest;
1923 }
1924 #endif
1925
1926 float vercmp_recursive(string v1, string v2)
1927 {
1928         float dot1, dot2;
1929         string s1, s2;
1930         float r;
1931
1932         dot1 = strstrofs(v1, ".", 0);
1933         dot2 = strstrofs(v2, ".", 0);
1934         if(dot1 == -1)
1935                 s1 = v1;
1936         else
1937                 s1 = substring(v1, 0, dot1);
1938         if(dot2 == -1)
1939                 s2 = v2;
1940         else
1941                 s2 = substring(v2, 0, dot2);
1942
1943         r = stof(s1) - stof(s2);
1944         if(r != 0)
1945                 return r;
1946
1947         r = strcasecmp(s1, s2);
1948         if(r != 0)
1949                 return r;
1950
1951         if(dot1 == -1)
1952                 if(dot2 == -1)
1953                         return 0;
1954                 else
1955                         return -1;
1956         else
1957                 if(dot2 == -1)
1958                         return 1;
1959                 else
1960                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1961 }
1962
1963 float vercmp(string v1, string v2)
1964 {
1965         if(strcasecmp(v1, v2) == 0) // early out check
1966                 return 0;
1967
1968         // "git" beats all
1969         if(v1 == "git")
1970                 return 1;
1971         if(v2 == "git")
1972                 return -1;
1973
1974         return vercmp_recursive(v1, v2);
1975 }
1976
1977 float u8_strsize(string s)
1978 {
1979         float l, i, c;
1980         l = 0;
1981         for(i = 0; ; ++i)
1982         {
1983                 c = str2chr(s, i);
1984                 if(c <= 0)
1985                         break;
1986                 ++l;
1987                 if(c >= 0x80)
1988                         ++l;
1989                 if(c >= 0x800)
1990                         ++l;
1991                 if(c >= 0x10000)
1992                         ++l;
1993         }
1994         return l;
1995 }
1996
1997 // translation helpers
1998 string language_filename(string s)
1999 {
2000         string fn;
2001         float fh;
2002         fn = prvm_language;
2003         if(fn == "" || fn == "dump")
2004                 return s;
2005         fn = strcat(s, ".", fn);
2006         if((fh = fopen(fn, FILE_READ)) >= 0)
2007         {
2008                 fclose(fh);
2009                 return fn;
2010         }
2011         return s;
2012 }
2013 string CTX(string s)
2014 {
2015         float p = strstrofs(s, "^", 0);
2016         if(p < 0)
2017                 return s;
2018         return substring(s, p+1, -1);
2019 }
2020
2021 // x-encoding (encoding as zero length invisible string)
2022 const string XENCODE_2  = "xX";
2023 const string XENCODE_22 = "0123456789abcdefABCDEF";
2024 string xencode(float f)
2025 {
2026         float a, b, c, d;
2027         d = mod(f, 22); f = floor(f / 22);
2028         c = mod(f, 22); f = floor(f / 22);
2029         b = mod(f, 22); f = floor(f / 22);
2030         a = mod(f,  2); // f = floor(f /  2);
2031         return strcat(
2032                 "^",
2033                 substring(XENCODE_2,  a, 1),
2034                 substring(XENCODE_22, b, 1),
2035                 substring(XENCODE_22, c, 1),
2036                 substring(XENCODE_22, d, 1)
2037         );
2038 }
2039 float xdecode(string s)
2040 {
2041         float a, b, c, d;
2042         if(substring(s, 0, 1) != "^")
2043                 return -1;
2044         if(strlen(s) < 5)
2045                 return -1;
2046         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
2047         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
2048         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
2049         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
2050         if(a < 0 || b < 0 || c < 0 || d < 0)
2051                 return -1;
2052         return ((a * 22 + b) * 22 + c) * 22 + d;
2053 }