qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ MINE_LAYER,
   4 /* function */ w_minelayer,
   5 /* ammotype */ ammo_rockets,
   6 /* impulse  */ 4,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* color        */ '0.75 1 0',
  10 /* model    */ "minelayer",
  11 /* netname  */ "minelayer",
  12 /* fullname */ _("Mine Layer")
  13 );
  14
  15 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  16 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, NONE, ammo) \
  18         w_cvar(id, sn, NONE, animtime) \
  19         w_cvar(id, sn, NONE, damage) \
  20         w_cvar(id, sn, NONE, damageforcescale) \
  21         w_cvar(id, sn, NONE, detonatedelay) \
  22         w_cvar(id, sn, NONE, edgedamage) \
  23         w_cvar(id, sn, NONE, force) \
  24         w_cvar(id, sn, NONE, health) \
  25         w_cvar(id, sn, NONE, lifetime) \
  26         w_cvar(id, sn, NONE, lifetime_countdown) \
  27         w_cvar(id, sn, NONE, limit) \
  28         w_cvar(id, sn, NONE, protection) \
  29         w_cvar(id, sn, NONE, proximityradius) \
  30         w_cvar(id, sn, NONE, radius) \
  31         w_cvar(id, sn, NONE, refire) \
  32         w_cvar(id, sn, NONE, remote_damage) \
  33         w_cvar(id, sn, NONE, remote_edgedamage) \
  34         w_cvar(id, sn, NONE, remote_force) \
  35         w_cvar(id, sn, NONE, remote_radius) \
  36         w_cvar(id, sn, NONE, speed) \
  37         w_cvar(id, sn, NONE, time) \
  38         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  39         w_prop(id, sn, float,  reloading_time, reload_time) \
  40         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  41         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  42         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  43         w_prop(id, sn, float,  weaponstart, weaponstart) \
  44         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  45
  46 #ifdef SVQC
  47 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  48 void W_Mine_Think (void);
  49 .float minelayer_detonate, mine_explodeanyway;
  50 .float mine_time;
  51 .vector mine_orientation;
  52 #endif
  53 #else
  54 #ifdef SVQC
  55 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  56
  57 void W_Mine_Stick (entity to)
  58 {
  59         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  60
  61         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  62
  63         entity newmine;
  64         newmine = spawn();
  65         newmine.classname = self.classname;
  66
  67         newmine.bot_dodge = self.bot_dodge;
  68         newmine.bot_dodgerating = self.bot_dodgerating;
  69
  70         newmine.owner = self.owner;
  71         newmine.realowner = self.realowner;
  72         setsize(newmine, '-4 -4 -4', '4 4 4');
  73         setorigin(newmine, self.origin);
  74         setmodel(newmine, "models/mine.md3");
  75         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  76
  77         newmine.mine_orientation = -trace_plane_normal;
  78
  79         newmine.takedamage = self.takedamage;
  80         newmine.damageforcescale = self.damageforcescale;
  81         newmine.health = self.health;
  82         newmine.event_damage = self.event_damage;
  83         newmine.spawnshieldtime = self.spawnshieldtime;
  84         newmine.damagedbycontents = TRUE;
  85
  86         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  87         newmine.projectiledeathtype = self.projectiledeathtype;
  88
  89         newmine.mine_time = self.mine_time;
  90
  91         newmine.touch = func_null;
  92         newmine.think = W_Mine_Think;
  93         newmine.nextthink = time;
  94         newmine.cnt = self.cnt;
  95         newmine.flags = self.flags;
  96
  97         remove(self);
  98         self = newmine;
  99
 100         if(to)
 101                 SetMovetypeFollow(self, to);
 102 }
 103
 104 void W_Mine_Explode ()
 105 {
 106         if(other.takedamage == DAMAGE_AIM)
 107                 if(IS_PLAYER(other))
 108                         if(DIFF_TEAM(self.realowner, other))
 109                                 if(other.deadflag == DEAD_NO)
 110                                         if(IsFlying(other))
 111                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 112
 113         self.event_damage = func_null;
 114         self.takedamage = DAMAGE_NO;
 115
 116         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 117
 118         if (self.realowner.weapon == WEP_MINE_LAYER)
 119         {
 120                 entity oldself;
 121                 oldself = self;
 122                 self = self.realowner;
 123                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 124                 {
 125                         self.cnt = WEP_MINE_LAYER;
 126                         ATTACK_FINISHED(self) = time;
 127                         self.switchweapon = w_getbestweapon(self);
 128                 }
 129                 self = oldself;
 130         }
 131         self.realowner.minelayer_mines -= 1;
 132         remove (self);
 133 }
 134
 135 void W_Mine_DoRemoteExplode ()
 136 {
 137         self.event_damage = func_null;
 138         self.takedamage = DAMAGE_NO;
 139
 140         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 141                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 142
 143         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 144
 145         if (self.realowner.weapon == WEP_MINE_LAYER)
 146         {
 147                 entity oldself;
 148                 oldself = self;
 149                 self = self.realowner;
 150                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 151                 {
 152                         self.cnt = WEP_MINE_LAYER;
 153                         ATTACK_FINISHED(self) = time;
 154                         self.switchweapon = w_getbestweapon(self);
 155                 }
 156                 self = oldself;
 157         }
 158         self.realowner.minelayer_mines -= 1;
 159         remove (self);
 160 }
 161
 162 void W_Mine_RemoteExplode ()
 163 {
 164         if(self.realowner.deadflag == DEAD_NO)
 165                 if((self.spawnshieldtime >= 0)
 166                         ? (time >= self.spawnshieldtime) // timer
 167                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 168                 )
 169                 {
 170                         W_Mine_DoRemoteExplode();
 171                 }
 172 }
 173
 174 void W_Mine_ProximityExplode ()
 175 {
 176         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 177         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 178         {
 179                 entity head;
 180                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 181                 while(head)
 182                 {
 183                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 184                                 return;
 185                         head = head.chain;
 186                 }
 187         }
 188
 189         self.mine_time = 0;
 190         W_Mine_Explode();
 191 }
 192
 193 float W_Mine_Count(entity e)
 194 {
 195         float minecount = 0;
 196         entity mine;
 197         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 198                 minecount += 1;
 199
 200         return minecount;
 201 }
 202
 203 void W_Mine_Think (void)
 204 {
 205         entity head;
 206
 207         self.nextthink = time;
 208
 209         if(self.movetype == MOVETYPE_FOLLOW)
 210         {
 211                 if(LostMovetypeFollow(self))
 212                 {
 213                         UnsetMovetypeFollow(self);
 214                         self.movetype = MOVETYPE_NONE;
 215                 }
 216         }
 217
 218         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 219         // TODO: replace this mine_trigger.wav sound with a real countdown
 220         if ((time > self.cnt) && (!self.mine_time))
 221         {
 222                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 223                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 224                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 225                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 226         }
 227
 228         // a player's mines shall explode if he disconnects or dies
 229         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 230         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 231         {
 232                 other = world;
 233                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 234                 W_Mine_Explode();
 235                 return;
 236         }
 237
 238         // set the mine for detonation when a foe gets close enough
 239         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 240         while(head)
 241         {
 242                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 243                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 244                 if(!self.mine_time)
 245                 {
 246                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 247                         self.mine_time = time + WEP_CVAR(minelayer, time);
 248                 }
 249                 head = head.chain;
 250         }
 251
 252         // explode if it's time to
 253         if(self.mine_time && time >= self.mine_time)
 254         {
 255                 W_Mine_ProximityExplode();
 256                 return;
 257         }
 258
 259         // remote detonation
 260         if (self.realowner.weapon == WEP_MINE_LAYER)
 261         if (self.realowner.deadflag == DEAD_NO)
 262         if (self.minelayer_detonate)
 263                 W_Mine_RemoteExplode();
 264 }
 265
 266 void W_Mine_Touch (void)
 267 {
 268         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 269                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 270
 271         if(WarpZone_Projectile_Touch())
 272         {
 273                 if(wasfreed(self))
 274                         self.realowner.minelayer_mines -= 1;
 275                 return;
 276         }
 277
 278         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 279         {
 280                 // hit a player
 281                 // don't stick
 282         }
 283         else
 284         {
 285                 W_Mine_Stick(other);
 286         }
 287 }
 288
 289 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 290 {
 291         if (self.health <= 0)
 292                 return;
 293
 294         float is_from_enemy = (inflictor.realowner != self.realowner);
 295
 296         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 297                 return; // g_projectiles_damage says to halt
 298
 299         self.health = self.health - damage;
 300         self.angles = vectoangles(self.velocity);
 301
 302         if (self.health <= 0)
 303                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 304 }
 305
 306 void W_Mine_Attack (void)
 307 {
 308         entity mine;
 309         entity flash;
 310
 311         // scan how many mines we placed, and return if we reached our limit
 312         if(WEP_CVAR(minelayer, limit))
 313         {
 314                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 315                 {
 316                         // the refire delay keeps this message from being spammed
 317                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 318                         play2(self, "weapons/unavailable.wav");
 319                         return;
 320                 }
 321         }
 322
 323         W_DecreaseAmmo(WEP_CVAR(minelayer, ammo));
 324
 325         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 326         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 327
 328         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 329         mine.owner = mine.realowner = self;
 330         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 331                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 332         else
 333                 mine.spawnshieldtime = -1;
 334         mine.classname = "mine";
 335         mine.bot_dodge = TRUE;
 336         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 337
 338         mine.takedamage = DAMAGE_YES;
 339         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 340         mine.health = WEP_CVAR(minelayer, health);
 341         mine.event_damage = W_Mine_Damage;
 342         mine.damagedbycontents = TRUE;
 343
 344         mine.movetype = MOVETYPE_TOSS;
 345         PROJECTILE_MAKETRIGGER(mine);
 346         mine.projectiledeathtype = WEP_MINE_LAYER;
 347         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 348
 349         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 350         W_SetupProjectileVelocity(mine, WEP_CVAR(minelayer, speed), 0);
 351         mine.angles = vectoangles (mine.velocity);
 352
 353         mine.touch = W_Mine_Touch;
 354         mine.think = W_Mine_Think;
 355         mine.nextthink = time;
 356         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 357         mine.flags = FL_PROJECTILE;
 358         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 359
 360         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 361
 362         // muzzle flash for 1st person view
 363         flash = spawn ();
 364         setmodel (flash, "models/flash.md3"); // precision set below
 365         SUB_SetFade (flash, time, 0.1);
 366         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 367         W_AttachToShotorg(flash, '5 0 0');
 368
 369         // common properties
 370
 371         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 372
 373         self.minelayer_mines = W_Mine_Count(self);
 374 }
 375
 376 float W_PlacedMines(float detonate)
 377 {
 378         entity mine;
 379         float minfound = 0;
 380
 381         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 382         {
 383                 if(detonate)
 384                 {
 385                         if(!mine.minelayer_detonate)
 386                         {
 387                                 mine.minelayer_detonate = TRUE;
 388                                 minfound = 1;
 389                         }
 390                 }
 391                 else
 392                         minfound = 1;
 393         }
 394         return minfound;
 395 }
 396
 397 float w_minelayer(float req)
 398 {
 399         entity mine;
 400         float ammo_amount;
 401         switch(req)
 402         {
 403                 case WR_AIM:
 404                 {
 405                         // aim and decide to fire if appropriate
 406                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 407                                 self.BUTTON_ATCK = FALSE;
 408                         else
 409                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 410                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 411                         {
 412                                 // decide whether to detonate mines
 413                                 entity targetlist, targ;
 414                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 415                                 float selfdamage, teamdamage, enemydamage;
 416                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 417                                 coredamage = WEP_CVAR(minelayer, damage);
 418                                 edgeradius = WEP_CVAR(minelayer, radius);
 419                                 recipricoledgeradius = 1 / edgeradius;
 420                                 selfdamage = 0;
 421                                 teamdamage = 0;
 422                                 enemydamage = 0;
 423                                 targetlist = findchainfloat(bot_attack, TRUE);
 424                                 mine = find(world, classname, "mine");
 425                                 while (mine)
 426                                 {
 427                                         if (mine.realowner != self)
 428                                         {
 429                                                 mine = find(mine, classname, "mine");
 430                                                 continue;
 431                                         }
 432                                         targ = targetlist;
 433                                         while (targ)
 434                                         {
 435                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 436                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 437                                                 // count potential damage according to type of target
 438                                                 if (targ == self)
 439                                                         selfdamage = selfdamage + d;
 440                                                 else if (targ.team == self.team && teamplay)
 441                                                         teamdamage = teamdamage + d;
 442                                                 else if (bot_shouldattack(targ))
 443                                                         enemydamage = enemydamage + d;
 444                                                 targ = targ.chain;
 445                                         }
 446                                         mine = find(mine, classname, "mine");
 447                                 }
 448                                 float desirabledamage;
 449                                 desirabledamage = enemydamage;
 450                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 451                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 452                                 if (teamplay && self.team)
 453                                         desirabledamage = desirabledamage - teamdamage;
 454
 455                                 mine = find(world, classname, "mine");
 456                                 while (mine)
 457                                 {
 458                                         if (mine.realowner != self)
 459                                         {
 460                                                 mine = find(mine, classname, "mine");
 461                                                 continue;
 462                                         }
 463                                         makevectors(mine.v_angle);
 464                                         targ = targetlist;
 465                                         if (skill > 9) // normal players only do this for the target they are tracking
 466                                         {
 467                                                 targ = targetlist;
 468                                                 while (targ)
 469                                                 {
 470                                                         if (
 471                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 472                                                                 && desirabledamage > 0.1*coredamage
 473                                                         )self.BUTTON_ATCK2 = TRUE;
 474                                                         targ = targ.chain;
 475                                                 }
 476                                         }else{
 477                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 478                                                 //As the distance gets larger, a correct detonation gets near imposible
 479                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 480                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 481                                                         if(IS_PLAYER(self.enemy))
 482                                                                 if(desirabledamage >= 0.1*coredamage)
 483                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 484                                                                                 self.BUTTON_ATCK2 = TRUE;
 485                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 486                                         }
 487
 488                                         mine = find(mine, classname, "mine");
 489                                 }
 490                                 // if we would be doing at X percent of the core damage, detonate it
 491                                 // but don't fire a new shot at the same time!
 492                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 493                                         self.BUTTON_ATCK2 = TRUE;
 494                                 if ((skill > 6.5) && (selfdamage > self.health))
 495                                         self.BUTTON_ATCK2 = FALSE;
 496                                 //if(self.BUTTON_ATCK2 == TRUE)
 497                                 //      dprint(ftos(desirabledamage),"\n");
 498                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 499                         }
 500
 501                         return TRUE;
 502                 }
 503                 case WR_THINK:
 504                 {
 505                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 506                         {
 507                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 508                                 if(!(W_PlacedMines(FALSE) && self.AMMO_VAL(WEP_MINE_LAYER) < WEP_CVAR(minelayer, ammo)))
 509                                         WEP_ACTION(self.weapon, WR_RELOAD);
 510                         }
 511                         else if (self.BUTTON_ATCK)
 512                         {
 513                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 514                                 {
 515                                         W_Mine_Attack();
 516                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 517                                 }
 518                         }
 519
 520                         if (self.BUTTON_ATCK2)
 521                         {
 522                                 if(W_PlacedMines(TRUE))
 523                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 524                         }
 525
 526                         return TRUE;
 527                 }
 528                 case WR_INIT:
 529                 {
 530                         precache_model ("models/flash.md3");
 531                         precache_model ("models/mine.md3");
 532                         precache_model ("models/weapons/g_minelayer.md3");
 533                         precache_model ("models/weapons/v_minelayer.md3");
 534                         precache_model ("models/weapons/h_minelayer.iqm");
 535                         precache_sound ("weapons/mine_det.wav");
 536                         precache_sound ("weapons/mine_fire.wav");
 537                         precache_sound ("weapons/mine_stick.wav");
 538                         precache_sound ("weapons/mine_trigger.wav");
 539                         MINELAYER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 540                         return TRUE;
 541                 }
 542                 case WR_CHECKAMMO1:
 543                 {
 544                         // don't switch while placing a mine
 545                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 546                         {
 547                                 ammo_amount = self.AMMO_VAL(WEP_MINE_LAYER) >= WEP_CVAR(minelayer, ammo);
 548                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 549                                 return ammo_amount;
 550                         }
 551                         return TRUE;
 552                 }
 553                 case WR_CHECKAMMO2:
 554                 {
 555                         if (W_PlacedMines(FALSE))
 556                                 return TRUE;
 557                         else
 558                                 return FALSE;
 559                 }
 560                 case WR_CONFIG:
 561                 {
 562                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 563                         return TRUE;
 564                 }
 565                 case WR_RESETPLAYER:
 566                 {
 567                         self.minelayer_mines = 0;
 568                         return TRUE;
 569                 }
 570                 case WR_RELOAD:
 571                 {
 572                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 573                         return TRUE;
 574                 }
 575                 case WR_SUICIDEMESSAGE:
 576                 {
 577                         return WEAPON_MINELAYER_SUICIDE;
 578                 }
 579                 case WR_KILLMESSAGE:
 580                 {
 581                         return WEAPON_MINELAYER_MURDER;
 582                 }
 583         }
 584         return TRUE;
 585 }
 586 #endif
 587 #ifdef CSQC
 588 float w_minelayer(float req)
 589 {
 590         switch(req)
 591         {
 592                 case WR_IMPACTEFFECT:
 593                 {
 594                         vector org2;
 595                         org2 = w_org + w_backoff * 12;
 596                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 597                         if(!w_issilent)
 598                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 599
 600                         return TRUE;
 601                 }
 602                 case WR_INIT:
 603                 {
 604                         precache_sound("weapons/mine_exp.wav");
 605                         return TRUE;
 606                 }
 607         }
 608         return TRUE;
 609 }
 610 #endif
 611 #endif