qcsrc/common/weapons/w_porto.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ PORTO,
   4 /* function */ W_Porto,
   5 /* ammotype */ ammo_none,
   6 /* impulse  */ 0,
   7 /* flags    */ WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON,
   8 /* rating   */ 0,
   9 /* color        */ '0.5 0.5 0.5',
  10 /* model    */ "porto" ,
  11 /* netname  */ "porto",
  12 /* fullname */ _("Port-O-Launch")
  13 );
  14
  15 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  16 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, BOTH, animtime) \
  18         w_cvar(id, sn, BOTH, lifetime) \
  19         w_cvar(id, sn, BOTH, refire) \
  20         w_cvar(id, sn, BOTH, speed) \
  21         w_cvar(id, sn, NONE, secondary) \
  22         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  23         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  24         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  25         w_prop(id, sn, float,  weaponstart, weaponstart) \
  26         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  27
  28 #ifdef SVQC
  29 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  30 .entity porto_current;
  31 .vector porto_v_angle; // holds "held" view angles
  32 .float porto_v_angle_held;
  33 .vector right_vector;
  34 #endif
  35 #else
  36 #ifdef SVQC
  37 void spawnfunc_weapon_porto (void) { weapon_defaultspawnfunc(WEP_PORTO); }
  38
  39 void W_Porto_Success (void)
  40 {
  41         if(self.realowner == world)
  42         {
  43                 objerror("Cannot succeed successfully: no owner\n");
  44                 return;
  45         }
  46
  47         self.realowner.porto_current = world;
  48         remove(self);
  49 }
  50
  51 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  52 void W_Porto_Fail (float failhard)
  53 {
  54         if(self.realowner == world)
  55         {
  56                 objerror("Cannot fail successfully: no owner\n");
  57                 return;
  58         }
  59
  60         // no portals here!
  61         if(self.cnt < 0)
  62         {
  63                 Portal_ClearWithID(self.realowner, self.portal_id);
  64         }
  65
  66         self.realowner.porto_current = world;
  67
  68         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  69         {
  70                 setsize (self, '-16 -16 0', '16 16 32');
  71                 setorigin(self, self.origin + trace_plane_normal);
  72                 if(move_out_of_solid(self))
  73                 {
  74                         self.flags = FL_ITEM;
  75                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  76                         tracetoss(self, self);
  77                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  78                         {
  79                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO, 0, self.origin, self.velocity);
  80                                 centerprint(self.realowner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  81                         }
  82                 }
  83         }
  84         remove(self);
  85 }
  86
  87 void W_Porto_Remove (entity p)
  88 {
  89         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  90         {
  91                 entity oldself;
  92                 oldself = self;
  93                 self = p.porto_current;
  94                 W_Porto_Fail(1);
  95                 self = oldself;
  96         }
  97 }
  98
  99 void W_Porto_Think (void)
 100 {
 101         trace_plane_normal = '0 0 0';
 102         if(self.realowner.playerid != self.playerid)
 103                 remove(self);
 104         else
 105                 W_Porto_Fail(0);
 106 }
 107
 108 void W_Porto_Touch (void)
 109 {
 110         vector norm;
 111
 112         // do not use PROJECTILE_TOUCH here
 113         // FIXME but DO handle warpzones!
 114
 115         if(other.classname == "portal")
 116                 return; // handled by the portal
 117
 118         norm = trace_plane_normal;
 119         if(trace_ent.iscreature)
 120         {
 121                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
 122                 if(trace_fraction >= 1)
 123                         return;
 124                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 125                         return;
 126                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 127                         return;
 128         }
 129
 130         if(self.realowner.playerid != self.playerid)
 131         {
 132                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 133                 remove(self);
 134         }
 135         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 136         {
 137                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTEN_NORM);
 138                 // just reflect
 139                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 140                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 141         }
 142         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 143         {
 144                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 145                 W_Porto_Fail(0);
 146                 if(self.cnt < 0)
 147                         Portal_ClearAll_PortalsOnly(self.realowner);
 148         }
 149         else if(self.cnt == 0)
 150         {
 151                 // in-portal only
 152                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 153                 {
 154                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 155                         trace_plane_normal = norm;
 156                         centerprint(self.realowner, "^1In^7-portal created.");
 157                         W_Porto_Success();
 158                 }
 159                 else
 160                 {
 161                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 162                         trace_plane_normal = norm;
 163                         W_Porto_Fail(0);
 164                 }
 165         }
 166         else if(self.cnt == 1)
 167         {
 168                 // out-portal only
 169                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 170                 {
 171                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 172                         trace_plane_normal = norm;
 173                         centerprint(self.realowner, "^4Out^7-portal created.");
 174                         W_Porto_Success();
 175                 }
 176                 else
 177                 {
 178                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 179                         trace_plane_normal = norm;
 180                         W_Porto_Fail(0);
 181                 }
 182         }
 183         else if(self.effects & EF_RED)
 184         {
 185                 self.effects += EF_BLUE - EF_RED;
 186                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 187                 {
 188                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 189                         trace_plane_normal = norm;
 190                         centerprint(self.realowner, "^1In^7-portal created.");
 191                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 192                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 193                         CSQCProjectile(self, TRUE, PROJECTILE_PORTO_BLUE, TRUE); // change type
 194                 }
 195                 else
 196                 {
 197                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 198                         trace_plane_normal = norm;
 199                         Portal_ClearAll_PortalsOnly(self.realowner);
 200                         W_Porto_Fail(0);
 201                 }
 202         }
 203         else
 204         {
 205                 if(self.realowner.portal_in.portal_id == self.portal_id)
 206                 {
 207                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 208                         {
 209                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 210                                 trace_plane_normal = norm;
 211                                 centerprint(self.realowner, "^4Out^7-portal created.");
 212                                 W_Porto_Success();
 213                         }
 214                         else
 215                         {
 216                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 217                                 Portal_ClearAll_PortalsOnly(self.realowner);
 218                                 W_Porto_Fail(0);
 219                         }
 220                 }
 221                 else
 222                 {
 223                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 224                         Portal_ClearAll_PortalsOnly(self.realowner);
 225                         W_Porto_Fail(0);
 226                 }
 227         }
 228 }
 229
 230 void W_Porto_Attack (float type)
 231 {
 232         entity gren;
 233
 234         W_SetupShot (self, FALSE, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 235         // always shoot from the eye
 236         w_shotdir = v_forward;
 237         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 238
 239         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 240
 241         gren = spawn ();
 242         gren.cnt = type;
 243         gren.owner = gren.realowner = self;
 244         gren.playerid = self.playerid;
 245         gren.classname = "porto";
 246         gren.bot_dodge = TRUE;
 247         gren.bot_dodgerating = 200;
 248         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 249         PROJECTILE_MAKETRIGGER(gren);
 250         gren.effects = EF_RED;
 251         gren.scale = 4;
 252         setorigin(gren, w_shotorg);
 253         setsize(gren, '0 0 0', '0 0 0');
 254
 255         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 256         gren.think = W_Porto_Think;
 257         gren.touch = W_Porto_Touch;
 258
 259         if(self.items & IT_STRENGTH)
 260                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 261         else
 262                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 263
 264         gren.angles = vectoangles (gren.velocity);
 265         gren.flags = FL_PROJECTILE;
 266
 267         gren.portal_id = time;
 268         self.porto_current = gren;
 269         gren.playerid = self.playerid;
 270         fixedmakevectors(fixedvectoangles(gren.velocity));
 271         gren.right_vector = v_right;
 272
 273         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 274
 275         if(type > 0)
 276                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_BLUE, TRUE);
 277         else
 278                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_RED, TRUE);
 279
 280         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 281 }
 282
 283 float w_nexball_weapon(float req); // WEAPONTODO
 284 float W_Porto(float req)
 285 {
 286         //vector v_angle_save;
 287
 288         if (g_nexball) { return w_nexball_weapon(req); }
 289
 290         switch(req)
 291         {
 292                 case WR_AIM:
 293                 {
 294                         self.BUTTON_ATCK = FALSE;
 295                         self.BUTTON_ATCK2 = FALSE;
 296                         if(!WEP_CVAR(porto, secondary))
 297                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), FALSE))
 298                                         self.BUTTON_ATCK = TRUE;
 299
 300                         return TRUE;
 301                 }
 302                 case WR_CONFIG:
 303                 {
 304                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 305                         return TRUE;
 306                 }
 307                 case WR_THINK:
 308                 {
 309                         if(WEP_CVAR(porto, secondary))
 310                         {
 311                                 if (self.BUTTON_ATCK)
 312                                 if (!self.porto_current)
 313                                 if (!self.porto_forbidden)
 314                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 315                                 {
 316                                         W_Porto_Attack(0);
 317                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 318                                 }
 319
 320                                 if (self.BUTTON_ATCK2)
 321                                 if (!self.porto_current)
 322                                 if (!self.porto_forbidden)
 323                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 324                                 {
 325                                         W_Porto_Attack(1);
 326                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 327                                 }
 328                         }
 329                         else
 330                         {
 331                                 if(self.porto_v_angle_held)
 332                                 {
 333                                         if(!self.BUTTON_ATCK2)
 334                                         {
 335                                                 self.porto_v_angle_held = 0;
 336
 337                                                 ClientData_Touch(self);
 338                                         }
 339                                 }
 340                                 else
 341                                 {
 342                                         if(self.BUTTON_ATCK2)
 343                                         {
 344                                                 self.porto_v_angle = self.v_angle;
 345                                                 self.porto_v_angle_held = 1;
 346
 347                                                 ClientData_Touch(self);
 348                                         }
 349                                 }
 350                                 if(self.porto_v_angle_held)
 351                                         makevectors(self.porto_v_angle); // override the previously set angles
 352
 353                                 if (self.BUTTON_ATCK)
 354                                 if (!self.porto_current)
 355                                 if (!self.porto_forbidden)
 356                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 357                                 {
 358                                         W_Porto_Attack(-1);
 359                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 360                                 }
 361                         }
 362
 363                         return TRUE;
 364                 }
 365                 case WR_INIT:
 366                 {
 367                         precache_model ("models/weapons/g_porto.md3");
 368                         precache_model ("models/weapons/v_porto.md3");
 369                         precache_model ("models/weapons/h_porto.iqm");
 370                         precache_model ("models/portal.md3");
 371                         precache_sound ("porto/bounce.wav");
 372                         precache_sound ("porto/create.wav");
 373                         precache_sound ("porto/expire.wav");
 374                         precache_sound ("porto/explode.wav");
 375                         precache_sound ("porto/fire.wav");
 376                         precache_sound ("porto/unsupported.wav");
 377                         PORTO_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 378                         return TRUE;
 379                 }
 380                 case WR_SETUP:
 381                 {
 382                         self.ammo_field = ammo_none;
 383                         return TRUE;
 384                 }
 385                 case WR_RESETPLAYER:
 386                 {
 387                         self.porto_current = world;
 388                         return TRUE;
 389                 }
 390         }
 391         return TRUE;
 392 }
 393 #endif
 394 #ifdef CSQC
 395 float W_Porto(float req)
 396 {
 397         switch(req)
 398         {
 399                 case WR_IMPACTEFFECT:
 400                 {
 401                         print("Since when does Porto send DamageInfo?\n");
 402                         return TRUE;
 403                 }
 404                 case WR_INIT:
 405                 {
 406                         // nothing to do
 407                         return TRUE;
 408                 }
 409                 case WR_ZOOMRETICLE:
 410                 {
 411                         // no weapon specific image for this weapon
 412                         return FALSE;
 413                 }
 414         }
 415         return TRUE;
 416 }
 417 #endif
 418 #endif