qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ IT_ROCKETS,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* model     */ "rl",
  10 /* shortname */ "devastator",
  11 /* fullname  */ _("Devastator")
  12 );
  13
  14 #define DEVASTATOR_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, damage) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, damageforcescale) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, detonatedelay) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, edgedamage) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, force) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, guidedelay) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, guidegoal) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, guiderate) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, guideratedelay) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, guidestop) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, health) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, lifetime) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, radius) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, refire) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, remote_damage) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, remote_edgedamage) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, remote_force) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, remote_radius) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, speed) \
  36         WEP_ADD_CVAR(weapon, MO_NONE, speedaccel) \
  37         WEP_ADD_CVAR(weapon, MO_NONE, speedstart) \
  38         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  39         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  40         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  41         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  42
  43 #ifdef SVQC
  44 DEVASTATOR_SETTINGS(devastator)
  45 .float rl_release;
  46 .float rl_detonate_later;
  47 #endif
  48 #else
  49 #ifdef SVQC
  50 void spawnfunc_weapon_rocketlauncher()
  51 {
  52         weapon_defaultspawnfunc(WEP_DEVASTATOR);
  53 }
  54
  55 void W_Devastator_Unregister()
  56 {
  57         if(self.realowner && self.realowner.lastrocket == self)
  58         {
  59                 self.realowner.lastrocket = world;
  60                 // self.realowner.rl_release = 1;
  61         }
  62 }
  63
  64 void W_Devastator_Explode()
  65 {
  66         W_Devastator_Unregister();
  67
  68         if(other.takedamage == DAMAGE_AIM)
  69                 if(IS_PLAYER(other))
  70                         if(IsDifferentTeam(self.realowner, other))
  71                                 if(other.deadflag == DEAD_NO)
  72                                         if(IsFlying(other))
  73                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  74
  75         self.event_damage = func_null;
  76         self.takedamage = DAMAGE_NO;
  77
  78         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  79
  80         if (self.realowner.weapon == WEP_DEVASTATOR)
  81         {
  82                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  83                 {
  84                         self.realowner.cnt = WEP_DEVASTATOR;
  85                         ATTACK_FINISHED(self.realowner) = time;
  86                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  87                 }
  88         }
  89         remove (self);
  90 }
  91
  92 void W_Devastator_DoRemoteExplode()
  93 {
  94         W_Devastator_Unregister();
  95
  96         self.event_damage = func_null;
  97         self.takedamage = DAMAGE_NO;
  98
  99         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 100
 101         if (self.realowner.weapon == WEP_DEVASTATOR)
 102         {
 103                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
 104                 {
 105                         self.realowner.cnt = WEP_DEVASTATOR;
 106                         ATTACK_FINISHED(self.realowner) = time;
 107                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 108                 }
 109         }
 110         remove (self);
 111 }
 112
 113 void W_Devastator_RemoteExplode()
 114 {
 115         if(self.realowner.deadflag == DEAD_NO)
 116         if(self.realowner.lastrocket)
 117         {
 118                 if((self.spawnshieldtime >= 0)
 119                         ? (time >= self.spawnshieldtime) // timer
 120                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 121                 )
 122                 {
 123                         W_Devastator_DoRemoteExplode();
 124                 }
 125         }
 126 }
 127
 128 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 129 {
 130         if(thisdir * goaldir > maxturn_cos)
 131                 return goaldir;
 132         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 133                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 134         float f, m2;
 135         vector v;
 136         // solve:
 137         //   g = normalize(thisdir + goaldir * X)
 138         //   thisdir * g = maxturn
 139         //
 140         //   gg = thisdir + goaldir * X
 141         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 142         //
 143         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 144         f = thisdir * goaldir;
 145         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 146         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 147         m2 = maxturn_cos * maxturn_cos;
 148         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 149         return normalize(thisdir + goaldir * v_y); // the larger solution!
 150 }
 151 // assume thisdir == -goaldir:
 152 //   f == -1
 153 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 154 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 155 //   x^2 - 2 * x + 1 = 0
 156 //   (x - 1)^2 = 0
 157 //   x = 1
 158 //   normalize(thisdir + goaldir)
 159 //   normalize(0)
 160
 161 void W_Devastator_Think (void)
 162 {
 163         vector desireddir, olddir, newdir, desiredorigin, goal;
 164 #if 0
 165         float cosminang, cosmaxang, cosang;
 166 #endif
 167         float velspeed, f;
 168         self.nextthink = time;
 169         if (time > self.cnt)
 170         {
 171                 other = world;
 172                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 173                 W_Devastator_Explode ();
 174                 return;
 175         }
 176
 177         // accelerate
 178         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 179         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 180         if (velspeed > 0)
 181                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 182
 183         // laser guided, or remote detonation
 184         if (self.realowner.weapon == WEP_DEVASTATOR)
 185         {
 186                 if(self == self.realowner.lastrocket)
 187                 if not(self.realowner.rl_release)
 188                 if not(self.BUTTON_ATCK2)
 189                 if(WEP_CVAR(devastator, guiderate))
 190                 if(time > self.pushltime)
 191                 if(self.realowner.deadflag == DEAD_NO)
 192                 {
 193                         f = WEP_CVAR(devastator, guideratedelay);
 194                         if(f)
 195                                 f = bound(0, (time - self.pushltime) / f, 1);
 196                         else
 197                                 f = 1;
 198
 199                         velspeed = vlen(self.velocity);
 200
 201                         makevectors(self.realowner.v_angle);
 202                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 203                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 204                         olddir = normalize(self.velocity);
 205
 206                         // now it gets tricky... we want to move like some curve to approximate the target direction
 207                         // but we are limiting the rate at which we can turn!
 208                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 209                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 210
 211                         self.velocity = newdir * velspeed;
 212                         self.angles = vectoangles(self.velocity);
 213
 214                         if(!self.count)
 215                         {
 216                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 217                                 // TODO add a better sound here
 218                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 219                                 self.count = 1;
 220                         }
 221                 }
 222
 223                 if(self.rl_detonate_later)
 224                         W_Devastator_RemoteExplode();
 225         }
 226
 227         if(self.csqcprojectile_clientanimate == 0)
 228                 UpdateCSQCProjectile(self);
 229 }
 230
 231 void W_Devastator_Touch (void)
 232 {
 233         if(WarpZone_Projectile_Touch())
 234         {
 235                 if(wasfreed(self))
 236                         W_Devastator_Unregister();
 237                 return;
 238         }
 239         W_Devastator_Unregister();
 240         W_Devastator_Explode ();
 241 }
 242
 243 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 244 {
 245         if (self.health <= 0)
 246                 return;
 247
 248         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 249                 return; // g_projectiles_damage says to halt
 250
 251         self.health = self.health - damage;
 252         self.angles = vectoangles(self.velocity);
 253
 254         if (self.health <= 0)
 255                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 256 }
 257
 258 void W_Devastator_Attack (void)
 259 {
 260         entity missile;
 261         entity flash;
 262
 263         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo));
 264
 265         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 266         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 267
 268         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 269         missile.owner = missile.realowner = self;
 270         self.lastrocket = missile;
 271         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 272                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 273         else
 274                 missile.spawnshieldtime = -1;
 275         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 276         missile.classname = "rocket";
 277         missile.bot_dodge = TRUE;
 278         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 279
 280         missile.takedamage = DAMAGE_YES;
 281         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 282         missile.health = WEP_CVAR(devastator, health);
 283         missile.event_damage = W_Devastator_Damage;
 284         missile.damagedbycontents = TRUE;
 285
 286         missile.movetype = MOVETYPE_FLY;
 287         PROJECTILE_MAKETRIGGER(missile);
 288         missile.projectiledeathtype = WEP_DEVASTATOR;
 289         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 290
 291         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 292         W_SetupProjectileVelocity(missile, WEP_CVAR(devastator, speedstart), 0);
 293         missile.angles = vectoangles (missile.velocity);
 294
 295         missile.touch = W_Devastator_Touch;
 296         missile.think = W_Devastator_Think;
 297         missile.nextthink = time;
 298         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 299         missile.flags = FL_PROJECTILE;
 300         missile.missile_flags = MIF_SPLASH;
 301
 302         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 303
 304         // muzzle flash for 1st person view
 305         flash = spawn ();
 306         setmodel (flash, "models/flash.md3"); // precision set below
 307         SUB_SetFade (flash, time, 0.1);
 308         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 309         W_AttachToShotorg(flash, '5 0 0');
 310
 311         // common properties
 312         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 313 }
 314
 315 float W_Devastator(float req)
 316 {
 317         entity rock;
 318         float rockfound;
 319         float ammo_amount;
 320         switch(req)
 321         {
 322                 case WR_AIM:
 323                 {
 324                         // aim and decide to fire if appropriate
 325                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 326                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 327                         {
 328                                 // decide whether to detonate rockets
 329                                 entity missile, targetlist, targ;
 330                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 331                                 float selfdamage, teamdamage, enemydamage;
 332                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 333                                 coredamage = WEP_CVAR(devastator, damage);
 334                                 edgeradius = WEP_CVAR(devastator, radius);
 335                                 recipricoledgeradius = 1 / edgeradius;
 336                                 selfdamage = 0;
 337                                 teamdamage = 0;
 338                                 enemydamage = 0;
 339                                 targetlist = findchainfloat(bot_attack, TRUE);
 340                                 missile = find(world, classname, "rocket");
 341                                 while (missile)
 342                                 {
 343                                         if (missile.realowner != self)
 344                                         {
 345                                                 missile = find(missile, classname, "rocket");
 346                                                 continue;
 347                                         }
 348                                         targ = targetlist;
 349                                         while (targ)
 350                                         {
 351                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 352                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 353                                                 // count potential damage according to type of target
 354                                                 if (targ == self)
 355                                                         selfdamage = selfdamage + d;
 356                                                 else if (targ.team == self.team && teamplay)
 357                                                         teamdamage = teamdamage + d;
 358                                                 else if (bot_shouldattack(targ))
 359                                                         enemydamage = enemydamage + d;
 360                                                 targ = targ.chain;
 361                                         }
 362                                         missile = find(missile, classname, "rocket");
 363                                 }
 364                                 float desirabledamage;
 365                                 desirabledamage = enemydamage;
 366                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 367                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 368                                 if (teamplay && self.team)
 369                                         desirabledamage = desirabledamage - teamdamage;
 370
 371                                 missile = find(world, classname, "rocket");
 372                                 while (missile)
 373                                 {
 374                                         if (missile.realowner != self)
 375                                         {
 376                                                 missile = find(missile, classname, "rocket");
 377                                                 continue;
 378                                         }
 379                                         makevectors(missile.v_angle);
 380                                         targ = targetlist;
 381                                         if (skill > 9) // normal players only do this for the target they are tracking
 382                                         {
 383                                                 targ = targetlist;
 384                                                 while (targ)
 385                                                 {
 386                                                         if (
 387                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 388                                                                 && desirabledamage > 0.1*coredamage
 389                                                         )self.BUTTON_ATCK2 = TRUE;
 390                                                         targ = targ.chain;
 391                                                 }
 392                                         }else{
 393                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 394                                                 //As the distance gets larger, a correct detonation gets near imposible
 395                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 396                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 397                                                         if(IS_PLAYER(self.enemy))
 398                                                                 if(desirabledamage >= 0.1*coredamage)
 399                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 400                                                                                 self.BUTTON_ATCK2 = TRUE;
 401                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 402                                         }
 403
 404                                         missile = find(missile, classname, "rocket");
 405                                 }
 406                                 // if we would be doing at X percent of the core damage, detonate it
 407                                 // but don't fire a new shot at the same time!
 408                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 409                                         self.BUTTON_ATCK2 = TRUE;
 410                                 if ((skill > 6.5) && (selfdamage > self.health))
 411                                         self.BUTTON_ATCK2 = FALSE;
 412                                 //if(self.BUTTON_ATCK2 == TRUE)
 413                                 //      dprint(ftos(desirabledamage),"\n");
 414                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 415                         }
 416
 417                         return TRUE;
 418                 }
 419                 case WR_THINK:
 420                 {
 421                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 422                                 weapon_action(self.weapon, WR_RELOAD);
 423                         else
 424                         {
 425                                 if (self.BUTTON_ATCK)
 426                                 {
 427                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 428                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 429                                         {
 430                                                 W_Devastator_Attack();
 431                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 432                                                 self.rl_release = 0;
 433                                         }
 434                                 }
 435                                 else
 436                                         self.rl_release = 1;
 437
 438                                 if (self.BUTTON_ATCK2)
 439                                 {
 440                                         rockfound = 0;
 441                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 442                                         {
 443                                                 if(!rock.rl_detonate_later)
 444                                                 {
 445                                                         rock.rl_detonate_later = TRUE;
 446                                                         rockfound = 1;
 447                                                 }
 448                                         }
 449                                         if(rockfound)
 450                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 451                                 }
 452                         }
 453
 454                         return TRUE;
 455                 }
 456                 case WR_PRECACHE:
 457                 {
 458                         if(autocvar_sv_precacheweapons)
 459                         {
 460                                 precache_model ("models/flash.md3");
 461                                 precache_model ("models/weapons/g_rl.md3");
 462                                 precache_model ("models/weapons/v_rl.md3");
 463                                 precache_model ("models/weapons/h_rl.iqm");
 464                                 precache_sound ("weapons/rocket_det.wav");
 465                                 precache_sound ("weapons/rocket_fire.wav");
 466                                 precache_sound ("weapons/rocket_mode.wav");
 467                         }
 468
 469                         #define WEP_ADD_CVAR(weapon,mode,name) /*nothing*/
 470                         #define WEP_ADD_PROP(weapon,prop,name) get_weaponinfo(WEP_DEVASTATOR).##prop = autocvar_g_balance_##weapon##_##name;
 471                         ARC_SETTINGS(devastator)
 472                         #undef WEP_ADD_CVAR
 473                         #undef WEP_ADD_PROP
 474
 475                         return TRUE;
 476                 }
 477                 case WR_SETUP:
 478                 {
 479                         weapon_setup(WEP_DEVASTATOR);
 480                         self.current_ammo = ammo_rockets;
 481                         self.rl_release = 1;
 482                         return TRUE;
 483                 }
 484                 case WR_CHECKAMMO1:
 485                 {
 486                         // don't switch while guiding a missile
 487                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 488                         {
 489                                 ammo_amount = FALSE;
 490                                 if(WEP_CVAR(devastator, reload_ammo))
 491                                 {
 492                                         if(self.ammo_rockets < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 493                                                 ammo_amount = TRUE;
 494                                 }
 495                                 else if(self.ammo_rockets < WEP_CVAR(devastator, ammo))
 496                                         ammo_amount = TRUE;
 497                                 return !ammo_amount;
 498                         }
 499
 500                         return TRUE;
 501                 }
 502                 case WR_CHECKAMMO2:
 503                 {
 504                         return FALSE;
 505                 }
 506                 case WR_RESETPLAYER:
 507                 {
 508                         self.rl_release = 0;
 509                         return TRUE;
 510                 }
 511                 case WR_RELOAD:
 512                 {
 513                         W_Reload(WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo), WEP_CVAR(devastator, reload_time), "weapons/reload.wav");
 514                         return TRUE;
 515                 }
 516                 case WR_SUICIDEMESSAGE:
 517                 {
 518                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 519                 }
 520                 case WR_KILLMESSAGE:
 521                 {
 522                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 523                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 524                         else
 525                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 526                 }
 527         }
 528         return TRUE;
 529 }
 530 #endif
 531 #ifdef CSQC
 532 float W_Devastator(float req)
 533 {
 534         switch(req)
 535         {
 536                 case WR_IMPACTEFFECT:
 537                 {
 538                         vector org2;
 539                         org2 = w_org + w_backoff * 12;
 540                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 541                         if(!w_issilent)
 542                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 543
 544                         return TRUE;
 545                 }
 546                 case WR_PRECACHE:
 547                 {
 548                         precache_sound("weapons/rocket_impact.wav");
 549                         return TRUE;
 550                 }
 551         }
 552         return TRUE;
 553 }
 554 #endif
 555 #endif