qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ DEVASTATOR,
   4 /* function */ W_Devastator,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 9,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "rl",
  10 /* netname  */ "devastator",
  11 /* fullname */ _("Devastator")
  12 );
  13
  14 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, ammo) \
  16         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, animtime) \
  17         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, damage) \
  18         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, damageforcescale) \
  19         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, detonatedelay) \
  20         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, edgedamage) \
  21         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, force) \
  22         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guidedelay) \
  23         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guidegoal) \
  24         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guiderate) \
  25         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guideratedelay) \
  26         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, guidestop) \
  27         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, health) \
  28         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, lifetime) \
  29         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, radius) \
  30         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, refire) \
  31         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_damage) \
  32         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_edgedamage) \
  33         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_force) \
  34         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, remote_radius) \
  35         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, speed) \
  36         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, speedaccel) \
  37         w_cvar(WEP_DEVASTATOR, devastator, MO_NONE, speedstart) \
  38         w_prop(WEP_DEVASTATOR, devastator, reloading_ammo, reload_ammo) \
  39         w_prop(WEP_DEVASTATOR, devastator, reloading_time, reload_time) \
  40         w_prop(WEP_DEVASTATOR, devastator, switchdelay_raise, switchdelay_raise) \
  41         w_prop(WEP_DEVASTATOR, devastator, switchdelay_drop, switchdelay_drop)
  42
  43 #ifdef SVQC
  44 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  45 .float rl_release;
  46 .float rl_detonate_later;
  47 #endif
  48 #else
  49 #ifdef SVQC
  50 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  51 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  52
  53 void W_Devastator_Unregister()
  54 {
  55         if(self.realowner && self.realowner.lastrocket == self)
  56         {
  57                 self.realowner.lastrocket = world;
  58                 // self.realowner.rl_release = 1;
  59         }
  60 }
  61
  62 void W_Devastator_Explode()
  63 {
  64         W_Devastator_Unregister();
  65
  66         if(other.takedamage == DAMAGE_AIM)
  67                 if(IS_PLAYER(other))
  68                         if(DIFF_TEAM(self.realowner, other))
  69                                 if(other.deadflag == DEAD_NO)
  70                                         if(IsFlying(other))
  71                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  72
  73         self.event_damage = func_null;
  74         self.takedamage = DAMAGE_NO;
  75
  76         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  77
  78         if (self.realowner.weapon == WEP_DEVASTATOR)
  79         {
  80                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  81                 {
  82                         self.realowner.cnt = WEP_DEVASTATOR;
  83                         ATTACK_FINISHED(self.realowner) = time;
  84                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  85                 }
  86         }
  87         remove (self);
  88 }
  89
  90 void W_Devastator_DoRemoteExplode()
  91 {
  92         W_Devastator_Unregister();
  93
  94         self.event_damage = func_null;
  95         self.takedamage = DAMAGE_NO;
  96
  97         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  98
  99         if (self.realowner.weapon == WEP_DEVASTATOR)
 100         {
 101                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
 102                 {
 103                         self.realowner.cnt = WEP_DEVASTATOR;
 104                         ATTACK_FINISHED(self.realowner) = time;
 105                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 106                 }
 107         }
 108         remove (self);
 109 }
 110
 111 void W_Devastator_RemoteExplode()
 112 {
 113         if(self.realowner.deadflag == DEAD_NO)
 114         if(self.realowner.lastrocket)
 115         {
 116                 if((self.spawnshieldtime >= 0)
 117                         ? (time >= self.spawnshieldtime) // timer
 118                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 119                 )
 120                 {
 121                         W_Devastator_DoRemoteExplode();
 122                 }
 123         }
 124 }
 125
 126 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 127 {
 128         if(thisdir * goaldir > maxturn_cos)
 129                 return goaldir;
 130         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 131                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 132         float f, m2;
 133         vector v;
 134         // solve:
 135         //   g = normalize(thisdir + goaldir * X)
 136         //   thisdir * g = maxturn
 137         //
 138         //   gg = thisdir + goaldir * X
 139         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 140         //
 141         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 142         f = thisdir * goaldir;
 143         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 144         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 145         m2 = maxturn_cos * maxturn_cos;
 146         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 147         return normalize(thisdir + goaldir * v_y); // the larger solution!
 148 }
 149 // assume thisdir == -goaldir:
 150 //   f == -1
 151 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 152 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 153 //   x^2 - 2 * x + 1 = 0
 154 //   (x - 1)^2 = 0
 155 //   x = 1
 156 //   normalize(thisdir + goaldir)
 157 //   normalize(0)
 158
 159 void W_Devastator_Think (void)
 160 {
 161         vector desireddir, olddir, newdir, desiredorigin, goal;
 162 #if 0
 163         float cosminang, cosmaxang, cosang;
 164 #endif
 165         float velspeed, f;
 166         self.nextthink = time;
 167         if (time > self.cnt)
 168         {
 169                 other = world;
 170                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 171                 W_Devastator_Explode ();
 172                 return;
 173         }
 174
 175         // accelerate
 176         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 177         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 178         if (velspeed > 0)
 179                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 180
 181         // laser guided, or remote detonation
 182         if (self.realowner.weapon == WEP_DEVASTATOR)
 183         {
 184                 if(self == self.realowner.lastrocket)
 185                 if(!self.realowner.rl_release)
 186                 if(!self.BUTTON_ATCK2)
 187                 if(WEP_CVAR(devastator, guiderate))
 188                 if(time > self.pushltime)
 189                 if(self.realowner.deadflag == DEAD_NO)
 190                 {
 191                         f = WEP_CVAR(devastator, guideratedelay);
 192                         if(f)
 193                                 f = bound(0, (time - self.pushltime) / f, 1);
 194                         else
 195                                 f = 1;
 196
 197                         velspeed = vlen(self.velocity);
 198
 199                         makevectors(self.realowner.v_angle);
 200                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 201                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 202                         olddir = normalize(self.velocity);
 203
 204                         // now it gets tricky... we want to move like some curve to approximate the target direction
 205                         // but we are limiting the rate at which we can turn!
 206                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 207                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 208
 209                         self.velocity = newdir * velspeed;
 210                         self.angles = vectoangles(self.velocity);
 211
 212                         if(!self.count)
 213                         {
 214                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 215                                 // TODO add a better sound here
 216                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 217                                 self.count = 1;
 218                         }
 219                 }
 220
 221                 if(self.rl_detonate_later)
 222                         W_Devastator_RemoteExplode();
 223         }
 224
 225         if(self.csqcprojectile_clientanimate == 0)
 226                 UpdateCSQCProjectile(self);
 227 }
 228
 229 void W_Devastator_Touch (void)
 230 {
 231         if(WarpZone_Projectile_Touch())
 232         {
 233                 if(wasfreed(self))
 234                         W_Devastator_Unregister();
 235                 return;
 236         }
 237         W_Devastator_Unregister();
 238         W_Devastator_Explode ();
 239 }
 240
 241 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 242 {
 243         if (self.health <= 0)
 244                 return;
 245
 246         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 247                 return; // g_projectiles_damage says to halt
 248
 249         self.health = self.health - damage;
 250         self.angles = vectoangles(self.velocity);
 251
 252         if (self.health <= 0)
 253                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 254 }
 255
 256 void W_Devastator_Attack (void)
 257 {
 258         entity missile;
 259         entity flash;
 260
 261         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo));
 262
 263         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 264         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 265
 266         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 267         missile.owner = missile.realowner = self;
 268         self.lastrocket = missile;
 269         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 270                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 271         else
 272                 missile.spawnshieldtime = -1;
 273         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 274         missile.classname = "rocket";
 275         missile.bot_dodge = TRUE;
 276         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 277
 278         missile.takedamage = DAMAGE_YES;
 279         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 280         missile.health = WEP_CVAR(devastator, health);
 281         missile.event_damage = W_Devastator_Damage;
 282         missile.damagedbycontents = TRUE;
 283
 284         missile.movetype = MOVETYPE_FLY;
 285         PROJECTILE_MAKETRIGGER(missile);
 286         missile.projectiledeathtype = WEP_DEVASTATOR;
 287         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 288
 289         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 290         W_SetupProjectileVelocity(missile, WEP_CVAR(devastator, speedstart), 0);
 291         missile.angles = vectoangles (missile.velocity);
 292
 293         missile.touch = W_Devastator_Touch;
 294         missile.think = W_Devastator_Think;
 295         missile.nextthink = time;
 296         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 297         missile.flags = FL_PROJECTILE;
 298         missile.missile_flags = MIF_SPLASH;
 299
 300         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 301
 302         // muzzle flash for 1st person view
 303         flash = spawn ();
 304         setmodel (flash, "models/flash.md3"); // precision set below
 305         SUB_SetFade (flash, time, 0.1);
 306         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 307         W_AttachToShotorg(flash, '5 0 0');
 308
 309         // common properties
 310         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 311 }
 312
 313 float W_Devastator(float req)
 314 {
 315         entity rock;
 316         float rockfound;
 317         float ammo_amount;
 318         switch(req)
 319         {
 320                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 321                 {
 322                         // aim and decide to fire if appropriate
 323                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 324                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 325                         {
 326                                 // decide whether to detonate rockets
 327                                 entity missile, targetlist, targ;
 328                                 targetlist = findchainfloat(bot_attack, TRUE);
 329                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 330                                 {
 331                                         targ = targetlist;
 332                                         while (targ)
 333                                         {
 334                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 335                                                 {
 336                                                         self.BUTTON_ATCK2 = TRUE;
 337                                                         break;
 338                                                 }
 339                                                 targ = targ.chain;
 340                                         }
 341                                 }
 342
 343                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 344                         }
 345
 346                         return TRUE;
 347                 }
 348                 case WR_THINK:
 349                 {
 350                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 351                                 WEP_ACTION(self.weapon, WR_RELOAD);
 352                         else
 353                         {
 354                                 if (self.BUTTON_ATCK)
 355                                 {
 356                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 357                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 358                                         {
 359                                                 W_Devastator_Attack();
 360                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 361                                                 self.rl_release = 0;
 362                                         }
 363                                 }
 364                                 else
 365                                         self.rl_release = 1;
 366
 367                                 if (self.BUTTON_ATCK2)
 368                                 {
 369                                         rockfound = 0;
 370                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 371                                         {
 372                                                 if(!rock.rl_detonate_later)
 373                                                 {
 374                                                         rock.rl_detonate_later = TRUE;
 375                                                         rockfound = 1;
 376                                                 }
 377                                         }
 378                                         if(rockfound)
 379                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 380                                 }
 381                         }
 382
 383                         return TRUE;
 384                 }
 385                 case WR_INIT:
 386                 {
 387                         if(autocvar_sv_precacheweapons)
 388                         {
 389                                 precache_model("models/flash.md3");
 390                                 precache_model("models/weapons/g_rl.md3");
 391                                 precache_model("models/weapons/v_rl.md3");
 392                                 precache_model("models/weapons/h_rl.iqm");
 393                                 precache_sound("weapons/rocket_det.wav");
 394                                 precache_sound("weapons/rocket_fire.wav");
 395                                 precache_sound("weapons/rocket_mode.wav");
 396                         }
 397                         DEVASTATOR_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 398                         return TRUE;
 399                 }
 400                 case WR_SETUP:
 401                 {
 402                         self.current_ammo = ammo_rockets;
 403                         self.rl_release = 1;
 404                         return TRUE;
 405                 }
 406                 case WR_CHECKAMMO1:
 407                 {
 408                         // don't switch while guiding a missile
 409                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 410                         {
 411                                 ammo_amount = FALSE;
 412                                 if(WEP_CVAR(devastator, reload_ammo))
 413                                 {
 414                                         if(self.ammo_rockets < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 415                                                 ammo_amount = TRUE;
 416                                 }
 417                                 else if(self.ammo_rockets < WEP_CVAR(devastator, ammo))
 418                                         ammo_amount = TRUE;
 419                                 return !ammo_amount;
 420                         }
 421
 422                         return TRUE;
 423                 }
 424                 case WR_CHECKAMMO2:
 425                 {
 426                         return FALSE;
 427                 }
 428                 case WR_CONFIG:
 429                 {
 430                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 431                         return TRUE;
 432                 }
 433                 case WR_RESETPLAYER:
 434                 {
 435                         self.rl_release = 0;
 436                         return TRUE;
 437                 }
 438                 case WR_RELOAD:
 439                 {
 440                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 441                         return TRUE;
 442                 }
 443                 case WR_SUICIDEMESSAGE:
 444                 {
 445                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 446                 }
 447                 case WR_KILLMESSAGE:
 448                 {
 449                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 450                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 451                         else
 452                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 453                 }
 454         }
 455         return TRUE;
 456 }
 457 #endif
 458 #ifdef CSQC
 459 float W_Devastator(float req)
 460 {
 461         switch(req)
 462         {
 463                 case WR_IMPACTEFFECT:
 464                 {
 465                         vector org2;
 466                         org2 = w_org + w_backoff * 12;
 467                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 468                         if(!w_issilent)
 469                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 470
 471                         return TRUE;
 472                 }
 473                 case WR_INIT:
 474                 {
 475                         precache_sound("weapons/rocket_impact.wav");
 476                         return TRUE;
 477                 }
 478         }
 479         return TRUE;
 480 }
 481 #endif
 482 #endif