qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ IT_ROCKETS,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* model     */ "rl",
  10 /* shortname */ "devastator",
  11 /* fullname  */ _("Devastator")
  12 );
  13
  14 #define DEVASTATOR_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, damage) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, damageforcescale) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, detonatedelay) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, edgedamage) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, force) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, guidedelay) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, guidegoal) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, guiderate) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, guideratedelay) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, guidestop) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, health) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, lifetime) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, radius) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, refire) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, remote_damage) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, remote_edgedamage) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, remote_force) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, remote_radius) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, speed) \
  36         WEP_ADD_CVAR(weapon, MO_NONE, speedaccel) \
  37         WEP_ADD_CVAR(weapon, MO_NONE, speedstart) \
  38         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  39         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  40
  41 #ifdef SVQC
  42 DEVASTATOR_SETTINGS(devastator)
  43 #endif
  44 #else
  45 #ifdef SVQC
  46 .float rl_release;
  47 .float rl_detonate_later;
  48
  49 void W_Devastator_Unregister()
  50 {
  51         if(self.realowner && self.realowner.lastrocket == self)
  52         {
  53                 self.realowner.lastrocket = world;
  54                 // self.realowner.rl_release = 1;
  55         }
  56 }
  57
  58 void W_Devastator_Explode ()
  59 {
  60         W_Devastator_Unregister();
  61
  62         if(other.takedamage == DAMAGE_AIM)
  63                 if(IS_PLAYER(other))
  64                         if(IsDifferentTeam(self.realowner, other))
  65                                 if(other.deadflag == DEAD_NO)
  66                                         if(IsFlying(other))
  67                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  68
  69         self.event_damage = func_null;
  70         self.takedamage = DAMAGE_NO;
  71
  72         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  73
  74         if (self.realowner.weapon == WEP_DEVASTATOR)
  75         {
  76                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  77                 {
  78                         self.realowner.cnt = WEP_DEVASTATOR;
  79                         ATTACK_FINISHED(self.realowner) = time;
  80                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  81                 }
  82         }
  83         remove (self);
  84 }
  85
  86 void W_Devastator_DoRemoteExplode ()
  87 {
  88         W_Devastator_Unregister();
  89
  90         self.event_damage = func_null;
  91         self.takedamage = DAMAGE_NO;
  92
  93         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  94
  95         if (self.realowner.weapon == WEP_DEVASTATOR)
  96         {
  97                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  98                 {
  99                         self.realowner.cnt = WEP_DEVASTATOR;
 100                         ATTACK_FINISHED(self.realowner) = time;
 101                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 102                 }
 103         }
 104         remove (self);
 105 }
 106
 107 void W_Devastator_RemoteExplode()
 108 {
 109         if(self.realowner.deadflag == DEAD_NO)
 110         if(self.realowner.lastrocket)
 111         {
 112                 if((self.spawnshieldtime >= 0)
 113                         ? (time >= self.spawnshieldtime) // timer
 114                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 115                 )
 116                 {
 117                         W_Devastator_DoRemoteExplode();
 118                 }
 119         }
 120 }
 121
 122 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 123 {
 124         if(thisdir * goaldir > maxturn_cos)
 125                 return goaldir;
 126         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 127                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 128         float f, m2;
 129         vector v;
 130         // solve:
 131         //   g = normalize(thisdir + goaldir * X)
 132         //   thisdir * g = maxturn
 133         //
 134         //   gg = thisdir + goaldir * X
 135         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 136         //
 137         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 138         f = thisdir * goaldir;
 139         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 140         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 141         m2 = maxturn_cos * maxturn_cos;
 142         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 143         return normalize(thisdir + goaldir * v_y); // the larger solution!
 144 }
 145 // assume thisdir == -goaldir:
 146 //   f == -1
 147 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 148 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 149 //   x^2 - 2 * x + 1 = 0
 150 //   (x - 1)^2 = 0
 151 //   x = 1
 152 //   normalize(thisdir + goaldir)
 153 //   normalize(0)
 154
 155 void W_Devastator_Think (void)
 156 {
 157         vector desireddir, olddir, newdir, desiredorigin, goal;
 158 #if 0
 159         float cosminang, cosmaxang, cosang;
 160 #endif
 161         float velspeed, f;
 162         self.nextthink = time;
 163         if (time > self.cnt)
 164         {
 165                 other = world;
 166                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 167                 W_Devastator_Explode ();
 168                 return;
 169         }
 170
 171         // accelerate
 172         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 173         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 174         if (velspeed > 0)
 175                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 176
 177         // laser guided, or remote detonation
 178         if (self.realowner.weapon == WEP_DEVASTATOR)
 179         {
 180                 if(self == self.realowner.lastrocket)
 181                 if not(self.realowner.rl_release)
 182                 if not(self.BUTTON_ATCK2)
 183                 if(WEP_CVAR(devastator, guiderate))
 184                 if(time > self.pushltime)
 185                 if(self.realowner.deadflag == DEAD_NO)
 186                 {
 187                         f = WEP_CVAR(devastator, guideratedelay);
 188                         if(f)
 189                                 f = bound(0, (time - self.pushltime) / f, 1);
 190                         else
 191                                 f = 1;
 192
 193                         velspeed = vlen(self.velocity);
 194
 195                         makevectors(self.realowner.v_angle);
 196                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 197                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 198                         olddir = normalize(self.velocity);
 199
 200                         // now it gets tricky... we want to move like some curve to approximate the target direction
 201                         // but we are limiting the rate at which we can turn!
 202                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 203                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 204
 205                         self.velocity = newdir * velspeed;
 206                         self.angles = vectoangles(self.velocity);
 207
 208                         if(!self.count)
 209                         {
 210                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 211                                 // TODO add a better sound here
 212                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 213                                 self.count = 1;
 214                         }
 215                 }
 216
 217                 if(self.rl_detonate_later)
 218                         W_Devastator_RemoteExplode();
 219         }
 220
 221         if(self.csqcprojectile_clientanimate == 0)
 222                 UpdateCSQCProjectile(self);
 223 }
 224
 225 void W_Devastator_Touch (void)
 226 {
 227         if(WarpZone_Projectile_Touch())
 228         {
 229                 if(wasfreed(self))
 230                         W_Devastator_Unregister();
 231                 return;
 232         }
 233         W_Devastator_Unregister();
 234         W_Devastator_Explode ();
 235 }
 236
 237 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 238 {
 239         if (self.health <= 0)
 240                 return;
 241
 242         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 243                 return; // g_projectiles_damage says to halt
 244
 245         self.health = self.health - damage;
 246         self.angles = vectoangles(self.velocity);
 247
 248         if (self.health <= 0)
 249                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 250 }
 251
 252 void W_Devastator_Attack (void)
 253 {
 254         entity missile;
 255         entity flash;
 256
 257         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo));
 258
 259         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 260         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 261
 262         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 263         missile.owner = missile.realowner = self;
 264         self.lastrocket = missile;
 265         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 266                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 267         else
 268                 missile.spawnshieldtime = -1;
 269         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 270         missile.classname = "rocket";
 271         missile.bot_dodge = TRUE;
 272         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 273
 274         missile.takedamage = DAMAGE_YES;
 275         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 276         missile.health = WEP_CVAR(devastator, health);
 277         missile.event_damage = W_Devastator_Damage;
 278         missile.damagedbycontents = TRUE;
 279
 280         missile.movetype = MOVETYPE_FLY;
 281         PROJECTILE_MAKETRIGGER(missile);
 282         missile.projectiledeathtype = WEP_DEVASTATOR;
 283         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 284
 285         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 286         W_SetupProjectileVelocity(missile, WEP_CVAR(devastator, speedstart), 0);
 287         missile.angles = vectoangles (missile.velocity);
 288
 289         missile.touch = W_Devastator_Touch;
 290         missile.think = W_Devastator_Think;
 291         missile.nextthink = time;
 292         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 293         missile.flags = FL_PROJECTILE;
 294         missile.missile_flags = MIF_SPLASH;
 295
 296         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 297
 298         // muzzle flash for 1st person view
 299         flash = spawn ();
 300         setmodel (flash, "models/flash.md3"); // precision set below
 301         SUB_SetFade (flash, time, 0.1);
 302         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 303         W_AttachToShotorg(flash, '5 0 0');
 304
 305         // common properties
 306         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 307 }
 308
 309 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 310
 311 float W_Devastator(float req)
 312 {
 313         entity rock;
 314         float rockfound;
 315         float ammo_amount;
 316
 317         if (req == WR_AIM)
 318         {
 319                 // aim and decide to fire if appropriate
 320                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 321                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 322                 {
 323                         // decide whether to detonate rockets
 324                         entity missile, targetlist, targ;
 325                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 326                         float selfdamage, teamdamage, enemydamage;
 327                         edgedamage = WEP_CVAR(devastator, edgedamage);
 328                         coredamage = WEP_CVAR(devastator, damage);
 329                         edgeradius = WEP_CVAR(devastator, radius);
 330                         recipricoledgeradius = 1 / edgeradius;
 331                         selfdamage = 0;
 332                         teamdamage = 0;
 333                         enemydamage = 0;
 334                         targetlist = findchainfloat(bot_attack, TRUE);
 335                         missile = find(world, classname, "rocket");
 336                         while (missile)
 337                         {
 338                                 if (missile.realowner != self)
 339                                 {
 340                                         missile = find(missile, classname, "rocket");
 341                                         continue;
 342                                 }
 343                                 targ = targetlist;
 344                                 while (targ)
 345                                 {
 346                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 347                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 348                                         // count potential damage according to type of target
 349                                         if (targ == self)
 350                                                 selfdamage = selfdamage + d;
 351                                         else if (targ.team == self.team && teamplay)
 352                                                 teamdamage = teamdamage + d;
 353                                         else if (bot_shouldattack(targ))
 354                                                 enemydamage = enemydamage + d;
 355                                         targ = targ.chain;
 356                                 }
 357                                 missile = find(missile, classname, "rocket");
 358                         }
 359                         float desirabledamage;
 360                         desirabledamage = enemydamage;
 361                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 362                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 363                         if (teamplay && self.team)
 364                                 desirabledamage = desirabledamage - teamdamage;
 365
 366                         missile = find(world, classname, "rocket");
 367                         while (missile)
 368                         {
 369                                 if (missile.realowner != self)
 370                                 {
 371                                         missile = find(missile, classname, "rocket");
 372                                         continue;
 373                                 }
 374                                 makevectors(missile.v_angle);
 375                                 targ = targetlist;
 376                                 if (skill > 9) // normal players only do this for the target they are tracking
 377                                 {
 378                                         targ = targetlist;
 379                                         while (targ)
 380                                         {
 381                                                 if (
 382                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 383                                                         && desirabledamage > 0.1*coredamage
 384                                                 )self.BUTTON_ATCK2 = TRUE;
 385                                                 targ = targ.chain;
 386                                         }
 387                                 }else{
 388                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 389                                         //As the distance gets larger, a correct detonation gets near imposible
 390                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 391                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 392                                                 if(IS_PLAYER(self.enemy))
 393                                                         if(desirabledamage >= 0.1*coredamage)
 394                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 395                                                                         self.BUTTON_ATCK2 = TRUE;
 396                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 397                                 }
 398
 399                                 missile = find(missile, classname, "rocket");
 400                         }
 401                         // if we would be doing at X percent of the core damage, detonate it
 402                         // but don't fire a new shot at the same time!
 403                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 404                                 self.BUTTON_ATCK2 = TRUE;
 405                         if ((skill > 6.5) && (selfdamage > self.health))
 406                                 self.BUTTON_ATCK2 = FALSE;
 407                         //if(self.BUTTON_ATCK2 == TRUE)
 408                         //      dprint(ftos(desirabledamage),"\n");
 409                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 410                 }
 411         }
 412         else if (req == WR_THINK)
 413         {
 414                 if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 415                         weapon_action(self.weapon, WR_RELOAD);
 416                 else
 417                 {
 418                         if (self.BUTTON_ATCK)
 419                         {
 420                                 if(self.rl_release || WEP_CVAR(devastator, guidestop))
 421                                 if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 422                                 {
 423                                         W_Devastator_Attack();
 424                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 425                                         self.rl_release = 0;
 426                                 }
 427                         }
 428                         else
 429                                 self.rl_release = 1;
 430
 431                         if (self.BUTTON_ATCK2)
 432                         {
 433                                 rockfound = 0;
 434                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 435                                 {
 436                                         if(!rock.rl_detonate_later)
 437                                         {
 438                                                 rock.rl_detonate_later = TRUE;
 439                                                 rockfound = 1;
 440                                         }
 441                                 }
 442                                 if(rockfound)
 443                                         sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 444                         }
 445                 }
 446         }
 447         else if (req == WR_PRECACHE)
 448         {
 449                 precache_model ("models/flash.md3");
 450                 precache_model ("models/weapons/g_rl.md3");
 451                 precache_model ("models/weapons/v_rl.md3");
 452                 precache_model ("models/weapons/h_rl.iqm");
 453                 precache_sound ("weapons/rocket_det.wav");
 454                 precache_sound ("weapons/rocket_fire.wav");
 455                 precache_sound ("weapons/rocket_mode.wav");
 456                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 457         }
 458         else if (req == WR_SETUP)
 459         {
 460                 weapon_setup(WEP_DEVASTATOR);
 461                 self.current_ammo = ammo_rockets;
 462                 self.rl_release = 1;
 463         }
 464         else if (req == WR_CHECKAMMO1)
 465         {
 466                 // don't switch while guiding a missile
 467                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 468                 {
 469                         ammo_amount = FALSE;
 470                         if(WEP_CVAR(devastator, reload_ammo))
 471                         {
 472                                 if(self.ammo_rockets < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 473                                         ammo_amount = TRUE;
 474                         }
 475                         else if(self.ammo_rockets < WEP_CVAR(devastator, ammo))
 476                                 ammo_amount = TRUE;
 477                         return !ammo_amount;
 478                 }
 479         }
 480         else if (req == WR_CHECKAMMO2)
 481                 return FALSE;
 482         else if (req == WR_RESETPLAYER)
 483         {
 484                 self.rl_release = 0;
 485         }
 486         else if (req == WR_RELOAD)
 487         {
 488                 W_Reload(WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo), WEP_CVAR(devastator, reload_time), "weapons/reload.wav");
 489         }
 490         else if (req == WR_SUICIDEMESSAGE)
 491         {
 492                 return WEAPON_ROCKETLAUNCHER_SUICIDE;
 493         }
 494         else if (req == WR_KILLMESSAGE)
 495         {
 496                 if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 497                         return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 498                 else
 499                         return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 500         }
 501         return TRUE;
 502 }
 503 #endif
 504 #ifdef CSQC
 505 float W_Devastator(float req)
 506 {
 507         if(req == WR_IMPACTEFFECT)
 508         {
 509                 vector org2;
 510                 org2 = w_org + w_backoff * 12;
 511                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 512                 if(!w_issilent)
 513                         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 514         }
 515         else if(req == WR_PRECACHE)
 516         {
 517                 precache_sound("weapons/rocket_impact.wav");
 518         }
 519         return TRUE;
 520 }
 521 #endif
 522 #endif