qcsrc/common/weapons/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ ELECTRO,
   4 /* function */ W_Electro,
   5 /* ammotype */ IT_CELLS,
   6 /* impulse  */ 5,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "electro",
  10 /* netname  */ "electro",
  11 /* fullname */ _("Electro")
  12 );
  13
  14 #define ELECTRO_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_ELECTRO, electro, MO_BOTH, ammo) \
  16         w_cvar(WEP_ELECTRO, electro, MO_BOTH, animtime) \
  17         w_cvar(WEP_ELECTRO, electro, MO_BOTH, damage) \
  18         w_cvar(WEP_ELECTRO, electro, MO_BOTH, edgedamage) \
  19         w_cvar(WEP_ELECTRO, electro, MO_BOTH, force) \
  20         w_cvar(WEP_ELECTRO, electro, MO_BOTH, radius) \
  21         w_cvar(WEP_ELECTRO, electro, MO_BOTH, refire) \
  22         w_cvar(WEP_ELECTRO, electro, MO_BOTH, speed) \
  23         w_cvar(WEP_ELECTRO, electro, MO_BOTH, spread) \
  24         w_cvar(WEP_ELECTRO, electro, MO_BOTH, lifetime) \
  25         w_cvar(WEP_ELECTRO, electro, MO_PRI,  comboradius) \
  26         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncefactor) \
  27         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncestop) \
  28         w_cvar(WEP_ELECTRO, electro, MO_SEC,  count) \
  29         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damageforcescale) \
  30         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damagedbycontents) \
  31         w_cvar(WEP_ELECTRO, electro, MO_SEC,  health) \
  32         w_cvar(WEP_ELECTRO, electro, MO_SEC,  refire2) \
  33         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_up) \
  34         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_z) \
  35         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius) \
  36         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius_thruwall) \
  37         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_damage) \
  38         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_edgedamage) \
  39         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_force) \
  40         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_radius) \
  41         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_speed) \
  42         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_safeammocheck) \
  43         w_prop(WEP_ELECTRO, electro, reloading_ammo, reload_ammo) \
  44         w_prop(WEP_ELECTRO, electro, reloading_time, reload_time) \
  45         w_prop(WEP_ELECTRO, electro, switchdelay_raise, switchdelay_raise) \
  46         w_prop(WEP_ELECTRO, electro, switchdelay_drop, switchdelay_drop)
  47
  48 #ifdef SVQC
  49 ELECTRO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  50 #endif
  51 #else
  52 #ifdef SVQC
  53 void spawnfunc_weapon_electro() { weapon_defaultspawnfunc(WEP_ELECTRO); }
  54
  55 .float electro_count;
  56 .float electro_secondarytime;
  57
  58 void W_Plasma_Explode_Combo(void);
  59
  60 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  61 {
  62         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  63         while(e)
  64         {
  65                 if(e.classname == "plasma")
  66                 {
  67                         // change owner to whoever caused the combo explosion
  68                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  69
  70                         if(
  71                                 (trace_fraction == 1)
  72                                 ||
  73                                 (WEP_CVAR(electro, combo_comboradius_thruwall) >= vlen(e.WarpZone_findradius_dist))
  74                         )
  75                         {
  76                                 e.realowner = own;
  77                                 e.takedamage = DAMAGE_NO;
  78                                 e.classname = "plasma_chain";
  79                                 e.think = W_Plasma_Explode_Combo;
  80                                 e.nextthink = time + vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed); // delay combo chains, looks cooler
  81                         }
  82                 }
  83                 e = e.chain;
  84         }
  85 }
  86
  87 void W_Plasma_Explode(void)
  88 {
  89         if(other.takedamage == DAMAGE_AIM)
  90                 if(IS_PLAYER(other))
  91                         if(DIFF_TEAM(self.realowner, other))
  92                                 if(other.deadflag == DEAD_NO)
  93                                         if(IsFlying(other))
  94                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
  95
  96         self.event_damage = func_null;
  97         self.takedamage = DAMAGE_NO;
  98
  99         if(self.movetype == MOVETYPE_BOUNCE)
 100         {
 101                 RadiusDamage(
 102                         self,
 103                         self.realowner,
 104                         WEP_CVAR_SEC(electro, damage),
 105                         WEP_CVAR_SEC(electro, edgedamage),
 106                         WEP_CVAR_SEC(electro, radius),
 107                         world,
 108                         world,
 109                         WEP_CVAR_SEC(electro, force),
 110                         self.projectiledeathtype,
 111                         other
 112                 );
 113         }
 114         else
 115         {
 116                 W_Plasma_TriggerCombo(self.origin, WEP_CVAR_PRI(electro, comboradius), self.realowner);
 117                 RadiusDamage(
 118                         self,
 119                         self.realowner,
 120                         WEP_CVAR_PRI(electro, damage),
 121                         WEP_CVAR_PRI(electro, edgedamage),
 122                         WEP_CVAR_PRI(electro, radius),
 123                         world,
 124                         world,
 125                         WEP_CVAR_PRI(electro, force),
 126                         self.projectiledeathtype,
 127                         other
 128                 );
 129         }
 130
 131         remove(self);
 132 }
 133
 134 void W_Plasma_Explode_Combo(void)
 135 {
 136         W_Plasma_TriggerCombo(self.origin, WEP_CVAR(electro, combo_comboradius), self.realowner);
 137
 138         self.event_damage = func_null;
 139
 140         RadiusDamage(
 141                 self,
 142                 self.realowner,
 143                 WEP_CVAR(electro, combo_damage),
 144                 WEP_CVAR(electro, combo_edgedamage),
 145                 WEP_CVAR(electro, combo_radius),
 146                 world,
 147                 world,
 148                 WEP_CVAR(electro, combo_force),
 149                 WEP_ELECTRO | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 150                 world
 151         );
 152
 153         remove (self);
 154 }
 155
 156 void W_Plasma_Touch(void)
 157 {
 158         PROJECTILE_TOUCH;
 159         if(other.takedamage == DAMAGE_AIM)
 160                 { W_Plasma_Explode(); }
 161         else
 162         {
 163                 //UpdateCSQCProjectile(self);
 164                 spamsound(self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTEN_NORM);
 165                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 166         }
 167 }
 168
 169 void W_Plasma_TouchExplode(void)
 170 {
 171         PROJECTILE_TOUCH;
 172         W_Plasma_Explode();
 173 }
 174
 175 void W_Plasma_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 176 {
 177         if(self.health <= 0)
 178                 return;
 179
 180         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 181         float is_combo = (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim");
 182
 183         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_combo ? 1 : -1)))
 184                 return; // g_projectiles_damage says to halt
 185
 186         self.health = self.health - damage;
 187         if(self.health <= 0)
 188         {
 189                 self.takedamage = DAMAGE_NO;
 190                 self.nextthink = time;
 191                 if(is_combo)
 192                 {
 193                         // change owner to whoever caused the combo explosion
 194                         self.realowner = inflictor.realowner;
 195                         self.classname = "plasma_chain";
 196                         self.think = W_Plasma_Explode_Combo;
 197                         self.nextthink = time +
 198                                 (
 199                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 200                                         min(
 201                                                 WEP_CVAR(electro, combo_radius),
 202                                                 vlen(self.origin - inflictor.origin)
 203                                         )
 204                                         /
 205                                         // delay combo chains, looks cooler
 206                                         WEP_CVAR(electro, combo_speed)
 207                                 );
 208                 }
 209                 else
 210                 {
 211                         self.use = W_Plasma_Explode;
 212                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 213                 }
 214         }
 215 }
 216
 217 void W_Electro_Attack_Bolt(void)
 218 {
 219         entity proj;
 220
 221         W_DecreaseAmmo(ammo_cells, WEP_CVAR_PRI(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 222
 223         W_SetupShot_ProjectileSize(self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, WEP_CVAR_PRI(electro, damage));
 224
 225         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 226
 227         proj = spawn ();
 228         proj.classname = "plasma_prim";
 229         proj.owner = proj.realowner = self;
 230         proj.bot_dodge = TRUE;
 231         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 232         proj.use = W_Plasma_Explode;
 233         proj.think = adaptor_think2use_hittype_splash;
 234         proj.nextthink = time + WEP_CVAR_PRI(electro, lifetime);
 235         PROJECTILE_MAKETRIGGER(proj);
 236         proj.projectiledeathtype = WEP_ELECTRO;
 237         setorigin(proj, w_shotorg);
 238
 239         proj.movetype = MOVETYPE_FLY;
 240         WEP_SETUPPROJVELOCITY_PRI(proj, electro);
 241         proj.angles = vectoangles(proj.velocity);
 242         proj.touch = W_Plasma_TouchExplode;
 243         setsize(proj, '0 0 -3', '0 0 -3');
 244         proj.flags = FL_PROJECTILE;
 245         proj.missile_flags = MIF_SPLASH;
 246
 247         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 248
 249         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 250 }
 251
 252 void W_Electro_Attack_Orbs(void)
 253 {
 254         W_DecreaseAmmo(ammo_cells, WEP_CVAR_SEC(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 255
 256         W_SetupShot_ProjectileSize(self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, WEP_CVAR_SEC(electro, damage));
 257
 258         w_shotdir = v_forward; // no TrueAim for grenades please
 259
 260         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 261
 262         entity proj = spawn();
 263         proj.classname = "plasma";
 264         proj.owner = proj.realowner = self;
 265         proj.use = W_Plasma_Explode;
 266         proj.think = adaptor_think2use_hittype_splash;
 267         proj.bot_dodge = TRUE;
 268         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 269         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 270         PROJECTILE_MAKETRIGGER(proj);
 271         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 272         setorigin(proj, w_shotorg);
 273
 274         //proj.glow_size = 50;
 275         //proj.glow_color = 45;
 276         proj.movetype = MOVETYPE_BOUNCE;
 277         WEP_SETUPPROJVELOCITY_UP_SEC(proj, electro);
 278         proj.touch = W_Plasma_Touch;
 279         setsize(proj, '0 0 -4', '0 0 -4');
 280         proj.takedamage = DAMAGE_YES;
 281         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 282         proj.health = WEP_CVAR_SEC(electro, health);
 283         proj.event_damage = W_Plasma_Damage;
 284         proj.flags = FL_PROJECTILE;
 285         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 286
 287         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 288         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 289         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 290
 291 #if 0
 292         entity p2;
 293         p2 = spawn();
 294         copyentity(proj, p2);
 295         setmodel(p2, "models/ebomb.mdl");
 296         setsize(p2, proj.mins, proj.maxs);
 297 #endif
 298
 299         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 300
 301         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 302 }
 303
 304 void W_Electro_CheckAttack()
 305 {
 306         if(self.electro_count > 1)
 307         if(self.BUTTON_ATCK2)
 308         if(weapon_prepareattack(1, -1))
 309         {
 310                 W_Electro_Attack_Orbs();
 311                 self.electro_count -= 1;
 312                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 313                 return;
 314         }
 315         w_ready();
 316 }
 317
 318 .float bot_secondary_electromooth;
 319 float W_Electro(float req)
 320 {
 321         float ammo_amount;
 322         switch(req)
 323         {
 324                 case WR_AIM:
 325                 {
 326                         self.BUTTON_ATCK = self.BUTTON_ATCK2 = FALSE;
 327                         if(vlen(self.origin-self.enemy.origin) > 1000)
 328                                 self.bot_secondary_electromooth = 0;
 329                         if(self.bot_secondary_electromooth == 0)
 330                         {
 331                                 float shoot;
 332
 333                                 if(WEP_CVAR_PRI(electro, speed))
 334                                         shoot = bot_aim(WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), FALSE);
 335                                 else
 336                                         shoot = bot_aim(1000000, 0, 0.001, FALSE);
 337
 338                                 if(shoot)
 339                                 {
 340                                         self.BUTTON_ATCK = TRUE;
 341                                         if(random() < 0.01) self.bot_secondary_electromooth = 1;
 342                                 }
 343                         }
 344                         else
 345                         {
 346                                 if(bot_aim(WEP_CVAR_SEC(electro, speed), autocvar_g_balance_mortar_secondary_speed_up, WEP_CVAR_SEC(electro, lifetime), TRUE)) // WHAT THE ACTUAL FUUUUUUUUUCK?!?!? WEAPONTODO
 347                                 {
 348                                         self.BUTTON_ATCK2 = TRUE;
 349                                         if(random() < 0.03) self.bot_secondary_electromooth = 0;
 350                                 }
 351                         }
 352
 353                         return TRUE;
 354                 }
 355                 case WR_THINK:
 356                 {
 357                         if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 358                         {
 359                                 ammo_amount = 0;
 360                                 if(self.clip_load >= WEP_CVAR_PRI(electro, ammo))
 361                                         ammo_amount = 1;
 362                                 if(self.clip_load >= WEP_CVAR_SEC(electro, ammo))
 363                                         ammo_amount += 1;
 364
 365                                 if(!ammo_amount)
 366                                 {
 367                                         WEP_ACTION(self.weapon, WR_RELOAD);
 368                                         return FALSE;
 369                                 }
 370
 371                                 return TRUE;
 372                         }
 373                         if (self.BUTTON_ATCK)
 374                         {
 375                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(electro, refire)))
 376                                 {
 377                                                 W_Electro_Attack_Bolt();
 378                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 379                                 }
 380                         }
 381                         else if(self.BUTTON_ATCK2)
 382                         {
 383                                 if(time >= self.electro_secondarytime)
 384                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(electro, refire)))
 385                                 {
 386                                         W_Electro_Attack_Orbs();
 387                                         self.electro_count = WEP_CVAR_SEC(electro, count);
 388                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 389                                         self.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor();
 390                                 }
 391                         }
 392
 393                         return TRUE;
 394                 }
 395                 case WR_INIT:
 396                 {
 397                         precache_model("models/weapons/g_electro.md3");
 398                         precache_model("models/weapons/v_electro.md3");
 399                         precache_model("models/weapons/h_electro.iqm");
 400                         precache_sound("weapons/electro_bounce.wav");
 401                         precache_sound("weapons/electro_fire.wav");
 402                         precache_sound("weapons/electro_fire2.wav");
 403                         precache_sound("weapons/electro_impact.wav");
 404                         precache_sound("weapons/electro_impact_combo.wav");
 405                         ELECTRO_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 406                         return TRUE;
 407                 }
 408                 case WR_SETUP:
 409                 {
 410                         self.current_ammo = ammo_cells;
 411                         return TRUE;
 412                 }
 413                 case WR_CHECKAMMO1:
 414                 {
 415                         ammo_amount = self.ammo_cells >= WEP_CVAR_PRI(electro, ammo);
 416                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_PRI(electro, ammo);
 417                         return ammo_amount;
 418                 }
 419                 case WR_CHECKAMMO2:
 420                 {
 421                         if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 422                         {
 423                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 424                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 425                         }
 426                         else
 427                         {
 428                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo);
 429                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo);
 430                         }
 431                         return ammo_amount;
 432                 }
 433                 case WR_CONFIG:
 434                 {
 435                         ELECTRO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 436                         return TRUE;
 437                 }
 438                 case WR_RESETPLAYER:
 439                 {
 440                         self.electro_secondarytime = time;
 441                         return TRUE;
 442                 }
 443                 case WR_RELOAD:
 444                 {
 445                         W_Reload(min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), "weapons/reload.wav");
 446                         return TRUE;
 447                 }
 448                 case WR_SUICIDEMESSAGE:
 449                 {
 450                         if(w_deathtype & HITTYPE_SECONDARY)
 451                                 return WEAPON_ELECTRO_SUICIDE_ORBS;
 452                         else
 453                                 return WEAPON_ELECTRO_SUICIDE_BOLT;
 454                 }
 455                 case WR_KILLMESSAGE:
 456                 {
 457                         if(w_deathtype & HITTYPE_SECONDARY)
 458                         {
 459                                 return WEAPON_ELECTRO_MURDER_ORBS;
 460                         }
 461                         else
 462                         {
 463                                 if(w_deathtype & HITTYPE_BOUNCE)
 464                                         return WEAPON_ELECTRO_MURDER_COMBO;
 465                                 else
 466                                         return WEAPON_ELECTRO_MURDER_BOLT;
 467                         }
 468                 }
 469         }
 470         return TRUE;
 471 }
 472 #endif
 473 #ifdef CSQC
 474 float W_Electro(float req)
 475 {
 476         switch(req)
 477         {
 478                 case WR_IMPACTEFFECT:
 479                 {
 480                         vector org2;
 481                         org2 = w_org + w_backoff * 6;
 482                         if(w_deathtype & HITTYPE_SECONDARY)
 483                         {
 484                                 pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 485                                 if(!w_issilent)
 486                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 487                         }
 488                         else
 489                         {
 490                                 if(w_deathtype & HITTYPE_BOUNCE)
 491                                 {
 492                                         // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 493                                         pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 494                                         if(!w_issilent)
 495                                                 sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTEN_NORM);
 496                                 }
 497                                 else
 498                                 {
 499                                         pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 500                                         if(!w_issilent)
 501                                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 502                                 }
 503                         }
 504
 505                         return TRUE;
 506                 }
 507                 case WR_INIT:
 508                 {
 509                         precache_sound("weapons/electro_impact.wav");
 510                         precache_sound("weapons/electro_impact_combo.wav");
 511                         return TRUE;
 512                 }
 513         }
 514         return TRUE;
 515 }
 516 #endif
 517 #endif