qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SEEKER,
   4 /* function  */ W_Seeker,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 8,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '0.5 1 0',
  10 /* modelname */ "seeker",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairseeker 0.8",
  13 /* refname   */ "seeker",
  14 /* wepname   */ _("T.A.G. Seeker")
  15 );
  16
  17 #define SEEKER_SETTINGS(w_cvar,w_prop) SEEKER_SETTINGS_LIST(w_cvar, w_prop, SEEKER, seeker)
  18 #define SEEKER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  19         w_cvar(id, sn, NONE, type) \
  20         w_cvar(id, sn, NONE, flac_ammo) \
  21         w_cvar(id, sn, NONE, flac_animtime) \
  22         w_cvar(id, sn, NONE, flac_damage) \
  23         w_cvar(id, sn, NONE, flac_edgedamage) \
  24         w_cvar(id, sn, NONE, flac_force) \
  25         w_cvar(id, sn, NONE, flac_lifetime) \
  26         w_cvar(id, sn, NONE, flac_lifetime_rand) \
  27         w_cvar(id, sn, NONE, flac_radius) \
  28         w_cvar(id, sn, NONE, flac_refire) \
  29         w_cvar(id, sn, NONE, flac_speed) \
  30         w_cvar(id, sn, NONE, flac_speed_up) \
  31         w_cvar(id, sn, NONE, flac_speed_z) \
  32         w_cvar(id, sn, NONE, flac_spread) \
  33         w_cvar(id, sn, NONE, missile_accel) \
  34         w_cvar(id, sn, NONE, missile_ammo) \
  35         w_cvar(id, sn, NONE, missile_animtime) \
  36         w_cvar(id, sn, NONE, missile_count) \
  37         w_cvar(id, sn, NONE, missile_damage) \
  38         w_cvar(id, sn, NONE, missile_damageforcescale) \
  39         w_cvar(id, sn, NONE, missile_decel) \
  40         w_cvar(id, sn, NONE, missile_delay) \
  41         w_cvar(id, sn, NONE, missile_edgedamage) \
  42         w_cvar(id, sn, NONE, missile_force) \
  43         w_cvar(id, sn, NONE, missile_health) \
  44         w_cvar(id, sn, NONE, missile_lifetime) \
  45         w_cvar(id, sn, NONE, missile_proxy) \
  46         w_cvar(id, sn, NONE, missile_proxy_delay) \
  47         w_cvar(id, sn, NONE, missile_proxy_maxrange) \
  48         w_cvar(id, sn, NONE, missile_radius) \
  49         w_cvar(id, sn, NONE, missile_refire) \
  50         w_cvar(id, sn, NONE, missile_smart) \
  51         w_cvar(id, sn, NONE, missile_smart_mindist) \
  52         w_cvar(id, sn, NONE, missile_smart_trace_max) \
  53         w_cvar(id, sn, NONE, missile_smart_trace_min) \
  54         w_cvar(id, sn, NONE, missile_speed) \
  55         w_cvar(id, sn, NONE, missile_speed_max) \
  56         w_cvar(id, sn, NONE, missile_speed_up) \
  57         w_cvar(id, sn, NONE, missile_speed_z) \
  58         w_cvar(id, sn, NONE, missile_spread) \
  59         w_cvar(id, sn, NONE, missile_turnrate) \
  60         w_cvar(id, sn, NONE, tag_ammo) \
  61         w_cvar(id, sn, NONE, tag_animtime) \
  62         w_cvar(id, sn, NONE, tag_damageforcescale) \
  63         w_cvar(id, sn, NONE, tag_health) \
  64         w_cvar(id, sn, NONE, tag_lifetime) \
  65         w_cvar(id, sn, NONE, tag_refire) \
  66         w_cvar(id, sn, NONE, tag_speed) \
  67         w_cvar(id, sn, NONE, tag_spread) \
  68         w_cvar(id, sn, NONE, tag_tracker_lifetime) \
  69         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  70         w_prop(id, sn, float,  reloading_time, reload_time) \
  71         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  72         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  73         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  74         w_prop(id, sn, float,  weaponstart, weaponstart) \
  75         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  76
  77 #ifdef SVQC
  78 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  79 .entity tag_target, wps_tag_tracker;
  80 .float tag_time;
  81 #endif
  82 #else
  83 #ifdef SVQC
  84 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  85
  86 // ============================
  87 // Begin: Missile functions, these are general functions to be manipulated by other code
  88 // ============================
  89 void W_Seeker_Missile_Explode()
  90 {
  91         self.event_damage = func_null;
  92         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  93
  94         remove (self);
  95 }
  96
  97 void W_Seeker_Missile_Touch()
  98 {
  99         PROJECTILE_TOUCH;
 100
 101         W_Seeker_Missile_Explode();
 102 }
 103
 104 void W_Seeker_Missile_Think()
 105 {
 106         entity e;
 107         vector desireddir, olddir, newdir, eorg;
 108         float turnrate;
 109         float dist;
 110         float spd;
 111
 112         if (time > self.cnt)
 113         {
 114                 self.projectiledeathtype |= HITTYPE_SPLASH;
 115                 W_Seeker_Missile_Explode();
 116         }
 117
 118         spd = vlen(self.velocity);
 119         spd = bound(
 120                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 121                 WEP_CVAR(seeker, missile_speed_max),
 122                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 123         );
 124
 125         if (self.enemy != world)
 126                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 127                         self.enemy = world;
 128
 129         if (self.enemy != world)
 130         {
 131                 e               = self.enemy;
 132                 eorg            = 0.5 * (e.absmin + e.absmax);
 133                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 134                 desireddir      = normalize(eorg - self.origin);
 135                 olddir          = normalize(self.velocity); // get my current direction
 136                 dist            = vlen(eorg - self.origin);
 137
 138                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 139                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 140                 {
 141                         // Is it a better idea (shorter distance) to trace to the target itself?
 142                         if ( vlen(self.origin + olddir * self.wait) < dist)
 143                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 144                         else
 145                                 traceline(self.origin, eorg, FALSE, self);
 146
 147                         // Setup adaptive tracelength
 148                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 149
 150                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 151                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 152                 }
 153
 154                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 155                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 156         }
 157         else
 158                 dist = 0;
 159
 160         // Proxy
 161         if (WEP_CVAR(seeker, missile_proxy))
 162         {
 163                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 164                 {
 165                         if (self.autoswitch == 0)
 166                         {
 167                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 168                         }
 169                         else
 170                         {
 171                                 if (self.autoswitch <= time)
 172                                 {
 173                                         W_Seeker_Missile_Explode();
 174                                         self.autoswitch = 0;
 175                                 }
 176                         }
 177                 }
 178                 else
 179                 {
 180                         if (self.autoswitch != 0)
 181                                 self.autoswitch = 0;
 182                 }
 183         }
 184         ///////////////
 185
 186         if (self.enemy.deadflag != DEAD_NO)
 187         {
 188                 self.enemy = world;
 189                 self.cnt = time + 1 + (random() * 4);
 190                 self.nextthink = self.cnt;
 191                 return;
 192         }
 193
 194         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 195         self.nextthink = time;// + 0.05; // csqc projectiles
 196         UpdateCSQCProjectile(self);
 197 }
 198
 199
 200
 201 void W_Seeker_Missile_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 202 {
 203         if (self.health <= 0)
 204                 return;
 205
 206         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 207                 return; // g_projectiles_damage says to halt
 208
 209         if (self.realowner == attacker)
 210                 self.health = self.health - (damage * 0.25);
 211         else
 212                 self.health = self.health - damage;
 213
 214         if (self.health <= 0)
 215                 W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode);
 216 }
 217
 218 /*
 219 void W_Seeker_Missile_Animate()
 220 {
 221         self.frame = self.frame +1;
 222         self.nextthink = time + 0.05;
 223
 224         if (self.enemy != world)
 225                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 226                         self.enemy = world;
 227
 228         if(self.frame == 5)
 229         {
 230                 self.think           = W_Seeker_Missile_Think;
 231                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 232
 233                 if (autocvar_g_balance_seeker_missile_proxy)
 234                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 235                 else
 236                         self.movetype    = MOVETYPE_FLYMISSILE;
 237         }
 238
 239         UpdateCSQCProjectile(self);
 240 }
 241 */
 242
 243 void W_Seeker_Fire_Missile(vector f_diff, entity m_target)
 244 {
 245         entity missile;
 246
 247         W_DecreaseAmmo(WEP_CVAR(seeker, missile_ammo));
 248
 249         makevectors(self.v_angle);
 250         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 251         w_shotorg += f_diff;
 252         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 253
 254         //self.detornator         = FALSE;
 255
 256         missile                 = spawn();
 257         missile.owner           = missile.realowner = self;
 258         missile.classname       = "seeker_missile";
 259         missile.bot_dodge       = TRUE;
 260         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 261
 262         missile.think           = W_Seeker_Missile_Think;
 263         missile.touch           = W_Seeker_Missile_Touch;
 264         missile.event_damage    = W_Seeker_Missile_Damage;
 265         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 266         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 267         missile.enemy           = m_target;
 268         missile.solid           = SOLID_BBOX;
 269         missile.scale           = 2;
 270         missile.takedamage      = DAMAGE_YES;
 271         missile.health          = WEP_CVAR(seeker, missile_health);
 272         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 273         missile.damagedbycontents = TRUE;
 274         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 275
 276         if (missile.enemy != world)
 277                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 278         else
 279                 missile.projectiledeathtype = WEP_SEEKER;
 280
 281
 282         setorigin (missile, w_shotorg);
 283         setsize (missile, '-4 -4 -4', '4 4 4');
 284         missile.movetype    = MOVETYPE_FLYMISSILE;
 285         missile.flags       = FL_PROJECTILE;
 286         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 287
 288         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 289
 290         missile.angles = vectoangles (missile.velocity);
 291
 292         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 293
 294         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 295 }
 296
 297 // ============================
 298 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 299 // ============================
 300 void W_Seeker_Flac_Explode()
 301 {
 302         self.event_damage = func_null;
 303
 304         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 305
 306         remove (self);
 307 }
 308
 309 void W_Seeker_Flac_Touch()
 310 {
 311         PROJECTILE_TOUCH;
 312
 313         W_Seeker_Flac_Explode();
 314 }
 315
 316 void W_Seeker_Fire_Flac()
 317 {
 318         entity missile;
 319         vector f_diff;
 320         float c;
 321
 322         W_DecreaseAmmo(WEP_CVAR(seeker, flac_ammo));
 323
 324         c = mod(self.bulletcounter, 4);
 325         switch(c)
 326         {
 327                 case 0:
 328                         f_diff = '-1.25 -3.75 0';
 329                         break;
 330                 case 1:
 331                         f_diff = '+1.25 -3.75 0';
 332                         break;
 333                 case 2:
 334                         f_diff = '-1.25 +3.75 0';
 335                         break;
 336                 case 3:
 337                 default:
 338                         f_diff = '+1.25 +3.75 0';
 339                         break;
 340         }
 341         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 342         w_shotorg += f_diff;
 343
 344         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 345
 346         missile                                 = spawn ();
 347         missile.owner                   = missile.realowner = self;
 348         missile.classname               = "missile";
 349         missile.bot_dodge               = TRUE;
 350         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 351         missile.touch                   = W_Seeker_Flac_Explode;
 352         missile.use                     = W_Seeker_Flac_Explode;
 353         missile.think                   = adaptor_think2use_hittype_splash;
 354         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 355         missile.solid                   = SOLID_BBOX;
 356         missile.movetype                = MOVETYPE_FLY;
 357         missile.projectiledeathtype = WEP_SEEKER;
 358         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 359         missile.flags                           = FL_PROJECTILE;
 360         missile.missile_flags       = MIF_SPLASH;
 361
 362         // csqc projectiles
 363         //missile.angles                                = vectoangles (missile.velocity);
 364         //missile.scale = 0.4; // BUG: the model is too big
 365
 366         setorigin (missile, w_shotorg);
 367         setsize (missile, '-2 -2 -2', '2 2 2');
 368
 369         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 370         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 371
 372         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 373 }
 374
 375 // ============================
 376 // Begin: Tag and rocket controllers
 377 // ============================
 378 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 379 {
 380         entity tag;
 381         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 382                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 383                         return tag;
 384
 385         return world;
 386 }
 387
 388 void W_Seeker_Attack()
 389 {
 390         entity tracker, closest_target;
 391
 392         closest_target = world;
 393         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 394         {
 395                 if (closest_target)
 396                 {
 397                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 398                                 closest_target = tracker.tag_target;
 399                 }
 400                 else
 401                         closest_target = tracker.tag_target;
 402         }
 403
 404         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 405         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 406                 closest_target = world;
 407
 408         W_Seeker_Fire_Missile('0 0 0', closest_target);
 409 }
 410
 411 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
 412 {
 413         float c;
 414         entity oldself,oldenemy;
 415         self.cnt = self.cnt - 1;
 416
 417         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.WEP_AMMO(SEEKER) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 418         {
 419                 remove(self);
 420                 return;
 421         }
 422
 423         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 424
 425         oldself = self;
 426         self = self.realowner;
 427
 428         oldenemy = self.enemy;
 429         self.enemy = oldself.enemy;
 430
 431         c = mod(self.cnt, 4);
 432         switch(c)
 433         {
 434                 case 0:
 435                         W_Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 436                         break;
 437                 case 1:
 438                         W_Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 439                         break;
 440                 case 2:
 441                         W_Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 442                         break;
 443                 case 3:
 444                 default:
 445                         W_Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 446                         break;
 447         }
 448
 449         self.enemy = oldenemy;
 450         self = oldself;
 451 }
 452
 453 void W_Seeker_Tracker_Think()
 454 {
 455         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 456         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 457         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 458         {
 459                 if (self)
 460                 {
 461                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 462                         remove(self);
 463                 }
 464                 return;
 465         }
 466
 467         // Update the think method information
 468         self.nextthink = time;
 469 }
 470
 471 // ============================
 472 // Begin: Tag projectile
 473 // ============================
 474 void W_Seeker_Tag_Explode()
 475 {
 476         //if(other==self.realowner)
 477         //    return;
 478         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 479
 480         remove (self);
 481 }
 482
 483 void W_Seeker_Tag_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 484 {
 485         if (self.health <= 0)
 486                 return;
 487         self.health = self.health - damage;
 488         if (self.health <= 0)
 489                 W_Seeker_Tag_Explode();
 490 }
 491
 492 void W_Seeker_Tag_Touch()
 493 {
 494         vector dir;
 495         vector org2;
 496         entity e;
 497
 498         PROJECTILE_TOUCH;
 499
 500         dir     = normalize (self.realowner.origin - self.origin);
 501         org2    = findbetterlocation (self.origin, 8);
 502
 503         te_knightspike(org2);
 504
 505         self.event_damage = func_null;
 506         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 507
 508         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 509         {
 510                 // check to see if this person is already tagged by me
 511                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 512
 513                 if (tag != world)
 514                 {
 515                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 516                                 WaypointSprite_Kill(other.wps_tag_tracker);
 517
 518                         tag.tag_time = time;
 519                 }
 520                 else
 521                 {
 522                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 523                         e             = spawn();
 524                         e.cnt         = WEP_CVAR(seeker, missile_count);
 525                         e.classname   = "tag_tracker";
 526                         e.owner       = self.owner;
 527                         e.realowner   = self.realowner;
 528
 529                         if(WEP_CVAR(seeker, type) == 1)
 530                         {
 531                                 e.tag_target  = other;
 532                                 e.tag_time    = time;
 533                                 e.think       = W_Seeker_Tracker_Think;
 534                         }
 535                         else
 536                         {
 537                                 e.enemy     = other;
 538                                 e.think     = W_Seeker_Vollycontroller_Think;
 539                         }
 540
 541                         e.nextthink   = time;
 542                 }
 543
 544                 if(WEP_CVAR(seeker, type) == 1)
 545                 {
 546                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 547                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 548                 }
 549         }
 550
 551         remove(self);
 552         return;
 553 }
 554
 555 void W_Seeker_Fire_Tag()
 556 {
 557         entity missile;
 558         W_DecreaseAmmo(WEP_CVAR(seeker, tag_ammo));
 559
 560         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 561
 562         missile                 = spawn();
 563         missile.owner           = missile.realowner = self;
 564         missile.classname       = "seeker_tag";
 565         missile.bot_dodge       = TRUE;
 566         missile.bot_dodgerating = 50;
 567         missile.touch           = W_Seeker_Tag_Touch;
 568         missile.think           = SUB_Remove;
 569         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 570         missile.movetype        = MOVETYPE_FLY;
 571         missile.solid           = SOLID_BBOX;
 572
 573         missile.takedamage       = DAMAGE_YES;
 574         missile.event_damage     = W_Seeker_Tag_Damage;
 575         missile.health           = WEP_CVAR(seeker, tag_health);
 576         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 577
 578         setorigin (missile, w_shotorg);
 579         setsize (missile, '-2 -2 -2', '2 2 2');
 580
 581         missile.flags       = FL_PROJECTILE;
 582         //missile.missile_flags = MIF_..?;
 583
 584         missile.movetype    = MOVETYPE_FLY;
 585         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 586         missile.angles = vectoangles (missile.velocity);
 587
 588         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 589
 590         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 591 }
 592
 593 // ============================
 594 // Begin: Genereal weapon functions
 595 // ============================
 596
 597 float W_Seeker(float req)
 598 {
 599         float ammo_amount;
 600
 601         switch(req)
 602         {
 603                 case WR_AIM:
 604                 {
 605                         if (WEP_CVAR(seeker, type) == 1)
 606                                 if (W_Seeker_Tagged_Info(self, self.enemy) != world)
 607                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 608                                 else
 609                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 610                         else
 611                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 612                         return TRUE;
 613                 }
 614                 case WR_THINK:
 615                 {
 616                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 617                                 WEP_ACTION(self.weapon, WR_RELOAD);
 618
 619                         else if (self.BUTTON_ATCK)
 620                         {
 621                                 if (WEP_CVAR(seeker, type) == 1)
 622                                 {
 623                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 624                                         {
 625                                                 W_Seeker_Attack();
 626                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 627                                         }
 628                                 }
 629                                 else
 630                                 {
 631                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 632                                         {
 633                                                 W_Seeker_Fire_Tag();
 634                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 635                                         }
 636                                 }
 637                         }
 638
 639                         else if (self.BUTTON_ATCK2)
 640                         {
 641                                 if (WEP_CVAR(seeker, type) == 1)
 642                                 {
 643                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 644                                         {
 645                                                 W_Seeker_Fire_Tag();
 646                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 647                                         }
 648                                 }
 649                                 else
 650                                 {
 651                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 652                                         {
 653                                                 W_Seeker_Fire_Flac();
 654                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 655                                         }
 656                                 }
 657                         }
 658
 659                         return TRUE;
 660                 }
 661                 case WR_INIT:
 662                 {
 663                         precache_model ("models/weapons/g_seeker.md3");
 664                         precache_model ("models/weapons/v_seeker.md3");
 665                         precache_model ("models/weapons/h_seeker.iqm");
 666                         precache_sound ("weapons/tag_fire.wav");
 667                         precache_sound ("weapons/flac_fire.wav");
 668                         precache_sound ("weapons/seeker_fire.wav");
 669                         SEEKER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 670                         return TRUE;
 671                 }
 672                 case WR_CHECKAMMO1:
 673                 {
 674                         if (WEP_CVAR(seeker, type) == 1)
 675                         {
 676                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, missile_ammo);
 677                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 678                         }
 679                         else
 680                         {
 681                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 682                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 683                         }
 684                         return ammo_amount;
 685                 }
 686                 case WR_CHECKAMMO2:
 687                 {
 688                         if (WEP_CVAR(seeker, type) == 1)
 689                         {
 690                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 691                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 692                         }
 693                         else
 694                         {
 695                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, flac_ammo);
 696                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 697                         }
 698                         return ammo_amount;
 699                 }
 700                 case WR_CONFIG:
 701                 {
 702                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 703                         return TRUE;
 704                 }
 705                 case WR_RELOAD:
 706                 {
 707                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 708                         return TRUE;
 709                 }
 710                 case WR_SUICIDEMESSAGE:
 711                 {
 712                         return WEAPON_SEEKER_SUICIDE;
 713                 }
 714                 case WR_KILLMESSAGE:
 715                 {
 716                         if(w_deathtype & HITTYPE_SECONDARY)
 717                                 return WEAPON_SEEKER_MURDER_TAG;
 718                         else
 719                                 return WEAPON_SEEKER_MURDER_SPRAY;
 720                 }
 721         }
 722         return TRUE;
 723 }
 724 #endif
 725 #ifdef CSQC
 726 float W_Seeker(float req)
 727 {
 728         switch(req)
 729         {
 730                 case WR_IMPACTEFFECT:
 731                 {
 732                         vector org2;
 733                         org2 = w_org + w_backoff * 6;
 734                         if(w_deathtype & HITTYPE_BOUNCE)
 735                         {
 736                                 if(w_deathtype & HITTYPE_SECONDARY)
 737                                 {
 738                                         if(!w_issilent)
 739                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 740                                 }
 741                                 else
 742                                 {
 743                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 744                                         if(!w_issilent)
 745                                         {
 746                                                 if (w_random<0.15)
 747                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 748                                                 else if (w_random<0.7)
 749                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 750                                                 else
 751                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 752                                         }
 753                                 }
 754                         }
 755                         else
 756                         {
 757                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 758                                 if(!w_issilent)
 759                                 {
 760                                         if (w_random<0.15)
 761                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 762                                         else if (w_random<0.7)
 763                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 764                                         else
 765                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 766                                 }
 767                         }
 768                         return TRUE;
 769                 }
 770                 case WR_INIT:
 771                 {
 772                         precache_sound("weapons/seekerexp1.wav");
 773                         precache_sound("weapons/seekerexp2.wav");
 774                         precache_sound("weapons/seekerexp3.wav");
 775                         precache_sound("weapons/tagexp1.wav");
 776                         precache_sound("weapons/tagexp2.wav");
 777                         precache_sound("weapons/tagexp3.wav");
 778                         precache_sound("weapons/tag_impact.wav");
 779                         return TRUE;
 780                 }
 781                 case WR_ZOOMRETICLE:
 782                 {
 783                         // no weapon specific image for this weapon
 784                         return FALSE;
 785                 }
 786         }
 787
 788         return TRUE;
 789 }
 790 #endif
 791 #endif