qcsrc/common/weapons/w_porto.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ PORTO,
   4 /* function  */ W_Porto,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 0,
   7 /* flags     */ WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON,
   8 /* rating    */ 0,
   9 /* color     */ '0.5 0.5 0.5',
  10 /* modelname */ "porto",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairporto 0.6",
  13 /* refname   */ "porto",
  14 /* wepname   */ _("Port-O-Launch")
  15 );
  16
  17 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  18 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  19         w_cvar(id, sn, BOTH, animtime) \
  20         w_cvar(id, sn, BOTH, lifetime) \
  21         w_cvar(id, sn, BOTH, refire) \
  22         w_cvar(id, sn, BOTH, speed) \
  23         w_cvar(id, sn, NONE, secondary) \
  24         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  25         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  26         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  27         w_prop(id, sn, float,  weaponstart, weaponstart) \
  28         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  29
  30 #ifdef SVQC
  31 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  32 .entity porto_current;
  33 .vector porto_v_angle; // holds "held" view angles
  34 .float porto_v_angle_held;
  35 .vector right_vector;
  36 #endif
  37 #else
  38 #ifdef SVQC
  39 void spawnfunc_weapon_porto (void) { weapon_defaultspawnfunc(WEP_PORTO); }
  40
  41 void W_Porto_Success (void)
  42 {
  43         if(self.realowner == world)
  44         {
  45                 objerror("Cannot succeed successfully: no owner\n");
  46                 return;
  47         }
  48
  49         self.realowner.porto_current = world;
  50         remove(self);
  51 }
  52
  53 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  54 void W_Porto_Fail (float failhard)
  55 {
  56         if(self.realowner == world)
  57         {
  58                 objerror("Cannot fail successfully: no owner\n");
  59                 return;
  60         }
  61
  62         // no portals here!
  63         if(self.cnt < 0)
  64         {
  65                 Portal_ClearWithID(self.realowner, self.portal_id);
  66         }
  67
  68         self.realowner.porto_current = world;
  69
  70         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  71         {
  72                 setsize (self, '-16 -16 0', '16 16 32');
  73                 setorigin(self, self.origin + trace_plane_normal);
  74                 if(move_out_of_solid(self))
  75                 {
  76                         self.flags = FL_ITEM;
  77                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  78                         tracetoss(self, self);
  79                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  80                         {
  81                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO, 0, self.origin, self.velocity);
  82                                 centerprint(self.realowner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  83                         }
  84                 }
  85         }
  86         remove(self);
  87 }
  88
  89 void W_Porto_Remove (entity p)
  90 {
  91         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  92         {
  93                 entity oldself;
  94                 oldself = self;
  95                 self = p.porto_current;
  96                 W_Porto_Fail(1);
  97                 self = oldself;
  98         }
  99 }
 100
 101 void W_Porto_Think (void)
 102 {
 103         trace_plane_normal = '0 0 0';
 104         if(self.realowner.playerid != self.playerid)
 105                 remove(self);
 106         else
 107                 W_Porto_Fail(0);
 108 }
 109
 110 void W_Porto_Touch (void)
 111 {
 112         vector norm;
 113
 114         // do not use PROJECTILE_TOUCH here
 115         // FIXME but DO handle warpzones!
 116
 117         if(other.classname == "portal")
 118                 return; // handled by the portal
 119
 120         norm = trace_plane_normal;
 121         if(trace_ent.iscreature)
 122         {
 123                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
 124                 if(trace_fraction >= 1)
 125                         return;
 126                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 127                         return;
 128                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 129                         return;
 130         }
 131
 132         if(self.realowner.playerid != self.playerid)
 133         {
 134                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 135                 remove(self);
 136         }
 137         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 138         {
 139                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTEN_NORM);
 140                 // just reflect
 141                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 142                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 143         }
 144         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 145         {
 146                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 147                 W_Porto_Fail(0);
 148                 if(self.cnt < 0)
 149                         Portal_ClearAll_PortalsOnly(self.realowner);
 150         }
 151         else if(self.cnt == 0)
 152         {
 153                 // in-portal only
 154                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 155                 {
 156                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 157                         trace_plane_normal = norm;
 158                         centerprint(self.realowner, "^1In^7-portal created.");
 159                         W_Porto_Success();
 160                 }
 161                 else
 162                 {
 163                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 164                         trace_plane_normal = norm;
 165                         W_Porto_Fail(0);
 166                 }
 167         }
 168         else if(self.cnt == 1)
 169         {
 170                 // out-portal only
 171                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 172                 {
 173                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 174                         trace_plane_normal = norm;
 175                         centerprint(self.realowner, "^4Out^7-portal created.");
 176                         W_Porto_Success();
 177                 }
 178                 else
 179                 {
 180                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 181                         trace_plane_normal = norm;
 182                         W_Porto_Fail(0);
 183                 }
 184         }
 185         else if(self.effects & EF_RED)
 186         {
 187                 self.effects += EF_BLUE - EF_RED;
 188                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 189                 {
 190                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 191                         trace_plane_normal = norm;
 192                         centerprint(self.realowner, "^1In^7-portal created.");
 193                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 194                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 195                         CSQCProjectile(self, TRUE, PROJECTILE_PORTO_BLUE, TRUE); // change type
 196                 }
 197                 else
 198                 {
 199                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 200                         trace_plane_normal = norm;
 201                         Portal_ClearAll_PortalsOnly(self.realowner);
 202                         W_Porto_Fail(0);
 203                 }
 204         }
 205         else
 206         {
 207                 if(self.realowner.portal_in.portal_id == self.portal_id)
 208                 {
 209                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 210                         {
 211                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 212                                 trace_plane_normal = norm;
 213                                 centerprint(self.realowner, "^4Out^7-portal created.");
 214                                 W_Porto_Success();
 215                         }
 216                         else
 217                         {
 218                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 219                                 Portal_ClearAll_PortalsOnly(self.realowner);
 220                                 W_Porto_Fail(0);
 221                         }
 222                 }
 223                 else
 224                 {
 225                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 226                         Portal_ClearAll_PortalsOnly(self.realowner);
 227                         W_Porto_Fail(0);
 228                 }
 229         }
 230 }
 231
 232 void W_Porto_Attack (float type)
 233 {
 234         entity gren;
 235
 236         W_SetupShot (self, FALSE, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 237         // always shoot from the eye
 238         w_shotdir = v_forward;
 239         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 240
 241         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 242
 243         gren = spawn ();
 244         gren.cnt = type;
 245         gren.owner = gren.realowner = self;
 246         gren.playerid = self.playerid;
 247         gren.classname = "porto";
 248         gren.bot_dodge = TRUE;
 249         gren.bot_dodgerating = 200;
 250         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 251         PROJECTILE_MAKETRIGGER(gren);
 252         gren.effects = EF_RED;
 253         gren.scale = 4;
 254         setorigin(gren, w_shotorg);
 255         setsize(gren, '0 0 0', '0 0 0');
 256
 257         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 258         gren.think = W_Porto_Think;
 259         gren.touch = W_Porto_Touch;
 260
 261         if(self.items & IT_STRENGTH)
 262                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 263         else
 264                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 265
 266         gren.angles = vectoangles (gren.velocity);
 267         gren.flags = FL_PROJECTILE;
 268
 269         gren.portal_id = time;
 270         self.porto_current = gren;
 271         gren.playerid = self.playerid;
 272         fixedmakevectors(fixedvectoangles(gren.velocity));
 273         gren.right_vector = v_right;
 274
 275         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 276
 277         if(type > 0)
 278                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_BLUE, TRUE);
 279         else
 280                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_RED, TRUE);
 281
 282         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 283 }
 284
 285 float w_nexball_weapon(float req); // WEAPONTODO
 286 float W_Porto(float req)
 287 {
 288         //vector v_angle_save;
 289
 290         if (g_nexball) { return w_nexball_weapon(req); }
 291
 292         switch(req)
 293         {
 294                 case WR_AIM:
 295                 {
 296                         self.BUTTON_ATCK = FALSE;
 297                         self.BUTTON_ATCK2 = FALSE;
 298                         if(!WEP_CVAR(porto, secondary))
 299                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), FALSE))
 300                                         self.BUTTON_ATCK = TRUE;
 301
 302                         return TRUE;
 303                 }
 304                 case WR_CONFIG:
 305                 {
 306                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 307                         return TRUE;
 308                 }
 309                 case WR_THINK:
 310                 {
 311                         if(WEP_CVAR(porto, secondary))
 312                         {
 313                                 if (self.BUTTON_ATCK)
 314                                 if (!self.porto_current)
 315                                 if (!self.porto_forbidden)
 316                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 317                                 {
 318                                         W_Porto_Attack(0);
 319                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 320                                 }
 321
 322                                 if (self.BUTTON_ATCK2)
 323                                 if (!self.porto_current)
 324                                 if (!self.porto_forbidden)
 325                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 326                                 {
 327                                         W_Porto_Attack(1);
 328                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 329                                 }
 330                         }
 331                         else
 332                         {
 333                                 if(self.porto_v_angle_held)
 334                                 {
 335                                         if(!self.BUTTON_ATCK2)
 336                                         {
 337                                                 self.porto_v_angle_held = 0;
 338
 339                                                 ClientData_Touch(self);
 340                                         }
 341                                 }
 342                                 else
 343                                 {
 344                                         if(self.BUTTON_ATCK2)
 345                                         {
 346                                                 self.porto_v_angle = self.v_angle;
 347                                                 self.porto_v_angle_held = 1;
 348
 349                                                 ClientData_Touch(self);
 350                                         }
 351                                 }
 352                                 if(self.porto_v_angle_held)
 353                                         makevectors(self.porto_v_angle); // override the previously set angles
 354
 355                                 if (self.BUTTON_ATCK)
 356                                 if (!self.porto_current)
 357                                 if (!self.porto_forbidden)
 358                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 359                                 {
 360                                         W_Porto_Attack(-1);
 361                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 362                                 }
 363                         }
 364
 365                         return TRUE;
 366                 }
 367                 case WR_INIT:
 368                 {
 369                         precache_model ("models/weapons/g_porto.md3");
 370                         precache_model ("models/weapons/v_porto.md3");
 371                         precache_model ("models/weapons/h_porto.iqm");
 372                         precache_model ("models/portal.md3");
 373                         precache_sound ("porto/bounce.wav");
 374                         precache_sound ("porto/create.wav");
 375                         precache_sound ("porto/expire.wav");
 376                         precache_sound ("porto/explode.wav");
 377                         precache_sound ("porto/fire.wav");
 378                         precache_sound ("porto/unsupported.wav");
 379                         PORTO_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 380                         return TRUE;
 381                 }
 382                 case WR_SETUP:
 383                 {
 384                         self.ammo_field = ammo_none;
 385                         return TRUE;
 386                 }
 387                 case WR_RESETPLAYER:
 388                 {
 389                         self.porto_current = world;
 390                         return TRUE;
 391                 }
 392         }
 393         return TRUE;
 394 }
 395 #endif
 396 #ifdef CSQC
 397 float W_Porto(float req)
 398 {
 399         switch(req)
 400         {
 401                 case WR_IMPACTEFFECT:
 402                 {
 403                         print("Since when does Porto send DamageInfo?\n");
 404                         return TRUE;
 405                 }
 406                 case WR_INIT:
 407                 {
 408                         // nothing to do
 409                         return TRUE;
 410                 }
 411                 case WR_ZOOMRETICLE:
 412                 {
 413                         // no weapon specific image for this weapon
 414                         return FALSE;
 415                 }
 416         }
 417         return TRUE;
 418 }
 419 #endif
 420 #endif