qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SEEKER,
   4 /* function */ w_seeker,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 8,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "seeker",
  10 /* netname  */ "seeker",
  11 /* fullname */ _("T.A.G. Seeker")
  12 );
  13
  14 #define SEEKER_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_SEEKER, seeker, MO_NONE, type) \
  16         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_ammo) \
  17         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_animtime) \
  18         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_damage) \
  19         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_edgedamage) \
  20         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_force) \
  21         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime) \
  22         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime_rand) \
  23         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_radius) \
  24         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_refire) \
  25         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed) \
  26         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed_up) \
  27         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed_z) \
  28         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_spread) \
  29         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_accel) \
  30         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_ammo) \
  31         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_animtime) \
  32         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_count) \
  33         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damage) \
  34         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damageforcescale) \
  35         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_decel) \
  36         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_delay) \
  37         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_edgedamage) \
  38         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_force) \
  39         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_health) \
  40         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_lifetime) \
  41         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy) \
  42         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_delay) \
  43         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_maxrange) \
  44         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_radius) \
  45         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_refire) \
  46         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart) \
  47         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_mindist) \
  48         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_max) \
  49         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_min) \
  50         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed) \
  51         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_max) \
  52         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_up) \
  53         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_z) \
  54         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_spread) \
  55         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_turnrate) \
  56         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_ammo) \
  57         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_animtime) \
  58         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_damageforcescale) \
  59         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_health) \
  60         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_lifetime) \
  61         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_refire) \
  62         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_speed) \
  63         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_spread) \
  64         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_tracker_lifetime) \
  65         w_prop(WEP_SEEKER, seeker, float,  reloading_ammo, reload_ammo) \
  66         w_prop(WEP_SEEKER, seeker, float,  reloading_time, reload_time) \
  67         w_prop(WEP_SEEKER, seeker, float,  switchdelay_raise, switchdelay_raise) \
  68         w_prop(WEP_SEEKER, seeker, float,  switchdelay_drop, switchdelay_drop) \
  69         w_prop(WEP_SEEKER, seeker, string, weaponreplace, weaponreplace) \
  70         w_prop(WEP_SEEKER, seeker, float,  weaponstart, weaponstart)
  71
  72 #ifdef SVQC
  73 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  74 .entity tag_target, wps_tag_tracker;
  75 .float tag_time;
  76 #endif
  77 #else
  78 #ifdef SVQC
  79 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  80
  81 // ============================
  82 // Begin: Missile functions, these are general functions to be manipulated by other code
  83 // ============================
  84 void Seeker_Missile_Explode ()
  85 {
  86         self.event_damage = func_null;
  87         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  88
  89         remove (self);
  90 }
  91
  92 void Seeker_Missile_Touch()
  93 {
  94         PROJECTILE_TOUCH;
  95
  96         Seeker_Missile_Explode();
  97 }
  98
  99 void Seeker_Missile_Think()
 100 {
 101         entity e;
 102         vector desireddir, olddir, newdir, eorg;
 103         float turnrate;
 104         float dist;
 105         float spd;
 106
 107         if (time > self.cnt)
 108         {
 109                 self.projectiledeathtype |= HITTYPE_SPLASH;
 110                 Seeker_Missile_Explode();
 111         }
 112
 113         spd = vlen(self.velocity);
 114         spd = bound(
 115                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 116                 WEP_CVAR(seeker, missile_speed_max),
 117                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 118         );
 119
 120         if (self.enemy != world)
 121                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 122                         self.enemy = world;
 123
 124         if (self.enemy != world)
 125         {
 126                 e               = self.enemy;
 127                 eorg            = 0.5 * (e.absmin + e.absmax);
 128                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 129                 desireddir      = normalize(eorg - self.origin);
 130                 olddir          = normalize(self.velocity); // get my current direction
 131                 dist            = vlen(eorg - self.origin);
 132
 133                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 134                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 135                 {
 136                         // Is it a better idea (shorter distance) to trace to the target itself?
 137                         if ( vlen(self.origin + olddir * self.wait) < dist)
 138                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 139                         else
 140                                 traceline(self.origin, eorg, FALSE, self);
 141
 142                         // Setup adaptive tracelength
 143                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 144
 145                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 146                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 147                 }
 148
 149                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 150                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 151         }
 152         else
 153                 dist = 0;
 154
 155         // Proxy
 156         if (WEP_CVAR(seeker, missile_proxy))
 157         {
 158                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 159                 {
 160                         if (self.autoswitch == 0)
 161                         {
 162                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 163                         }
 164                         else
 165                         {
 166                                 if (self.autoswitch <= time)
 167                                 {
 168                                         Seeker_Missile_Explode();
 169                                         self.autoswitch = 0;
 170                                 }
 171                         }
 172                 }
 173                 else
 174                 {
 175                         if (self.autoswitch != 0)
 176                                 self.autoswitch = 0;
 177                 }
 178         }
 179         ///////////////
 180
 181         if (self.enemy.deadflag != DEAD_NO)
 182         {
 183                 self.enemy = world;
 184                 self.cnt = time + 1 + (random() * 4);
 185                 self.nextthink = self.cnt;
 186                 return;
 187         }
 188
 189         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 190         self.nextthink = time;// + 0.05; // csqc projectiles
 191         UpdateCSQCProjectile(self);
 192 }
 193
 194
 195
 196 void Seeker_Missile_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 197 {
 198         if (self.health <= 0)
 199                 return;
 200
 201         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 202                 return; // g_projectiles_damage says to halt
 203
 204         if (self.realowner == attacker)
 205                 self.health = self.health - (damage * 0.25);
 206         else
 207                 self.health = self.health - damage;
 208
 209         if (self.health <= 0)
 210                 W_PrepareExplosionByDamage(attacker, Seeker_Missile_Explode);
 211 }
 212
 213 /*
 214 void Seeker_Missile_Animate()
 215 {
 216         self.frame = self.frame +1;
 217         self.nextthink = time + 0.05;
 218
 219         if (self.enemy != world)
 220                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 221                         self.enemy = world;
 222
 223         if(self.frame == 5)
 224         {
 225                 self.think           = Seeker_Missile_Think;
 226                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 227
 228                 if (autocvar_g_balance_seeker_missile_proxy)
 229                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 230                 else
 231                         self.movetype    = MOVETYPE_FLYMISSILE;
 232         }
 233
 234         UpdateCSQCProjectile(self);
 235 }
 236 */
 237
 238 void Seeker_Fire_Missile(vector f_diff, entity m_target)
 239 {
 240         entity missile;
 241
 242         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, missile_ammo), autocvar_g_balance_seeker_reload_ammo);
 243
 244         makevectors(self.v_angle);
 245         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 246         w_shotorg += f_diff;
 247         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 248
 249         //self.detornator         = FALSE;
 250
 251         missile                 = spawn();
 252         missile.owner           = missile.realowner = self;
 253         missile.classname       = "seeker_missile";
 254         missile.bot_dodge       = TRUE;
 255         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 256
 257         missile.think           = Seeker_Missile_Think;
 258         missile.touch           = Seeker_Missile_Touch;
 259         missile.event_damage    = Seeker_Missile_Damage;
 260         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 261         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 262         missile.enemy           = m_target;
 263         missile.solid           = SOLID_BBOX;
 264         missile.scale           = 2;
 265         missile.takedamage      = DAMAGE_YES;
 266         missile.health          = WEP_CVAR(seeker, missile_health);
 267         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 268         missile.damagedbycontents = TRUE;
 269         //missile.think           = Seeker_Missile_Animate; // csqc projectiles.
 270
 271         if (missile.enemy != world)
 272                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 273         else
 274                 missile.projectiledeathtype = WEP_SEEKER;
 275
 276
 277         setorigin (missile, w_shotorg);
 278         setsize (missile, '-4 -4 -4', '4 4 4');
 279         missile.movetype    = MOVETYPE_FLYMISSILE;
 280         missile.flags       = FL_PROJECTILE;
 281         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 282
 283         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, missile_);
 284
 285         missile.angles = vectoangles (missile.velocity);
 286
 287         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 288
 289         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 290 }
 291
 292 // ============================
 293 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 294 // ============================
 295 void Seeker_Flac_Explode ()
 296 {
 297         self.event_damage = func_null;
 298
 299         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 300
 301         remove (self);
 302 }
 303
 304 void Seeker_Flac_Touch()
 305 {
 306         PROJECTILE_TOUCH;
 307
 308         Seeker_Flac_Explode();
 309 }
 310
 311 void Seeker_Fire_Flac()
 312 {
 313         entity missile;
 314         vector f_diff;
 315         float c;
 316
 317         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, flac_ammo), autocvar_g_balance_seeker_reload_ammo);
 318
 319         c = mod(self.bulletcounter, 4);
 320         switch(c)
 321         {
 322                 case 0:
 323                         f_diff = '-1.25 -3.75 0';
 324                         break;
 325                 case 1:
 326                         f_diff = '+1.25 -3.75 0';
 327                         break;
 328                 case 2:
 329                         f_diff = '-1.25 +3.75 0';
 330                         break;
 331                 case 3:
 332                 default:
 333                         f_diff = '+1.25 +3.75 0';
 334                         break;
 335         }
 336         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 337         w_shotorg += f_diff;
 338
 339         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 340
 341         missile                                 = spawn ();
 342         missile.owner                   = missile.realowner = self;
 343         missile.classname               = "missile";
 344         missile.bot_dodge               = TRUE;
 345         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 346         missile.touch                   = Seeker_Flac_Explode;
 347         missile.use                     = Seeker_Flac_Explode;
 348         missile.think                   = adaptor_think2use_hittype_splash;
 349         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 350         missile.solid                   = SOLID_BBOX;
 351         missile.movetype                = MOVETYPE_FLY;
 352         missile.projectiledeathtype = WEP_SEEKER;
 353         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 354         missile.flags                           = FL_PROJECTILE;
 355         missile.missile_flags       = MIF_SPLASH;
 356
 357         // csqc projectiles
 358         //missile.angles                                = vectoangles (missile.velocity);
 359         //missile.scale = 0.4; // BUG: the model is too big
 360
 361         setorigin (missile, w_shotorg);
 362         setsize (missile, '-2 -2 -2', '2 2 2');
 363
 364         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, flac_);
 365         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 366
 367         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 368 }
 369
 370 // ============================
 371 // Begin: Tag and rocket controllers
 372 // ============================
 373 entity Seeker_Tagged_Info(entity isowner, entity istarget)
 374 {
 375         entity tag;
 376         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 377                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 378                         return tag;
 379
 380         return world;
 381 }
 382
 383 void Seeker_Attack()
 384 {
 385         entity tracker, closest_target;
 386
 387         closest_target = world;
 388         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 389         {
 390                 if (closest_target)
 391                 {
 392                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 393                                 closest_target = tracker.tag_target;
 394                 }
 395                 else
 396                         closest_target = tracker.tag_target;
 397         }
 398
 399         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 400         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 401                 closest_target = world;
 402
 403         Seeker_Fire_Missile('0 0 0', closest_target);
 404 }
 405
 406 void Seeker_Vollycontroller_Think() // TODO: Merge this with Seeker_Attack
 407 {
 408         float c;
 409         entity oldself,oldenemy;
 410         self.cnt = self.cnt - 1;
 411
 412         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.ammo_rockets < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 413         {
 414                 remove(self);
 415                 return;
 416         }
 417
 418         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 419
 420         oldself = self;
 421         self = self.realowner;
 422
 423         oldenemy = self.enemy;
 424         self.enemy = oldself.enemy;
 425
 426         c = mod(self.cnt, 4);
 427         switch(c)
 428         {
 429                 case 0:
 430                         Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 431                         break;
 432                 case 1:
 433                         Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 434                         break;
 435                 case 2:
 436                         Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 437                         break;
 438                 case 3:
 439                 default:
 440                         Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 441                         break;
 442         }
 443
 444         self.enemy = oldenemy;
 445         self = oldself;
 446 }
 447
 448 void Seeker_Tracker_Think()
 449 {
 450         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 451         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 452         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 453         {
 454                 if (self)
 455                 {
 456                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 457                         remove(self);
 458                 }
 459                 return;
 460         }
 461
 462         // Update the think method information
 463         self.nextthink = time;
 464 }
 465
 466 // ============================
 467 // Begin: Tag projectile
 468 // ============================
 469 void Seeker_Tag_Explode ()
 470 {
 471         //if(other==self.realowner)
 472         //    return;
 473         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 474
 475         remove (self);
 476 }
 477
 478 void Seeker_Tag_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 479 {
 480         if (self.health <= 0)
 481                 return;
 482         self.health = self.health - damage;
 483         if (self.health <= 0)
 484                 Seeker_Tag_Explode();
 485 }
 486
 487 void Seeker_Tag_Touch()
 488 {
 489         vector dir;
 490         vector org2;
 491         entity e;
 492
 493         PROJECTILE_TOUCH;
 494
 495         dir     = normalize (self.realowner.origin - self.origin);
 496         org2    = findbetterlocation (self.origin, 8);
 497
 498         te_knightspike(org2);
 499
 500         self.event_damage = func_null;
 501         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 502
 503         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 504         {
 505                 // check to see if this person is already tagged by me
 506                 entity tag = Seeker_Tagged_Info(self.realowner, other);
 507
 508                 if (tag != world)
 509                 {
 510                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 511                                 WaypointSprite_Kill(other.wps_tag_tracker);
 512
 513                         tag.tag_time = time;
 514                 }
 515                 else
 516                 {
 517                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 518                         e             = spawn();
 519                         e.cnt         = WEP_CVAR(seeker, missile_count);
 520                         e.classname   = "tag_tracker";
 521                         e.owner       = self.owner;
 522                         e.realowner   = self.realowner;
 523
 524                         if(WEP_CVAR(seeker, type) == 1)
 525                         {
 526                                 e.tag_target  = other;
 527                                 e.tag_time    = time;
 528                                 e.think       = Seeker_Tracker_Think;
 529                         }
 530                         else
 531                         {
 532                                 e.enemy     = other;
 533                                 e.think     = Seeker_Vollycontroller_Think;
 534                         }
 535
 536                         e.nextthink   = time;
 537                 }
 538
 539                 if(WEP_CVAR(seeker, type) == 1)
 540                 {
 541                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 542                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 543                 }
 544         }
 545
 546         remove(self);
 547         return;
 548 }
 549
 550 void Seeker_Fire_Tag()
 551 {
 552         entity missile;
 553         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, tag_ammo), autocvar_g_balance_seeker_reload_ammo);
 554
 555         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 556
 557         missile                 = spawn();
 558         missile.owner           = missile.realowner = self;
 559         missile.classname       = "seeker_tag";
 560         missile.bot_dodge       = TRUE;
 561         missile.bot_dodgerating = 50;
 562         missile.touch           = Seeker_Tag_Touch;
 563         missile.think           = SUB_Remove;
 564         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 565         missile.movetype        = MOVETYPE_FLY;
 566         missile.solid           = SOLID_BBOX;
 567
 568         missile.takedamage       = DAMAGE_YES;
 569         missile.event_damage     = Seeker_Tag_Damage;
 570         missile.health           = WEP_CVAR(seeker, tag_health);
 571         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 572
 573         setorigin (missile, w_shotorg);
 574         setsize (missile, '-2 -2 -2', '2 2 2');
 575
 576         missile.flags       = FL_PROJECTILE;
 577         //missile.missile_flags = MIF_..?;
 578
 579         missile.movetype    = MOVETYPE_FLY;
 580         WEP_SETUPPROJVELOCITY_NONE(missile, seeker, tag_);
 581         missile.angles = vectoangles (missile.velocity);
 582
 583         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 584
 585         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 586 }
 587
 588 // ============================
 589 // Begin: Genereal weapon functions
 590 // ============================
 591
 592 float w_seeker(float req)
 593 {
 594         float ammo_amount;
 595
 596         switch(req)
 597         {
 598                 case WR_AIM:
 599                 {
 600                         if (WEP_CVAR(seeker, type) == 1)
 601                                 if (Seeker_Tagged_Info(self, self.enemy) != world)
 602                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 603                                 else
 604                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 605                         else
 606                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 607                         return TRUE;
 608                 }
 609                 case WR_THINK:
 610                 {
 611                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 612                                 WEP_ACTION(self.weapon, WR_RELOAD);
 613
 614                         else if (self.BUTTON_ATCK)
 615                         {
 616                                 if (WEP_CVAR(seeker, type) == 1)
 617                                 {
 618                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 619                                         {
 620                                                 Seeker_Attack();
 621                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 622                                         }
 623                                 }
 624                                 else
 625                                 {
 626                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 627                                         {
 628                                                 Seeker_Fire_Tag();
 629                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 630                                         }
 631                                 }
 632                         }
 633
 634                         else if (self.BUTTON_ATCK2)
 635                         {
 636                                 if (WEP_CVAR(seeker, type) == 1)
 637                                 {
 638                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 639                                         {
 640                                                 Seeker_Fire_Tag();
 641                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 642                                         }
 643                                 }
 644                                 else
 645                                 {
 646                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 647                                         {
 648                                                 Seeker_Fire_Flac();
 649                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 650                                         }
 651                                 }
 652                         }
 653
 654                         return TRUE;
 655                 }
 656                 case WR_INIT:
 657                 {
 658                         precache_model ("models/weapons/g_seeker.md3");
 659                         precache_model ("models/weapons/v_seeker.md3");
 660                         precache_model ("models/weapons/h_seeker.iqm");
 661                         precache_sound ("weapons/tag_fire.wav");
 662                         precache_sound ("weapons/flac_fire.wav");
 663                         precache_sound ("weapons/seeker_fire.wav");
 664                         SEEKER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 665                         return TRUE;
 666                 }
 667                 case WR_SETUP:
 668                 {
 669                         self.current_ammo = ammo_rockets;
 670                         return TRUE;
 671                 }
 672                 case WR_CHECKAMMO1:
 673                 {
 674                         if (WEP_CVAR(seeker, type) == 1)
 675                         {
 676                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, missile_ammo);
 677                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 678                         }
 679                         else
 680                         {
 681                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 682                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 683                         }
 684                         return ammo_amount;
 685                 }
 686                 case WR_CHECKAMMO2:
 687                 {
 688                         if (WEP_CVAR(seeker, type) == 1)
 689                         {
 690                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 691                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 692                         }
 693                         else
 694                         {
 695                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, flac_ammo);
 696                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 697                         }
 698                         return ammo_amount;
 699                 }
 700                 case WR_CONFIG:
 701                 {
 702                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 703                         return TRUE;
 704                 }
 705                 case WR_RELOAD:
 706                 {
 707                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 708                         return TRUE;
 709                 }
 710                 case WR_SUICIDEMESSAGE:
 711                 {
 712                         return WEAPON_SEEKER_SUICIDE;
 713                 }
 714                 case WR_KILLMESSAGE:
 715                 {
 716                         if(w_deathtype & HITTYPE_SECONDARY)
 717                                 return WEAPON_SEEKER_MURDER_TAG;
 718                         else
 719                                 return WEAPON_SEEKER_MURDER_SPRAY;
 720                 }
 721         }
 722         return TRUE;
 723 }
 724 #endif
 725 #ifdef CSQC
 726 float w_seeker(float req)
 727 {
 728         switch(req)
 729         {
 730                 case WR_IMPACTEFFECT:
 731                 {
 732                         vector org2;
 733                         org2 = w_org + w_backoff * 6;
 734                         if(w_deathtype & HITTYPE_BOUNCE)
 735                         {
 736                                 if(w_deathtype & HITTYPE_SECONDARY)
 737                                 {
 738                                         if(!w_issilent)
 739                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 740                                 }
 741                                 else
 742                                 {
 743                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 744                                         if(!w_issilent)
 745                                         {
 746                                                 if (w_random<0.15)
 747                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 748                                                 else if (w_random<0.7)
 749                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 750                                                 else
 751                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 752                                         }
 753                                 }
 754                         }
 755                         else
 756                         {
 757                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 758                                 if(!w_issilent)
 759                                 {
 760                                         if (w_random<0.15)
 761                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 762                                         else if (w_random<0.7)
 763                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 764                                         else
 765                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 766                                 }
 767                         }
 768                         return TRUE;
 769                 }
 770                 case WR_INIT:
 771                 {
 772                         precache_sound("weapons/seekerexp1.wav");
 773                         precache_sound("weapons/seekerexp2.wav");
 774                         precache_sound("weapons/seekerexp3.wav");
 775                         precache_sound("weapons/tagexp1.wav");
 776                         precache_sound("weapons/tagexp2.wav");
 777                         precache_sound("weapons/tagexp3.wav");
 778                         precache_sound("weapons/tag_impact.wav");
 779                         return TRUE;
 780                 }
 781         }
 782
 783         return TRUE;
 784 }
 785 #endif
 786 #endif