qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ DEVASTATOR,
   4 /* function */ W_Devastator,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 9,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "rl",
  10 /* netname  */ "devastator",
  11 /* fullname */ _("Devastator")
  12 );
  13
  14 #define DEVASTATOR_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, damage) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, damageforcescale) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, detonatedelay) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, edgedamage) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, force) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, guidedelay) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, guidegoal) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, guiderate) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, guideratedelay) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, guidestop) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, health) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, lifetime) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, radius) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, refire) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, remote_damage) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, remote_edgedamage) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, remote_force) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, remote_radius) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, speed) \
  36         WEP_ADD_CVAR(weapon, MO_NONE, speedaccel) \
  37         WEP_ADD_CVAR(weapon, MO_NONE, speedstart) \
  38         WEP_ADD_CVAR(weapon, MO_NONE, foobarsdfsd) \
  39         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  40         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  41         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  42         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  43
  44 #ifdef SVQC
  45 DEVASTATOR_SETTINGS(devastator)
  46 .float rl_release;
  47 .float rl_detonate_later;
  48 #endif
  49 #else
  50 #ifdef SVQC
  51 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  52 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  53
  54 void W_Devastator_Unregister()
  55 {
  56         if(self.realowner && self.realowner.lastrocket == self)
  57         {
  58                 self.realowner.lastrocket = world;
  59                 // self.realowner.rl_release = 1;
  60         }
  61 }
  62
  63 void W_Devastator_Explode()
  64 {
  65         W_Devastator_Unregister();
  66
  67         if(other.takedamage == DAMAGE_AIM)
  68                 if(IS_PLAYER(other))
  69                         if(IsDifferentTeam(self.realowner, other))
  70                                 if(other.deadflag == DEAD_NO)
  71                                         if(IsFlying(other))
  72                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  73
  74         self.event_damage = func_null;
  75         self.takedamage = DAMAGE_NO;
  76
  77         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  78
  79         if (self.realowner.weapon == WEP_DEVASTATOR)
  80         {
  81                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  82                 {
  83                         self.realowner.cnt = WEP_DEVASTATOR;
  84                         ATTACK_FINISHED(self.realowner) = time;
  85                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  86                 }
  87         }
  88         remove (self);
  89 }
  90
  91 void W_Devastator_DoRemoteExplode()
  92 {
  93         W_Devastator_Unregister();
  94
  95         self.event_damage = func_null;
  96         self.takedamage = DAMAGE_NO;
  97
  98         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  99
 100         if (self.realowner.weapon == WEP_DEVASTATOR)
 101         {
 102                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
 103                 {
 104                         self.realowner.cnt = WEP_DEVASTATOR;
 105                         ATTACK_FINISHED(self.realowner) = time;
 106                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 107                 }
 108         }
 109         remove (self);
 110 }
 111
 112 void W_Devastator_RemoteExplode()
 113 {
 114         if(self.realowner.deadflag == DEAD_NO)
 115         if(self.realowner.lastrocket)
 116         {
 117                 if((self.spawnshieldtime >= 0)
 118                         ? (time >= self.spawnshieldtime) // timer
 119                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 120                 )
 121                 {
 122                         W_Devastator_DoRemoteExplode();
 123                 }
 124         }
 125 }
 126
 127 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 128 {
 129         if(thisdir * goaldir > maxturn_cos)
 130                 return goaldir;
 131         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 132                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 133         float f, m2;
 134         vector v;
 135         // solve:
 136         //   g = normalize(thisdir + goaldir * X)
 137         //   thisdir * g = maxturn
 138         //
 139         //   gg = thisdir + goaldir * X
 140         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 141         //
 142         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 143         f = thisdir * goaldir;
 144         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 145         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 146         m2 = maxturn_cos * maxturn_cos;
 147         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 148         return normalize(thisdir + goaldir * v_y); // the larger solution!
 149 }
 150 // assume thisdir == -goaldir:
 151 //   f == -1
 152 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 153 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 154 //   x^2 - 2 * x + 1 = 0
 155 //   (x - 1)^2 = 0
 156 //   x = 1
 157 //   normalize(thisdir + goaldir)
 158 //   normalize(0)
 159
 160 void W_Devastator_Think (void)
 161 {
 162         vector desireddir, olddir, newdir, desiredorigin, goal;
 163 #if 0
 164         float cosminang, cosmaxang, cosang;
 165 #endif
 166         float velspeed, f;
 167         self.nextthink = time;
 168         if (time > self.cnt)
 169         {
 170                 other = world;
 171                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 172                 W_Devastator_Explode ();
 173                 return;
 174         }
 175
 176         // accelerate
 177         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 178         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 179         if (velspeed > 0)
 180                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 181
 182         // laser guided, or remote detonation
 183         if (self.realowner.weapon == WEP_DEVASTATOR)
 184         {
 185                 if(self == self.realowner.lastrocket)
 186                 if not(self.realowner.rl_release)
 187                 if not(self.BUTTON_ATCK2)
 188                 if(WEP_CVAR(devastator, guiderate))
 189                 if(time > self.pushltime)
 190                 if(self.realowner.deadflag == DEAD_NO)
 191                 {
 192                         f = WEP_CVAR(devastator, guideratedelay);
 193                         if(f)
 194                                 f = bound(0, (time - self.pushltime) / f, 1);
 195                         else
 196                                 f = 1;
 197
 198                         velspeed = vlen(self.velocity);
 199
 200                         makevectors(self.realowner.v_angle);
 201                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 202                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 203                         olddir = normalize(self.velocity);
 204
 205                         // now it gets tricky... we want to move like some curve to approximate the target direction
 206                         // but we are limiting the rate at which we can turn!
 207                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 208                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 209
 210                         self.velocity = newdir * velspeed;
 211                         self.angles = vectoangles(self.velocity);
 212
 213                         if(!self.count)
 214                         {
 215                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 216                                 // TODO add a better sound here
 217                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 218                                 self.count = 1;
 219                         }
 220                 }
 221
 222                 if(self.rl_detonate_later)
 223                         W_Devastator_RemoteExplode();
 224         }
 225
 226         if(self.csqcprojectile_clientanimate == 0)
 227                 UpdateCSQCProjectile(self);
 228 }
 229
 230 void W_Devastator_Touch (void)
 231 {
 232         if(WarpZone_Projectile_Touch())
 233         {
 234                 if(wasfreed(self))
 235                         W_Devastator_Unregister();
 236                 return;
 237         }
 238         W_Devastator_Unregister();
 239         W_Devastator_Explode ();
 240 }
 241
 242 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 243 {
 244         if (self.health <= 0)
 245                 return;
 246
 247         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 248                 return; // g_projectiles_damage says to halt
 249
 250         self.health = self.health - damage;
 251         self.angles = vectoangles(self.velocity);
 252
 253         if (self.health <= 0)
 254                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 255 }
 256
 257 void W_Devastator_Attack (void)
 258 {
 259         entity missile;
 260         entity flash;
 261
 262         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo));
 263
 264         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 265         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 266
 267         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 268         missile.owner = missile.realowner = self;
 269         self.lastrocket = missile;
 270         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 271                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 272         else
 273                 missile.spawnshieldtime = -1;
 274         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 275         missile.classname = "rocket";
 276         missile.bot_dodge = TRUE;
 277         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 278
 279         missile.takedamage = DAMAGE_YES;
 280         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 281         missile.health = WEP_CVAR(devastator, health);
 282         missile.event_damage = W_Devastator_Damage;
 283         missile.damagedbycontents = TRUE;
 284
 285         missile.movetype = MOVETYPE_FLY;
 286         PROJECTILE_MAKETRIGGER(missile);
 287         missile.projectiledeathtype = WEP_DEVASTATOR;
 288         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 289
 290         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 291         W_SetupProjectileVelocity(missile, WEP_CVAR(devastator, speedstart), 0);
 292         missile.angles = vectoangles (missile.velocity);
 293
 294         missile.touch = W_Devastator_Touch;
 295         missile.think = W_Devastator_Think;
 296         missile.nextthink = time;
 297         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 298         missile.flags = FL_PROJECTILE;
 299         missile.missile_flags = MIF_SPLASH;
 300
 301         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 302
 303         // muzzle flash for 1st person view
 304         flash = spawn ();
 305         setmodel (flash, "models/flash.md3"); // precision set below
 306         SUB_SetFade (flash, time, 0.1);
 307         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 308         W_AttachToShotorg(flash, '5 0 0');
 309
 310         // common properties
 311         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 312 }
 313
 314 float W_Devastator(float req)
 315 {
 316         entity rock;
 317         float rockfound;
 318         float ammo_amount;
 319         switch(req)
 320         {
 321                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 322                 {
 323                         // aim and decide to fire if appropriate
 324                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 325                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 326                         {
 327                                 // decide whether to detonate rockets
 328                                 entity missile, targetlist, targ;
 329                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 330                                 float selfdamage, teamdamage, enemydamage;
 331                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 332                                 coredamage = WEP_CVAR(devastator, damage);
 333                                 edgeradius = WEP_CVAR(devastator, radius);
 334                                 recipricoledgeradius = 1 / edgeradius;
 335                                 selfdamage = 0;
 336                                 teamdamage = 0;
 337                                 enemydamage = 0;
 338                                 targetlist = findchainfloat(bot_attack, TRUE);
 339                                 missile = find(world, classname, "rocket");
 340                                 while (missile)
 341                                 {
 342                                         if (missile.realowner != self)
 343                                         {
 344                                                 missile = find(missile, classname, "rocket");
 345                                                 continue;
 346                                         }
 347                                         targ = targetlist;
 348                                         while (targ)
 349                                         {
 350                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 351                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 352                                                 // count potential damage according to type of target
 353                                                 if (targ == self)
 354                                                         selfdamage = selfdamage + d;
 355                                                 else if (targ.team == self.team && teamplay)
 356                                                         teamdamage = teamdamage + d;
 357                                                 else if (bot_shouldattack(targ))
 358                                                         enemydamage = enemydamage + d;
 359                                                 targ = targ.chain;
 360                                         }
 361                                         missile = find(missile, classname, "rocket");
 362                                 }
 363                                 float desirabledamage;
 364                                 desirabledamage = enemydamage;
 365                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 366                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 367                                 if (teamplay && self.team)
 368                                         desirabledamage = desirabledamage - teamdamage;
 369
 370                                 missile = find(world, classname, "rocket");
 371                                 while (missile)
 372                                 {
 373                                         if (missile.realowner != self)
 374                                         {
 375                                                 missile = find(missile, classname, "rocket");
 376                                                 continue;
 377                                         }
 378                                         makevectors(missile.v_angle);
 379                                         targ = targetlist;
 380                                         if (skill > 9) // normal players only do this for the target they are tracking
 381                                         {
 382                                                 targ = targetlist;
 383                                                 while (targ)
 384                                                 {
 385                                                         if (
 386                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 387                                                                 && desirabledamage > 0.1*coredamage
 388                                                         )self.BUTTON_ATCK2 = TRUE;
 389                                                         targ = targ.chain;
 390                                                 }
 391                                         }else{
 392                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 393                                                 //As the distance gets larger, a correct detonation gets near imposible
 394                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 395                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 396                                                         if(IS_PLAYER(self.enemy))
 397                                                                 if(desirabledamage >= 0.1*coredamage)
 398                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 399                                                                                 self.BUTTON_ATCK2 = TRUE;
 400                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 401                                         }
 402
 403                                         missile = find(missile, classname, "rocket");
 404                                 }
 405                                 // if we would be doing at X percent of the core damage, detonate it
 406                                 // but don't fire a new shot at the same time!
 407                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 408                                         self.BUTTON_ATCK2 = TRUE;
 409                                 if ((skill > 6.5) && (selfdamage > self.health))
 410                                         self.BUTTON_ATCK2 = FALSE;
 411                                 //if(self.BUTTON_ATCK2 == TRUE)
 412                                 //      dprint(ftos(desirabledamage),"\n");
 413                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 414                         }
 415
 416                         return TRUE;
 417                 }
 418                 case WR_THINK:
 419                 {
 420                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 421                                 WEP_ACTION(self.weapon, WR_RELOAD);
 422                         else
 423                         {
 424                                 if (self.BUTTON_ATCK)
 425                                 {
 426                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 427                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 428                                         {
 429                                                 W_Devastator_Attack();
 430                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 431                                                 self.rl_release = 0;
 432                                         }
 433                                 }
 434                                 else
 435                                         self.rl_release = 1;
 436
 437                                 if (self.BUTTON_ATCK2)
 438                                 {
 439                                         rockfound = 0;
 440                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 441                                         {
 442                                                 if(!rock.rl_detonate_later)
 443                                                 {
 444                                                         rock.rl_detonate_later = TRUE;
 445                                                         rockfound = 1;
 446                                                 }
 447                                         }
 448                                         if(rockfound)
 449                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 450                                 }
 451                         }
 452
 453                         return TRUE;
 454                 }
 455                 case WR_INIT:
 456                 {
 457                         if(autocvar_sv_precacheweapons)
 458                         {
 459                                 precache_model("models/flash.md3");
 460                                 precache_model("models/weapons/g_rl.md3");
 461                                 precache_model("models/weapons/v_rl.md3");
 462                                 precache_model("models/weapons/h_rl.iqm");
 463                                 precache_sound("weapons/rocket_det.wav");
 464                                 precache_sound("weapons/rocket_fire.wav");
 465                                 precache_sound("weapons/rocket_mode.wav");
 466                         }
 467
 468                         #define WEP_ADD_CVAR(weapon,mode,name) /*nothing*/
 469                         #define WEP_ADD_PROP(weapon,prop,name) WEP_SET_PROP(WEP_DEVASTATOR,weapon,prop,name)
 470                         ARC_SETTINGS(devastator)
 471                         #undef WEP_ADD_CVAR
 472                         #undef WEP_ADD_PROP
 473                         return TRUE;
 474                 }
 475                 case WR_SETUP:
 476                 {
 477                         weapon_setup(WEP_DEVASTATOR);
 478                         self.current_ammo = ammo_rockets;
 479                         self.rl_release = 1;
 480                         return TRUE;
 481                 }
 482                 case WR_CHECKAMMO1:
 483                 {
 484                         // don't switch while guiding a missile
 485                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 486                         {
 487                                 ammo_amount = FALSE;
 488                                 if(WEP_CVAR(devastator, reload_ammo))
 489                                 {
 490                                         if(self.ammo_rockets < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 491                                                 ammo_amount = TRUE;
 492                                 }
 493                                 else if(self.ammo_rockets < WEP_CVAR(devastator, ammo))
 494                                         ammo_amount = TRUE;
 495                                 return !ammo_amount;
 496                         }
 497
 498                         return TRUE;
 499                 }
 500                 case WR_CHECKAMMO2:
 501                 {
 502                         return FALSE;
 503                 }
 504                 case WR_CONFIG:
 505                 {
 506                         WEP_CONFIG_SETTINGS(DEVASTATOR_SETTINGS(devastator))
 507                         return TRUE;
 508                 }
 509                 case WR_RESETPLAYER:
 510                 {
 511                         self.rl_release = 0;
 512                         return TRUE;
 513                 }
 514                 case WR_RELOAD:
 515                 {
 516                         W_Reload(WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo), WEP_CVAR(devastator, reload_time), "weapons/reload.wav");
 517                         return TRUE;
 518                 }
 519                 case WR_SUICIDEMESSAGE:
 520                 {
 521                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 522                 }
 523                 case WR_KILLMESSAGE:
 524                 {
 525                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 526                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 527                         else
 528                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 529                 }
 530         }
 531         return TRUE;
 532 }
 533 #endif
 534 #ifdef CSQC
 535 float W_Devastator(float req)
 536 {
 537         switch(req)
 538         {
 539                 case WR_IMPACTEFFECT:
 540                 {
 541                         vector org2;
 542                         org2 = w_org + w_backoff * 12;
 543                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 544                         if(!w_issilent)
 545                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 546
 547                         return TRUE;
 548                 }
 549                 case WR_INIT:
 550                 {
 551                         precache_sound("weapons/rocket_impact.wav");
 552                         return TRUE;
 553                 }
 554         }
 555         return TRUE;
 556 }
 557 #endif
 558 #endif