qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ DEVASTATOR,
   4 /* function */ W_Devastator,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 9,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "rl",
  10 /* netname  */ "devastator",
  11 /* fullname */ _("Devastator")
  12 );
  13
  14 #define DEVASTATOR_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, damage) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, damageforcescale) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, detonatedelay) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, edgedamage) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, force) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, guidedelay) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, guidegoal) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, guiderate) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, guideratedelay) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, guidestop) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, health) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, lifetime) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, radius) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, refire) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, remote_damage) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, remote_edgedamage) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, remote_force) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, remote_radius) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, speed) \
  36         WEP_ADD_CVAR(weapon, MO_NONE, speedaccel) \
  37         WEP_ADD_CVAR(weapon, MO_NONE, speedstart) \
  38         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  39         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  40         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  41         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  42
  43 #ifdef SVQC
  44 DEVASTATOR_SETTINGS(devastator)
  45 .float rl_release;
  46 .float rl_detonate_later;
  47 #endif
  48 #else
  49 #ifdef SVQC
  50 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  51 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  52
  53 void W_Devastator_Unregister()
  54 {
  55         if(self.realowner && self.realowner.lastrocket == self)
  56         {
  57                 self.realowner.lastrocket = world;
  58                 // self.realowner.rl_release = 1;
  59         }
  60 }
  61
  62 void W_Devastator_Explode()
  63 {
  64         W_Devastator_Unregister();
  65
  66         if(other.takedamage == DAMAGE_AIM)
  67                 if(IS_PLAYER(other))
  68                         if(IsDifferentTeam(self.realowner, other))
  69                                 if(other.deadflag == DEAD_NO)
  70                                         if(IsFlying(other))
  71                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  72
  73         self.event_damage = func_null;
  74         self.takedamage = DAMAGE_NO;
  75
  76         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  77
  78         if (self.realowner.weapon == WEP_DEVASTATOR)
  79         {
  80                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  81                 {
  82                         self.realowner.cnt = WEP_DEVASTATOR;
  83                         ATTACK_FINISHED(self.realowner) = time;
  84                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  85                 }
  86         }
  87         remove (self);
  88 }
  89
  90 void W_Devastator_DoRemoteExplode()
  91 {
  92         W_Devastator_Unregister();
  93
  94         self.event_damage = func_null;
  95         self.takedamage = DAMAGE_NO;
  96
  97         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  98
  99         if (self.realowner.weapon == WEP_DEVASTATOR)
 100         {
 101                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
 102                 {
 103                         self.realowner.cnt = WEP_DEVASTATOR;
 104                         ATTACK_FINISHED(self.realowner) = time;
 105                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 106                 }
 107         }
 108         remove (self);
 109 }
 110
 111 void W_Devastator_RemoteExplode()
 112 {
 113         if(self.realowner.deadflag == DEAD_NO)
 114         if(self.realowner.lastrocket)
 115         {
 116                 if((self.spawnshieldtime >= 0)
 117                         ? (time >= self.spawnshieldtime) // timer
 118                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 119                 )
 120                 {
 121                         W_Devastator_DoRemoteExplode();
 122                 }
 123         }
 124 }
 125
 126 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 127 {
 128         if(thisdir * goaldir > maxturn_cos)
 129                 return goaldir;
 130         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 131                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 132         float f, m2;
 133         vector v;
 134         // solve:
 135         //   g = normalize(thisdir + goaldir * X)
 136         //   thisdir * g = maxturn
 137         //
 138         //   gg = thisdir + goaldir * X
 139         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 140         //
 141         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 142         f = thisdir * goaldir;
 143         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 144         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 145         m2 = maxturn_cos * maxturn_cos;
 146         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 147         return normalize(thisdir + goaldir * v_y); // the larger solution!
 148 }
 149 // assume thisdir == -goaldir:
 150 //   f == -1
 151 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 152 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 153 //   x^2 - 2 * x + 1 = 0
 154 //   (x - 1)^2 = 0
 155 //   x = 1
 156 //   normalize(thisdir + goaldir)
 157 //   normalize(0)
 158
 159 void W_Devastator_Think (void)
 160 {
 161         vector desireddir, olddir, newdir, desiredorigin, goal;
 162 #if 0
 163         float cosminang, cosmaxang, cosang;
 164 #endif
 165         float velspeed, f;
 166         self.nextthink = time;
 167         if (time > self.cnt)
 168         {
 169                 other = world;
 170                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 171                 W_Devastator_Explode ();
 172                 return;
 173         }
 174
 175         // accelerate
 176         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 177         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 178         if (velspeed > 0)
 179                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 180
 181         // laser guided, or remote detonation
 182         if (self.realowner.weapon == WEP_DEVASTATOR)
 183         {
 184                 if(self == self.realowner.lastrocket)
 185                 if not(self.realowner.rl_release)
 186                 if not(self.BUTTON_ATCK2)
 187                 if(WEP_CVAR(devastator, guiderate))
 188                 if(time > self.pushltime)
 189                 if(self.realowner.deadflag == DEAD_NO)
 190                 {
 191                         f = WEP_CVAR(devastator, guideratedelay);
 192                         if(f)
 193                                 f = bound(0, (time - self.pushltime) / f, 1);
 194                         else
 195                                 f = 1;
 196
 197                         velspeed = vlen(self.velocity);
 198
 199                         makevectors(self.realowner.v_angle);
 200                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 201                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 202                         olddir = normalize(self.velocity);
 203
 204                         // now it gets tricky... we want to move like some curve to approximate the target direction
 205                         // but we are limiting the rate at which we can turn!
 206                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 207                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 208
 209                         self.velocity = newdir * velspeed;
 210                         self.angles = vectoangles(self.velocity);
 211
 212                         if(!self.count)
 213                         {
 214                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 215                                 // TODO add a better sound here
 216                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 217                                 self.count = 1;
 218                         }
 219                 }
 220
 221                 if(self.rl_detonate_later)
 222                         W_Devastator_RemoteExplode();
 223         }
 224
 225         if(self.csqcprojectile_clientanimate == 0)
 226                 UpdateCSQCProjectile(self);
 227 }
 228
 229 void W_Devastator_Touch (void)
 230 {
 231         if(WarpZone_Projectile_Touch())
 232         {
 233                 if(wasfreed(self))
 234                         W_Devastator_Unregister();
 235                 return;
 236         }
 237         W_Devastator_Unregister();
 238         W_Devastator_Explode ();
 239 }
 240
 241 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 242 {
 243         if (self.health <= 0)
 244                 return;
 245
 246         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 247                 return; // g_projectiles_damage says to halt
 248
 249         self.health = self.health - damage;
 250         self.angles = vectoangles(self.velocity);
 251
 252         if (self.health <= 0)
 253                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 254 }
 255
 256 void W_Devastator_Attack (void)
 257 {
 258         entity missile;
 259         entity flash;
 260
 261         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(devastator, ammo), WEP_CVAR(devastator, reload_ammo));
 262
 263         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 264         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 265
 266         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 267         missile.owner = missile.realowner = self;
 268         self.lastrocket = missile;
 269         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 270                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 271         else
 272                 missile.spawnshieldtime = -1;
 273         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 274         missile.classname = "rocket";
 275         missile.bot_dodge = TRUE;
 276         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 277
 278         missile.takedamage = DAMAGE_YES;
 279         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 280         missile.health = WEP_CVAR(devastator, health);
 281         missile.event_damage = W_Devastator_Damage;
 282         missile.damagedbycontents = TRUE;
 283
 284         missile.movetype = MOVETYPE_FLY;
 285         PROJECTILE_MAKETRIGGER(missile);
 286         missile.projectiledeathtype = WEP_DEVASTATOR;
 287         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 288
 289         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 290         W_SetupProjectileVelocity(missile, WEP_CVAR(devastator, speedstart), 0);
 291         missile.angles = vectoangles (missile.velocity);
 292
 293         missile.touch = W_Devastator_Touch;
 294         missile.think = W_Devastator_Think;
 295         missile.nextthink = time;
 296         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 297         missile.flags = FL_PROJECTILE;
 298         missile.missile_flags = MIF_SPLASH;
 299
 300         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 301
 302         // muzzle flash for 1st person view
 303         flash = spawn ();
 304         setmodel (flash, "models/flash.md3"); // precision set below
 305         SUB_SetFade (flash, time, 0.1);
 306         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 307         W_AttachToShotorg(flash, '5 0 0');
 308
 309         // common properties
 310         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 311 }
 312
 313 float W_Devastator(float req)
 314 {
 315         entity rock;
 316         float rockfound;
 317         float ammo_amount;
 318         switch(req)
 319         {
 320                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 321                 {
 322                         // aim and decide to fire if appropriate
 323                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 324                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 325                         {
 326                                 // decide whether to detonate rockets
 327                                 entity missile, targetlist, targ;
 328                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 329                                 float selfdamage, teamdamage, enemydamage;
 330                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 331                                 coredamage = WEP_CVAR(devastator, damage);
 332                                 edgeradius = WEP_CVAR(devastator, radius);
 333                                 recipricoledgeradius = 1 / edgeradius;
 334                                 selfdamage = 0;
 335                                 teamdamage = 0;
 336                                 enemydamage = 0;
 337                                 targetlist = findchainfloat(bot_attack, TRUE);
 338                                 missile = find(world, classname, "rocket");
 339                                 while (missile)
 340                                 {
 341                                         if (missile.realowner != self)
 342                                         {
 343                                                 missile = find(missile, classname, "rocket");
 344                                                 continue;
 345                                         }
 346                                         targ = targetlist;
 347                                         while (targ)
 348                                         {
 349                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 350                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 351                                                 // count potential damage according to type of target
 352                                                 if (targ == self)
 353                                                         selfdamage = selfdamage + d;
 354                                                 else if (targ.team == self.team && teamplay)
 355                                                         teamdamage = teamdamage + d;
 356                                                 else if (bot_shouldattack(targ))
 357                                                         enemydamage = enemydamage + d;
 358                                                 targ = targ.chain;
 359                                         }
 360                                         missile = find(missile, classname, "rocket");
 361                                 }
 362                                 float desirabledamage;
 363                                 desirabledamage = enemydamage;
 364                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 365                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 366                                 if (teamplay && self.team)
 367                                         desirabledamage = desirabledamage - teamdamage;
 368
 369                                 missile = find(world, classname, "rocket");
 370                                 while (missile)
 371                                 {
 372                                         if (missile.realowner != self)
 373                                         {
 374                                                 missile = find(missile, classname, "rocket");
 375                                                 continue;
 376                                         }
 377                                         makevectors(missile.v_angle);
 378                                         targ = targetlist;
 379                                         if (skill > 9) // normal players only do this for the target they are tracking
 380                                         {
 381                                                 targ = targetlist;
 382                                                 while (targ)
 383                                                 {
 384                                                         if (
 385                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 386                                                                 && desirabledamage > 0.1*coredamage
 387                                                         )self.BUTTON_ATCK2 = TRUE;
 388                                                         targ = targ.chain;
 389                                                 }
 390                                         }else{
 391                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 392                                                 //As the distance gets larger, a correct detonation gets near imposible
 393                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 394                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 395                                                         if(IS_PLAYER(self.enemy))
 396                                                                 if(desirabledamage >= 0.1*coredamage)
 397                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 398                                                                                 self.BUTTON_ATCK2 = TRUE;
 399                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 400                                         }
 401
 402                                         missile = find(missile, classname, "rocket");
 403                                 }
 404                                 // if we would be doing at X percent of the core damage, detonate it
 405                                 // but don't fire a new shot at the same time!
 406                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 407                                         self.BUTTON_ATCK2 = TRUE;
 408                                 if ((skill > 6.5) && (selfdamage > self.health))
 409                                         self.BUTTON_ATCK2 = FALSE;
 410                                 //if(self.BUTTON_ATCK2 == TRUE)
 411                                 //      dprint(ftos(desirabledamage),"\n");
 412                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 413                         }
 414
 415                         return TRUE;
 416                 }
 417                 case WR_THINK:
 418                 {
 419                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 420                                 WEP_ACTION(self.weapon, WR_RELOAD);
 421                         else
 422                         {
 423                                 if (self.BUTTON_ATCK)
 424                                 {
 425                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 426                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 427                                         {
 428                                                 W_Devastator_Attack();
 429                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 430                                                 self.rl_release = 0;
 431                                         }
 432                                 }
 433                                 else
 434                                         self.rl_release = 1;
 435
 436                                 if (self.BUTTON_ATCK2)
 437                                 {
 438                                         rockfound = 0;
 439                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 440                                         {
 441                                                 if(!rock.rl_detonate_later)
 442                                                 {
 443                                                         rock.rl_detonate_later = TRUE;
 444                                                         rockfound = 1;
 445                                                 }
 446                                         }
 447                                         if(rockfound)
 448                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 449                                 }
 450                         }
 451
 452                         return TRUE;
 453                 }
 454                 case WR_INIT:
 455                 {
 456                         if(autocvar_sv_precacheweapons)
 457                         {
 458                                 precache_model("models/flash.md3");
 459                                 precache_model("models/weapons/g_rl.md3");
 460                                 precache_model("models/weapons/v_rl.md3");
 461                                 precache_model("models/weapons/h_rl.iqm");
 462                                 precache_sound("weapons/rocket_det.wav");
 463                                 precache_sound("weapons/rocket_fire.wav");
 464                                 precache_sound("weapons/rocket_mode.wav");
 465                         }
 466                         WEP_SET_PROPS(DEVASTATOR_SETTINGS(devastator), WEP_DEVASTATOR)
 467                         return TRUE;
 468                 }
 469                 case WR_SETUP:
 470                 {
 471                         self.current_ammo = ammo_rockets;
 472                         self.rl_release = 1;
 473                         return TRUE;
 474                 }
 475                 case WR_CHECKAMMO1:
 476                 {
 477                         // don't switch while guiding a missile
 478                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 479                         {
 480                                 ammo_amount = FALSE;
 481                                 if(WEP_CVAR(devastator, reload_ammo))
 482                                 {
 483                                         if(self.ammo_rockets < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 484                                                 ammo_amount = TRUE;
 485                                 }
 486                                 else if(self.ammo_rockets < WEP_CVAR(devastator, ammo))
 487                                         ammo_amount = TRUE;
 488                                 return !ammo_amount;
 489                         }
 490
 491                         return TRUE;
 492                 }
 493                 case WR_CHECKAMMO2:
 494                 {
 495                         return FALSE;
 496                 }
 497                 case WR_CONFIG:
 498                 {
 499                         WEP_CONFIG_SETTINGS(DEVASTATOR_SETTINGS(devastator))
 500                         return TRUE;
 501                 }
 502                 case WR_RESETPLAYER:
 503                 {
 504                         self.rl_release = 0;
 505                         return TRUE;
 506                 }
 507                 case WR_RELOAD:
 508                 {
 509                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 510                         return TRUE;
 511                 }
 512                 case WR_SUICIDEMESSAGE:
 513                 {
 514                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 515                 }
 516                 case WR_KILLMESSAGE:
 517                 {
 518                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 519                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 520                         else
 521                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 522                 }
 523         }
 524         return TRUE;
 525 }
 526 #endif
 527 #ifdef CSQC
 528 float W_Devastator(float req)
 529 {
 530         switch(req)
 531         {
 532                 case WR_IMPACTEFFECT:
 533                 {
 534                         vector org2;
 535                         org2 = w_org + w_backoff * 12;
 536                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 537                         if(!w_issilent)
 538                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 539
 540                         return TRUE;
 541                 }
 542                 case WR_INIT:
 543                 {
 544                         precache_sound("weapons/rocket_impact.wav");
 545                         return TRUE;
 546                 }
 547         }
 548         return TRUE;
 549 }
 550 #endif
 551 #endif