qcsrc/common/weapons/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ ELECTRO,
   4 /* function */ W_Electro,
   5 /* ammotype */ IT_CELLS,
   6 /* impulse  */ 5,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "electro",
  10 /* netname  */ "electro",
  11 /* fullname */ _("Electro")
  12 );
  13
  14 #define ELECTRO_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_ELECTRO, electro, MO_BOTH, ammo) \
  16         w_cvar(WEP_ELECTRO, electro, MO_BOTH, animtime) \
  17         w_cvar(WEP_ELECTRO, electro, MO_BOTH, damage) \
  18         w_cvar(WEP_ELECTRO, electro, MO_BOTH, edgedamage) \
  19         w_cvar(WEP_ELECTRO, electro, MO_BOTH, force) \
  20         w_cvar(WEP_ELECTRO, electro, MO_BOTH, radius) \
  21         w_cvar(WEP_ELECTRO, electro, MO_BOTH, refire) \
  22         w_cvar(WEP_ELECTRO, electro, MO_BOTH, speed) \
  23         w_cvar(WEP_ELECTRO, electro, MO_BOTH, spread) \
  24         w_cvar(WEP_ELECTRO, electro, MO_BOTH, lifetime) \
  25         w_cvar(WEP_ELECTRO, electro, MO_PRI,  comboradius) \
  26         w_cvar(WEP_ELECTRO, electro, MO_PRI,  midaircombo_interval) \
  27         w_cvar(WEP_ELECTRO, electro, MO_PRI,  midaircombo_radius) \
  28         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncefactor) \
  29         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncestop) \
  30         w_cvar(WEP_ELECTRO, electro, MO_SEC,  count) \
  31         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damageforcescale) \
  32         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damagedbycontents) \
  33         w_cvar(WEP_ELECTRO, electro, MO_SEC,  takedamageexplode) \
  34         w_cvar(WEP_ELECTRO, electro, MO_SEC,  health) \
  35         w_cvar(WEP_ELECTRO, electro, MO_SEC,  refire2) \
  36         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_up) \
  37         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_z) \
  38         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius) \
  39         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius_thruwall) \
  40         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_damage) \
  41         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_edgedamage) \
  42         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_force) \
  43         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_radius) \
  44         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_speed) \
  45         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_safeammocheck) \
  46         w_prop(WEP_ELECTRO, electro, reloading_ammo, reload_ammo) \
  47         w_prop(WEP_ELECTRO, electro, reloading_time, reload_time) \
  48         w_prop(WEP_ELECTRO, electro, switchdelay_raise, switchdelay_raise) \
  49         w_prop(WEP_ELECTRO, electro, switchdelay_drop, switchdelay_drop)
  50
  51 #ifdef SVQC
  52 ELECTRO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  53 .float electro_count;
  54 .float electro_secondarytime;
  55 void W_Plasma_Explode_Combo(void);
  56 #endif
  57 #else
  58 #ifdef SVQC
  59 void spawnfunc_weapon_electro() { weapon_defaultspawnfunc(WEP_ELECTRO); }
  60
  61 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  62 {
  63         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  64         while(e)
  65         {
  66                 if(e.classname == "plasma")
  67                 {
  68                         // change owner to whoever caused the combo explosion
  69                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  70
  71                         if(
  72                                 (trace_fraction == 1)
  73                                 ||
  74                                 (WEP_CVAR(electro, combo_comboradius_thruwall) >= vlen(e.WarpZone_findradius_dist))
  75                         )
  76                         {
  77                                 e.realowner = own;
  78                                 e.takedamage = DAMAGE_NO;
  79                                 e.classname = "plasma_chain";
  80                                 e.think = W_Plasma_Explode_Combo;
  81                                 e.nextthink = time + vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed); // delay combo chains, looks cooler
  82                         }
  83                 }
  84                 e = e.chain;
  85         }
  86 }
  87
  88 void W_Plasma_Explode(void)
  89 {
  90         if(other.takedamage == DAMAGE_AIM)
  91                 if(IS_PLAYER(other))
  92                         if(DIFF_TEAM(self.realowner, other))
  93                                 if(other.deadflag == DEAD_NO)
  94                                         if(IsFlying(other))
  95                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
  96
  97         self.event_damage = func_null;
  98         self.takedamage = DAMAGE_NO;
  99
 100         if(self.movetype == MOVETYPE_BOUNCE)
 101         {
 102                 RadiusDamage(
 103                         self,
 104                         self.realowner,
 105                         WEP_CVAR_SEC(electro, damage),
 106                         WEP_CVAR_SEC(electro, edgedamage),
 107                         WEP_CVAR_SEC(electro, radius),
 108                         world,
 109                         world,
 110                         WEP_CVAR_SEC(electro, force),
 111                         self.projectiledeathtype,
 112                         other
 113                 );
 114         }
 115         else
 116         {
 117                 W_Plasma_TriggerCombo(self.origin, WEP_CVAR_PRI(electro, comboradius), self.realowner);
 118                 RadiusDamage(
 119                         self,
 120                         self.realowner,
 121                         WEP_CVAR_PRI(electro, damage),
 122                         WEP_CVAR_PRI(electro, edgedamage),
 123                         WEP_CVAR_PRI(electro, radius),
 124                         world,
 125                         world,
 126                         WEP_CVAR_PRI(electro, force),
 127                         self.projectiledeathtype,
 128                         other
 129                 );
 130         }
 131
 132         remove(self);
 133 }
 134
 135 void W_Plasma_Explode_Combo(void)
 136 {
 137         W_Plasma_TriggerCombo(self.origin, WEP_CVAR(electro, combo_comboradius), self.realowner);
 138
 139         self.event_damage = func_null;
 140
 141         RadiusDamage(
 142                 self,
 143                 self.realowner,
 144                 WEP_CVAR(electro, combo_damage),
 145                 WEP_CVAR(electro, combo_edgedamage),
 146                 WEP_CVAR(electro, combo_radius),
 147                 world,
 148                 world,
 149                 WEP_CVAR(electro, combo_force),
 150                 WEP_ELECTRO | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 151                 world
 152         );
 153
 154         remove (self);
 155 }
 156
 157 void W_Plasma_Touch(void)
 158 {
 159         PROJECTILE_TOUCH;
 160         if(other.takedamage == DAMAGE_AIM)
 161                 { if(WEP_CVAR_SEC(electro, takedamageexplode)) { W_Plasma_Explode(); } }
 162         else
 163         {
 164                 //UpdateCSQCProjectile(self);
 165                 spamsound(self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTEN_NORM);
 166                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 167         }
 168 }
 169
 170 void W_Plasma_TouchExplode(void)
 171 {
 172         PROJECTILE_TOUCH;
 173         W_Plasma_Explode();
 174 }
 175
 176 void W_Plasma_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 177 {
 178         if(self.health <= 0)
 179                 return;
 180
 181         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 182         float is_combo = (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim");
 183
 184         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_combo ? 1 : -1)))
 185                 return; // g_projectiles_damage says to halt
 186
 187         self.health = self.health - damage;
 188         if(self.health <= 0)
 189         {
 190                 self.takedamage = DAMAGE_NO;
 191                 self.nextthink = time;
 192                 if(is_combo)
 193                 {
 194                         // change owner to whoever caused the combo explosion
 195                         self.realowner = inflictor.realowner;
 196                         self.classname = "plasma_chain";
 197                         self.think = W_Plasma_Explode_Combo;
 198                         self.nextthink = time +
 199                                 (
 200                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 201                                         min(
 202                                                 WEP_CVAR(electro, combo_radius),
 203                                                 vlen(self.origin - inflictor.origin)
 204                                         )
 205                                         /
 206                                         // delay combo chains, looks cooler
 207                                         WEP_CVAR(electro, combo_speed)
 208                                 );
 209                 }
 210                 else
 211                 {
 212                         self.use = W_Plasma_Explode;
 213                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 214                 }
 215         }
 216 }
 217
 218 void W_Plasma_Think()
 219 {
 220         if(time >= self.ltime)
 221         {
 222                 self.use();
 223                 return;
 224         }
 225
 226         if(WEP_CVAR_PRI(electro, midaircombo_radius))
 227         {
 228                 self.nextthink = min(time + WEP_CVAR_PRI(electro, midaircombo_interval), self.ltime);
 229                 W_Plasma_TriggerCombo(self.origin, WEP_CVAR_PRI(electro, midaircombo_radius), self.realowner);
 230         }
 231         else { self.nextthink = self.ltime; }
 232 }
 233
 234 void W_Electro_Attack_Bolt(void)
 235 {
 236         entity proj;
 237
 238         W_DecreaseAmmo(ammo_cells, WEP_CVAR_PRI(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 239
 240         W_SetupShot_ProjectileSize(self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, WEP_CVAR_PRI(electro, damage));
 241
 242         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 243
 244         proj = spawn ();
 245         proj.classname = "plasma_prim";
 246         proj.owner = proj.realowner = self;
 247         proj.bot_dodge = TRUE;
 248         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 249         proj.use = W_Plasma_Explode;
 250         proj.think = W_Plasma_Think;
 251         proj.nextthink = time;
 252         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
 253         PROJECTILE_MAKETRIGGER(proj);
 254         proj.projectiledeathtype = WEP_ELECTRO;
 255         setorigin(proj, w_shotorg);
 256
 257         proj.movetype = MOVETYPE_FLY;
 258         WEP_SETUPPROJVELOCITY_PRI(proj, electro);
 259         proj.angles = vectoangles(proj.velocity);
 260         proj.touch = W_Plasma_TouchExplode;
 261         setsize(proj, '0 0 -3', '0 0 -3');
 262         proj.flags = FL_PROJECTILE;
 263         proj.missile_flags = MIF_SPLASH;
 264
 265         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 266
 267         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 268 }
 269
 270 void W_Electro_Attack_Orbs(void)
 271 {
 272         W_DecreaseAmmo(ammo_cells, WEP_CVAR_SEC(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 273
 274         W_SetupShot_ProjectileSize(self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, WEP_CVAR_SEC(electro, damage));
 275
 276         w_shotdir = v_forward; // no TrueAim for grenades please
 277
 278         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 279
 280         entity proj = spawn();
 281         proj.classname = "plasma";
 282         proj.owner = proj.realowner = self;
 283         proj.use = W_Plasma_Explode;
 284         proj.think = adaptor_think2use_hittype_splash;
 285         proj.bot_dodge = TRUE;
 286         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 287         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 288         PROJECTILE_MAKETRIGGER(proj);
 289         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 290         setorigin(proj, w_shotorg);
 291
 292         //proj.glow_size = 50;
 293         //proj.glow_color = 45;
 294         proj.movetype = MOVETYPE_BOUNCE;
 295         WEP_SETUPPROJVELOCITY_UP_SEC(proj, electro);
 296         proj.touch = W_Plasma_Touch;
 297         setsize(proj, '0 0 -4', '0 0 -4');
 298         proj.takedamage = DAMAGE_YES;
 299         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 300         proj.health = WEP_CVAR_SEC(electro, health);
 301         proj.event_damage = W_Plasma_Damage;
 302         proj.flags = FL_PROJECTILE;
 303         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 304
 305         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 306         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 307         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 308
 309 #if 0
 310         entity p2;
 311         p2 = spawn();
 312         copyentity(proj, p2);
 313         setmodel(p2, "models/ebomb.mdl");
 314         setsize(p2, proj.mins, proj.maxs);
 315 #endif
 316
 317         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 318
 319         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 320 }
 321
 322 void W_Electro_CheckAttack()
 323 {
 324         if(self.electro_count > 1)
 325         if(self.BUTTON_ATCK2)
 326         if(weapon_prepareattack(1, -1))
 327         {
 328                 W_Electro_Attack_Orbs();
 329                 self.electro_count -= 1;
 330                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 331                 return;
 332         }
 333         w_ready();
 334 }
 335
 336 .float bot_secondary_electromooth;
 337 float W_Electro(float req)
 338 {
 339         float ammo_amount;
 340         switch(req)
 341         {
 342                 case WR_AIM:
 343                 {
 344                         self.BUTTON_ATCK = self.BUTTON_ATCK2 = FALSE;
 345                         if(vlen(self.origin-self.enemy.origin) > 1000) { self.bot_secondary_electromooth = 0; }
 346                         if(self.bot_secondary_electromooth == 0)
 347                         {
 348                                 float shoot;
 349
 350                                 if(WEP_CVAR_PRI(electro, speed))
 351                                         shoot = bot_aim(WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), FALSE);
 352                                 else
 353                                         shoot = bot_aim(1000000, 0, 0.001, FALSE);
 354
 355                                 if(shoot)
 356                                 {
 357                                         self.BUTTON_ATCK = TRUE;
 358                                         if(random() < 0.01) self.bot_secondary_electromooth = 1;
 359                                 }
 360                         }
 361                         else
 362                         {
 363                                 if(bot_aim(WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), TRUE))
 364                                 {
 365                                         self.BUTTON_ATCK2 = TRUE;
 366                                         if(random() < 0.03) self.bot_secondary_electromooth = 0;
 367                                 }
 368                         }
 369
 370                         return TRUE;
 371                 }
 372                 case WR_THINK:
 373                 {
 374                         if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 375                         {
 376                                 ammo_amount = 0;
 377                                 if(self.clip_load >= WEP_CVAR_PRI(electro, ammo))
 378                                         ammo_amount = 1;
 379                                 if(self.clip_load >= WEP_CVAR_SEC(electro, ammo))
 380                                         ammo_amount += 1;
 381
 382                                 if(!ammo_amount)
 383                                 {
 384                                         WEP_ACTION(self.weapon, WR_RELOAD);
 385                                         return FALSE;
 386                                 }
 387
 388                                 return TRUE;
 389                         }
 390
 391                         if(self.BUTTON_ATCK)
 392                         {
 393                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(electro, refire)))
 394                                 {
 395                                                 W_Electro_Attack_Bolt();
 396                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 397                                 }
 398                         }
 399                         else if(self.BUTTON_ATCK2)
 400                         {
 401                                 if(time >= self.electro_secondarytime)
 402                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(electro, refire)))
 403                                 {
 404                                         W_Electro_Attack_Orbs();
 405                                         self.electro_count = WEP_CVAR_SEC(electro, count);
 406                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 407                                         self.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor();
 408                                 }
 409                         }
 410
 411                         return TRUE;
 412                 }
 413                 case WR_INIT:
 414                 {
 415                         precache_model("models/weapons/g_electro.md3");
 416                         precache_model("models/weapons/v_electro.md3");
 417                         precache_model("models/weapons/h_electro.iqm");
 418                         precache_sound("weapons/electro_bounce.wav");
 419                         precache_sound("weapons/electro_fire.wav");
 420                         precache_sound("weapons/electro_fire2.wav");
 421                         precache_sound("weapons/electro_impact.wav");
 422                         precache_sound("weapons/electro_impact_combo.wav");
 423                         ELECTRO_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 424                         return TRUE;
 425                 }
 426                 case WR_SETUP:
 427                 {
 428                         self.current_ammo = ammo_cells;
 429                         return TRUE;
 430                 }
 431                 case WR_CHECKAMMO1:
 432                 {
 433                         ammo_amount = self.ammo_cells >= WEP_CVAR_PRI(electro, ammo);
 434                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_PRI(electro, ammo);
 435                         return ammo_amount;
 436                 }
 437                 case WR_CHECKAMMO2:
 438                 {
 439                         if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 440                         {
 441                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 442                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 443                         }
 444                         else
 445                         {
 446                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo);
 447                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo);
 448                         }
 449                         return ammo_amount;
 450                 }
 451                 case WR_CONFIG:
 452                 {
 453                         ELECTRO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 454                         return TRUE;
 455                 }
 456                 case WR_RESETPLAYER:
 457                 {
 458                         self.electro_secondarytime = time;
 459                         return TRUE;
 460                 }
 461                 case WR_RELOAD:
 462                 {
 463                         W_Reload(min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), "weapons/reload.wav");
 464                         return TRUE;
 465                 }
 466                 case WR_SUICIDEMESSAGE:
 467                 {
 468                         if(w_deathtype & HITTYPE_SECONDARY)
 469                                 return WEAPON_ELECTRO_SUICIDE_ORBS;
 470                         else
 471                                 return WEAPON_ELECTRO_SUICIDE_BOLT;
 472                 }
 473                 case WR_KILLMESSAGE:
 474                 {
 475                         if(w_deathtype & HITTYPE_SECONDARY)
 476                         {
 477                                 return WEAPON_ELECTRO_MURDER_ORBS;
 478                         }
 479                         else
 480                         {
 481                                 if(w_deathtype & HITTYPE_BOUNCE)
 482                                         return WEAPON_ELECTRO_MURDER_COMBO;
 483                                 else
 484                                         return WEAPON_ELECTRO_MURDER_BOLT;
 485                         }
 486                 }
 487         }
 488         return TRUE;
 489 }
 490 #endif
 491 #ifdef CSQC
 492 float W_Electro(float req)
 493 {
 494         switch(req)
 495         {
 496                 case WR_IMPACTEFFECT:
 497                 {
 498                         vector org2;
 499                         org2 = w_org + w_backoff * 6;
 500                         if(w_deathtype & HITTYPE_SECONDARY)
 501                         {
 502                                 pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 503                                 if(!w_issilent)
 504                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 505                         }
 506                         else
 507                         {
 508                                 if(w_deathtype & HITTYPE_BOUNCE)
 509                                 {
 510                                         // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 511                                         pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 512                                         if(!w_issilent)
 513                                                 sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTEN_NORM);
 514                                 }
 515                                 else
 516                                 {
 517                                         pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 518                                         if(!w_issilent)
 519                                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 520                                 }
 521                         }
 522
 523                         return TRUE;
 524                 }
 525                 case WR_INIT:
 526                 {
 527                         precache_sound("weapons/electro_impact.wav");
 528                         precache_sound("weapons/electro_impact_combo.wav");
 529                         return TRUE;
 530                 }
 531         }
 532         return TRUE;
 533 }
 534 #endif
 535 #endif