qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 0',
  10 /* firstpmdl */ "models/weapons/h_rl.iqm",
  11 /* thirdpmdl */ "models/weapons/v_rl.md3",
  12 /* pickupmdl */ "models/weapons/g_rl.md3",
  13 /* simplemdl */ "foobar",
  14 /* crosshair */ "gfx/crosshairrocketlauncher 0.5875",
  15 /* refname   */ "devastator",
  16 /* wepname   */ _("Devastator")
  17 );
  18
  19 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  20 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  21         w_cvar(id, sn, NONE, ammo) \
  22         w_cvar(id, sn, NONE, animtime) \
  23         w_cvar(id, sn, NONE, damage) \
  24         w_cvar(id, sn, NONE, damageforcescale) \
  25         w_cvar(id, sn, NONE, detonatedelay) \
  26         w_cvar(id, sn, NONE, edgedamage) \
  27         w_cvar(id, sn, NONE, force) \
  28         w_cvar(id, sn, NONE, guidedelay) \
  29         w_cvar(id, sn, NONE, guidegoal) \
  30         w_cvar(id, sn, NONE, guiderate) \
  31         w_cvar(id, sn, NONE, guideratedelay) \
  32         w_cvar(id, sn, NONE, guidestop) \
  33         w_cvar(id, sn, NONE, health) \
  34         w_cvar(id, sn, NONE, lifetime) \
  35         w_cvar(id, sn, NONE, radius) \
  36         w_cvar(id, sn, NONE, refire) \
  37         w_cvar(id, sn, NONE, remote_damage) \
  38         w_cvar(id, sn, NONE, remote_edgedamage) \
  39         w_cvar(id, sn, NONE, remote_force) \
  40         w_cvar(id, sn, NONE, remote_radius) \
  41         w_cvar(id, sn, NONE, speed) \
  42         w_cvar(id, sn, NONE, speedaccel) \
  43         w_cvar(id, sn, NONE, speedstart) \
  44         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  45         w_prop(id, sn, float,  reloading_time, reload_time) \
  46         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  47         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  48         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  49         w_prop(id, sn, float,  weaponstart, weaponstart) \
  50         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  51
  52 #ifdef SVQC
  53 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  54 .float rl_release;
  55 .float rl_detonate_later;
  56 #endif
  57 #else
  58 #ifdef SVQC
  59 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  60 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  61
  62 void W_Devastator_Unregister()
  63 {
  64         if(self.realowner && self.realowner.lastrocket == self)
  65         {
  66                 self.realowner.lastrocket = world;
  67                 // self.realowner.rl_release = 1;
  68         }
  69 }
  70
  71 void W_Devastator_Explode()
  72 {
  73         W_Devastator_Unregister();
  74
  75         if(other.takedamage == DAMAGE_AIM)
  76                 if(IS_PLAYER(other))
  77                         if(DIFF_TEAM(self.realowner, other))
  78                                 if(other.deadflag == DEAD_NO)
  79                                         if(IsFlying(other))
  80                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  81
  82         self.event_damage = func_null;
  83         self.takedamage = DAMAGE_NO;
  84
  85         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  86
  87         if (self.realowner.weapon == WEP_DEVASTATOR)
  88         {
  89                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
  90                 {
  91                         self.realowner.cnt = WEP_DEVASTATOR;
  92                         ATTACK_FINISHED(self.realowner) = time;
  93                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  94                 }
  95         }
  96         remove (self);
  97 }
  98
  99 void W_Devastator_DoRemoteExplode()
 100 {
 101         W_Devastator_Unregister();
 102
 103         self.event_damage = func_null;
 104         self.takedamage = DAMAGE_NO;
 105
 106         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 107
 108         if (self.realowner.weapon == WEP_DEVASTATOR)
 109         {
 110                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 111                 {
 112                         self.realowner.cnt = WEP_DEVASTATOR;
 113                         ATTACK_FINISHED(self.realowner) = time;
 114                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 115                 }
 116         }
 117         remove (self);
 118 }
 119
 120 void W_Devastator_RemoteExplode()
 121 {
 122         if(self.realowner.deadflag == DEAD_NO)
 123         if(self.realowner.lastrocket)
 124         {
 125                 if((self.spawnshieldtime >= 0)
 126                         ? (time >= self.spawnshieldtime) // timer
 127                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 128                 )
 129                 {
 130                         W_Devastator_DoRemoteExplode();
 131                 }
 132         }
 133 }
 134
 135 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 136 {
 137         if(thisdir * goaldir > maxturn_cos)
 138                 return goaldir;
 139         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 140                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 141         float f, m2;
 142         vector v;
 143         // solve:
 144         //   g = normalize(thisdir + goaldir * X)
 145         //   thisdir * g = maxturn
 146         //
 147         //   gg = thisdir + goaldir * X
 148         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 149         //
 150         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 151         f = thisdir * goaldir;
 152         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 153         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 154         m2 = maxturn_cos * maxturn_cos;
 155         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 156         return normalize(thisdir + goaldir * v_y); // the larger solution!
 157 }
 158 // assume thisdir == -goaldir:
 159 //   f == -1
 160 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 161 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 162 //   x^2 - 2 * x + 1 = 0
 163 //   (x - 1)^2 = 0
 164 //   x = 1
 165 //   normalize(thisdir + goaldir)
 166 //   normalize(0)
 167
 168 void W_Devastator_Think (void)
 169 {
 170         vector desireddir, olddir, newdir, desiredorigin, goal;
 171 #if 0
 172         float cosminang, cosmaxang, cosang;
 173 #endif
 174         float velspeed, f;
 175         self.nextthink = time;
 176         if (time > self.cnt)
 177         {
 178                 other = world;
 179                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 180                 W_Devastator_Explode ();
 181                 return;
 182         }
 183
 184         // accelerate
 185         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 186         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 187         if (velspeed > 0)
 188                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 189
 190         // laser guided, or remote detonation
 191         if (self.realowner.weapon == WEP_DEVASTATOR)
 192         {
 193                 if(self == self.realowner.lastrocket)
 194                 if(!self.realowner.rl_release)
 195                 if(!self.BUTTON_ATCK2)
 196                 if(WEP_CVAR(devastator, guiderate))
 197                 if(time > self.pushltime)
 198                 if(self.realowner.deadflag == DEAD_NO)
 199                 {
 200                         f = WEP_CVAR(devastator, guideratedelay);
 201                         if(f)
 202                                 f = bound(0, (time - self.pushltime) / f, 1);
 203                         else
 204                                 f = 1;
 205
 206                         velspeed = vlen(self.velocity);
 207
 208                         makevectors(self.realowner.v_angle);
 209                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 210                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 211                         olddir = normalize(self.velocity);
 212
 213                         // now it gets tricky... we want to move like some curve to approximate the target direction
 214                         // but we are limiting the rate at which we can turn!
 215                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 216                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 217
 218                         self.velocity = newdir * velspeed;
 219                         self.angles = vectoangles(self.velocity);
 220
 221                         if(!self.count)
 222                         {
 223                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 224                                 // TODO add a better sound here
 225                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 226                                 self.count = 1;
 227                         }
 228                 }
 229
 230                 if(self.rl_detonate_later)
 231                         W_Devastator_RemoteExplode();
 232         }
 233
 234         if(self.csqcprojectile_clientanimate == 0)
 235                 UpdateCSQCProjectile(self);
 236 }
 237
 238 void W_Devastator_Touch (void)
 239 {
 240         if(WarpZone_Projectile_Touch())
 241         {
 242                 if(wasfreed(self))
 243                         W_Devastator_Unregister();
 244                 return;
 245         }
 246         W_Devastator_Unregister();
 247         W_Devastator_Explode ();
 248 }
 249
 250 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 251 {
 252         if (self.health <= 0)
 253                 return;
 254
 255         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 256                 return; // g_projectiles_damage says to halt
 257
 258         self.health = self.health - damage;
 259         self.angles = vectoangles(self.velocity);
 260
 261         if (self.health <= 0)
 262                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 263 }
 264
 265 void W_Devastator_Attack (void)
 266 {
 267         entity missile;
 268         entity flash;
 269
 270         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 271
 272         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 273         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 274
 275         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 276         missile.owner = missile.realowner = self;
 277         self.lastrocket = missile;
 278         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 279                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 280         else
 281                 missile.spawnshieldtime = -1;
 282         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 283         missile.classname = "rocket";
 284         missile.bot_dodge = TRUE;
 285         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 286
 287         missile.takedamage = DAMAGE_YES;
 288         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 289         missile.health = WEP_CVAR(devastator, health);
 290         missile.event_damage = W_Devastator_Damage;
 291         missile.damagedbycontents = TRUE;
 292
 293         missile.movetype = MOVETYPE_FLY;
 294         PROJECTILE_MAKETRIGGER(missile);
 295         missile.projectiledeathtype = WEP_DEVASTATOR;
 296         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 297
 298         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 299         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 300         missile.angles = vectoangles (missile.velocity);
 301
 302         missile.touch = W_Devastator_Touch;
 303         missile.think = W_Devastator_Think;
 304         missile.nextthink = time;
 305         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 306         missile.flags = FL_PROJECTILE;
 307         missile.missile_flags = MIF_SPLASH;
 308
 309         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 310
 311         // muzzle flash for 1st person view
 312         flash = spawn ();
 313         setmodel (flash, "models/flash.md3"); // precision set below
 314         SUB_SetFade (flash, time, 0.1);
 315         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 316         W_AttachToShotorg(flash, '5 0 0');
 317
 318         // common properties
 319         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 320 }
 321
 322 float W_Devastator(float req)
 323 {
 324         entity rock;
 325         float rockfound;
 326         float ammo_amount;
 327         switch(req)
 328         {
 329                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 330                 {
 331                         // aim and decide to fire if appropriate
 332                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 333                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 334                         {
 335                                 // decide whether to detonate rockets
 336                                 entity missile, targetlist, targ;
 337                                 targetlist = findchainfloat(bot_attack, TRUE);
 338                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 339                                 {
 340                                         targ = targetlist;
 341                                         while(targ)
 342                                         {
 343                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 344                                                 {
 345                                                         self.BUTTON_ATCK2 = TRUE;
 346                                                         break;
 347                                                 }
 348                                                 targ = targ.chain;
 349                                         }
 350                                 }
 351
 352                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 353                         }
 354
 355                         return TRUE;
 356                 }
 357                 case WR_THINK:
 358                 {
 359                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 360                                 WEP_ACTION(self.weapon, WR_RELOAD);
 361                         else
 362                         {
 363                                 if(self.BUTTON_ATCK)
 364                                 {
 365                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 366                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 367                                         {
 368                                                 W_Devastator_Attack();
 369                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 370                                                 self.rl_release = 0;
 371                                         }
 372                                 }
 373                                 else
 374                                         self.rl_release = 1;
 375
 376                                 if(self.BUTTON_ATCK2)
 377                                 {
 378                                         rockfound = 0;
 379                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 380                                         {
 381                                                 if(!rock.rl_detonate_later)
 382                                                 {
 383                                                         rock.rl_detonate_later = TRUE;
 384                                                         rockfound = 1;
 385                                                 }
 386                                         }
 387                                         if(rockfound)
 388                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 389                                 }
 390                         }
 391
 392                         return TRUE;
 393                 }
 394                 case WR_INIT:
 395                 {
 396                         if(autocvar_sv_precacheweapons)
 397                         {
 398                                 precache_model("models/flash.md3");
 399                                 precache_model("models/weapons/g_rl.md3");
 400                                 precache_model("models/weapons/v_rl.md3");
 401                                 precache_model("models/weapons/h_rl.iqm");
 402                                 precache_sound("weapons/rocket_det.wav");
 403                                 precache_sound("weapons/rocket_fire.wav");
 404                                 precache_sound("weapons/rocket_mode.wav");
 405                         }
 406                         DEVASTATOR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 407                         return TRUE;
 408                 }
 409                 case WR_SETUP:
 410                 {
 411                         self.rl_release = 1;
 412                         return TRUE;
 413                 }
 414                 case WR_CHECKAMMO1:
 415                 {
 416                         // don't switch while guiding a missile
 417                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 418                         {
 419                                 ammo_amount = FALSE;
 420                                 if(WEP_CVAR(devastator, reload_ammo))
 421                                 {
 422                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 423                                                 ammo_amount = TRUE;
 424                                 }
 425                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 426                                         ammo_amount = TRUE;
 427                                 return !ammo_amount;
 428                         }
 429
 430                         return TRUE;
 431                 }
 432                 case WR_CHECKAMMO2:
 433                 {
 434                         return FALSE;
 435                 }
 436                 case WR_CONFIG:
 437                 {
 438                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 439                         return TRUE;
 440                 }
 441                 case WR_RESETPLAYER:
 442                 {
 443                         self.rl_release = 0;
 444                         return TRUE;
 445                 }
 446                 case WR_RELOAD:
 447                 {
 448                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 449                         return TRUE;
 450                 }
 451                 case WR_SUICIDEMESSAGE:
 452                 {
 453                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 454                 }
 455                 case WR_KILLMESSAGE:
 456                 {
 457                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 458                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 459                         else
 460                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 461                 }
 462         }
 463         return TRUE;
 464 }
 465 #endif
 466 #ifdef CSQC
 467 float W_Devastator(float req)
 468 {
 469         switch(req)
 470         {
 471                 case WR_IMPACTEFFECT:
 472                 {
 473                         vector org2;
 474                         org2 = w_org + w_backoff * 12;
 475                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 476                         if(!w_issilent)
 477                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 478
 479                         return TRUE;
 480                 }
 481                 case WR_INIT:
 482                 {
 483                         precache_sound("weapons/rocket_impact.wav");
 484                         return TRUE;
 485                 }
 486                 case WR_ZOOMRETICLE:
 487                 {
 488                         // no weapon specific image for this weapon
 489                         return FALSE;
 490                 }
 491         }
 492         return TRUE;
 493 }
 494 #endif
 495 #endif